New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p2zexp.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P2Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P2Z/p2zexp.F90 @ 7041

Last change on this file since 7041 was 7041, checked in by cetlod, 7 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782

  • Property svn:keywords set to Id
File size: 11.2 KB
Line 
1MODULE p2zexp
2   !!======================================================================
3   !!                         ***  MODULE p2zsed  ***
4   !! TOP :   LOBSTER Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :    -   !  1999    (O. Aumont, C. Le Quere)  original code
7   !!              -   !  2001-05 (O. Aumont, E. Kestenare) add sediment computations
8   !!             1.0  !  2005-06 (A.-S. Kremeur) new temporal integration for sedpoc
9   !!             2.0  !  2007-12  (C. Deltel, G. Madec)  F90
10   !!             3.5  !  2012-03  (C. Ethe)  Merge PISCES-LOBSTER
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                     LOBSTER bio-model
15   !!----------------------------------------------------------------------
16   !!   p2z_exp        :  Compute loss of organic matter in the sediments
17   !!----------------------------------------------------------------------
18   USE oce_trc         !
19   USE trc
20   USE sms_pisces
21   USE p2zsed
22   USE lbclnk
23   USE prtctl_trc      ! Print control for debbuging
24   USE trd_oce
25   USE trdtrc
26   USE iom
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   p2z_exp   
32   PUBLIC   p2z_exp_init 
33   PUBLIC   p2z_exp_alloc
34
35   !
36   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   dminl     !: fraction of sinking POC released in sediments
37   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   dmin3     !: fraction of sinking POC released at each level
38   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocb   !: mass of POC in sediments
39   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocn   !: mass of POC in sediments
40   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   cmask     !: Coastal mask area
41   REAL(wp)                                ::   areacot   !: surface coastal area
42
43   !! * Substitutions
44#  include "vectopt_loop_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p2z_exp( kt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p2z_exp  ***
55      !!
56      !! ** Purpose :   MODELS EXPORT OF BIOGENIC MATTER (POC ''SOFT
57      !!              TISSUE'') AND ITS DISTRIBUTION IN WATER COLUMN
58      !!
59      !! ** Method  : - IN THE SURFACE LAYER POC IS PRODUCED ACCORDING TO
60      !!              NURTRIENTS AVAILABLE AND GROWTH CONDITIONS. NUTRIENT UPTAKE
61      !!              KINETICS FOLLOW MICHAELIS-MENTON FORMULATION.
62      !!              THE TOTAL PARTICLE AMOUNT PRODUCED, IS DISTRIBUTED IN THE WATER
63      !!              COLUMN BELOW THE SURFACE LAYER.
64      !!---------------------------------------------------------------------
65      !!
66      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
67      !!
68      INTEGER  ::   ji, jj, jk, jl, ikt
69      REAL(wp) ::   zgeolpoc, zfact, zwork, ze3t, zsedpocd, zmaskt
70      REAL(wp), POINTER, DIMENSION(:,:)   ::  zsedpoca
71      CHARACTER (len=25) :: charout
72      !!---------------------------------------------------------------------
73      !
74      IF( nn_timing == 1 )  CALL timing_start('p2z_exp')
75      !
76      IF( kt == nittrc000 )   CALL p2z_exp_init
77
78      CALL wrk_alloc( jpi, jpj, zsedpoca ) 
79      zsedpoca(:,:) = 0.
80
81
82      ! VERTICAL DISTRIBUTION OF NEWLY PRODUCED BIOGENIC
83      ! POC IN THE WATER COLUMN
84      ! (PARTS OF NEWLY FORMED MATTER REMAINING IN THE DIFFERENT
85      ! LAYERS IS DETERMINED BY DMIN3 DEFINED IN sms_p2z.F90
86      ! ----------------------------------------------------------------------
87      DO jk = 1, jpkm1
88         DO jj = 2, jpjm1
89            DO ji = fs_2, fs_jpim1
90               ze3t = 1. / e3t_n(ji,jj,jk)
91               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + ze3t * dmin3(ji,jj,jk) * xksi(ji,jj)
92            END DO
93         END DO
94      END DO
95
96      ! Find the last level of the water column
97      ! Compute fluxes due to sinking particles (slow)
98   
99
100      zgeolpoc = 0.e0         !     Initialization
101      ! Release of nutrients from the "simple" sediment
102      DO jj = 2, jpjm1
103         DO ji = fs_2, fs_jpim1
104            ikt = mbkt(ji,jj) 
105            tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) + sedlam * sedpocn(ji,jj) / e3t_n(ji,jj,ikt) 
106            ! Deposition of organic matter in the sediment
107            zwork = vsed * trn(ji,jj,ikt,jpdet)
108            zsedpoca(ji,jj) = ( zwork + dminl(ji,jj) * xksi(ji,jj)   &
109               &           - sedlam * sedpocn(ji,jj) - sedlostpoc * sedpocn(ji,jj) ) * rdt
110            zgeolpoc = zgeolpoc + sedlostpoc * sedpocn(ji,jj) * e1e2t(ji,jj)
111         END DO
112      END DO
113
114      DO jj = 2, jpjm1
115         DO ji = fs_2, fs_jpim1
116            tra(ji,jj,1,jpno3) = tra(ji,jj,1,jpno3) + zgeolpoc * cmask(ji,jj) / areacot / e3t_n(ji,jj,1)
117         END DO
118      END DO
119
120      CALL lbc_lnk( sedpocn, 'T', 1. )
121 
122      ! Oa & Ek: diagnostics depending on jpdia2d !          left as example
123      IF( lk_iomput )  CALL iom_put( "SEDPOC" , sedpocn )
124
125     
126      ! Time filter and swap of arrays
127      ! ------------------------------
128      IF( neuler == 0 .AND. kt == nittrc000 ) THEN        ! Euler time-stepping at first time-step
129        !                                             ! (only swap)
130        sedpocn(:,:) = zsedpoca(:,:)
131        !                                             
132      ELSE
133        !
134        DO jj = 1, jpj
135           DO ji = 1, jpi
136              zsedpocd = zsedpoca(ji,jj) - 2. * sedpocn(ji,jj) + sedpocb(ji,jj)      ! time laplacian on tracers
137              sedpocb(ji,jj) = sedpocn(ji,jj) + atfp * zsedpocd                     ! sedpocb <-- filtered sedpocn
138              sedpocn(ji,jj) = zsedpoca(ji,jj)                                       ! sedpocn <-- sedpoca
139           END DO
140        END DO
141        !
142      ENDIF
143      !
144      IF( lrst_trc ) THEN
145         IF(lwp) WRITE(numout,*)
146         IF(lwp) WRITE(numout,*) 'p2z_exp : POC in sediment fields written in ocean restart file ',   &
147            &                    'at it= ', kt,' date= ', ndastp
148         IF(lwp) WRITE(numout,*) '~~~~'
149         CALL iom_rstput( kt, nitrst, numrtw, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
150         CALL iom_rstput( kt, nitrst, numrtw, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
151      ENDIF
152      !
153      CALL wrk_dealloc( jpi, jpj, zsedpoca)   ! temporary save of trends
154
155      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
156         WRITE(charout, FMT="('exp')")
157         CALL prt_ctl_trc_info(charout)
158         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
159      ENDIF
160      !
161      IF( nn_timing == 1 )  CALL timing_stop('p2z_exp')
162      !
163   END SUBROUTINE p2z_exp
164
165   SUBROUTINE p2z_exp_init
166      !!----------------------------------------------------------------------
167      !!                    ***  ROUTINE p4z_exp_init  ***
168      !! ** purpose :   specific initialisation for export
169      !!----------------------------------------------------------------------
170      INTEGER  ::   ji, jj, jk
171      REAL(wp) ::   zmaskt, zfluo, zfluu
172      REAL(wp), POINTER, DIMENSION(:,:  ) :: zrro
173      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdm0
174      !!---------------------------------------------------------------------
175
176      IF(lwp) THEN
177         WRITE(numout,*)
178         WRITE(numout,*) ' p2z_exp: LOBSTER export'
179         WRITE(numout,*) ' ~~~~~~~'
180         WRITE(numout,*) '  compute remineralisation-damping arrays for tracers'
181      ENDIF
182      !
183      ! Allocate temporary workspace
184      CALL wrk_alloc( jpi, jpj,      zrro )
185      CALL wrk_alloc( jpi, jpj, jpk, zdm0 )
186
187
188      ! Calculate vertical distribution of newly formed biogenic poc
189      ! in the water column in the case of max. possible bottom depth
190      ! ------------------------------------------------------------
191      zdm0 = 0._wp
192      zrro = 1._wp
193      DO jk = jpkb, jpkm1
194         DO jj = 1, jpj
195            DO ji = 1, jpi
196               zfluo = ( gdepw_n(ji,jj,jk  ) / gdepw_n(ji,jj,jpkb) )**xhr
197               zfluu = ( gdepw_n(ji,jj,jk+1) / gdepw_n(ji,jj,jpkb) )**xhr
198               IF( zfluo.GT.1. )   zfluo = 1._wp
199               zdm0(ji,jj,jk) = zfluo - zfluu
200               IF( jk <= jpkb-1 )   zdm0(ji,jj,jk) = 0._wp
201               zrro(ji,jj) = zrro(ji,jj) - zdm0(ji,jj,jk)
202            END DO
203         END DO
204      END DO
205      !
206      zdm0(:,:,jpk) = zrro(:,:)
207
208      ! Calculate vertical distribution of newly formed biogenic poc
209      ! in the water column with realistic topography (first "dry" layer
210      ! contains total fraction, which has passed to the upper layers)
211      ! ----------------------------------------------------------------------
212      dminl(:,:)   = 0._wp
213      dmin3(:,:,:) = zdm0
214      DO jk = 1, jpk
215         DO jj = 1, jpj
216            DO ji = 1, jpi
217               IF( tmask(ji,jj,jk) == 0._wp ) THEN
218                  dminl(ji,jj) = dminl(ji,jj) + dmin3(ji,jj,jk)
219                  dmin3(ji,jj,jk) = 0._wp
220               ENDIF
221            END DO
222         END DO
223      END DO
224
225      DO jj = 1, jpj
226         DO ji = 1, jpi
227            IF( tmask(ji,jj,1) == 0 )   dmin3(ji,jj,1) = 0._wp
228         END DO
229      END DO
230
231      ! Coastal mask
232      cmask(:,:) = 0._wp
233      DO jj = 2, jpjm1
234         DO ji = fs_2, fs_jpim1
235            IF( tmask(ji,jj,1) /= 0. ) THEN
236               zmaskt = tmask(ji+1,jj,1) * tmask(ji-1,jj,1) * tmask(ji,jj+1,1) * tmask(ji,jj-1,1) 
237               IF( zmaskt == 0. )   cmask(ji,jj) = 1._wp
238            END IF
239         END DO
240      END DO
241      CALL lbc_lnk( cmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
242      areacot = glob_sum( e1e2t(:,:) * cmask(:,:) )
243      !
244      IF( ln_rsttr ) THEN
245         CALL iom_get( numrtr, jpdom_autoglo, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
246         CALL iom_get( numrtr, jpdom_autoglo, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
247      ELSE
248         sedpocb(:,:) = 0._wp
249         sedpocn(:,:) = 0._wp
250      ENDIF
251      !
252      CALL wrk_dealloc( jpi, jpj,      zrro )
253      CALL wrk_dealloc( jpi, jpj, jpk, zdm0 )
254      !
255   END SUBROUTINE p2z_exp_init
256
257   INTEGER FUNCTION p2z_exp_alloc()
258      !!----------------------------------------------------------------------
259      !!                     ***  ROUTINE p2z_exp_alloc  ***
260      !!----------------------------------------------------------------------
261      ALLOCATE( cmask(jpi,jpj) , dminl(jpi,jpj) , dmin3(jpi,jpj,jpk), &
262         &      sedpocb(jpi,jpj) , sedpocn(jpi,jpj),   STAT=p2z_exp_alloc )
263      IF( p2z_exp_alloc /= 0 ) CALL ctl_warn('p2z_exp_alloc : failed to allocate arrays.')
264      !
265   END FUNCTION p2z_exp_alloc
266
267#else
268   !!======================================================================
269   !!  Dummy module :                                   No PISCES bio-model
270   !!======================================================================
271CONTAINS
272   SUBROUTINE p2z_exp( kt )                   ! Empty routine
273      INTEGER, INTENT( in ) ::   kt
274      WRITE(*,*) 'p2z_exp: You should not have seen this print! error?', kt
275   END SUBROUTINE p2z_exp
276#endif 
277
278   !!======================================================================
279END MODULE  p2zexp
Note: See TracBrowser for help on using the repository browser.