New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmort.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmort.F90 @ 7068

Last change on this file since 7068 was 7068, checked in by cetlod, 8 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782
  • Property svn:keywords set to Id
File size: 11.2 KB
Line 
1MODULE p4zmort
2   !!======================================================================
3   !!                         ***  MODULE p4zmort  ***
4   !! TOP :   PISCES Compute the mortality terms for phytoplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont)  Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9   !!   p4z_mort       :   Compute the mortality terms for phytoplankton
10   !!   p4z_mort_init  :   Initialize the mortality params for phytoplankton
11   !!----------------------------------------------------------------------
12   USE oce_trc         !  shared variables between ocean and passive tracers
13   USE trc             !  passive tracers common variables
14   USE sms_pisces      !  PISCES Source Minus Sink variables
15   USE p4zsink         !  vertical flux of particulate matter due to sinking
16   USE p4zprod         !  Primary productivity
17   USE prtctl_trc      !  print control for debugging
18
19   IMPLICIT NONE
20   PRIVATE
21
22   PUBLIC   p4z_mort   
23   PUBLIC   p4z_mort_init   
24
25   !! * Shared module variables
26   REAL(wp), PUBLIC :: wchl    !:
27   REAL(wp), PUBLIC :: wchld   !:
28   REAL(wp), PUBLIC :: wchldm  !:
29   REAL(wp), PUBLIC :: mprat   !:
30   REAL(wp), PUBLIC :: mprat2  !:
31
32
33   !!----------------------------------------------------------------------
34   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
35   !! $Id$
36   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38
39CONTAINS
40
41   SUBROUTINE p4z_mort( kt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE p4z_mort  ***
44      !!
45      !! ** Purpose :   Calls the different subroutine to initialize and compute
46      !!                the different phytoplankton mortality terms
47      !!
48      !! ** Method  : - ???
49      !!---------------------------------------------------------------------
50      INTEGER, INTENT(in) ::   kt ! ocean time step
51      !!---------------------------------------------------------------------
52
53      CALL p4z_nano            ! nanophytoplankton
54
55      CALL p4z_diat            ! diatoms
56
57   END SUBROUTINE p4z_mort
58
59
60   SUBROUTINE p4z_nano
61      !!---------------------------------------------------------------------
62      !!                     ***  ROUTINE p4z_nano  ***
63      !!
64      !! ** Purpose :   Compute the mortality terms for nanophytoplankton
65      !!
66      !! ** Method  : - ???
67      !!---------------------------------------------------------------------
68      INTEGER  :: ji, jj, jk
69      REAL(wp) :: zsizerat, zcompaph
70      REAL(wp) :: zfactfe, zfactch, zprcaca, zfracal
71      REAL(wp) :: ztortp , zrespp , zmortp
72      CHARACTER (len=25) :: charout
73      !!---------------------------------------------------------------------
74      !
75      IF( nn_timing == 1 )  CALL timing_start('p4z_nano')
76      !
77      prodcal(:,:,:) = 0.  !: calcite production variable set to zero
78      DO jk = 1, jpkm1
79         DO jj = 1, jpj
80            DO ji = 1, jpi
81               zcompaph = MAX( ( trb(ji,jj,jk,jpphy) - 1e-8 ), 0.e0 )
82               !     When highly limited by macronutrients, very small cells
83               !     dominate the community. As a consequence, aggregation
84               !     due to turbulence is negligible. Mortality is also set
85               !     to 0
86               zsizerat = MIN(1., MAX( 0., (quotan(ji,jj,jk) - 0.2) / 0.3) ) * trb(ji,jj,jk,jpphy)
87               !     Squared mortality of Phyto similar to a sedimentation term during
88               !     blooms (Doney et al. 1996)
89               zrespp = wchl * 1.e6 * xstep * xdiss(ji,jj,jk) * zcompaph * zsizerat 
90
91               !     Phytoplankton mortality. This mortality loss is slightly
92               !     increased when nutrients are limiting phytoplankton growth
93               !     as observed for instance in case of iron limitation.
94               ztortp = mprat * xstep * zcompaph / ( xkmort + trb(ji,jj,jk,jpphy) ) * zsizerat
95
96               zmortp = zrespp + ztortp
97
98               !   Update the arrays TRA which contains the biological sources and sinks
99
100               zfactfe = trb(ji,jj,jk,jpnfe)/(trb(ji,jj,jk,jpphy)+rtrn)
101               zfactch = trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
102               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zmortp
103               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zmortp * zfactch
104               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zmortp * zfactfe
105               zprcaca = xfracal(ji,jj,jk) * zmortp
106               !
107               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
108               !
109               zfracal = 0.5 * xfracal(ji,jj,jk)
110               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
111               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
112               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
113               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfracal * zmortp
114               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ( 1. - zfracal ) * zmortp
115               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ( 1. - zfracal ) * zmortp * zfactfe
116               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zfracal * zmortp * zfactfe
117            END DO
118         END DO
119      END DO
120      !
121       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
122         WRITE(charout, FMT="('nano')")
123         CALL prt_ctl_trc_info(charout)
124         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
125       ENDIF
126      !
127      IF( nn_timing == 1 )  CALL timing_stop('p4z_nano')
128      !
129   END SUBROUTINE p4z_nano
130
131   SUBROUTINE p4z_diat
132      !!---------------------------------------------------------------------
133      !!                     ***  ROUTINE p4z_diat  ***
134      !!
135      !! ** Purpose :   Compute the mortality terms for diatoms
136      !!
137      !! ** Method  : - ???
138      !!---------------------------------------------------------------------
139      INTEGER  ::  ji, jj, jk
140      REAL(wp) ::  zfactfe,zfactsi,zfactch, zcompadi
141      REAL(wp) ::  zrespp2, ztortp2, zmortp2
142      REAL(wp) ::  zlim2, zlim1
143      CHARACTER (len=25) :: charout
144      !!---------------------------------------------------------------------
145      !
146      IF( nn_timing == 1 )  CALL timing_start('p4z_diat')
147      !
148
149      !    Aggregation term for diatoms is increased in case of nutrient
150      !    stress as observed in reality. The stressed cells become more
151      !    sticky and coagulate to sink quickly out of the euphotic zone
152      !     ------------------------------------------------------------
153
154      DO jk = 1, jpkm1
155         DO jj = 1, jpj
156            DO ji = 1, jpi
157
158               zcompadi = MAX( ( trb(ji,jj,jk,jpdia) - 1e-9), 0. )
159
160               !    Aggregation term for diatoms is increased in case of nutrient
161               !    stress as observed in reality. The stressed cells become more
162               !    sticky and coagulate to sink quickly out of the euphotic zone
163               !     ------------------------------------------------------------
164               !  Phytoplankton respiration
165               !     ------------------------
166               zlim2   = xlimdia(ji,jj,jk) * xlimdia(ji,jj,jk)
167               zlim1   = 0.25 * ( 1. - zlim2 ) / ( 0.25 + zlim2 ) 
168               zrespp2 = 1.e6 * xstep * (  wchld + wchldm * zlim1 ) * xdiss(ji,jj,jk) * zcompadi * trb(ji,jj,jk,jpdia)
169
170               !     Phytoplankton mortality.
171               !     ------------------------
172               ztortp2 = mprat2 * xstep * trb(ji,jj,jk,jpdia)  / ( xkmort + trb(ji,jj,jk,jpdia) ) * zcompadi 
173
174               zmortp2 = zrespp2 + ztortp2
175
176               !   Update the arrays tra which contains the biological sources and sinks
177               !   ---------------------------------------------------------------------
178               zfactch = trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
179               zfactfe = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
180               zfactsi = trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
181               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zmortp2 
182               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zmortp2 * zfactch
183               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zmortp2 * zfactfe
184               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zmortp2 * zfactsi
185               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zmortp2 * zfactsi
186               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zrespp2 + 0.5 * ztortp2
187               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + 0.5 * ztortp2
188               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 0.5 * ztortp2 * zfactfe
189               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ( zrespp2 + 0.5 * ztortp2 ) * zfactfe
190            END DO
191         END DO
192      END DO
193      !
194      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
195         WRITE(charout, FMT="('diat')")
196         CALL prt_ctl_trc_info(charout)
197         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
198      ENDIF
199      !
200      IF( nn_timing == 1 )  CALL timing_stop('p4z_diat')
201      !
202   END SUBROUTINE p4z_diat
203
204   SUBROUTINE p4z_mort_init
205
206      !!----------------------------------------------------------------------
207      !!                  ***  ROUTINE p4z_mort_init  ***
208      !!
209      !! ** Purpose :   Initialization of phytoplankton parameters
210      !!
211      !! ** Method  :   Read the nampismort namelist and check the parameters
212      !!      called at the first timestep
213      !!
214      !! ** input   :   Namelist nampismort
215      !!
216      !!----------------------------------------------------------------------
217
218      NAMELIST/nampismort/ wchl, wchld, wchldm, mprat, mprat2
219      INTEGER :: ios                 ! Local integer output status for namelist read
220
221      REWIND( numnatp_ref )              ! Namelist nampismort in reference namelist : Pisces phytoplankton
222      READ  ( numnatp_ref, nampismort, IOSTAT = ios, ERR = 901)
223901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismort in reference namelist', lwp )
224
225      REWIND( numnatp_cfg )              ! Namelist nampismort in configuration namelist : Pisces phytoplankton
226      READ  ( numnatp_cfg, nampismort, IOSTAT = ios, ERR = 902 )
227902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismort in configuration namelist', lwp )
228      IF(lwm) WRITE ( numonp, nampismort )
229
230      IF(lwp) THEN                         ! control print
231         WRITE(numout,*) ' '
232         WRITE(numout,*) ' Namelist parameters for phytoplankton mortality, nampismort'
233         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
234         WRITE(numout,*) '    quadratic mortality of phytoplankton      wchl      =', wchl
235         WRITE(numout,*) '    maximum quadratic mortality of diatoms    wchld     =', wchld
236         WRITE(numout,*) '    maximum quadratic mortality of diatoms    wchldm    =', wchldm
237         WRITE(numout,*) '    phytoplankton mortality rate              mprat     =', mprat
238         WRITE(numout,*) '    Diatoms mortality rate                    mprat2    =', mprat2
239      ENDIF
240
241   END SUBROUTINE p4z_mort_init
242
243   !!======================================================================
244END MODULE p4zmort
Note: See TracBrowser for help on using the repository browser.