New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

limsbc.F90 in branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

Context Navigation

source: branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 8142

Last change on this file since 8142 was 8142, checked in by vancop, 7 years ago
Melt pond interfaces practically operational
Property svn:keywords set to `Id`
File size: 20.6 KB

Rev	Line
[888]	1	MODULE limsbc
	2	!!======================================================================
	3	!! * MODULE limsbc *
	4	!! computation of the flux at the sea ice/ocean interface
	5	!!======================================================================
[2528]	6	!! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code
	7	!! 3.0 ! 2008-03 (C. Tallandier) surface module
	8	!! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling
	9	!! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
	10	!! ! + simplification of the ice-ocean stress calculation
[3625]	11	!! 3.4 ! 2011-02 (G. Madec) dynamical allocation
[4161]	12	!! - ! 2012 (D. Iovino) salt flux change
	13	!! - ! 2012-05 (C. Rousset) add penetration solar flux
[3625]	14	!! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass
[888]	15	!!----------------------------------------------------------------------
	16	#if defined key_lim3
	17	!!----------------------------------------------------------------------
	18	!! 'key_lim3' LIM 3.0 sea-ice model
	19	!!----------------------------------------------------------------------
[2715]	20	!! lim_sbc_alloc : allocate the limsbc arrays
	21	!! lim_sbc_init : initialisation
	22	!! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface
	23	!! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface
[888]	24	!!----------------------------------------------------------------------
	25	USE par_oce ! ocean parameters
[4299]	26	USE phycst ! physical constants
[888]	27	USE dom_oce ! ocean domain
[4299]	28	USE ice ! LIM sea-ice variables
[888]	29	USE sbc_ice ! Surface boundary condition: sea-ice fields
	30	USE sbc_oce ! Surface boundary condition: ocean fields
[4299]	31	USE sbccpl
[5407]	32	USE oce , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass
[2528]	33	USE albedo ! albedo parameters
[4299]	34	USE lbclnk ! ocean lateral boundary condition - MPP exchanges
[2715]	35	USE lib_mpp ! MPP library
[3294]	36	USE wrk_nemo ! work arrays
[4299]	37	USE in_out_manager ! I/O manager
	38	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
[5123]	39	USE traqsr ! add penetration of solar flux in the calculation of heat budget
[4688]	40	USE iom
	41	USE domvvl ! Variable volume
[5123]	42	USE limctl
[5167]	43	USE limcons
[888]	44
	45	IMPLICIT NONE
	46	PRIVATE
	47
[5123]	48	PUBLIC lim_sbc_init ! called by sbc_lim_init
[2715]	49	PUBLIC lim_sbc_flx ! called by sbc_ice_lim
	50	PUBLIC lim_sbc_tau ! called by sbc_ice_lim
[888]	51
[2715]	52	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2]
	53	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s]
[1526]	54
[888]	55	!! * Substitutions
	56	# include "vectopt_loop_substitute.h90"
[4614]	57	# include "domzgr_substitute.h90"
[888]	58	!!----------------------------------------------------------------------
[4161]	59	!! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
[1146]	60	!! $Id$
[2528]	61	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
[888]	62	!!----------------------------------------------------------------------
	63	CONTAINS
	64
[2715]	65	INTEGER FUNCTION lim_sbc_alloc()
	66	!!-------------------------------------------------------------------
	67	!! * ROUTINE lim_sbc_alloc *
	68	!!-------------------------------------------------------------------
[6515]	69	ALLOCATE( utau_oce(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc )
[2715]	70	!
	71	IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc )
	72	IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
	73	END FUNCTION lim_sbc_alloc
	74
	75
[918]	76	SUBROUTINE lim_sbc_flx( kt )
	77	!!-------------------------------------------------------------------
	78	!! * ROUTINE lim_sbc_flx *
	79	!!
	80	!! ** Purpose : Update the surface ocean boundary condition for heat
	81	!! salt and mass over areas where sea-ice is non-zero
	82	!!
	83	!! ** Action : - computes the heat and freshwater/salt fluxes
	84	!! at the ice-ocean interface.
	85	!! - Update the ocean sbc
	86	!!
[1037]	87	!! ** Outputs : - qsr : sea heat flux: solar
	88	!! - qns : sea heat flux: non solar
	89	!! - emp : freshwater budget: volume flux
[3625]	90	!! - sfx : salt flux
[1037]	91	!! - fr_i : ice fraction
	92	!! - tn_ice : sea-ice surface temperature
