New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmicro.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmicro.F90 @ 7068

Last change on this file since 7068 was 7068, checked in by cetlod, 8 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782
File size: 13.5 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
11   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations
17   USE p4zsink         !  vertical flux of particulate matter due to sinking
18   USE p4zint          !  interpolation and computation of various fields
19   USE p4zprod         !  production
20   USE iom             !  I/O manager
21   USE prtctl_trc      !  print control for debugging
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_micro         ! called in p4zbio.F90
27   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
31   REAL(wp), PUBLIC ::  xpref2c     !: microzoo preference for POC
32   REAL(wp), PUBLIC ::  xpref2p     !: microzoo preference for nanophyto
33   REAL(wp), PUBLIC ::  xpref2d     !: microzoo preference for diatoms
34   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
35   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
36   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
37   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
38   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
39   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
40   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
41   REAL(wp), PUBLIC ::  xkgraz      !: non assimilated fraction of P by microzoo
42   REAL(wp), PUBLIC ::  unass       !: Efficicency of microzoo growth
43   REAL(wp), PUBLIC ::  sigma1      !: Fraction of microzoo excretion as DOM
44   REAL(wp), PUBLIC ::  epsher      !: half sturation constant for grazing 1
45
46
47   !!----------------------------------------------------------------------
48   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
49   !! $Id: p4zmicro.F90 3160 2011-11-20 14:27:18Z cetlod $
50   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52
53CONTAINS
54
55   SUBROUTINE p4z_micro( kt, knt )
56      !!---------------------------------------------------------------------
57      !!                     ***  ROUTINE p4z_micro  ***
58      !!
59      !! ** Purpose :   Compute the sources/sinks for microzooplankton
60      !!
61      !! ** Method  : - ???
62      !!---------------------------------------------------------------------
63      INTEGER, INTENT(in) ::  kt  ! ocean time step
64      INTEGER, INTENT(in) ::  knt 
65      !
66      INTEGER  :: ji, jj, jk
67      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
68      REAL(wp) :: zgraze  , zdenom, zdenom2
69      REAL(wp) :: zfact   , zfood, zfoodlim
70      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
71      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
72      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
73      REAL(wp) :: zgrazp, zgrazm, zgrazsd
74      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
75      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
76      CHARACTER (len=25) :: charout
77      !!---------------------------------------------------------------------
78      !
79      IF( nn_timing == 1 )  CALL timing_start('p4z_micro')
80      !
81      IF( lk_iomput )  CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
82      !
83      DO jk = 1, jpkm1
84         DO jj = 1, jpj
85            DO ji = 1, jpi
86               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
87               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
88
89               !  Respiration rates of both zooplankton
90               !  -------------------------------------
91               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
92                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
93
94               !  Zooplankton mortality. A square function has been selected with
95               !  no real reason except that it seems to be more stable and may mimic predation.
96               !  ---------------------------------------------------------------
97               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo)
98
99               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
100               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
101               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
102               
103               !     Microzooplankton grazing
104               !     ------------------------
105               zfood     = xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi
106               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
107               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
108               zdenom2   = zdenom / ( zfood + rtrn )
109               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) 
110
111               zgrazp    = zgraze  * xpref2p * zcompaph  * zdenom2 
112               zgrazm    = zgraze  * xpref2c * zcompapoc * zdenom2 
113               zgrazsd   = zgraze  * xpref2d * zcompadi  * zdenom2 
114
115               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
116               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
117               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
118               !
119               zgraztot  = zgrazp  + zgrazm  + zgrazsd 
120               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
121               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
122
123               ! Grazing by microzooplankton
124               IF( lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
125
126               !    Various remineralization and excretion terms
127               !    --------------------------------------------
128               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztot + rtrn )
129               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztot + rtrn )
130               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
131               zepsherv  = zepshert * MIN( epsher, (1. - unass) * zgrasrat / ferat3, (1. - unass) * zgrasratn )
132               zgrafer   = zgraztot * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
133               zgrarem   = zgraztot * ( 1. - zepsherv - unass )
134               zgrapoc   = zgraztot * unass
135
136               !  Update of the TRA arrays
137               !  ------------------------
138               zgrarsig  = zgrarem * sigma1
139               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
140               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
141               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
142               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
143               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
144               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
145               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
146               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
147               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
148               !   Update the arrays TRA which contain the biological sources and sinks
149               !   --------------------------------------------------------------------
150               zmortz = ztortz + zrespz
151               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztot 
152               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
153               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
154               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
155               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
156               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
157               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
158               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
159               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
160               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
161               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
162               !
163               ! calcite production
164               zprcaca = xfracal(ji,jj,jk) * zgrazp
165               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
166               !
167               zprcaca = part * zprcaca
168               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
169               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
170               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
171            END DO
172         END DO
173      END DO
174      !
175      IF( lk_iomput .AND. knt == nrdttrc ) THEN
176         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
177         IF( iom_use( "GRAZ1" ) ) THEN
178            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
179            CALL iom_put( "GRAZ1", zw3d )
180         ENDIF
181         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
182      ENDIF
183      !
184      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
185         WRITE(charout, FMT="('micro')")
186         CALL prt_ctl_trc_info(charout)
187         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
188      ENDIF
189      !
190      IF( lk_iomput )  CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
191      !
192      IF( nn_timing == 1 )  CALL timing_stop('p4z_micro')
193      !
194   END SUBROUTINE p4z_micro
195
196
197   SUBROUTINE p4z_micro_init
198
199      !!----------------------------------------------------------------------
200      !!                  ***  ROUTINE p4z_micro_init  ***
201      !!
202      !! ** Purpose :   Initialization of microzooplankton parameters
203      !!
204      !! ** Method  :   Read the nampiszoo namelist and check the parameters
205      !!                called at the first timestep (nittrc000)
206      !!
207      !! ** input   :   Namelist nampiszoo
208      !!
209      !!----------------------------------------------------------------------
210
211      NAMELIST/nampiszoo/ part, grazrat, resrat, mzrat, xpref2c, xpref2p, &
212         &                xpref2d,  xthreshdia,  xthreshphy,  xthreshpoc, &
213         &                xthresh, xkgraz, epsher, sigma1, unass
214      INTEGER :: ios                 ! Local integer output status for namelist read
215
216      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
217      READ  ( numnatp_ref, nampiszoo, IOSTAT = ios, ERR = 901)
218901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiszoo in reference namelist', lwp )
219
220      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
221      READ  ( numnatp_cfg, nampiszoo, IOSTAT = ios, ERR = 902 )
222902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiszoo in configuration namelist', lwp )
223      IF(lwm) WRITE ( numonp, nampiszoo )
224
225      IF(lwp) THEN                         ! control print
226         WRITE(numout,*) ' '
227         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszoo'
228         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
229         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
230         WRITE(numout,*) '    microzoo preference for POC                     xpref2c     =', xpref2c
231         WRITE(numout,*) '    microzoo preference for nano                    xpref2p     =', xpref2p
232         WRITE(numout,*) '    microzoo preference for diatoms                 xpref2d     =', xpref2d
233         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
234         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
235         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
236         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
237         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
238         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
239         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
240         WRITE(numout,*) '    non assimilated fraction of P by microzoo       unass       =', unass
241         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
242         WRITE(numout,*) '    Fraction of microzoo excretion as DOM           sigma1      =', sigma1
243         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
244      ENDIF
245
246   END SUBROUTINE p4z_micro_init
247
248   !!======================================================================
249END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.