source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlys.F90 @ 7041

Last change on this file since 7041 was 7041, checked in by cetlod, 4 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782

File size: 9.9 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!----------------------------------------------------------------------
14#if defined key_pisces
15   !!----------------------------------------------------------------------
16   !!   'key_pisces'                                       PISCES bio-model
17   !!----------------------------------------------------------------------
18   !!   p4z_lys        :   Compute the CaCO3 dissolution
19   !!   p4z_lys_init   :   Read the namelist parameters
20   !!----------------------------------------------------------------------
21   USE oce_trc         !  shared variables between ocean and passive tracers
22   USE trc             !  passive tracers common variables
23   USE sms_pisces      !  PISCES Source Minus Sink variables
24   USE prtctl_trc      !  print control for debugging
25   USE iom             !  I/O manager
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
31   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
32
33   !! * Shared module variables
34   REAL(wp), PUBLIC :: kdca !: diss. rate constant calcite
35   REAL(wp), PUBLIC :: nca  !: order of reaction for calcite dissolution
36
37   !! * Module variables
38   REAL(wp) :: calcon = 1.03E-2           !: mean calcite concentration [Ca2+] in sea water [mole/kg solution]
39 
40   INTEGER  :: rmtss                      !: number of seconds per month
41
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
44   !! $Id: p4zlys.F90 3321 2012-03-05 17:10:55Z cetlod $
45   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47
48CONTAINS
49
50   SUBROUTINE p4z_lys( kt, knt )
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE p4z_lys  ***
53      !!
54      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
55      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
56      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      !
61      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
62      INTEGER  ::   ji, jj, jk, jn
63      REAL(wp) ::   zalk, zdic, zph, zah2
64      REAL(wp) ::   zdispot, zfact, zcalcon, zalka, zaldi
65      REAL(wp) ::   zomegaca, zexcess, zexcess0
66      CHARACTER (len=25) :: charout
67      REAL(wp), POINTER, DIMENSION(:,:,:) :: zco3, zco3sat, zcaldiss   
68      !!---------------------------------------------------------------------
69      !
70      IF( nn_timing == 1 )  CALL timing_start('p4z_lys')
71      !
72      CALL wrk_alloc( jpi, jpj, jpk, zco3, zco3sat, zcaldiss )
73      !
74      zco3    (:,:,:) = 0.
75      zcaldiss(:,:,:) = 0.
76      !     -------------------------------------------
77      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
78      !     -------------------------------------------
79     
80      DO jn = 1, 5                               !  BEGIN OF ITERATION
81         !
82         DO jk = 1, jpkm1
83            DO jj = 1, jpj
84               DO ji = 1, jpi
85                  zfact = rhop(ji,jj,jk) / 1000. + rtrn
86                  zph  = hi(ji,jj,jk) * tmask(ji,jj,jk) / zfact + ( 1.-tmask(ji,jj,jk) ) * 1.e-9 ! [H+]
87                  zdic  = trb(ji,jj,jk,jpdic) / zfact
88                  zalka = trb(ji,jj,jk,jptal) / zfact
89                  ! CALCULATE [ALK]([CO3--], [HCO3-])
90                  zalk  = zalka - ( akw3(ji,jj,jk) / zph - zph / ( aphscale(ji,jj,jk) + rtrn )  &
91                  &       + borat(ji,jj,jk) / ( 1. + zph / akb3(ji,jj,jk) ) )
92                  ! CALCULATE [H+] and [CO3--]
93                  zaldi = zdic - zalk
94                  zah2  = SQRT( zaldi * zaldi + 4.* ( zalk * ak23(ji,jj,jk) / ak13(ji,jj,jk) ) * ( zdic + zaldi ) )
95                  zah2  = 0.5 * ak13(ji,jj,jk) / zalk * ( zaldi + zah2 )
96                  !
97                  zco3(ji,jj,jk) = zalk / ( 2. + zah2 / ak23(ji,jj,jk) ) * zfact
98                  hi(ji,jj,jk)   = zah2 * zfact
99               END DO
100            END DO
101         END DO
102         !
103      END DO 
104
105      !     ---------------------------------------------------------
106      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
107      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
108      !        MGCO3)
109      !     ---------------------------------------------------------
110
111      DO jk = 1, jpkm1
112         DO jj = 1, jpj
113            DO ji = 1, jpi
114
115               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
116               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
117               zcalcon  = calcon * ( tsn(ji,jj,jk,jp_sal) / 35._wp )
118               zfact    = rhop(ji,jj,jk) / 1000._wp
119               zomegaca = ( zcalcon * zco3(ji,jj,jk) ) / ( aksp(ji,jj,jk) * zfact + rtrn )
120               zco3sat(ji,jj,jk) = aksp(ji,jj,jk) * zfact / ( zcalcon + rtrn )
121
122               ! SET DEGREE OF UNDER-/SUPERSATURATION
123               excess(ji,jj,jk) = 1._wp - zomegaca
124               zexcess0 = MAX( 0., excess(ji,jj,jk) )
125               zexcess  = zexcess0**nca
126
127               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
128               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
129               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
130               zdispot = kdca * zexcess * trb(ji,jj,jk,jpcal)
131              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
132              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
133              zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
134              zco3(ji,jj,jk)      = zco3(ji,jj,jk) + zcaldiss(ji,jj,jk)
135              !
136              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
137              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
138              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
139            END DO
140         END DO
141      END DO
142      !
143
144      IF( lk_iomput .AND. knt == nrdttrc ) THEN
145         IF( iom_use( "PH"     ) ) CALL iom_put( "PH"    , -1. * LOG10( hi(:,:,:) )          * tmask(:,:,:) )
146         IF( iom_use( "CO3"    ) ) CALL iom_put( "CO3"   , zco3(:,:,:)    * 1.e+3            * tmask(:,:,:) )
147         IF( iom_use( "CO3sat" ) ) CALL iom_put( "CO3sat", zco3sat(:,:,:) * 1.e+3            * tmask(:,:,:) )
148         IF( iom_use( "DCAL"   ) ) CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) )
149      ENDIF
150      !
151      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
152        WRITE(charout, FMT="('lys ')")
153        CALL prt_ctl_trc_info(charout)
154        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
155      ENDIF
156      !
157      CALL wrk_dealloc( jpi, jpj, jpk, zco3, zco3sat, zcaldiss )
158      !
159      IF( nn_timing == 1 )  CALL timing_stop('p4z_lys')
160      !
161   END SUBROUTINE p4z_lys
162
163   SUBROUTINE p4z_lys_init
164
165      !!----------------------------------------------------------------------
166      !!                  ***  ROUTINE p4z_lys_init  ***
167      !!
168      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
169      !!
170      !! ** Method  :   Read the nampiscal namelist and check the parameters
171      !!      called at the first timestep (nittrc000)
172      !!
173      !! ** input   :   Namelist nampiscal
174      !!
175      !!----------------------------------------------------------------------
176      INTEGER  ::  ji, jj, jk
177      INTEGER  ::  ios                 ! Local integer output status for namelist read
178      REAL(wp) ::  zcaralk, zbicarb, zco3
179      REAL(wp) ::  ztmas, ztmas1
180
181      NAMELIST/nampiscal/ kdca, nca
182      !!----------------------------------------------------------------------
183
184      REWIND( numnatp_ref )              ! Namelist nampiscal in reference namelist : Pisces CaCO3 dissolution
185      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
186901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in reference namelist', lwp )
187
188      REWIND( numnatp_cfg )              ! Namelist nampiscal in configuration namelist : Pisces CaCO3 dissolution
189      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
190902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in configuration namelist', lwp )
191      IF(lwm) WRITE ( numonp, nampiscal )
192
193      IF(lwp) THEN                         ! control print
194         WRITE(numout,*) ' '
195         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
196         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
197         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
198         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
199      ENDIF
200
201      ! Number of seconds per month
202      rmtss =  nyear_len(1) * rday / raamo
203      !
204   END SUBROUTINE p4z_lys_init
205
206#else
207   !!======================================================================
208   !!  Dummy module :                                   No PISCES bio-model
209   !!======================================================================
210CONTAINS
211   SUBROUTINE p4z_lys( kt )                   ! Empty routine
212      INTEGER, INTENT( in ) ::   kt
213      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
214   END SUBROUTINE p4z_lys
215#endif 
216   !!======================================================================
217END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.