[6316]	93	!! - alb_ice : sea-ice albedo (recomputed only for coupled mode)
[888]	94	!!
	95	!! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
	96	!! Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
[4990]	97	!! These refs are now obsolete since everything has been revised
[5123]	98	!! The ref should be Rousset et al., 2015
[888]	99	!!---------------------------------------------------------------------
[5407]	100	INTEGER, INTENT(in) :: kt ! number of iteration
	101	INTEGER :: ji, jj, jl, jk ! dummy loop indices
	102	REAL(wp) :: zqmass ! Heat flux associated with mass exchange ice->ocean (W.m-2)
	103	REAL(wp) :: zqsr ! New solar flux received by the ocean
[4990]	104	!
[6316]	105	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_cs, zalb_os ! 3D workspace
	106	REAL(wp), POINTER, DIMENSION(:,:) :: zalb ! 2D workspace
[888]	107	!!---------------------------------------------------------------------
[921]	108
[6515]	109	! --- case we bypass ice thermodynamics --- !
	110	IF( .NOT. ln_limthd ) THEN ! we suppose ice is impermeable => ocean is isolated from atmosphere
	111	hfx_in (:,:) = pfrld(:,:) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
	112	hfx_out (:,:) = pfrld(:,:) * qns_oce(:,:) + qemp_oce(:,:)
	113	ftr_ice (:,:,:) = 0._wp
	114	emp_ice (:,:) = 0._wp
	115	qemp_ice (:,:) = 0._wp
	116	qevap_ice(:,:,:) = 0._wp
	117	ENDIF
	118
[6399]	119	! albedo output
[6316]	120	CALL wrk_alloc( jpi,jpj, zalb )
	121
	122	zalb(:,:) = 0._wp
[6763]	123	WHERE ( at_i_b <= epsi06 ) ; zalb(:,:) = 0.066_wp
	124	ELSEWHERE ; zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b
[6316]	125	END WHERE
[8142]	126	IF( iom_use('alb_ice' ) ) CALL iom_put( "alb_ice" , zalb(:,:) ) ! ice albedo output
[6316]	127
[6763]	128	zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + 0.066_wp * ( 1._wp - at_i_b )
[8142]	129	IF( iom_use('albedo' ) ) CALL iom_put( "albedo" , zalb(:,:) ) ! surface albedo output
[6316]	130
	131	CALL wrk_dealloc( jpi,jpj, zalb )
	132	!
	133
[888]	134	DO jj = 1, jpj
	135	DO ji = 1, jpi
	136
[4688]	137	!------------------------------------------!
	138	! heat flux at the ocean surface !
	139	!------------------------------------------!
[5407]	140	! Solar heat flux reaching the ocean = zqsr (W.m-2)
[4688]	141	!---------------------------------------------------
[5407]	142	zqsr = qsr_tot(ji,jj)
	143	DO jl = 1, jpl
	144	zqsr = zqsr - a_i_b(ji,jj,jl) * ( qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) )
	145	END DO
[888]	146
[4688]	147	! Total heat flux reaching the ocean = hfx_out (W.m-2)
	148	!---------------------------------------------------
[5407]	149	zqmass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC)
	150	hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr
[4161]	151
[6399]	152	! Add the residual from heat diffusion equation and sublimation (W.m-2)
	153	!----------------------------------------------------------------------
	154	hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) + &
	155	& ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) )
[5146]	156
[4688]	157	! New qsr and qns used to compute the oceanic heat flux at the next time step
[6399]	158	!----------------------------------------------------------------------------
[5407]	159	qsr(ji,jj) = zqsr
	160	qns(ji,jj) = hfx_out(ji,jj) - zqsr
[888]	161
[4688]	162	!------------------------------------------!
	163	! mass flux at the ocean surface !
	164	!------------------------------------------!
[888]	165	! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
	166	! -------------------------------------------------------------------------------------
	167	! The idea of this approach is that the system that we consider is the ICE-OCEAN system
	168	! Thus FW flux = External ( E-P+snow melt)
	169	! Salt flux = Exchanges in the ice-ocean system then converted into FW
	170	! Associated to Ice formation AND Ice melting
	171	! Even if i see Ice melting as a FW and SALT flux
	172	!
[4688]	173	! mass flux from ice/ocean
[4765]	174	wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) &
[6515]	175	+ wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj)
[2528]	176
[8142]	177	IF ( ln_pnd_fw ) &
	178	wfx_ice(ji,jj) = wfx_ice(ji,jj) + wfx_pnd(ji,jj)
	179
