source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmicro.F90 @ 7041

Last change on this file since 7041 was 7041, checked in by cetlod, 4 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782

File size: 14.1 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
15   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zlim          !  Co-limitations
21   USE p4zsink         !  vertical flux of particulate matter due to sinking
22   USE p4zint          !  interpolation and computation of various fields
23   USE p4zprod         !  production
24   USE iom             !  I/O manager
25   USE prtctl_trc      !  print control for debugging
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   p4z_micro         ! called in p4zbio.F90
31   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
32
33   !! * Shared module variables
34   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
35   REAL(wp), PUBLIC ::  xpref2c     !: microzoo preference for POC
36   REAL(wp), PUBLIC ::  xpref2p     !: microzoo preference for nanophyto
37   REAL(wp), PUBLIC ::  xpref2d     !: microzoo preference for diatoms
38   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
39   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
40   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
41   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
42   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
43   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
44   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
45   REAL(wp), PUBLIC ::  xkgraz      !: non assimilated fraction of P by microzoo
46   REAL(wp), PUBLIC ::  unass       !: Efficicency of microzoo growth
47   REAL(wp), PUBLIC ::  sigma1      !: Fraction of microzoo excretion as DOM
48   REAL(wp), PUBLIC ::  epsher      !: half sturation constant for grazing 1
49
50
51   !!----------------------------------------------------------------------
52   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
53   !! $Id: p4zmicro.F90 3160 2011-11-20 14:27:18Z cetlod $
54   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56
57CONTAINS
58
59   SUBROUTINE p4z_micro( kt, knt )
60      !!---------------------------------------------------------------------
61      !!                     ***  ROUTINE p4z_micro  ***
62      !!
63      !! ** Purpose :   Compute the sources/sinks for microzooplankton
64      !!
65      !! ** Method  : - ???
66      !!---------------------------------------------------------------------
67      INTEGER, INTENT(in) ::  kt  ! ocean time step
68      INTEGER, INTENT(in) ::  knt 
69      !
70      INTEGER  :: ji, jj, jk
71      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
72      REAL(wp) :: zgraze  , zdenom, zdenom2
73      REAL(wp) :: zfact   , zfood, zfoodlim
74      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
75      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
76      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
77      REAL(wp) :: zgrazp, zgrazm, zgrazsd
78      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
79      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
80      CHARACTER (len=25) :: charout
81      !!---------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('p4z_micro')
84      !
85      IF( lk_iomput )  CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
86      !
87      DO jk = 1, jpkm1
88         DO jj = 1, jpj
89            DO ji = 1, jpi
90               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
91               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
92
93               !  Respiration rates of both zooplankton
94               !  -------------------------------------
95               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
96                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
97
98               !  Zooplankton mortality. A square function has been selected with
99               !  no real reason except that it seems to be more stable and may mimic predation.
100               !  ---------------------------------------------------------------
101               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo)
102
103               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
104               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
105               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
106               
107               !     Microzooplankton grazing
108               !     ------------------------
109               zfood     = xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi
110               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
111               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
112               zdenom2   = zdenom / ( zfood + rtrn )
113               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) 
114
115               zgrazp    = zgraze  * xpref2p * zcompaph  * zdenom2 
116               zgrazm    = zgraze  * xpref2c * zcompapoc * zdenom2 
117               zgrazsd   = zgraze  * xpref2d * zcompadi  * zdenom2 
118
119               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
120               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
121               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
122               !
123               zgraztot  = zgrazp  + zgrazm  + zgrazsd 
124               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
125               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
126
127               ! Grazing by microzooplankton
128               IF( lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
129
130               !    Various remineralization and excretion terms
131               !    --------------------------------------------
132               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztot + rtrn )
133               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztot + rtrn )
134               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
135               zepsherv  = zepshert * MIN( epsher, (1. - unass) * zgrasrat / ferat3, (1. - unass) * zgrasratn )
136               zgrafer   = zgraztot * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
137               zgrarem   = zgraztot * ( 1. - zepsherv - unass )
138               zgrapoc   = zgraztot * unass
139
140               !  Update of the TRA arrays
141               !  ------------------------
142               zgrarsig  = zgrarem * sigma1
143               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
144               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
145               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
146               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
147               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
148               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
149               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
150               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
151               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
152               !   Update the arrays TRA which contain the biological sources and sinks
153               !   --------------------------------------------------------------------
154               zmortz = ztortz + zrespz
155               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztot 
156               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
157               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
158               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
159               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
160               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
161               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
162               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
163               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
164               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
165               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
166               !
167               ! calcite production
168               zprcaca = xfracal(ji,jj,jk) * zgrazp
169               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
170               !
171               zprcaca = part * zprcaca
172               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
173               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
174               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
175            END DO
176         END DO
177      END DO
178      !
179      IF( lk_iomput .AND. knt == nrdttrc ) THEN
180         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
181         IF( iom_use( "GRAZ1" ) ) THEN
182            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
183            CALL iom_put( "GRAZ1", zw3d )
184         ENDIF
185         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
186      ENDIF
187      !
188      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
189         WRITE(charout, FMT="('micro')")
190         CALL prt_ctl_trc_info(charout)
191         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
192      ENDIF
193      !
194      IF( lk_iomput )  CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
195      !
196      IF( nn_timing == 1 )  CALL timing_stop('p4z_micro')
197      !
198   END SUBROUTINE p4z_micro
199
200
201   SUBROUTINE p4z_micro_init
202
203      !!----------------------------------------------------------------------
204      !!                  ***  ROUTINE p4z_micro_init  ***
205      !!
206      !! ** Purpose :   Initialization of microzooplankton parameters
207      !!
208      !! ** Method  :   Read the nampiszoo namelist and check the parameters
209      !!                called at the first timestep (nittrc000)
210      !!
211      !! ** input   :   Namelist nampiszoo
212      !!
213      !!----------------------------------------------------------------------
214
215      NAMELIST/nampiszoo/ part, grazrat, resrat, mzrat, xpref2c, xpref2p, &
216         &                xpref2d,  xthreshdia,  xthreshphy,  xthreshpoc, &
217         &                xthresh, xkgraz, epsher, sigma1, unass
218      INTEGER :: ios                 ! Local integer output status for namelist read
219
220      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
221      READ  ( numnatp_ref, nampiszoo, IOSTAT = ios, ERR = 901)
222901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiszoo in reference namelist', lwp )
223
224      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
225      READ  ( numnatp_cfg, nampiszoo, IOSTAT = ios, ERR = 902 )
226902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiszoo in configuration namelist', lwp )
227      IF(lwm) WRITE ( numonp, nampiszoo )
228
229      IF(lwp) THEN                         ! control print
230         WRITE(numout,*) ' '
231         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszoo'
232         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
233         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
234         WRITE(numout,*) '    microzoo preference for POC                     xpref2c     =', xpref2c
235         WRITE(numout,*) '    microzoo preference for nano                    xpref2p     =', xpref2p
236         WRITE(numout,*) '    microzoo preference for diatoms                 xpref2d     =', xpref2d
237         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
238         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
239         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
240         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
241         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
242         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
243         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
244         WRITE(numout,*) '    non assimilated fraction of P by microzoo       unass       =', unass
245         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
246         WRITE(numout,*) '    Fraction of microzoo excretion as DOM           sigma1      =', sigma1
247         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
248      ENDIF
249
250   END SUBROUTINE p4z_micro_init
251
252#else
253   !!======================================================================
254   !!  Dummy module :                                   No PISCES bio-model
255   !!======================================================================
256CONTAINS
257   SUBROUTINE p4z_micro                    ! Empty routine
258   END SUBROUTINE p4z_micro
259#endif 
260
261   !!======================================================================
262END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.