New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim.F90 in branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_r6859_LIM3_meltponds/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 8106

Last change on this file since 8106 was 8106, checked in by vancop, 7 years ago

Follow up on melt ponds and albedo

  • Property svn:keywords set to Id
File size: 35.8 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!            3.6  ! 2014-07  (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ice             ! LIM-3: ice variables
25   USE thd_ice         ! LIM-3: thermodynamical variables
26
27   USE sbc_oce         ! Surface boundary condition: ocean fields
28   USE sbc_ice         ! Surface boundary condition: ice   fields
29   USE sbcblk_core     ! Surface boundary condition: CORE bulk
30   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
31   USE sbccpl          ! Surface boundary condition: coupled interface
32   USE sbcana          ! Surface boundary condition: analytic formulation
33   USE albedo          ! ocean & ice albedo
34
35   USE phycst          ! Define parameters for the routines
36   USE eosbn2          ! equation of state
37   USE limdyn          ! Ice dynamics
38   USE limtrp          ! Ice transport
39   USE limhdf          ! Ice horizontal diffusion
40   USE limthd          ! Ice thermodynamics
41   USE limitd_me       ! Mechanics on ice thickness distribution
42   USE limsbc          ! sea surface boundary condition
43   USE limdiahsb       ! Ice budget diagnostics
44   USE limwri          ! Ice outputs
45   USE limrst          ! Ice restarts
46   USE limupdate1      ! update of global variables
47   USE limupdate2      ! update of global variables
48   USE limvar          ! Ice variables switch
49
50   ! MV MP 2016
51   USE limmp
52   ! END MV MP 2016
53
54   USE limistate       ! LIM initial state
55   USE limthd_sal      ! LIM ice thermodynamics: salinity
56
57   USE c1d             ! 1D vertical configuration
58   USE lbclnk          ! lateral boundary condition - MPP link
59   USE lib_mpp         ! MPP library
60   USE wrk_nemo        ! work arrays
61   USE timing          ! Timing
62   USE iom             ! I/O manager library
63   USE in_out_manager  ! I/O manager
64   USE prtctl          ! Print control
65   USE lib_fortran     !
66   USE limctl
67
68#if defined key_bdy 
69   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
70#endif
71# if defined key_agrif
72   USE agrif_ice
73   USE agrif_lim3_update
74   USE agrif_lim3_interp
75# endif
76
77   IMPLICIT NONE
78   PRIVATE
79
80   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
81   PUBLIC sbc_lim_init ! routine called by sbcmod.F90
82   
83   !! * Substitutions
84#  include "domzgr_substitute.h90"
85#  include "vectopt_loop_substitute.h90"
86   !!----------------------------------------------------------------------
87   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
88   !! $Id$
89   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
90   !!----------------------------------------------------------------------
91CONTAINS
92
93   !!======================================================================
94
95   SUBROUTINE sbc_ice_lim( kt, kblk )
96      !!---------------------------------------------------------------------
97      !!                  ***  ROUTINE sbc_ice_lim  ***
98      !!                   
99      !! ** Purpose :   update the ocean surface boundary condition via the
100      !!                Louvain la Neuve Sea Ice Model time stepping
101      !!
102      !! ** Method  :   ice model time stepping
103      !!              - call the ice dynamics routine
104      !!              - call the ice advection/diffusion routine
105      !!              - call the ice thermodynamics routine
106      !!              - call the routine that computes mass and
107      !!                heat fluxes at the ice/ocean interface
108      !!              - save the outputs
109      !!              - save the outputs for restart when necessary
110      !!
111      !! ** Action  : - time evolution of the LIM sea-ice model
112      !!              - update all sbc variables below sea-ice:
113      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
114      !!---------------------------------------------------------------------
115      INTEGER, INTENT(in) ::   kt      ! ocean time step
116      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=1 ANALYTIC, =3 CLIO, =4 CORE, =5 COUPLED)
117      !!
118      INTEGER  ::   jl                 ! dummy loop index
119      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
120      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zutau_ice, zvtau_ice 
121      !!----------------------------------------------------------------------
122
123      IF( nn_timing == 1 )  CALL timing_start('sbc_ice_lim')
124
125      ! clem: it is important to initialize agrif_lim3 variables here and not in sbc_lim_init
126# if defined key_agrif
127      IF( kt == nit000 ) THEN
128         IF( .NOT. Agrif_Root() )   CALL Agrif_InitValues_cont_lim3
129      ENDIF
130# endif
131
132      !-----------------------!
133      ! --- Ice time step --- !
134      !-----------------------!
135      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
136
137# if defined key_agrif
138         IF( .NOT. Agrif_Root() )  lim_nbstep = MOD( lim_nbstep, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) + 1
139# endif
140
141         ! mean surface ocean current at ice velocity point (C-grid dynamics :  U- & V-points as the ocean)
142         u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
143         v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
144         
145         ! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
146         CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
147         t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
148         
149         ! Mask sea ice surface temperature (set to rt0 over land)
150         DO jl = 1, jpl
151            t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
152         END DO     
153         !
154         !------------------------------------------------!                                           
155         ! --- Dynamical coupling with the atmosphere --- !                                           
156         !------------------------------------------------!
157         ! It provides the following fields:
158         ! utau_ice, vtau_ice : surface ice stress (U- & V-points)   [N/m2]
159         !-----------------------------------------------------------------
160         SELECT CASE( kblk )
161            CASE( jp_ana     )   ;    CALL ana_ice_tau                              ! analytic formulation           
162            CASE( jp_clio    )   ;    CALL blk_ice_clio_tau                         ! CLIO bulk formulation           
163            CASE( jp_core    )   ;    CALL blk_ice_core_tau                         ! CORE bulk formulation
164            CASE( jp_purecpl )   ;    CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled   formulation
165         END SELECT
166         
167         IF( ln_mixcpl) THEN                                                       ! Case of a mixed Bulk/Coupled formulation
168            CALL wrk_alloc( jpi,jpj    , zutau_ice, zvtau_ice)
169                                      CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
170            utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
171            vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
172            CALL wrk_dealloc( jpi,jpj  , zutau_ice, zvtau_ice)
173         ENDIF
174
175         !-------------------------------------------------------!
176         ! --- ice dynamics and transport (except in 1D case) ---!
177         !-------------------------------------------------------!
178         numit = numit + nn_fsbc                  ! Ice model time step
179         !                                                   
180                                      CALL sbc_lim_bef         ! Store previous ice values
181                                      CALL sbc_lim_diag0       ! set diag of mass, heat and salt fluxes to 0
182                                      CALL lim_rst_opn( kt )   ! Open Ice restart file
183         !
184         ! --- zap this if no ice dynamics --- !
185         IF( .NOT. lk_c1d .AND. ln_limdyn ) THEN
186            !
187            IF( nn_limdyn /= 0 ) THEN                          ! -- Ice dynamics
188                                      CALL lim_dyn( kt )       !     rheology 
189            ELSE
190               u_ice(:,:) = rn_uice * umask(:,:,1)             !     or prescribed velocity
191               v_ice(:,:) = rn_vice * vmask(:,:,1)
192            ENDIF
193                                      CALL lim_trp( kt )       ! -- Ice transport (Advection/diffusion)
194            IF( nn_limdyn == 2 .AND. nn_monocat /= 2 )  &      ! -- Mechanical redistribution (ridging/rafting)
195               &                      CALL lim_itd_me         
196            IF( nn_limdyn == 2 )      CALL lim_update1( kt )   ! -- Corrections
197            !
198         ENDIF
199
200         ! ---
201#if defined key_agrif
202         IF( .NOT. Agrif_Root() )     CALL agrif_interp_lim3('T')
203#endif
204#if defined key_bdy
205         IF( ln_limthd )              CALL bdy_ice_lim( kt )   ! -- bdy ice thermo
206#endif
207
208         ! previous lead fraction and ice volume for flux calculations
209                                      CALL sbc_lim_bef                       
210                                      CALL lim_var_glo2eqv     ! ht_i and ht_s for ice albedo calculation
211                                      CALL lim_var_agg(1)      ! at_i for coupling (via pfrld)
212         !
213         pfrld(:,:)   = 1._wp - at_i(:,:)
214         phicif(:,:)  = vt_i(:,:)
215         
216         !------------------------------------------------------!                                           
217         ! --- Thermodynamical coupling with the atmosphere --- !                                           
218         !------------------------------------------------------!
219         ! It provides the following fields:
220         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
221         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
222         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
223         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
224         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
225         !----------------------------------------------------------------------------------------
226         CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs )
227         
228                                      CALL albedo_ice( t_su, ht_i, ht_s, a_ip_frac, h_ip, ln_pnd_rad, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos MV MP 2016
229
230         SELECT CASE( kblk )
231
232            CASE( jp_ana )                                        ! analytic formulation
233                                      CALL ana_ice_flx
234               
235            CASE( jp_clio )                                       ! CLIO bulk formulation
236               ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
237               ! (alb_ice) is computed within the bulk routine
238                                      CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, alb_ice )
239               IF( ln_mixcpl      )   CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
240               IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
241               
242            CASE( jp_core )                                       ! CORE bulk formulation
243               ! albedo depends on cloud fraction because of non-linear spectral effects
244               alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
245                                      CALL blk_ice_core_flx( t_su, alb_ice )
246               IF( ln_mixcpl      )   CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
247               IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
248               
249            CASE ( jp_purecpl )                                    ! Coupled formulation
250               ! albedo depends on cloud fraction because of non-linear spectral effects
251               alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
252                                      CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
253               IF( nn_limflx == 2 )   CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
254
255         END SELECT
256
257         CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs )
258
259         !----------------------------!
260         ! --- ice thermodynamics --- !
261         !----------------------------!
262         ! --- zap this if no ice thermo --- !
263         IF( ln_limthd )              CALL lim_thd( kt )        ! -- Ice thermodynamics     
264
265         ! MV MP 2016
266         IF ( ln_pnd )                CALL lim_mp( kt )         ! -- Melt ponds
267         ! END MV MP 2016
268
269         IF( ln_limthd )              CALL lim_update2( kt )    ! -- Corrections
270         ! ---
271# if defined key_agrif
272         IF( .NOT. Agrif_Root() )     CALL agrif_update_lim3( kt )
273# endif
274                                      CALL lim_var_glo2eqv      ! necessary calls (at least for coupling)
275                                      CALL lim_var_agg( 2 )     ! necessary calls (at least for coupling)
276                                      !
277# if defined key_agrif
278!!         IF( .NOT. Agrif_Root() )     CALL Agrif_ChildGrid_To_ParentGrid()  ! clem: should be called at the update frequency only (cf agrif_lim3_update)
279# endif
280                                      CALL lim_sbc_flx( kt )    ! -- Update surface ocean mass, heat and salt fluxes
281# if defined key_agrif
282!!         IF( .NOT. Agrif_Root() )     CALL Agrif_ParentGrid_To_ChildGrid()  ! clem: should be called at the update frequency only (cf agrif_lim3_update)
283# endif
284         IF( ln_limdiahsb )           CALL lim_diahsb( kt )     ! -- Diagnostics and outputs
285         !
286                                      CALL lim_wri( 1 )         ! -- Ice outputs
287         !
288         IF( kt == nit000 .AND. ln_rstart )   &
289            &                         CALL iom_close( numrir )  ! close input ice restart file
290         !
291         IF( lrst_ice )               CALL lim_rst_write( kt )  ! -- Ice restart file
292         !
293         IF( ln_limctl )              CALL lim_ctl( kt )        ! alerts in case of model crash
294         !
295      ENDIF   ! End sea-ice time step only
296
297      !-------------------------!
298      ! --- Ocean time step --- !
299      !-------------------------!
300      ! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
301      !    using before instantaneous surf. currents
302      IF( ln_limdyn )                 CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )
303!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
304      !
305      IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
306      !
307   END SUBROUTINE sbc_ice_lim
308   
309
310   SUBROUTINE sbc_lim_init
311      !!----------------------------------------------------------------------
312      !!                  ***  ROUTINE sbc_lim_init  ***
313      !!
314      !! ** purpose :   Allocate all the dynamic arrays of the LIM-3 modules
315      !!----------------------------------------------------------------------
316      INTEGER :: ierr
317      INTEGER :: ji, jj
318      !!----------------------------------------------------------------------
319      IF(lwp) WRITE(numout,*)
320      IF(lwp) WRITE(numout,*) 'sbc_lim_init : update ocean surface boudary condition' 
321      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
322      !
323                                       ! Open the reference and configuration namelist files and namelist output file
324      CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp ) 
325      CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
326      IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
327
328      CALL ice_run                     ! set some ice run parameters
329      !
330      !                                ! Allocate the ice arrays
331      ierr =        ice_alloc        ()      ! ice variables
332      ierr = ierr + sbc_ice_alloc    ()      ! surface forcing
333      ierr = ierr + thd_ice_alloc    ()      ! thermodynamics
334      IF( ln_limdyn )   ierr = ierr + lim_itd_me_alloc ()      ! ice thickness distribution - mechanics
335      !
336      IF( lk_mpp    )   CALL mpp_sum( ierr )
337      IF( ierr /= 0 )   CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
338      !
339      CALL lim_dyn_init                ! set ice dynamics parameters
340      !
341      CALL lim_itd_init                ! ice thickness distribution initialization
342      !
343      CALL lim_hdf_init                ! set ice horizontal diffusion computation parameters
344      !
345      CALL lim_thd_init                ! set ice thermodynics parameters
346      !
347      CALL lim_thd_sal_init            ! set ice salinity parameters
348       
349      ! MV MP 2016
350      CALL lim_mp_init                 ! set melt ponds parameters
351      ! END MV MP 2016
352
353      IF( ln_limdyn )   CALL lim_itd_me_init             ! ice thickness distribution initialization for mecanical deformation
354      !                                ! Initial sea-ice state
355      IF( .NOT. ln_rstart ) THEN              ! start from rest: sea-ice deduced from sst
356         numit = 0
357         numit = nit000 - 1
358         CALL lim_istate
359      ELSE                                    ! start from a restart file
360         CALL lim_rst_read
361         numit = nit000 - 1
362      ENDIF
363      CALL lim_var_agg(2)
364      CALL lim_var_glo2eqv
365      !
366      CALL lim_sbc_init                 ! ice surface boundary condition   
367      !
368      IF( ln_limdiahsb) CALL lim_diahsb_init  ! initialization for diags
369      !
370      fr_i(:,:)     = at_i(:,:)         ! initialisation of sea-ice fraction
371      tn_ice(:,:,:) = t_su(:,:,:)       ! initialisation of surface temp for coupled simu
372      !
373      DO jj = 1, jpj
374         DO ji = 1, jpi
375            IF( gphit(ji,jj) > 0._wp ) THEN  ;  rn_amax_2d(ji,jj) = rn_amax_n  ! NH
376            ELSE                             ;  rn_amax_2d(ji,jj) = rn_amax_s  ! SH
377            ENDIF
378        ENDDO
379      ENDDO 
380      !
381      nstart = numit  + nn_fsbc     
382      nitrun = nitend - nit000 + 1 
383      nlast  = numit  + nitrun 
384      !
385      IF( nstock == 0 )   nstock = nlast + 1
386      !
387      !
388   END SUBROUTINE sbc_lim_init
389
390
391   SUBROUTINE ice_run
392      !!-------------------------------------------------------------------
393      !!                  ***  ROUTINE ice_run ***
394      !!                 
395      !! ** Purpose :   Definition some run parameter for ice model
396      !!
397      !! ** Method  :   Read the namicerun namelist and check the parameter
398      !!              values called at the first timestep (nit000)
399      !!
400      !! ** input   :   Namelist namicerun
401      !!-------------------------------------------------------------------
402      INTEGER  ::   ios                 ! Local integer output status for namelist read
403      NAMELIST/namicerun/ jpl, nlay_i, nlay_s, rn_amax_n, rn_amax_s, cn_icerst_in, cn_icerst_indir,   &
404         &                cn_icerst_out, cn_icerst_outdir, ln_limthd, ln_limdyn, nn_limdyn, rn_uice, rn_vice 
405      NAMELIST/namicediag/ ln_limdiachk, ln_limdiahsb, ln_limctl, iiceprt, jiceprt 
406      !!-------------------------------------------------------------------
407      !                   
408      REWIND( numnam_ice_ref )              ! Namelist namicerun in reference namelist : Parameters for ice
409      READ  ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
410901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
411
412      REWIND( numnam_ice_cfg )              ! Namelist namicerun in configuration namelist : Parameters for ice
413      READ  ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
414902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
415      IF(lwm) WRITE ( numoni, namicerun )
416      !
417      REWIND( numnam_ice_ref )              ! Namelist namicediag in reference namelist : Parameters for ice
418      READ  ( numnam_ice_ref, namicediag, IOSTAT = ios, ERR = 903)
419903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in reference namelist', lwp )
420
421      REWIND( numnam_ice_cfg )              ! Namelist namicediag in configuration namelist : Parameters for ice
422      READ  ( numnam_ice_cfg, namicediag, IOSTAT = ios, ERR = 904 )
423904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in configuration namelist', lwp )
424      IF(lwm) WRITE ( numoni, namicediag )
425      !
426      IF(lwp) THEN                        ! control print
427         WRITE(numout,*)
428         WRITE(numout,*) 'ice_run : ice share~d parameters for dynamics/advection/thermo of sea-ice'
429         WRITE(numout,*) ' ~~~~~~'
430         WRITE(numout,*) '   number of ice  categories                               = ', jpl
431         WRITE(numout,*) '   number of ice  layers                                   = ', nlay_i
432         WRITE(numout,*) '   number of snow layers                                   = ', nlay_s
433         WRITE(numout,*) '   maximum ice concentration for NH                        = ', rn_amax_n 
434         WRITE(numout,*) '   maximum ice concentration for SH                        = ', rn_amax_s
435         WRITE(numout,*) '   Ice thermodynamics (T) or not (F)            ln_limthd  = ', ln_limthd
436         WRITE(numout,*) '   Ice dynamics       (T) or not (F)            ln_limdyn  = ', ln_limdyn
437         WRITE(numout,*) '     (ln_limdyn=T) Ice dynamics switch          nn_limdyn  = ', nn_limdyn
438         WRITE(numout,*) '       2: total'
439         WRITE(numout,*) '       1: advection only (no diffusion, no ridging/rafting)'
440         WRITE(numout,*) '       0: advection only (as 1 + prescribed velocity, bypass rheology)'
441         WRITE(numout,*) '     (ln_limdyn=T) prescribed u-vel (case nn_limdyn=0)     = ', rn_uice
442         WRITE(numout,*) '     (ln_limdyn=T) prescribed v-vel (case nn_limdyn=0)     = ', rn_vice
443         WRITE(numout,*)
444         WRITE(numout,*) '...and ice diagnostics'
445         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~'
446         WRITE(numout,*) '   Diagnose online heat/mass/salt budget     ln_limdiachk  = ', ln_limdiachk
447         WRITE(numout,*) '   Output          heat/mass/salt budget     ln_limdiahsb  = ', ln_limdiahsb
448         WRITE(numout,*) '   control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_limctl
449         WRITE(numout,*) '   i-index for control prints (ln_limctl=true)             = ', iiceprt
450         WRITE(numout,*) '   j-index for control prints (ln_limctl=true)             = ', jiceprt
451      ENDIF
452      !
453      ! sea-ice timestep and inverse
454      rdt_ice   = REAL(nn_fsbc) * rdt 
455      r1_rdtice = 1._wp / rdt_ice 
456
457      ! inverse of nlay_i and nlay_s
458      r1_nlay_i = 1._wp / REAL( nlay_i, wp )
459      r1_nlay_s = 1._wp / REAL( nlay_s, wp )
460      !
461#if defined key_bdy
462      IF( lwp .AND. ln_limdiachk )  CALL ctl_warn('online conservation check activated but it does not work with BDY')
463#endif
464      !
465      IF( lwp ) WRITE(numout,*) '   ice timestep rdt_ice  = ', rdt_ice
466      !
467   END SUBROUTINE ice_run
468
469
470   SUBROUTINE lim_itd_init
471      !!------------------------------------------------------------------
472      !!                ***  ROUTINE lim_itd_init ***
473      !!
474      !! ** Purpose :   Initializes the ice thickness distribution
475      !! ** Method  :   ...
476      !! ** input   :   Namelist namiceitd
477      !!-------------------------------------------------------------------
478      INTEGER  ::   ios                 ! Local integer output status for namelist read
479      NAMELIST/namiceitd/ nn_catbnd, rn_himean
480      !
481      INTEGER  ::   jl                   ! dummy loop index
482      REAL(wp) ::   zc1, zc2, zc3, zx1   ! local scalars
483      REAL(wp) ::   zhmax, znum, zden, zalpha !
484      !!------------------------------------------------------------------
485      !
486      REWIND( numnam_ice_ref )              ! Namelist namiceitd in reference namelist : Parameters for ice
487      READ  ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 905)
488905   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
489
490      REWIND( numnam_ice_cfg )              ! Namelist namiceitd in configuration namelist : Parameters for ice
491      READ  ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 906 )
492906   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
493      IF(lwm) WRITE ( numoni, namiceitd )
494      !
495      IF(lwp) THEN                        ! control print
496         WRITE(numout,*)
497         WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
498         WRITE(numout,*) '~~~~~~~~~~~~'
499         WRITE(numout,*) '   shape of ice categories distribution                          nn_catbnd = ', nn_catbnd
500         WRITE(numout,*) '   mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
501      ENDIF
502
503      !----------------------------------
504      !- Thickness categories boundaries
505      !----------------------------------
506      hi_max(:) = 0._wp
507
508      SELECT CASE ( nn_catbnd  )       
509                                   !----------------------
510         CASE (1)                  ! tanh function (CICE)
511                                   !----------------------
512         zc1 =  3._wp / REAL( jpl, wp )
513         zc2 = 10._wp * zc1
514         zc3 =  3._wp
515
516         DO jl = 1, jpl
517            zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
518            hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
519         END DO
520
521                                   !----------------------
522         CASE (2)                  ! h^(-alpha) function
523                                   !----------------------
524         zalpha = 0.05             ! exponent of the transform function
525
526         zhmax  = 3.*rn_himean
527
528         DO jl = 1, jpl 
529            znum = jpl * ( zhmax+1 )**zalpha
530            zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
531            hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
532         END DO
533
534      END SELECT
535
536      DO jl = 1, jpl
537         hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
538      END DO
539
540      ! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
541      hi_max(jpl) = 99._wp
542
543      IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
544      IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
545      !
546   END SUBROUTINE lim_itd_init
547
548   
549   SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
550      !!---------------------------------------------------------------------
551      !!                  ***  ROUTINE ice_lim_flx  ***
552      !!                   
553      !! ** Purpose :   update the ice surface boundary condition by averaging and / or
554      !!                redistributing fluxes on ice categories                   
555      !!
556      !! ** Method  :   average then redistribute
557      !!
558      !! ** Action  :   
559      !!---------------------------------------------------------------------
560      INTEGER                   , INTENT(in   ) ::   k_limflx   ! =-1 do nothing; =0 average ;
561                                                                ! =1 average and redistribute ; =2 redistribute
562      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
563      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
564      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
565      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
566      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
567      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
568      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
569      !
570      INTEGER  ::   jl      ! dummy loop index
571      !
572      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m    ! Mean albedo over all categories
573      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m    ! Mean temperature over all categories
574      !
575      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m   ! Mean solar heat flux over all categories
576      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m   ! Mean non solar heat flux over all categories
577      REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m  ! Mean sublimation over all categories
578      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m   ! Mean d(qns)/dT over all categories
579      REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
580      !!----------------------------------------------------------------------
581
582      IF( nn_timing == 1 )  CALL timing_start('ice_lim_flx')
583      !
584      !
585      SELECT CASE( k_limflx )                              !==  averaged on all ice categories  ==!
586      CASE( 0 , 1 )
587         CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
588         !
589         z_qns_m  (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
590         z_qsr_m  (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
591         z_dqn_m  (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
592         z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
593         z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
594         DO jl = 1, jpl
595            pdqn_ice  (:,:,jl) = z_dqn_m(:,:)
596            pdevap_ice(:,:,jl) = z_devap_m(:,:)
597         END DO
598         !
599         DO jl = 1, jpl
600            pqns_ice (:,:,jl) = z_qns_m(:,:)
601            pqsr_ice (:,:,jl) = z_qsr_m(:,:)
602            pevap_ice(:,:,jl) = z_evap_m(:,:)
603         END DO
604         !
605         CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
606      END SELECT
607
608      SELECT CASE( k_limflx )                              !==  redistribution on all ice categories  ==!
609      CASE( 1 , 2 )
610         CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
611         !
612         zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) ) 
613         ztem_m(:,:) = fice_ice_ave ( ptn_ice  (:,:,:) ) 
614         DO jl = 1, jpl
615            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
616            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
617            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) ) 
618         END DO
619         !
620         CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
621      END SELECT
622      !
623      IF( nn_timing == 1 )  CALL timing_stop('ice_lim_flx')
624      !
625   END SUBROUTINE ice_lim_flx
626
627   SUBROUTINE sbc_lim_bef
628      !!----------------------------------------------------------------------
629      !!                  ***  ROUTINE sbc_lim_bef  ***
630      !!
631      !! ** purpose :  store ice variables at "before" time step
632      !!----------------------------------------------------------------------
633      a_i_b  (:,:,:)   = a_i  (:,:,:)     ! ice area
634      e_i_b  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
635      v_i_b  (:,:,:)   = v_i  (:,:,:)     ! ice volume
636      v_s_b  (:,:,:)   = v_s  (:,:,:)     ! snow volume
637      e_s_b  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
638      smv_i_b(:,:,:)   = smv_i(:,:,:)     ! salt content
639      oa_i_b (:,:,:)   = oa_i (:,:,:)     ! areal age content
640      u_ice_b(:,:)     = u_ice(:,:)
641      v_ice_b(:,:)     = v_ice(:,:)
642      at_i_b (:,:)     = SUM( a_i_b(:,:,:), dim=3 )
643     
644   END SUBROUTINE sbc_lim_bef
645
646   SUBROUTINE sbc_lim_diag0
647      !!----------------------------------------------------------------------
648      !!                  ***  ROUTINE sbc_lim_diag0  ***
649      !!
650      !! ** purpose :  set ice-ocean and ice-atm. fluxes to zeros at the beggining
651      !!               of the time step
652      !!----------------------------------------------------------------------
653      sfx    (:,:) = 0._wp   ;
654      sfx_bri(:,:) = 0._wp   ;   sfx_lam(:,:) = 0._wp
655      sfx_sni(:,:) = 0._wp   ;   sfx_opw(:,:) = 0._wp
656      sfx_bog(:,:) = 0._wp   ;   sfx_dyn(:,:) = 0._wp
657      sfx_bom(:,:) = 0._wp   ;   sfx_sum(:,:) = 0._wp
658      sfx_res(:,:) = 0._wp   ;   sfx_sub(:,:) = 0._wp
659     
660      wfx_snw(:,:) = 0._wp   ;   wfx_ice(:,:) = 0._wp
661      wfx_sni(:,:) = 0._wp   ;   wfx_opw(:,:) = 0._wp
662      wfx_bog(:,:) = 0._wp   ;   wfx_dyn(:,:) = 0._wp
663      wfx_bom(:,:) = 0._wp   ;   wfx_sum(:,:) = 0._wp
664      wfx_res(:,:) = 0._wp   ;   wfx_sub(:,:) = 0._wp
665      wfx_spr(:,:) = 0._wp   ;   wfx_lam(:,:) = 0._wp 
666
667      ! MV MP 2016
668      wfx_pnd(:,:) = 0._wp
669      ! END MV MP 2016
670     
671      hfx_thd(:,:) = 0._wp   ;   
672      hfx_snw(:,:) = 0._wp   ;   hfx_opw(:,:) = 0._wp
673      hfx_bog(:,:) = 0._wp   ;   hfx_dyn(:,:) = 0._wp
674      hfx_bom(:,:) = 0._wp   ;   hfx_sum(:,:) = 0._wp
675      hfx_res(:,:) = 0._wp   ;   hfx_sub(:,:) = 0._wp
676      hfx_spr(:,:) = 0._wp   ;   hfx_dif(:,:) = 0._wp 
677      hfx_err(:,:) = 0._wp   ;   hfx_err_rem(:,:) = 0._wp
678      hfx_err_dif(:,:) = 0._wp
679      wfx_err_sub(:,:) = 0._wp
680     
681      afx_tot(:,:) = 0._wp   ;
682      afx_dyn(:,:) = 0._wp   ;   afx_thd(:,:) = 0._wp
683
684      diag_heat(:,:) = 0._wp ;   diag_smvi(:,:) = 0._wp ;
685      diag_vice(:,:) = 0._wp ;   diag_vsnw(:,:) = 0._wp ;
686
687      tau_icebfr(:,:) = 0._wp; ! landfast ice param only (clem: important to keep the init here)
688     
689   END SUBROUTINE sbc_lim_diag0
690
691     
692   FUNCTION fice_cell_ave ( ptab )
693      !!--------------------------------------------------------------------------
694      !! * Compute average over categories, for grid cell (ice covered and free ocean)
695      !!--------------------------------------------------------------------------
696      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
697      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
698      INTEGER :: jl ! Dummy loop index
699     
700      fice_cell_ave (:,:) = 0.0_wp
701      DO jl = 1, jpl
702         fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
703      END DO
704     
705   END FUNCTION fice_cell_ave
706   
707   
708   FUNCTION fice_ice_ave ( ptab )
709      !!--------------------------------------------------------------------------
710      !! * Compute average over categories, for ice covered part of grid cell
711      !!--------------------------------------------------------------------------
712      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
713      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
714
715      fice_ice_ave (:,:) = 0.0_wp
716      WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
717
718   END FUNCTION fice_ice_ave
719
720
721#else
722   !!----------------------------------------------------------------------
723   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
724   !!----------------------------------------------------------------------
725CONTAINS
726   SUBROUTINE sbc_ice_lim ( kt, kblk )     ! Dummy routine
727      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
728   END SUBROUTINE sbc_ice_lim
729   SUBROUTINE sbc_lim_init                 ! Dummy routine
730   END SUBROUTINE sbc_lim_init
731#endif
732
733   !!======================================================================
734END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.