[4688]	180	! mass flux at the ocean/ice interface
[6399]	181	fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) ) ! F/M mass flux save at least for biogeochemical model
	182	emp(ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange)
[888]	183	END DO
	184	END DO
	185
[3625]	186	!------------------------------------------!
	187	! salt flux at the ocean surface !
	188	!------------------------------------------!
[4765]	189	sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:) &
[6515]	190	& + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:) + sfx_sub(:,:) + sfx_lam(:,:)
[3625]	191
[4688]	192	!-------------------------------------------------------------!
	193	! mass of snow and ice per unit area for embedded sea-ice !
	194	!-------------------------------------------------------------!
	195	IF( nn_ice_embd /= 0 ) THEN
	196	! save mass from the previous ice time step
	197	snwice_mass_b(:,:) = snwice_mass(:,:)
	198	! new mass per unit area
[5123]	199	snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) )
[4688]	200	! time evolution of snow+ice mass
[3625]	201	snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice
	202	ENDIF
[921]	203
[888]	204	!-----------------------------------------------!
	205	! Storing the transmitted variables !
	206	!-----------------------------------------------!
[1037]	207	fr_i (:,:) = at_i(:,:) ! Sea-ice fraction
[888]	208	tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature
	209
[5407]	210	!------------------------------------------------------------------------!
	211	! Snow/ice albedo (only if sent to coupler, useless in forced mode) !
	212	!------------------------------------------------------------------------!
	213	CALL wrk_alloc( jpi, jpj, jpl, zalb_cs, zalb_os )
[8106]	214	CALL albedo_ice( t_su, ht_i, ht_s, a_ip_frac, h_ip, ln_pnd_rad, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
[8099]	215
[5407]	216	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
	217	CALL wrk_dealloc( jpi, jpj, jpl, zalb_cs, zalb_os )
[4990]	218
[5167]	219	! conservation test
[6994]	220	IF( ln_limdiachk ) CALL lim_cons_final( 'limsbc' )
[4688]	221
[5167]	222	! control prints
[6994]	223	IF( ln_limctl ) CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' )
	224	IF( ln_ctl ) CALL lim_prt3D( 'limsbc' )
[5167]	225
[918]	226	END SUBROUTINE lim_sbc_flx
[888]	227
[2528]	228
	229	SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
	230	!!-------------------------------------------------------------------
	231	!! * ROUTINE lim_sbc_tau *
	232	!!
	233	!! ** Purpose : Update the ocean surface stresses due to the ice
	234	!!
	235	!! ** Action : * at each ice time step (every nn_fsbc time step):
	236	!! - compute the modulus of ice-ocean relative velocity
	237	!! (rhoCd) at T-point (C-grid) or I-point (B-grid)
	238	!! tmod_io = rhoco * \| U_ice-U_oce \|
	239	!! - update the modulus of stress at ocean surface
	240	!! taum = frld * taum + (1-frld) * tmod_io * \| U_ice-U_oce \|
	241	!! * at each ocean time step (every kt):
	242	!! compute linearized ice-ocean stresses as
	243	!! Utau = tmod_io * \| U_ice - pU_oce \|
	244	!! using instantaneous current ocean velocity (usually before)
	245	!!
	246	!! NB: - ice-ocean rotation angle no more allowed
	247	!! - here we make an approximation: taum is only computed every ice time step
	248	!! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
	249	!! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
	250	!!
	251	!! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
	252	!! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
	253	!!---------------------------------------------------------------------
	254	INTEGER , INTENT(in) :: kt ! ocean time-step index
	255	REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents
	256	!!
	257	INTEGER :: ji, jj ! dummy loop indices
	258	REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar
[6989]	259	REAL(wp) :: zat_v, zvtau_ice, zv_t, zrhoco ! - -
[2715]	260	!!---------------------------------------------------------------------
[6989]	261	zrhoco = rau0 * rn_cio
[2715]	262	!
[2528]	263	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step)
	264	DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point)
	265	DO ji = fs_2, fs_jpim1
	266	! ! 2*(U_ice-U_oce) at T-point
	267	zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)
	268	zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1)
	269	! ! \|U_ice-U_oce\|^2
	270	zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t )
	271	! ! update the ocean stress modulus
[6989]	272	taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt
	273	tmod_io(ji,jj) = zrhoco * SQRT( zmodt ) ! rhoco * \|U_ice-U_oce\| at T-point
