source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmeso.F90 @ 7041

Last change on this file since 7041 was 7041, checked in by cetlod, 4 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782

File size: 17.5 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
15   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zint          !  interpolation and computation of various fields
22   USE p4zprod         !  production
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_meso              ! called in p4zbio.F90
30   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
34   REAL(wp), PUBLIC ::  xprefc       !: mesozoo preference for POC
35   REAL(wp), PUBLIC ::  xprefp       !: mesozoo preference for nanophyto
36   REAL(wp), PUBLIC ::  xprefz       !: mesozoo preference for diatoms
37   REAL(wp), PUBLIC ::  xprefpoc     !: mesozoo preference for POC
38   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
39   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
40   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
41   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
42   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
43   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
44   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
45   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
46   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
47   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
48   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
49   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
50   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
51
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
54   !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $
55   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57
58CONTAINS
59
60   SUBROUTINE p4z_meso( kt, knt )
61      !!---------------------------------------------------------------------
62      !!                     ***  ROUTINE p4z_meso  ***
63      !!
64      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
65      !!
66      !! ** Method  : - ???
67      !!---------------------------------------------------------------------
68      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
69      INTEGER  :: ji, jj, jk
70      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
71      REAL(wp) :: zgraze2 , zdenom, zdenom2
72      REAL(wp) :: zfact   , zfood, zfoodlim, zproport
73      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2
74      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
75      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat, zgrasratn
76      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
77      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
78      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
79      CHARACTER (len=25) :: charout
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
81
82      !!---------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('p4z_meso')
85      !
86      IF( lk_iomput ) THEN
87         CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
88         zgrazing(:,:,:) = 0._wp
89      ENDIF
90
91      DO jk = 1, jpkm1
92         DO jj = 1, jpj
93            DO ji = 1, jpi
94               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
95               zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
96
97               !  Respiration rates of both zooplankton
98               !  -------------------------------------
99               zrespz2   = resrat2 * zfact * trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
100                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
101
102               !  Zooplankton mortality. A square function has been selected with
103               !  no real reason except that it seems to be more stable and may mimic predation
104               !  ---------------------------------------------------------------
105               ztortz2   = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes)
106               !
107               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
108               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
109               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
110               ! it is to predation by mesozooplankton
111               ! -------------------------------------------------------------------------------
112               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
113                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
114               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
115
116               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
117               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
118               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
119               zdenom2   = zdenom / ( zfood + rtrn )
120               zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) 
121
122               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
123               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
124               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
125               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
126
127               zgraznf   = zgrazn   * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
128               zgrazf    = zgrazd   * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
129               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
130
131               !  Mesozooplankton flux feeding on GOC
132               !  ----------------------------------
133               !  ----------------------------------
134               zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
135               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)
136               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
137               zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
138               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes)
139               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
140              !
141              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
142              ! Compute the proportion of filter feeders
143              zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztot)
144              ! Compute fractionation of aggregates. It is assumed that
145              ! diatoms based aggregates are more prone to fractionation
146              ! since they are more porous (marine snow instead of fecal pellets)
147              zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
148              zratio2   = zratio * zratio
149              zfrac     = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
150               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
151               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
152              zfracfe   = zfrac * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
153
154              zgrazffep = zproport * zgrazffep
155              zgrazffeg = zproport * zgrazffeg
156              zgrazfffp = zproport * zgrazfffp
157              zgrazfffg = zproport * zgrazfffg
158              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
159              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
160              &   + zgrazpoc + zgrazffep + zgrazffeg
161              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
162
163              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
164              IF( lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
165
166              !    Mesozooplankton efficiency
167              !    --------------------------
168               zgrasrat  =  ( zgraztotf +rtrn )/ ( zgraztot + rtrn )
169               zgrasratn =  ( zgraztotn +rtrn )/ ( zgraztot + rtrn )
170               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
171               zepsherv  = zepshert * MIN( epsher2, (1. - unass2) * zgrasrat / ferat3, (1. - unass2) * zgrasratn )
172               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) &
173                &       + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz2
174               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
175                &       + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz2 )
176               zgrapoc2  = zgraztot * unass2
177
178               !   Update the arrays TRA which contain the biological sources and sinks
179               zgrarsig  = zgrarem2 * sigma2
180               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
181               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
182               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
183               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
184               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
185               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
186               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
187
188               zmortz2 = ztortz2 + zrespz2
189               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz2 + zrespz2
190               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
191               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
192               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
193               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
194               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
195               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
196               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
197               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
198               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
199               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
200
201               ! calcite production
202               zprcaca = xfracal(ji,jj,jk) * zgrazn
203               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
204               !
205               zprcaca = part2 * zprcaca
206               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
207               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
208               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
209               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
210               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
211               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
212               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
213                   &                + zgraztotf * unass2 - zfracfe
214            END DO
215         END DO
216      END DO
217      !
218      IF( lk_iomput .AND. knt == nrdttrc ) THEN
219         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
220         IF( iom_use( "GRAZ2" ) ) THEN
221            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
222            CALL iom_put( "GRAZ2", zw3d )
223         ENDIF
224         IF( iom_use( "PCAL" ) ) THEN
225            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
226            CALL iom_put( "PCAL", zw3d ) 
227         ENDIF
228         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
229      ENDIF
230      !
231      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
232        WRITE(charout, FMT="('meso')")
233        CALL prt_ctl_trc_info(charout)
234        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
235      ENDIF
236      !
237      IF( lk_iomput )  CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
238      !
239      IF( nn_timing == 1 )  CALL timing_stop('p4z_meso')
240      !
241   END SUBROUTINE p4z_meso
242
243   SUBROUTINE p4z_meso_init
244
245      !!----------------------------------------------------------------------
246      !!                  ***  ROUTINE p4z_meso_init  ***
247      !!
248      !! ** Purpose :   Initialization of mesozooplankton parameters
249      !!
250      !! ** Method  :   Read the nampismes namelist and check the parameters
251      !!      called at the first timestep (nittrc000)
252      !!
253      !! ** input   :   Namelist nampismes
254      !!
255      !!----------------------------------------------------------------------
256
257      NAMELIST/nampismes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
258         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
259         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
260      INTEGER :: ios                 ! Local integer output status for namelist read
261
262      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
263      READ  ( numnatp_ref, nampismes, IOSTAT = ios, ERR = 901)
264901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in reference namelist', lwp )
265
266      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
267      READ  ( numnatp_cfg, nampismes, IOSTAT = ios, ERR = 902 )
268902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in configuration namelist', lwp )
269      IF(lwm) WRITE ( numonp, nampismes )
270
271
272      IF(lwp) THEN                         ! control print
273         WRITE(numout,*) ' ' 
274         WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes'
275         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
276         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2        =', part2
277         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc       =', xprefc
278         WRITE(numout,*) '    mesozoo preference for POC                     xprefp       =', xprefp
279         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz       =', xprefz
280         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc     =', xprefpoc
281         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
282         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
283         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
284         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
285         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2     =', xthresh2
286         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2      =', resrat2
287         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2       =', mzrat2
288         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2     =', grazrat2
289         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux     =', grazflux
290         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2       =', unass2
291         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2      =', epsher2
292         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
293         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2      =', xkgraz2
294      ENDIF
295
296
297   END SUBROUTINE p4z_meso_init
298
299
300#else
301   !!======================================================================
302   !!  Dummy module :                                   No PISCES bio-model
303   !!======================================================================
304CONTAINS
305   SUBROUTINE p4z_meso                    ! Empty routine
306   END SUBROUTINE p4z_meso
307#endif 
308
309   !!======================================================================
310END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.