| 1 | MODULE albedo |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE albedo *** |
|---|
| 4 | !! Ocean forcing: bulk thermohaline forcing of the ocean (or ice) |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : 8.0 ! 2001-04 (LIM 1.0) |
|---|
| 7 | !! NEMO 1.0 ! 2003-07 (C. Ethe, G. Madec) Optimization (old name:shine) |
|---|
| 8 | !! - ! 2004-11 (C. Talandier) add albedo_init |
|---|
| 9 | !! - ! 2006-06 (M. Vancoppenolle) LIM 3.0 |
|---|
| 10 | !! - ! 2006-08 (G. Madec) cleaning for surface module |
|---|
| 11 | !! 3.6 ! 2016-01 (C. Rousset) new parameterization for sea ice albedo |
|---|
| 12 | !! x.x ! 2017-05 (M. Vancoppenolle, O. Lecomte) Melt ponds |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! albedo_ice : albedo for ice (clear and overcast skies) |
|---|
| 17 | !! albedo_oce : albedo for ocean (clear and overcast skies) |
|---|
| 18 | !! albedo_init : initialisation of albedo computation |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE phycst ! physical constants |
|---|
| 21 | USE in_out_manager ! I/O manager |
|---|
| 22 | USE lib_mpp ! MPP library |
|---|
| 23 | USE wrk_nemo ! work arrays |
|---|
| 24 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 25 | |
|---|
| 26 | IMPLICIT NONE |
|---|
| 27 | PRIVATE |
|---|
| 28 | |
|---|
| 29 | PUBLIC albedo_ice ! routine called sbcice_lim.F90 |
|---|
| 30 | PUBLIC albedo_oce ! routine called by ??? |
|---|
| 31 | |
|---|
| 32 | INTEGER :: albd_init = 0 !: control flag for initialization |
|---|
| 33 | |
|---|
| 34 | REAL(wp) :: rmue = 0.40 ! cosine of local solar altitude |
|---|
| 35 | REAL(wp) :: ralb_oce = 0.066 ! ocean or lead albedo (Pegau and Paulson, Ann. Glac. 2001) |
|---|
| 36 | REAL(wp) :: c1 = 0.05 ! snow thickness (only for nn_ice_alb=0) |
|---|
| 37 | REAL(wp) :: c2 = 0.10 ! " " |
|---|
| 38 | REAL(wp) :: rcloud = 0.06 ! cloud effect on albedo (only-for nn_ice_alb=0) |
|---|
| 39 | |
|---|
| 40 | ! !!* namelist namsbc_alb |
|---|
| 41 | INTEGER :: nn_ice_alb |
|---|
| 42 | REAL(wp) :: rn_alb_sdry, rn_alb_smlt, rn_alb_idry, rn_alb_imlt, rn_alb_dpnd |
|---|
| 43 | |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 46 | !! $Id$ |
|---|
| 47 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | CONTAINS |
|---|
| 50 | |
|---|
| 51 | SUBROUTINE albedo_ice( pt_ice, ph_ice, ph_snw, pafrac_pnd, ph_pnd, ld_pnd, pa_ice_cs, pa_ice_os ) |
|---|
| 52 | !!---------------------------------------------------------------------- |
|---|
| 53 | !! *** ROUTINE albedo_ice *** |
|---|
| 54 | !! |
|---|
| 55 | !! ** Purpose : Computation of the albedo of the snow/ice system |
|---|
| 56 | !! |
|---|
| 57 | !! ** Method : Two schemes are available (from namelist parameter nn_ice_alb) |
|---|
| 58 | !! 0: the scheme is that of Shine & Henderson-Sellers (JGR 1985) for clear-skies |
|---|
| 59 | !! 1: the scheme is "home made" (for cloudy skies) and based on Brandt et al. (J. Climate 2005) |
|---|
| 60 | !! and Grenfell & Perovich (JGR 2004) |
|---|
| 61 | !! 2: fractional surface-based formulation of scheme 1 (NEW) |
|---|
| 62 | !! Description of scheme 1: |
|---|
| 63 | !! 1) Albedo dependency on ice thickness follows the findings from Brandt et al (2005) |
|---|
| 64 | !! which are an update of Allison et al. (JGR 1993) ; Brandt et al. 1999 |
|---|
| 65 | !! 0-5cm : linear function of ice thickness |
|---|
| 66 | !! 5-150cm: log function of ice thickness |
|---|
| 67 | !! > 150cm: constant |
|---|
| 68 | !! 2) Albedo dependency on snow thickness follows the findings from Grenfell & Perovich (2004) |
|---|
| 69 | !! i.e. it increases as -EXP(-snw_thick/0.02) during freezing and -EXP(-snw_thick/0.03) during melting |
|---|
| 70 | !! 3) Albedo dependency on clouds is speculated from measurements of Grenfell and Perovich (2004) |
|---|
| 71 | !! i.e. cloudy-clear albedo depend on cloudy albedo following a 2d order polynomial law |
|---|
| 72 | !! 4) The needed 4 parameters are: dry and melting snow, freezing ice and bare puddled ice |
|---|
| 73 | !! |
|---|
| 74 | !! ** Note : The parameterization from Shine & Henderson-Sellers presents several misconstructions: |
|---|
| 75 | !! 1) ice albedo when ice thick. tends to 0 is different than ocean albedo |
|---|
| 76 | !! 2) for small ice thick. covered with some snow (<3cm?), albedo is larger |
|---|
| 77 | !! under melting conditions than under freezing conditions |
|---|
| 78 | !! 3) the evolution of ice albedo as a function of ice thickness shows |
|---|
| 79 | !! 3 sharp inflexion points (at 5cm, 100cm and 150cm) that look highly unrealistic |
|---|
| 80 | !! |
|---|
| 81 | !! References : Shine & Henderson-Sellers 1985, JGR, 90(D1), 2243-2250. |
|---|
| 82 | !! Brandt et al. 2005, J. Climate, vol 18 |
|---|
| 83 | !! Grenfell & Perovich 2004, JGR, vol 109 |
|---|
| 84 | !! |
|---|
| 85 | !!---------------------------------------------------------------------- |
|---|
| 86 | !! |
|---|
| 87 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: pt_ice ! ice surface temperature (Kelvin) |
|---|
| 88 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_ice ! sea-ice thickness |
|---|
| 89 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_snw ! snow depth |
|---|
| 90 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: pafrac_pnd ! melt pond relative fraction (per unit ice area) |
|---|
| 91 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_pnd ! melt pond depth |
|---|
| 92 | LOGICAL , INTENT(in ) :: ld_pnd ! melt ponds radiatively active or not |
|---|
| 93 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: pa_ice_cs ! albedo of ice under clear sky |
|---|
| 94 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: pa_ice_os ! albedo of ice under overcast sky |
|---|
| 95 | !! |
|---|
| 96 | INTEGER :: ji, jj, jl ! dummy loop indices |
|---|
| 97 | INTEGER :: ijpl ! number of ice categories (3rd dim of ice input arrays) |
|---|
| 98 | REAL(wp) :: ralb_im, ralb_sf, ralb_sm, ralb_if, ralb_dp |
|---|
| 99 | REAL(wp) :: zswitch, z1_c1, z1_c2 |
|---|
| 100 | REAL(wp) :: zhref_pnd |
|---|
| 101 | REAL(wp) :: zalb_sm, zalb_sf, zalb_st ! albedo of snow melting, freezing, total |
|---|
| 102 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb, zalb_it ! intermediate variable & albedo of ice (snow free) |
|---|
| 103 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_pnd ! ponded sea ice albedo |
|---|
| 104 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_ice ! bare sea ice albedo |
|---|
| 105 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_snw ! snow-covered sea ice albedo |
|---|
| 106 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zafrac_snw ! relative snow fraction |
|---|
| 107 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zafrac_ice ! relative ice fraction |
|---|
| 108 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zafrac_pnd ! relative ice fraction (effective) |
|---|
| 109 | !! |
|---|
| 110 | !!--------------------------------------------------------------------- |
|---|
| 111 | |
|---|
| 112 | WRITE(numout,*) ' albedo_ice ' |
|---|
| 113 | WRITE(numout,*) ' ld_pnd : ', ld_pnd |
|---|
| 114 | WRITE(numout,*) ' nn_ice_alb : ', nn_ice_alb |
|---|
| 115 | |
|---|
| 116 | ijpl = SIZE( pt_ice, 3 ) ! number of ice categories |
|---|
| 117 | |
|---|
| 118 | CALL wrk_alloc( jpi,jpj,ijpl, zalb, zalb_it ) |
|---|
| 119 | CALL wrk_alloc( jpi,jpj,ijpl, zalb_pnd, zalb_ice, zalb_snw ) |
|---|
| 120 | CALL wrk_alloc( jpi,jpj,ijpl, zalb_pnd, zafrac_snw, zafrac_ice, zafrac_pnd ) |
|---|
| 121 | |
|---|
| 122 | IF( albd_init == 0 ) CALL albedo_init ! initialization |
|---|
| 123 | |
|---|
| 124 | ralb_sf = rn_alb_sdry ! dry snow |
|---|
| 125 | ralb_sm = rn_alb_smlt ! melting snow |
|---|
| 126 | ralb_if = rn_alb_idry ! bare frozen ice |
|---|
| 127 | ralb_im = rn_alb_imlt ! bare puddled ice (assumes implicit contribution of melt ponds) |
|---|
| 128 | ralb_dp = rn_alb_dpnd ! deep pond albedo |
|---|
| 129 | |
|---|
| 130 | !----------------------------------------------------- |
|---|
| 131 | ! Snow-free albedo (no ice thickness dependence yet) |
|---|
| 132 | !----------------------------------------------------- |
|---|
| 133 | ! |
|---|
| 134 | ! Part common to nn_ice_alb = 0, 1, 2 |
|---|
| 135 | ! |
|---|
| 136 | |
|---|
| 137 | zalb = ralb_if |
|---|
| 138 | IF ( .NOT. ld_pnd ) THEN !--- No melt ponds OR radiatively inactive melt ponds |
|---|
| 139 | |
|---|
| 140 | ! Bare ice albedo is prescribed, with implicit assumption on pond fraction and depth |
|---|
| 141 | WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice ) ; zalb = ralb_im ; END WHERE |
|---|
| 142 | ! !!! MV I think we could replace rt0_ice by rt0 and get rid of rt0 |
|---|
| 143 | |
|---|
| 144 | ENDIF |
|---|
| 145 | |
|---|
| 146 | SELECT CASE ( nn_ice_alb ) |
|---|
| 147 | |
|---|
| 148 | !------------------------------------------ |
|---|
| 149 | ! Shine and Henderson-Sellers (1985) |
|---|
| 150 | !------------------------------------------ |
|---|
| 151 | ! NB: This parameterization is based on clear sky values |
|---|
| 152 | |
|---|
| 153 | CASE( 0 ) |
|---|
| 154 | |
|---|
| 155 | ! Thickness-dependent bare ice albedo |
|---|
| 156 | WHERE ( 1.5 < ph_ice ) ; zalb_it = zalb |
|---|
| 157 | ELSE WHERE( 1.0 < ph_ice .AND. ph_ice <= 1.5 ) ; zalb_it = 0.472 + 2.0 * ( zalb - 0.472 ) * ( ph_ice - 1.0 ) |
|---|
| 158 | ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.0 ) ; zalb_it = 0.2467 + 0.7049 * ph_ice & |
|---|
| 159 | & - 0.8608 * ph_ice * ph_ice & |
|---|
| 160 | & + 0.3812 * ph_ice * ph_ice * ph_ice |
|---|
| 161 | ELSE WHERE ; zalb_it = 0.1 + 3.6 * ph_ice |
|---|
| 162 | END WHERE |
|---|
| 163 | |
|---|
| 164 | IF ( ld_pnd ) THEN |
|---|
| 165 | ! Depth-dependent ponded ice albedo |
|---|
| 166 | zhref_pnd = 0.05 ! Characteristic length scale for thickness dependence of ponded ice albedo, Lecomte et al (2015) |
|---|
| 167 | zalb_pnd = ralb_dp - ( ralb_dp - zalb_it ) * EXP( - ph_pnd / zhref_pnd ) |
|---|
| 168 | |
|---|
| 169 | ! Snow-free ice albedo is a function of pond fraction |
|---|
| 170 | WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice ) ; zalb_it = zalb_it * ( 1. - pafrac_pnd ) + zalb_pnd * pafrac_pnd ; END WHERE |
|---|
| 171 | ENDIF |
|---|
| 172 | |
|---|
| 173 | ! Note that this way of coding things means that the thickness |
|---|
| 174 | ! dependence of bare ice albedo is also altering the ponded ice albedo |
|---|
| 175 | ! I'm not sure that this is valid, but at least, this maintains |
|---|
| 176 | ! consistency with previous formulation (see below) |
|---|
| 177 | |
|---|
| 178 | DO jl = 1, ijpl |
|---|
| 179 | DO jj = 1, jpj |
|---|
| 180 | DO ji = 1, jpi |
|---|
| 181 | ! Freezing snow |
|---|
| 182 | ! no effect of underlying ice layer IF snow thickness > c1. Albedo does not depend on snow thick if > c2 |
|---|
| 183 | ! ! freezing snow |
|---|
| 184 | zswitch = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ( ph_snw(ji,jj,jl) - c1 ) ) ) |
|---|
| 185 | zalb_sf = ( 1._wp - zswitch ) * ( zalb_it(ji,jj,jl) & |
|---|
| 186 | & + ph_snw(ji,jj,jl) * ( ralb_sf - zalb_it(ji,jj,jl) ) / c1 ) & |
|---|
| 187 | & + zswitch * ralb_sf |
|---|
| 188 | |
|---|
| 189 | ! Melting snow |
|---|
| 190 | ! no effect of underlying ice layer. Albedo does not depend on snow thick IF > c2 |
|---|
| 191 | zswitch = MAX( 0._wp , SIGN( 1._wp , ph_snw(ji,jj,jl) - c2 ) ) |
|---|
| 192 | zalb_sm = ( 1._wp - zswitch ) * ( ralb_im + ph_snw(ji,jj,jl) * ( ralb_sm - ralb_im ) / c2 ) & |
|---|
| 193 | & + zswitch * ralb_sm |
|---|
| 194 | |
|---|
| 195 | ! Snow albedo |
|---|
| 196 | zswitch = MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) ) |
|---|
| 197 | zalb_st = zswitch * zalb_sm + ( 1._wp - zswitch ) * zalb_sf |
|---|
| 198 | |
|---|
| 199 | ! Surface albedo |
|---|
| 200 | zswitch = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) ) |
|---|
| 201 | pa_ice_cs(ji,jj,jl) = zswitch * zalb_st + ( 1._wp - zswitch ) * zalb_it(ji,jj,jl) |
|---|
| 202 | |
|---|
| 203 | END DO |
|---|
| 204 | END DO |
|---|
| 205 | END DO |
|---|
| 206 | |
|---|
| 207 | pa_ice_os(:,:,:) = pa_ice_cs(:,:,:) + rcloud ! Oberhuber correction for overcast sky |
|---|
| 208 | |
|---|
| 209 | !------------------------------------------ |
|---|
| 210 | ! New parameterization (2016) |
|---|
| 211 | !------------------------------------------ |
|---|
| 212 | ! NB: This parameterization is based on overcast skies values |
|---|
| 213 | |
|---|
| 214 | CASE( 1 ) |
|---|
| 215 | |
|---|
| 216 | ! ! Reference (overcast sky) values |
|---|
| 217 | ! ralb_sf = 0.85 ! dry snow |
|---|
| 218 | ! ralb_sm = 0.75 ! melting snow |
|---|
| 219 | ! ralb_if = 0.60 ! bare frozen ice |
|---|
| 220 | ! ralb_dp = 0.36 ! ponded-ice overcast albedo (Lecomte et al, 2015) |
|---|
| 221 | ! ! early melt pnds 0.27, late melt ponds 0.14 Grenfell & Perovich |
|---|
| 222 | ! Perovich et al 2002 (Sheba) => the only dataset for which all types of ice/snow were retrieved |
|---|
| 223 | ! ralb_sf = 0.85 ! dry snow |
|---|
| 224 | ! ralb_sm = 0.72 ! melting snow |
|---|
| 225 | ! ralb_if = 0.65 ! bare frozen ice |
|---|
| 226 | ! Brandt et al 2005 (East Antarctica) |
|---|
| 227 | ! ralb_sf = 0.87 ! dry snow |
|---|
| 228 | ! ralb_sm = 0.82 ! melting snow |
|---|
| 229 | ! ralb_if = 0.54 ! bare frozen ice |
|---|
| 230 | ! |
|---|
| 231 | ! Computation of snow-free ice albedo |
|---|
| 232 | z1_c1 = 1. / ( LOG(1.5) - LOG(0.05) ) |
|---|
| 233 | z1_c2 = 1. / 0.05 |
|---|
| 234 | |
|---|
| 235 | ! Accounting for the ice-thickness dependency |
|---|
| 236 | WHERE ( 1.5 < ph_ice ) ; zalb_it = zalb |
|---|
| 237 | ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.5 ) ; zalb_it = zalb + ( 0.18 - zalb ) * z1_c1 * & |
|---|
| 238 | & ( LOG(1.5) - LOG(ph_ice) ) |
|---|
| 239 | ELSE WHERE ; zalb_it = ralb_oce + ( 0.18 - ralb_oce ) * z1_c2 * ph_ice |
|---|
| 240 | END WHERE |
|---|
| 241 | |
|---|
| 242 | IF ( ld_pnd ) THEN |
|---|
| 243 | ! Depth-dependent ponded ice albedo |
|---|
| 244 | zhref_pnd = 0.05 ! Characteristic length scale for thickness dependence of ponded ice albedo, Lecomte et al (2015) |
|---|
| 245 | zalb_pnd = ralb_dp - ( ralb_dp - zalb_it ) * EXP( - ph_pnd / zhref_pnd ) |
|---|
| 246 | |
|---|
| 247 | ! Snow-free ice albedo is weighted mean of ponded ice and bare ice contributions |
|---|
| 248 | WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice ) ; zalb_it = zalb_it * ( 1. - pafrac_pnd ) + zalb_pnd * pafrac_pnd ; END WHERE |
|---|
| 249 | ENDIF |
|---|
| 250 | |
|---|
| 251 | z1_c1 = 1. / 0.02 |
|---|
| 252 | z1_c2 = 1. / 0.03 |
|---|
| 253 | |
|---|
| 254 | ! Overcast sky surface albedo (accounting for snow, ice melt ponds) |
|---|
| 255 | DO jl = 1, ijpl |
|---|
| 256 | DO jj = 1, jpj |
|---|
| 257 | DO ji = 1, jpi |
|---|
| 258 | |
|---|
| 259 | ! Snow depth dependence of snow albedo |
|---|
| 260 | zalb_sf = ralb_sf - ( ralb_sf - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c1 ); |
|---|
| 261 | zalb_sm = ralb_sm - ( ralb_sm - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c2 ); |
|---|
| 262 | |
|---|
| 263 | ! Snow albedo (MV I guess we could use rt0 instead of rt0_snow) |
|---|
| 264 | zswitch = MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) ) |
|---|
| 265 | zalb_st = zswitch * zalb_sm + ( 1._wp - zswitch ) * zalb_sf |
|---|
| 266 | |
|---|
| 267 | ! Surface albedo |
|---|
| 268 | zswitch = MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) ) |
|---|
| 269 | pa_ice_os(ji,jj,jl) = ( 1._wp - zswitch ) * zalb_st + zswitch * zalb_it(ji,jj,jl) |
|---|
| 270 | |
|---|
| 271 | END DO |
|---|
| 272 | END DO |
|---|
| 273 | END DO |
|---|
| 274 | |
|---|
| 275 | ! Clear sky surface albedo |
|---|
| 276 | pa_ice_cs = pa_ice_os - ( - 0.1010 * pa_ice_os * pa_ice_os + 0.1933 * pa_ice_os - 0.0148 ); |
|---|
| 277 | |
|---|
| 278 | !--------------------------------------------------- |
|---|
| 279 | ! Fractional surface-based parameterization (2017) |
|---|
| 280 | !--------------------------------------------------- |
|---|
| 281 | CASE( 2 ) |
|---|
| 282 | |
|---|
| 283 | ! MV: I propose this formulation that is more elegant, and more easy to expand towards |
|---|
| 284 | ! varying pond and snow fraction. |
|---|
| 285 | ! Formulation 1 has issues to handle ponds and snow together that |
|---|
| 286 | ! can't easily be fixed. This one handles it better, I believe. |
|---|
| 287 | |
|---|
| 288 | !----------------------------------------- |
|---|
| 289 | ! Snow, bare ice and ponded ice fractions |
|---|
| 290 | !----------------------------------------- |
|---|
| 291 | ! Specific fractions (zafrac) refer to relative area covered by snow within each ice category |
|---|
| 292 | |
|---|
| 293 | !--- Effective pond fraction (for now, we prevent melt ponds and snow at the same time) |
|---|
| 294 | zafrac_pnd = 0._wp |
|---|
| 295 | IF ( ld_pnd ) THEN |
|---|
| 296 | WHERE( ph_snw == 0._wp ) ; zafrac_pnd = pafrac_pnd ; END WHERE ! Snow fully "shades" melt ponds |
|---|
| 297 | ENDIF |
|---|
| 298 | |
|---|
| 299 | !--- Specific snow fraction (for now, prescribed) |
|---|
| 300 | WHERE ( ph_snw > 0._wp ) ; zafrac_snw = 1. |
|---|
| 301 | ELSE WHERE ; zafrac_snw = 0. |
|---|
| 302 | END WHERE |
|---|
| 303 | |
|---|
| 304 | !--- Specific ice fraction |
|---|
| 305 | zafrac_ice = 1. - zafrac_snw - zafrac_pnd |
|---|
| 306 | |
|---|
| 307 | !-------------------------------------------------- |
|---|
| 308 | ! Snow-covered, pond-covered, and bare ice albedos |
|---|
| 309 | !-------------------------------------------------- |
|---|
| 310 | ! Bare ice albedo |
|---|
| 311 | z1_c1 = 1. / ( LOG(1.5) - LOG(0.05) ) |
|---|
| 312 | z1_c2 = 1. / 0.05 |
|---|
| 313 | WHERE ( 1.5 < ph_ice ) ; zalb_ice = zalb |
|---|
| 314 | ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.5 ) ; zalb_ice = zalb + ( 0.18 - zalb ) * z1_c1 * & |
|---|
| 315 | & ( LOG(1.5) - LOG(ph_ice) ) |
|---|
| 316 | ELSE WHERE ; zalb_ice = ralb_oce + ( 0.18 - ralb_oce ) * z1_c2 * ph_ice |
|---|
| 317 | END WHERE |
|---|
| 318 | |
|---|
| 319 | ! Snow-covered ice albedo (freezing, melting cases) |
|---|
| 320 | z1_c1 = 1. / 0.02 |
|---|
| 321 | z1_c2 = 1. / 0.03 |
|---|
| 322 | |
|---|
| 323 | WHERE( pt_ice < rt0_snow ) ; zalb_snw = ralb_sf - ( ralb_sf - zalb_ice ) * EXP( - ph_snw * z1_c1 ); |
|---|
| 324 | ELSE WHERE ; zalb_snw = ralb_sm - ( ralb_sm - zalb_ice ) * EXP( - ph_snw * z1_c2 ); |
|---|
| 325 | END WHERE |
|---|
| 326 | |
|---|
| 327 | ! Depth-dependent ponded ice albedo |
|---|
| 328 | zhref_pnd = 0.05 ! Characteristic length scale for thickness dependence of ponded ice albedo, Lecomte et al (2015) |
|---|
| 329 | zalb_pnd = ralb_dp - ( ralb_dp - zalb_ice ) * EXP( - ph_pnd / zhref_pnd ) |
|---|
| 330 | |
|---|
| 331 | ! Surface albedo is weighted mean of snow, ponds and bare ice contributions |
|---|
| 332 | pa_ice_os = zafrac_snw * zalb_snw + zafrac_pnd * zalb_pnd + zafrac_ice * zalb_ice |
|---|
| 333 | |
|---|
| 334 | pa_ice_cs = pa_ice_os - ( - 0.1010 * pa_ice_os * pa_ice_os + 0.1933 * pa_ice_os - 0.0148 ) |
|---|
| 335 | |
|---|
| 336 | END SELECT |
|---|
| 337 | |
|---|
| 338 | CALL wrk_dealloc( jpi,jpj,ijpl, zalb, zalb_it ) |
|---|
| 339 | CALL wrk_dealloc( jpi,jpj,ijpl, zalb_pnd, zalb_ice, zalb_snw ) |
|---|
| 340 | CALL wrk_dealloc( jpi,jpj,ijpl, zalb_pnd, zafrac_snw, zafrac_ice, zafrac_pnd ) |
|---|
| 341 | ! |
|---|
| 342 | END SUBROUTINE albedo_ice |
|---|
| 343 | |
|---|
| 344 | |
|---|
| 345 | SUBROUTINE albedo_oce( pa_oce_os , pa_oce_cs ) |
|---|
| 346 | !!---------------------------------------------------------------------- |
|---|
| 347 | !! *** ROUTINE albedo_oce *** |
|---|
| 348 | !! |
|---|
| 349 | !! ** Purpose : Computation of the albedo of the ocean |
|---|
| 350 | !!---------------------------------------------------------------------- |
|---|
| 351 | REAL(wp), DIMENSION(:,:), INTENT(out) :: pa_oce_os ! albedo of ocean under overcast sky |
|---|
| 352 | REAL(wp), DIMENSION(:,:), INTENT(out) :: pa_oce_cs ! albedo of ocean under clear sky |
|---|
| 353 | !! |
|---|
| 354 | REAL(wp) :: zcoef |
|---|
| 355 | !!---------------------------------------------------------------------- |
|---|
| 356 | ! |
|---|
| 357 | zcoef = 0.05 / ( 1.1 * rmue**1.4 + 0.15 ) ! Parameterization of Briegled and Ramanathan, 1982 |
|---|
| 358 | pa_oce_cs(:,:) = zcoef |
|---|
| 359 | pa_oce_os(:,:) = 0.06 ! Parameterization of Kondratyev, 1969 and Payne, 1972 |
|---|
| 360 | ! |
|---|
| 361 | END SUBROUTINE albedo_oce |
|---|
| 362 | |
|---|
| 363 | |
|---|
| 364 | SUBROUTINE albedo_init |
|---|
| 365 | !!---------------------------------------------------------------------- |
|---|
| 366 | !! *** ROUTINE albedo_init *** |
|---|
| 367 | !! |
|---|
| 368 | !! ** Purpose : initializations for the albedo parameters |
|---|
| 369 | !! |
|---|
| 370 | !! ** Method : Read the namelist namsbc_alb |
|---|
| 371 | !!---------------------------------------------------------------------- |
|---|
| 372 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 373 | NAMELIST/namsbc_alb/ nn_ice_alb, rn_alb_sdry, rn_alb_smlt, rn_alb_idry , rn_alb_imlt, rn_alb_dpnd |
|---|
| 374 | !!---------------------------------------------------------------------- |
|---|
| 375 | ! |
|---|
| 376 | albd_init = 1 ! indicate that the initialization has been done |
|---|
| 377 | ! |
|---|
| 378 | REWIND( numnam_ref ) ! Namelist namsbc_alb in reference namelist : Albedo parameters |
|---|
| 379 | READ ( numnam_ref, namsbc_alb, IOSTAT = ios, ERR = 901) |
|---|
| 380 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in reference namelist', lwp ) |
|---|
| 381 | |
|---|
| 382 | REWIND( numnam_cfg ) ! Namelist namsbc_alb in configuration namelist : Albedo parameters |
|---|
| 383 | READ ( numnam_cfg, namsbc_alb, IOSTAT = ios, ERR = 902 ) |
|---|
| 384 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in configuration namelist', lwp ) |
|---|
| 385 | IF(lwm) WRITE ( numond, namsbc_alb ) |
|---|
| 386 | ! |
|---|
| 387 | IF(lwp) THEN ! Control print |
|---|
| 388 | WRITE(numout,*) |
|---|
| 389 | WRITE(numout,*) 'albedo : set albedo parameters' |
|---|
| 390 | WRITE(numout,*) '~~~~~~~' |
|---|
| 391 | WRITE(numout,*) ' Namelist namsbc_alb : albedo ' |
|---|
| 392 | WRITE(numout,*) ' choose the albedo parameterization nn_ice_alb = ', nn_ice_alb |
|---|
| 393 | WRITE(numout,*) ' albedo of dry snow rn_alb_sdry = ', rn_alb_sdry |
|---|
| 394 | WRITE(numout,*) ' albedo of melting snow rn_alb_smlt = ', rn_alb_smlt |
|---|
| 395 | WRITE(numout,*) ' albedo of dry ice rn_alb_idry = ', rn_alb_idry |
|---|
| 396 | WRITE(numout,*) ' albedo of bare ice rn_alb_imlt = ', rn_alb_imlt |
|---|
| 397 | WRITE(numout,*) ' albedo of ponded ice rn_alb_dpnd = ', rn_alb_dpnd |
|---|
| 398 | ENDIF |
|---|
| 399 | ! |
|---|
| 400 | END SUBROUTINE albedo_init |
|---|
| 401 | |
|---|
| 402 | !!====================================================================== |
|---|
| 403 | END MODULE albedo |
|---|