[2528]	274	END DO
	275	END DO
[6515]	276	CALL lbc_lnk_multi( taum, 'T', 1., tmod_io, 'T', 1. )
[2528]	277	!
	278	utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step
	279	vtau_oce(:,:) = vtau(:,:)
	280	!
	281	ENDIF
[2715]	282	!
	283	! !== every ocean time-step ==!
	284	!
[2528]	285	DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle
	286	DO ji = fs_2, fs_jpim1 ! Vect. Opt.
	287	zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points
	288	zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp
	289	! ! linearized quadratic drag formulation
	290	zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
	291	zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
	292	! ! stresses at the ocean surface
	293	utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
	294	vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
	295	END DO
	296	END DO
[6515]	297	CALL lbc_lnk_multi( utau, 'U', -1., vtau, 'V', -1. ) ! lateral boundary condition
[2528]	298	!
	299	!
	300	END SUBROUTINE lim_sbc_tau
	301
[2715]	302
	303	SUBROUTINE lim_sbc_init
	304	!!-------------------------------------------------------------------
	305	!! * ROUTINE lim_sbc_init *
	306	!!
	307	!! ** Purpose : Preparation of the file ice_evolu for the output of
	308	!! the temporal evolution of key variables
	309	!!
	310	!! ** input : Namelist namicedia
	311	!!-------------------------------------------------------------------
[4299]	312	INTEGER :: ji, jj, jk ! dummy loop indices
[3625]	313	REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar
[2715]	314	IF(lwp) WRITE(numout,*)
	315	IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
	316	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ '
	317
	318	! ! allocate lim_sbc array
	319	IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
	320	!
[4205]	321	IF( .NOT. ln_rstart ) THEN
	322	! ! embedded sea ice
	323	IF( nn_ice_embd /= 0 ) THEN ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass
[5123]	324	snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) )
[4205]	325	snwice_mass_b(:,:) = snwice_mass(:,:)
	326	ELSE
	327	snwice_mass (:,:) = 0.0_wp ! no mass exchanges
	328	snwice_mass_b(:,:) = 0.0_wp ! no mass exchanges
	329	ENDIF
	330	IF( nn_ice_embd == 2 ) THEN ! full embedment (case 2) deplete the initial ssh below sea-ice area
	331	sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0
	332	sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0
[4302]	333	#if defined key_vvl
	334	! key_vvl necessary? clem: yes for compilation purpose
[4301]	335	DO jk = 1,jpkm1 ! adjust initial vertical scale factors
	336	fse3t_n(:,:,jk) = e3t_0(:,:,jk)( 1._wp + sshn(:,:)tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
	337	fse3t_b(:,:,jk) = e3t_0(:,:,jk)( 1._wp + sshb(:,:)tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
	338	ENDDO
	339	fse3t_a(:,:,:) = fse3t_b(:,:,:)
	340	! Reconstruction of all vertical scale factors at now and before time
	341	! steps
	342	! =============================================================================
	343	! Horizontal scale factor interpolations
	344	! --------------------------------------
	345	CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' )
	346	CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' )
	347	CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' )
	348	CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' )
	349	CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' )
	350	! Vertical scale factor interpolations
	351	! ------------------------------------
	352	CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W' )
	353	CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' )
	354	CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' )
	355	CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' )
	356	CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' )
	357	! t- and w- points depth
	358	! ----------------------
	359	fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1)
	360	fsdepw_n(:,:,1) = 0.0_wp
	361	fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:)
	362	DO jk = 2, jpk
	363	fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk)
	364	fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1)
	365	fsde3w_n(:,:,jk) = fsdept_n(:,:,jk ) - sshn (:,:)
	366	END DO
	367	#endif
[4205]	368	ENDIF
	369	ENDIF ! .NOT. ln_rstart
[2715]	370	!
[4161]	371
[2715]	372	END SUBROUTINE lim_sbc_init
	373
[888]	374	#else
	375	!!----------------------------------------------------------------------
	376	!! Default option : Dummy module NO LIM 3.0 sea-ice model
	377	!!----------------------------------------------------------------------
	378	CONTAINS
	379	SUBROUTINE lim_sbc ! Dummy routine
	380	END SUBROUTINE lim_sbc
	381	#endif
	382
	383	!!======================================================================
	384	END MODULE limsbc

Note: See TracBrowser for help on using the repository browser.

Download in other formats: