New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 8142

Last change on this file since 8142 was 6994, checked in by clem, 8 years ago

clean online sea ice diagnostics
  • Property svn:keywords set to Id
File size: 34.4 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! LIM: sea-ice variables
25   USE sbc_oce        ! Surface boundary condition: ocean fields
26   USE sbc_ice        ! Surface boundary condition: ice fields
27   USE thd_ice        ! LIM thermodynamic sea-ice variables
28   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
29   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
30   USE limthd_da      ! LIM: thermodynamics, lateral melting
31   USE limthd_sal     ! LIM: thermodynamics, ice salinity
32   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
33   USE limthd_lac     ! LIM-3 lateral accretion
34   USE limitd_th      ! remapping thickness distribution
35   USE limtab         ! LIM: 1D <==> 2D transformation
36   USE limvar         ! LIM: sea-ice variables
37   USE lbclnk         ! lateral boundary condition - MPP links
38   USE lib_mpp        ! MPP library
39   USE wrk_nemo       ! work arrays
40   USE in_out_manager ! I/O manager
41   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
42   USE timing         ! Timing
43   USE limcons        ! conservation tests
44   USE limctl
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   lim_thd         ! called by limstp module
50   PUBLIC   lim_thd_init    ! called by sbc_lim_init
51
52   !! * Substitutions
53#  include "domzgr_substitute.h90"
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE lim_thd( kt )
63      !!-------------------------------------------------------------------
64      !!                ***  ROUTINE lim_thd  ***       
65      !! 
66      !! ** Purpose : This routine manages ice thermodynamics
67      !!         
68      !! ** Action : - Initialisation of some variables
69      !!             - Some preliminary computation (oceanic heat flux
70      !!               at the ice base, snow acc.,heat budget of the leads)
71      !!             - selection of the icy points and put them in an array
72      !!             - call lim_thd_dif  for vertical heat diffusion
73      !!             - call lim_thd_dh   for vertical ice growth and melt
74      !!             - call lim_thd_ent  for enthalpy remapping
75      !!             - call lim_thd_sal  for ice desalination
76      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
77      !!             - back to the geographic grid
78      !!     
79      !! ** References :
80      !!---------------------------------------------------------------------
81      INTEGER, INTENT(in) :: kt    ! number of iteration
82      !!
83      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
84      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
85      INTEGER  :: ii, ij           ! temporary dummy loop index
86      REAL(wp) :: zfric_u, zqld, zqfr
87      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
88      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
89      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
90      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
91      !
92      !!-------------------------------------------------------------------
93
94      IF( nn_timing == 1 )  CALL timing_start('limthd')
95
96      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
97
98      IF( kt == nit000 .AND. lwp ) THEN
99         WRITE(numout,*)'' 
100         WRITE(numout,*)' lim_thd '
101         WRITE(numout,*)' ~~~~~~~~'
102      ENDIF
103     
104      ! conservation test
105      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
106
107      CALL lim_var_glo2eqv
108
109      !---------------------------------------------!
110      ! computation of friction velocity at T points
111      !---------------------------------------------!
112      IF( ln_limdyn ) THEN
113         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
114         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
115         DO jj = 2, jpjm1 
116            DO ji = fs_2, fs_jpim1
117               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
118                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
119                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
120            END DO
121         END DO
122      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
123         DO jj = 2, jpjm1
124            DO ji = fs_2, fs_jpim1
125               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
126                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
127                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
128            END DO
129         END DO
130      ENDIF
131      CALL lbc_lnk( zfric, 'T',  1. )
132      !
133      !----------------------------------!
134      ! Initialization and units change
135      !----------------------------------!
136      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
137
138      ! Change the units of heat content; from J/m2 to J/m3
139      DO jl = 1, jpl
140         DO jk = 1, nlay_i
141            DO jj = 1, jpj
142               DO ji = 1, jpi
143                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
144                  !Energy of melting q(S,T) [J.m-3]
145                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
146               END DO
147            END DO
148         END DO
149         DO jk = 1, nlay_s
150            DO jj = 1, jpj
151               DO ji = 1, jpi
152                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
153                  !Energy of melting q(S,T) [J.m-3]
154                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
155               END DO
156            END DO
157         END DO
158      END DO
159
160      !--------------------------------------------------------------------!
161      ! Partial computation of forcing for the thermodynamic sea ice model
162      !--------------------------------------------------------------------!
163      DO jj = 1, jpj
164         DO ji = 1, jpi
165            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
166            !
167            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
168            !           !  practically no "direct lateral ablation"
169            !           
170            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
171            !           !  temperature and turbulent mixing (McPhee, 1992)
172            !
173            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
174            zqld =  tmask(ji,jj,1) * rdt_ice *  &
175               &    ( pfrld(ji,jj) * qsr_oce(ji,jj) * frq_m(ji,jj) + pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
176
177            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
178            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
179
180            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
181            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
182            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
183            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
184            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
185            !                        the freezing point, so that we do not have SST < T_freeze
186            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
187
188            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
189            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
190
191            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
192            IF( zqld > 0._wp ) THEN
193               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
194               qlead(ji,jj) = 0._wp
195            ELSE
196               fhld (ji,jj) = 0._wp
197            ENDIF
198            !
199            ! Net heat flux on top of the ice-ocean [W.m-2]
200            ! ---------------------------------------------
201            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
202         END DO
203      END DO
204     
205      ! In case we bypass open-water ice formation
206      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
207      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
208      IF( .NOT. ln_limdH )  hfx_in(:,:) = pfrld(:,:) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
209      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
210
211      ! ---------------------------------------------------------------------
212      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
213      ! ---------------------------------------------------------------------
214      !     First  step here              :  non solar + precip - qlead - qturb
215      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
216      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
217      DO jj = 1, jpj
218         DO ji = 1, jpi
219            hfx_out(ji,jj) =   pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
220               &             - qlead(ji,jj) * r1_rdtice                         &  ! heat flux taken from the ocean where there is open water ice formation
221               &             - at_i(ji,jj) * fhtur(ji,jj)                       &  ! heat flux taken by turbulence
222               &             - at_i(ji,jj) *  fhld(ji,jj)                          ! heat flux taken during bottom growth/melt
223                                                                                   !    (fhld should be 0 while bott growth)
224         END DO
225      END DO
226         
227      !------------------------------------------------------------------------------!
228      ! Thermodynamic computation (only on grid points covered by ice)
229      !------------------------------------------------------------------------------!
230      DO jl = 1, jpl      !loop over ice categories
231
232         ! select ice covered grid points
233         nbpb = 0
234         DO jj = 1, jpj
235            DO ji = 1, jpi
236               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
237                  nbpb      = nbpb  + 1
238                  npb(nbpb) = (jj - 1) * jpi + ji
239               ENDIF
240            END DO
241         END DO
242
243         ! debug point to follow
244         jiindex_1d = 0
245         IF( ln_limctl ) THEN
246            DO ji = mi0(iiceprt), mi1(iiceprt)
247               DO jj = mj0(jiceprt), mj1(jiceprt)
248                  jiindex_1d = (jj - 1) * jpi + ji
249                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
250               END DO
251            END DO
252         ENDIF
253
254         IF( lk_mpp )         CALL mpp_ini_ice( nbpb , numout )
255
256         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
257            !                                                               
258            s_i_new   (:) = 0._wp ; dh_s_tot (:) = 0._wp                     ! --- some init --- !
259            dh_i_surf (:) = 0._wp ; dh_i_bott(:) = 0._wp
260            dh_snowice(:) = 0._wp ; dh_i_sub (:) = 0._wp
261
262                              CALL lim_thd_1d2d( nbpb, jl, 1 )               ! --- Move to 1D arrays --- !
263            !
264            IF( ln_limdH )    CALL lim_thd_dif( 1, nbpb )                    ! --- Ice/Snow Temperature profile --- !
265            !
266            IF( ln_limdH )    CALL lim_thd_dh( 1, nbpb )                     ! --- Ice/Snow thickness --- !   
267            !
268            IF( ln_limdH )    CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) )  ! --- Ice enthalpy remapping --- !
269            !
270                              CALL lim_thd_sal( 1, nbpb )                    ! --- Ice salinity --- !   
271            !
272                              CALL lim_thd_temp( 1, nbpb )                   ! --- temperature update --- !
273            !
274            IF( ln_limdH ) THEN
275               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
276                              CALL lim_thd_lam( 1, nbpb )                    ! --- extra lateral melting if monocat --- !
277               END IF
278            END IF
279            !
280                              CALL lim_thd_1d2d( nbpb, jl, 2 )               ! --- Move to 2D arrays --- !
281            !
282            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
283         ENDIF
284         !
285      END DO !jl
286
287      IF( ln_limdA)           CALL lim_thd_da                                ! --- lateral melting --- !
288
289      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
290      DO jl = 1, jpl
291         DO jk = 1, nlay_i
292            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
293         END DO
294         DO jk = 1, nlay_s
295            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
296         END DO
297      END DO
298 
299      ! Change thickness to volume
300      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
301      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
302      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
303
304      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
305      DO jl  = 1, jpl
306         DO jj = 1, jpj
307            DO ji = 1, jpi
308               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
309               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
310            END DO
311         END DO
312      END DO
313
314      CALL lim_var_zapsmall
315
316      ! control checks
317      IF( ln_limctl )    CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
318      !
319      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
320
321      !------------------------------------------------!
322      !  Transport ice between thickness categories
323      !------------------------------------------------!
324      ! Given thermodynamic growth rates, transport ice between thickness categories.
325      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
326
327      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
328
329      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
330
331      !------------------------------------------------!
332      !  Add frazil ice growing in leads
333      !------------------------------------------------!
334      IF( ln_limdiachk ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
335
336      IF( ln_limdO )     CALL lim_thd_lac
337     
338      ! conservation test
339      IF( ln_limdiachk ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
340
341      ! Control print
342      IF( ln_ctl )       CALL lim_prt3D( 'limthd' )
343      !
344      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
345      !
346      IF( nn_timing == 1 )  CALL timing_stop('limthd')
347
348   END SUBROUTINE lim_thd 
349
350 
351   SUBROUTINE lim_thd_temp( kideb, kiut )
352      !!-----------------------------------------------------------------------
353      !!                   ***  ROUTINE lim_thd_temp ***
354      !!                 
355      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
356      !!
357      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
358      !!-------------------------------------------------------------------
359      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
360      !!
361      INTEGER  ::   ji, jk   ! dummy loop indices
362      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
363      !!-------------------------------------------------------------------
364      ! Recover ice temperature
365      DO jk = 1, nlay_i
366         DO ji = kideb, kiut
367            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
368            ! Conversion q(S,T) -> T (second order equation)
369            zaaa          =  cpic
370            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
371            zccc          =  lfus * ( ztmelts - rt0 )
372            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
373            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
374           
375            ! mask temperature
376            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
377            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
378         END DO
379      END DO
380
381   END SUBROUTINE lim_thd_temp
382
383   SUBROUTINE lim_thd_lam( kideb, kiut )
384      !!-----------------------------------------------------------------------
385      !!                   ***  ROUTINE lim_thd_lam ***
386      !!                 
387      !! ** Purpose :   Lateral melting in case monocategory
388      !!                          ( dA = A/2h dh )
389      !!-----------------------------------------------------------------------
390      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
391      INTEGER             ::   ji                 ! dummy loop indices
392      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
393      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
394      REAL(wp)            ::   zvi, zvs           ! ice/snow volumes
395
396      DO ji = kideb, kiut
397         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
398         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
399            zvi          = a_i_1d(ji) * ht_i_1d(ji)
400            zvs          = a_i_1d(ji) * ht_s_1d(ji)
401            ! lateral melting = concentration change
402            zhi_bef     = ht_i_1d(ji) - zdh_mel
403            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
404            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
405            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
406            ! adjust thickness
407            ht_i_1d(ji) = zvi / a_i_1d(ji)           
408            ht_s_1d(ji) = zvs / a_i_1d(ji)           
409            ! retrieve total concentration
410            at_i_1d(ji) = a_i_1d(ji)
411         END IF
412      END DO
413     
414   END SUBROUTINE lim_thd_lam
415
416   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
417      !!-----------------------------------------------------------------------
418      !!                   ***  ROUTINE lim_thd_1d2d ***
419      !!                 
420      !! ** Purpose :   move arrays from 1d to 2d and the reverse
421      !!-----------------------------------------------------------------------
422      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D
423                                        ! 2= from 1D to 2D
424      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
425      INTEGER, INTENT(in) ::   jl       ! ice cat
426      INTEGER             ::   jk       ! dummy loop indices
427
428      SELECT CASE( kn )
429
430      CASE( 1 )
431
432         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
433         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
434         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
435         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
436         
437         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
438         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
439         DO jk = 1, nlay_s
440            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
441            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
442         END DO
443         DO jk = 1, nlay_i
444            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
445            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
446            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
447         END DO
448         
449         CALL tab_2d_1d( nbpb, qprec_ice_1d(1:nbpb), qprec_ice(:,:) , jpi, jpj, npb(1:nbpb) )
450         CALL tab_2d_1d( nbpb, qevap_ice_1d(1:nbpb), qevap_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
451         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
452         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
453         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
454         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
455         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
456         CALL tab_2d_1d( nbpb, evap_ice_1d (1:nbpb), evap_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
457         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
458         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
459         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
460         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
461         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
462         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
463         
464         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
465         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
466         
467         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
468         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
469         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
470         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
471         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
472         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
473         
474         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
475         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
476         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
477         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
478         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
479         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
480         CALL tab_2d_1d( nbpb, sfx_sub_1d (1:nbpb), sfx_sub         , jpi, jpj,npb(1:nbpb) )
481 
482         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
483         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
484         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
485         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
486         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
487         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
488         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
489         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
490         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
491         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
492         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
493         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
494         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
495
496      CASE( 2 )
497
498         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
499         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
500         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
501         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
502         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
503         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
504         DO jk = 1, nlay_s
505            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
506            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
507         END DO
508         DO jk = 1, nlay_i
509            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
510            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
511            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
512         END DO
513         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
514         
515         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
516         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
517         
518         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
519         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
520         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
521         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
522         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
523         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
524         
525         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
526         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
527         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
528         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
529         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
530         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
531         CALL tab_1d_2d( nbpb, sfx_sub       , npb, sfx_sub_1d(1:nbpb)   , jpi, jpj )       
532 
533         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
534         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
535         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
536         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
537         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
538         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
539         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
540         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
541         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
542         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
543         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
544         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
545         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
546         !
547         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
548         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
549         !         
550      END SELECT
551
552   END SUBROUTINE lim_thd_1d2d
553
554
555   SUBROUTINE lim_thd_init
556      !!-----------------------------------------------------------------------
557      !!                   ***  ROUTINE lim_thd_init ***
558      !!                 
559      !! ** Purpose :   Physical constants and parameters linked to the ice
560      !!              thermodynamics
561      !!
562      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
563      !!              parameter values called at the first timestep (nit000)
564      !!
565      !! ** input   :   Namelist namicether
566      !!-------------------------------------------------------------------
567      INTEGER  ::   ios                 ! Local integer output status for namelist read
568      NAMELIST/namicethd/ rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon,ln_it_qnsice,nn_monocat,  &
569         &                ln_limdH, rn_betas,                                                          &
570         &                ln_limdA, rn_beta, rn_dmin,                                                  &
571         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin
572      !!-------------------------------------------------------------------
573      !
574      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
575      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
576901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
577
578      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
579      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
580902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
581      IF(lwm) WRITE ( numoni, namicethd )
582      !
583      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
584         nn_monocat = 0
585         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
586      ENDIF
587      !
588      IF(lwp) THEN                          ! control print
589         WRITE(numout,*)
590         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
591         WRITE(numout,*) '~~~~~~~~~~~~~'
592         WRITE(numout,*)'   -- limthd_dif --'
593         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
594         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
595         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
596         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
597         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
598         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
599         WRITE(numout,*)'   -- limthd_dh --'
600         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
601         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
602         WRITE(numout,*)'   -- limthd_da --'
603         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
604         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
605         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
606         WRITE(numout,*)'   -- limthd_lac --'
607         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
608         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
609         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
610         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
611         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
612         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
613         WRITE(numout,*)'   -- limitd_th --'
614         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
615         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
616      ENDIF
617      !
618   END SUBROUTINE lim_thd_init
619
620#else
621   !!----------------------------------------------------------------------
622   !!   Default option         Dummy module          NO  LIM3 sea-ice model
623   !!----------------------------------------------------------------------
624#endif
625
626   !!======================================================================
627END MODULE limthd
Note: See TracBrowser for help on using the repository browser.