New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcblk_algo_ecmwf.F90 in branches/2016/dev_r6711_SIMPLIF_6_aerobulk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_r6711_SIMPLIF_6_aerobulk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcblk_algo_ecmwf.F90 @ 6723

Last change on this file since 6723 was 6723, checked in by gm, 8 years ago

#1751 - branch SIMPLIF_6_aerobulk: add aerobulk package including NCAR, COARE and ECMWF bulk

File size: 20.3 KB
Line 
1MODULE sbcblk_algo_ecmwf
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_algo_ecmwf  ***
4   !! Computes turbulent components of surface fluxes
5   !!         according to the method in IFS of the ECMWF model
6   !!
7   !!   * bulk transfer coefficients C_D, C_E and C_H
8   !!   * air temp. and spec. hum. adjusted from zt (2m) to zu (10m) if needed
9   !!   * the effective bulk wind speed at 10m U_blk
10   !!   => all these are used in bulk formulas in sbcblk.F90
11   !!
12   !!    Using the bulk formulation/param. of IFS of ECMWF (cycle 31r2)
13   !!         based on IFS doc (avaible online on the ECMWF's website)
14   !!
15   !!
16   !!       Routine turb_ecmwf maintained and developed in AeroBulk
17   !!                     (http://aerobulk.sourceforge.net/)
18   !!
19   !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
20   !!----------------------------------------------------------------------
21   !!
22   !! History :  4.0  !  2016-06  (L.Brodeau) Original code
23   !!
24   !!----------------------------------------------------------------------
25   !!   turb_ecmwf  : computes the bulk turbulent transfer coefficients
26   !!                   adjusts t_air and q_air from zt to zu m
27   !!                   returns the effective bulk wind speed at 10m
28   !!----------------------------------------------------------------------
29   USE oce             ! ocean dynamics and tracers
30   USE dom_oce         ! ocean space and time domain
31   USE phycst          ! physical constants
32   USE iom             ! I/O manager library
33   USE lib_mpp         ! distribued memory computing library
34   USE wrk_nemo        ! work arrays
35   USE timing          ! Timing
36   USE in_out_manager  ! I/O manager
37   USE prtctl          ! Print control
38   USE sbcwave, ONLY   :  cdn_wave ! wave module
39#if defined key_lim3 || defined key_cice
40   USE sbc_ice         ! Surface boundary condition: ice fields
41#endif
42   USE lib_fortran     ! to use key_nosignedzero
43
44   USE sbc_oce         ! Surface boundary condition: ocean fields
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC :: TURB_ECMWF
50
51   !                   !! ECMWF own values for given constants, taken form IFS documentation...
52   REAL(wp), PARAMETER ::   charn0 = 0.018    ! Charnock constant (pretty high value here !!!
53   !                                          !    =>  Usually 0.011 for moderate winds)
54   REAL(wp), PARAMETER ::   zi0     = 1000.   ! scale height of the atmospheric boundary layer...1
55   REAL(wp), PARAMETER ::   Beta0    = 1.     ! gustiness parameter ( = 1.25 in COAREv3)
56   REAL(wp), PARAMETER ::   rctv0    = 0.608  ! constant to obtain virtual temperature...
57   REAL(wp), PARAMETER ::   Cp_dry = 1005.0   ! Specic heat of dry air, constant pressure      [J/K/kg]
58   REAL(wp), PARAMETER ::   Cp_vap = 1860.0   ! Specic heat of water vapor, constant pressure  [J/K/kg]
59   REAL(wp), PARAMETER ::   alpha_M = 0.11    ! For roughness length (smooth surface term)
60   REAL(wp), PARAMETER ::   alpha_H = 0.40    ! (Chapter 3, p.34, IFS doc Cy31r1)
61   REAL(wp), PARAMETER ::   alpha_Q = 0.62    !
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE TURB_ECMWF( zt, zu, sst, t_zt, ssq , q_zt , U_zu,   &
66      &                   Cd, Ch, Ce , t_zu, q_zu, U_blk )
67      !!----------------------------------------------------------------------------------
68      !!                      ***  ROUTINE  turb_ecmwf  ***
69      !!
70      !!            2015: L. Brodeau (brodeau@gmail.com)
71      !!
72      !! ** Purpose :   Computes turbulent transfert coefficients of surface
73      !!                fluxes according to IFS doc. (cycle 31)
74      !!                If relevant (zt /= zu), adjust temperature and humidity from height zt to zu
75      !!
76      !! ** Method : Monin Obukhov Similarity Theory
77      !!
78      !! INPUT :
79      !! -------
80      !!    *  zt   : height for temperature and spec. hum. of air            [m]
81      !!    *  zu   : height for wind speed (generally 10m)                   [m]
82      !!    *  U_zu : scalar wind speed at 10m                                [m/s]
83      !!    *  sst  : SST                                                     [K]
84      !!    *  t_zt : potential air temperature at zt                         [K]
85      !!    *  ssq  : specific humidity at saturation at SST                  [kg/kg]
86      !!    *  q_zt : specific humidity of air at zt                          [kg/kg]
87      !!
88      !!
89      !! OUTPUT :
90      !! --------
91      !!    *  Cd     : drag coefficient
92      !!    *  Ch     : sensible heat coefficient
93      !!    *  Ce     : evaporation coefficient
94      !!    *  t_zu   : pot. air temperature adjusted at wind height zu       [K]
95      !!    *  q_zu   : specific humidity of air        //                    [kg/kg]
96      !!    *  U_blk  : bulk wind at 10m                                      [m/s]
97      !!
98      !!
99      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
100      !!----------------------------------------------------------------------------------
101      REAL(wp), INTENT(in   )                     ::   zt       ! height for t_zt and q_zt                    [m]
102      REAL(wp), INTENT(in   )                     ::   zu       ! height for U_zu                             [m]
103      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   sst      ! sea surface temperature                [Kelvin]
104      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   t_zt     ! potential air temperature              [Kelvin]
105      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   ssq      ! sea surface specific humidity           [kg/kg]
106      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_zt     ! specific air humidity                   [kg/kg]
107      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   U_zu     ! relative wind module at zu                [m/s]
108      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cd       ! transfer coefficient for momentum         (tau)
109      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ch       ! transfer coefficient for sensible heat (Q_sens)
110      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ce       ! transfert coefficient for evaporation   (Q_lat)
111      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   t_zu     ! pot. air temp. adjusted at zu               [K]
112      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   q_zu     ! spec. humidity adjusted at zu           [kg/kg]
113      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   U_blk    ! bulk wind at 10m                          [m/s]
114      !
115      INTEGER :: j_itt
116      LOGICAL ::   l_zt_equal_zu = .FALSE.      ! if q and t are given at same height as U
117      INTEGER , PARAMETER ::   nb_itt = 4       ! number of itterations
118      !
119      REAL(wp), DIMENSION(:,:), POINTER  ::   u_star, t_star, q_star,   &
120         &  dt_zu, dq_zu,    &
121         &  znu_a,           & !: Nu_air, Viscosity of air
122         &  Linv,            & !: 1/L (inverse of Monin Obukhov length...
123         &  z0, z0t, z0q
124      REAL(wp), DIMENSION(:,:), POINTER ::   func_m, func_h
125      REAL(wp), DIMENSION(:,:), POINTER ::   ztmp0, ztmp1, ztmp2
126      !!----------------------------------------------------------------------------------
127      !
128      IF( nn_timing == 1 )   CALL timing_start('turb_ecmwf')
129      !
130      CALL wrk_alloc( jpi,jpj,   u_star, t_star, q_star, func_m, func_h, dt_zu, dq_zu, Linv )
131      CALL wrk_alloc( jpi,jpj,   znu_a, z0, z0t, z0q, ztmp0, ztmp1, ztmp2 )
132      !
133      ! Identical first gess as in COARE, with IFS parameter values though
134      !
135      l_zt_equal_zu = .FALSE.
136      IF( ABS(zu - zt) < 0.01 )   l_zt_equal_zu = .TRUE.    ! testing "zu == zt" is risky with double precision
137
138
139      !! First guess of temperature and humidity at height zu:
140      t_zu = MAX( t_zt , 0.0  )   ! who knows what's given on masked-continental regions...
141      q_zu = MAX( q_zt , 1.e-6)   !               "
142
143      !! Pot. temp. difference (and we don't want it to be 0!)
144      dt_zu = t_zu - sst   ;   dt_zu = SIGN( MAX(ABS(dt_zu),1.e-6), dt_zu )
145      dq_zu = q_zu - ssq   ;   dq_zu = SIGN( MAX(ABS(dq_zu),1.e-9), dq_zu )
146
147      znu_a = visc_air(t_zt) ! Air viscosity (m^2/s) at zt given from temperature in (K)
148
149      ztmp2 = 0.5 * 0.5  ! initial guess for wind gustiness contribution
150      U_blk = SQRT(U_zu*U_zu + ztmp2)
151
152      ! z0     = 0.0001
153      ztmp2   = 10000.     ! optimization: ztmp2 == 1/z0
154      ztmp0   = LOG(zu*ztmp2)
155      ztmp1   = LOG(10.*ztmp2)
156      u_star = 0.035*U_blk*ztmp1/ztmp0       ! (u* = 0.035*Un10)
157
158      z0     = charn0*u_star*u_star/grav + 0.11*znu_a/u_star
159      z0t    = 0.1*EXP(vkarmn/(0.00115/(vkarmn/ztmp1)))   !  WARNING: 1/z0t !
160
161      Cd     = (vkarmn/ztmp0)**2    ! first guess of Cd
162
163      ztmp0 = vkarmn*vkarmn/LOG(zt*z0t)/Cd
164
165      ztmp2 = Ri_bulk( zu, t_zu, dt_zu, q_zu, dq_zu, U_blk )   ! Ribu = Bulk Richardson number
166
167      !! First estimate of zeta_u, depending on the stability, ie sign of Ribu (ztmp2):
168      ztmp1 = 0.5 + SIGN( 0.5 , ztmp2 )
169      func_m = ztmp0*ztmp2 ! temporary array !!
170      !!             Ribu < 0                                 Ribu > 0   Beta = 1.25
171      func_h = (1.-ztmp1)*(func_m/(1.+ztmp2/(-zu/(zi0*0.004*Beta0**3)))) &  ! temporary array !!! func_h == zeta_u
172         &  +     ztmp1*(func_m*(1. + 27./9.*ztmp2/ztmp0))
173
174      !! First guess M-O stability dependent scaling params.(u*,t*,q*) to estimate z0 and z/L
175      ztmp0   =        vkarmn/(LOG(zu*z0t) - psi_h_ecmwf(func_h))
176
177      u_star = U_blk*vkarmn/(LOG(zu) - LOG(z0)  - psi_m_ecmwf(func_h))
178      t_star = dt_zu*ztmp0
179      q_star = dq_zu*ztmp0
180
181      ! What's need to be done if zt /= zu:
182      IF( .NOT. l_zt_equal_zu ) THEN
183         !
184         !! First update of values at zu (or zt for wind)
185         ztmp0 = psi_h_ecmwf(func_h) - psi_h_ecmwf(zt*func_h/zu)    ! zt*func_h/zu == zeta_t
186         ztmp1 = log(zt/zu) + ztmp0
187         t_zu = t_zt - t_star/vkarmn*ztmp1
188         q_zu = q_zt - q_star/vkarmn*ztmp1
189         q_zu = (0.5 + sign(0.5,q_zu))*q_zu !Makes it impossible to have negative humidity :
190
191         dt_zu = t_zu - sst  ; dt_zu = SIGN( MAX(ABS(dt_zu),1.E-6), dt_zu )
192         dq_zu = q_zu - ssq  ; dq_zu = SIGN( MAX(ABS(dq_zu),1.E-9), dq_zu )
193         !
194      ENDIF
195
196
197      !! => that was same first guess as in COARE...
198
199
200      !! First guess of inverse of Monin-Obukov length (1/L) :
201      ztmp0 = (1. + rctv0*q_zu)  ! the factor to apply to temp. to get virt. temp...
202      Linv  =  grav*vkarmn*(t_star*ztmp0 + rctv0*t_zu*q_star) / ( u_star*u_star * t_zu*ztmp0 )
203
204      !! Functions such as  u* = U_blk*vkarmn/func_m
205      ztmp1 = zu + z0
206      ztmp0 = ztmp1*Linv
207      func_m = LOG(ztmp1) -LOG(z0) - psi_m_ecmwf(ztmp0) + psi_m_ecmwf(z0*Linv)
208      func_h = LOG(ztmp1*z0t) - psi_h_ecmwf(ztmp0) + psi_h_ecmwf(1./z0t*Linv)
209
210
211      !! ITERATION BLOCK
212      !! ***************
213
214      DO j_itt = 1, nb_itt
215
216         !! Bulk Richardson Number at z=zu (Eq. 3.25)
217         ztmp0 = Ri_bulk(zu, t_zu, dt_zu, q_zu, dq_zu, U_blk)
218
219         !! New estimate of the inverse of the Monin-Obukhon length (Linv == zeta/zu) :
220         Linv = ztmp0*func_m*func_m/func_h / zu     ! From Eq. 3.23, Chap.3, p.33, IFS doc - Cy31r1
221
222         !! Update func_m with new Linv:
223         ztmp1 = zu + z0
224         func_m = LOG(ztmp1) -LOG(z0) - psi_m_ecmwf(ztmp1*Linv) + psi_m_ecmwf(z0*Linv)
225
226         !! Need to update roughness lengthes:
227         u_star = U_blk*vkarmn/func_m
228         ztmp2  = u_star*u_star
229         ztmp1  = znu_a/u_star
230         z0    = alpha_M*ztmp1 + charn0*ztmp2/grav
231         z0t    = alpha_H*ztmp1                              ! eq.3.26, Chap.3, p.34, IFS doc - Cy31r1
232         z0q    = alpha_Q*ztmp1
233
234         !! Update wind at 10m taking into acount convection-related wind gustiness:
235         ! Only true when unstable (L<0) => when ztmp0 < 0 => - !!!
236         ztmp2 = ztmp2 * (MAX(-zi0*Linv/vkarmn,0.))**(2./3.) ! => w*^2  (combining Eq. 3.8 and 3.18, hap.3, IFS doc - Cy31r1)
237         !! => equivalent using Beta=1 (gustiness parameter, 1.25 for COARE, also zi0=600 in COARE..)
238         U_blk = MAX(sqrt(U_zu*U_zu + ztmp2), 0.2)              ! eq.3.17, Chap.3, p.32, IFS doc - Cy31r1
239         ! => 0.2 prevents U_blk to be 0 in stable case when U_zu=0.
240
241
242         !! Need to update "theta" and "q" at zu in case they are given at different heights
243         !! as well the air-sea differences:
244         IF( .NOT. l_zt_equal_zu ) THEN
245
246            !! Arrays func_m and func_h are free for a while so using them as temporary arrays...
247            func_h = psi_h_ecmwf((zu+z0)*Linv) ! temporary array !!!
248            func_m = psi_h_ecmwf((zt+z0)*Linv) ! temporary array !!!
249
250            ztmp2  = psi_h_ecmwf(z0t*Linv)
251            ztmp0  = func_h - ztmp2
252            ztmp1  = vkarmn/(LOG(zu+z0) - LOG(z0t) - ztmp0)
253            t_star = dt_zu*ztmp1
254            ztmp2  = ztmp0 - func_m + ztmp2
255            ztmp1  = LOG(zt/zu) + ztmp2
256            t_zu   = t_zt - t_star/vkarmn*ztmp1
257
258            ztmp2  = psi_h_ecmwf(z0q*Linv)
259            ztmp0  = func_h - ztmp2
260            ztmp1  = vkarmn/(LOG(zu+z0) - LOG(z0q) - ztmp0)
261            q_star = dq_zu*ztmp1
262            ztmp2  = ztmp0 - func_m + ztmp2
263            ztmp1  = log(zt/zu) + ztmp2
264            q_zu   = q_zt - q_star/vkarmn*ztmp1
265
266            dt_zu = t_zu - sst ;  dt_zu = SIGN( MAX(ABS(dt_zu),1.E-6), dt_zu )
267            dq_zu = q_zu - ssq ;  dq_zu = SIGN( MAX(ABS(dq_zu),1.E-9), dq_zu )
268         END IF
269
270         !! Updating because of updated z0 and z0t and new Linv...
271         ztmp1 = zu + z0
272         ztmp0 = ztmp1*Linv
273         func_m = log(ztmp1) - LOG(z0) - psi_m_ecmwf(ztmp0) + psi_m_ecmwf(z0*Linv)
274         func_h = log(ztmp1) - LOG(z0t) - psi_h_ecmwf(ztmp0) + psi_h_ecmwf(z0t*Linv)
275
276      END DO
277
278      Cd = vkarmn*vkarmn/(func_m*func_m)
279      Ch = vkarmn*vkarmn/(func_m*func_h)
280      ztmp1 = log((zu + z0)/z0q) - psi_h_ecmwf((zu + z0)*Linv) + psi_h_ecmwf(z0q*Linv)   ! func_q
281      Ce = vkarmn*vkarmn/(func_m*ztmp1)
282
283      CALL wrk_dealloc( jpi,jpj,   u_star, t_star, q_star, func_m, func_h, dt_zu, dq_zu, Linv )
284      CALL wrk_dealloc( jpi,jpj,   znu_a, z0, z0t, z0q, ztmp0, ztmp1, ztmp2 )
285      !
286      IF( nn_timing == 1 )   CALL timing_stop('turb_ecmwf')
287      !
288   END SUBROUTINE TURB_ECMWF
289
290
291   FUNCTION psi_m_ecmwf( pzeta )
292      !!----------------------------------------------------------------------------------
293      !! Universal profile stability function for momentum
294      !!     ECMWF / as in IFS cy31r1 documentation, available online
295      !!     at ecmwf.int
296      !!
297      !! pzeta : stability paramenter, z/L where z is altitude measurement
298      !!         and L is M-O length
299      !!
300      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
301      !!----------------------------------------------------------------------------------
302      REAL(wp), DIMENSION(jpi,jpj) :: psi_m_ecmwf
303      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta
304      !
305      INTEGER  ::   ji, jj    ! dummy loop indices
306      REAL(wp) :: zzeta, zx, ztmp, psi_unst, psi_stab, stab
307      !!----------------------------------------------------------------------------------
308      !
309      DO jj = 1, jpj
310         DO ji = 1, jpi
311            !
312            zzeta = MIN( pzeta(ji,jj) , 5. ) !! Very stable conditions (L positif and big!):
313            !
314            ! Unstable (Paulson 1970):
315            !   eq.3.20, Chap.3, p.33, IFS doc - Cy31r1
316            zx = SQRT(ABS(1. - 16.*zzeta))
317            ztmp = 1. + SQRT(zx)
318            ztmp = ztmp*ztmp
319            psi_unst = LOG( 0.125*ztmp*(1. + zx) )   &
320               &       -2.*ATAN( SQRT(zx) ) + 0.5*rpi
321            !
322            ! Unstable:
323            ! eq.3.22, Chap.3, p.33, IFS doc - Cy31r1
324            psi_stab = -2./3.*(zzeta - 5./0.35)*EXP(-0.35*zzeta) &
325               &       - zzeta - 2./3.*5./0.35
326            !
327            ! Combining:
328            stab = 0.5 + SIGN(0.5, zzeta) ! zzeta > 0 => stab = 1
329            !
330            psi_m_ecmwf(ji,jj) = (1. - stab) * psi_unst & ! (zzeta < 0) Unstable
331               &                +      stab  * psi_stab   ! (zzeta > 0) Stable
332            !
333         END DO
334      END DO
335      !
336   END FUNCTION psi_m_ecmwf
337
338   
339   FUNCTION psi_h_ecmwf( pzeta )
340      !!----------------------------------------------------------------------------------
341      !! Universal profile stability function for temperature and humidity
342      !!     ECMWF / as in IFS cy31r1 documentation, available online
343      !!     at ecmwf.int
344      !!
345      !! pzeta : stability paramenter, z/L where z is altitude measurement
346      !!         and L is M-O length
347      !!
348      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
349      !!----------------------------------------------------------------------------------
350      REAL(wp), DIMENSION(jpi,jpj) :: psi_h_ecmwf
351      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta
352      !
353      INTEGER  ::   ji, jj     ! dummy loop indices
354      REAL(wp) ::  zzeta, zx, psi_unst, psi_stab, stab
355      !!----------------------------------------------------------------------------------
356      !
357      DO jj = 1, jpj
358         DO ji = 1, jpi
359            !
360            zzeta = MIN(pzeta(ji,jj) , 5.)   ! Very stable conditions (L positif and big!):
361            !
362            zx  = ABS(1. - 16.*zzeta)**.25        ! this is actually (1/phi_m)**2  !!!
363            !                                     ! eq.3.19, Chap.3, p.33, IFS doc - Cy31r1
364            ! Unstable (Paulson 1970) :
365            psi_unst = 2.*LOG(0.5*(1. + zx*zx))   ! eq.3.20, Chap.3, p.33, IFS doc - Cy31r1
366            !
367            ! Stable:
368            psi_stab = -2./3.*(zzeta - 5./0.35)*EXP(-0.35*zzeta) & ! eq.3.22, Chap.3, p.33, IFS doc - Cy31r1
369               &       - ABS(1. + 2./3.*zzeta)**1.5 - 2./3.*5./0.35 + 1. 
370            ! LB: added ABS() to avoid NaN values when unstable, which contaminates the unstable solution...
371            !
372            stab = 0.5 + SIGN(0.5, zzeta) ! zzeta > 0 => stab = 1
373            !
374            !
375            psi_h_ecmwf(ji,jj) = (1. - stab) * psi_unst &   ! (zzeta < 0) Unstable
376               &                +    stab    * psi_stab     ! (zzeta > 0) Stable
377            !
378         END DO
379      END DO
380      !
381   END FUNCTION psi_h_ecmwf
382
383
384   FUNCTION Ri_bulk( pz, ptz, pdt, pqz, pdq, pub )
385      !!----------------------------------------------------------------------------------
386      !! Bulk Richardson number (Eq. 3.25 IFS doc)
387      !!
388      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
389      !!----------------------------------------------------------------------------------
390      REAL(wp), DIMENSION(jpi,jpj) ::   Ri_bulk   !
391      !
392      REAL(wp)                    , INTENT(in) ::   pz    ! height above the sea        [m]
393      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   ptz   ! air temperature at pz m     [K]
394      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pdt   ! ptz - sst                   [K]
395      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pqz   ! air temperature at pz m [kg/kg]
396      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pdq   ! pqz - ssq               [kg/kg]
397      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pub   ! bulk wind speed           [m/s]
398      !!----------------------------------------------------------------------------------
399      !
400      Ri_bulk =   grav*pz/(pub*pub)                                          &
401         &      * ( pdt/(ptz - 0.5_wp*(pdt + grav*pz/(Cp_dry+Cp_vap*pqz)))   &
402         &          + rctv0*pdq )
403      !
404   END FUNCTION Ri_bulk
405
406
407   FUNCTION visc_air(ptak)
408      !!----------------------------------------------------------------------------------
409      !! Air kinetic viscosity (m^2/s) given from temperature in degrees...
410      !!
411      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
412      !!----------------------------------------------------------------------------------
413      REAL(wp), DIMENSION(jpi,jpj)             ::   visc_air   !
414      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   ptak       ! air temperature in (K)
415      !
416      INTEGER  ::   ji, jj      ! dummy loop indices
417      REAL(wp) ::   ztc, ztc2   ! local scalar
418      !!----------------------------------------------------------------------------------
419      !
420      DO jj = 1, jpj
421         DO ji = 1, jpi
422            ztc  = ptak(ji,jj) - rt0   ! air temp, in deg. C
423            ztc2 = ztc*ztc
424            visc_air(ji,jj) = 1.326e-5*(1. + 6.542E-3*ztc + 8.301e-6*ztc2 - 4.84e-9*ztc2*ztc)
425         END DO
426      END DO
427      !
428   END FUNCTION visc_air
429
430   !!======================================================================
431END MODULE sbcblk_algo_ecmwf
Note: See TracBrowser for help on using the repository browser.