New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 7162

Last change on this file since 7162 was 7162, checked in by cetlod, 7 years ago

new top interface : Add PISCES quota model
File size: 28.6 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  :   Initialization of the parameters for growth
12   !!   p4z_prod_alloc :   Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zlim          !  Co-limitations of differents nutrients
18   USE prtctl_trc      !  print control for debugging
19   USE iom             !  I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_prod         ! called in p4zbio.F90
25   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
26   PUBLIC   p4z_prod_alloc
27
28   !! * Shared module variables
29   LOGICAL , PUBLIC ::  ln_newprod      !:
30   REAL(wp), PUBLIC ::  pislopen         !:
31   REAL(wp), PUBLIC ::  pisloped        !:
32   REAL(wp), PUBLIC ::  xadap           !:
33   REAL(wp), PUBLIC ::  excretn          !:
34   REAL(wp), PUBLIC ::  excretd         !:
35   REAL(wp), PUBLIC ::  bresp           !:
36   REAL(wp), PUBLIC ::  chlcnm          !:
37   REAL(wp), PUBLIC ::  chlcdm          !:
38   REAL(wp), PUBLIC ::  chlcmin         !:
39   REAL(wp), PUBLIC ::  fecnm           !:
40   REAL(wp), PUBLIC ::  fecdm           !:
41   REAL(wp), PUBLIC ::  grosip          !:
42
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
46   
47   REAL(wp) :: r1_rday                !: 1 / rday
48   REAL(wp) :: texcretn               !: 1 - excretn
49   REAL(wp) :: texcretd               !: 1 - excretd       
50
51   !!----------------------------------------------------------------------
52   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
53   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE p4z_prod( kt , knt )
59      !!---------------------------------------------------------------------
60      !!                     ***  ROUTINE p4z_prod  ***
61      !!
62      !! ** Purpose :   Compute the phytoplankton production depending on
63      !!              light, temperature and nutrient availability
64      !!
65      !! ** Method  : - ???
66      !!---------------------------------------------------------------------
67      !
68      INTEGER, INTENT(in) :: kt, knt
69      !
70      INTEGER  ::   ji, jj, jk
71      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
72      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
73      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
74      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
75      REAL(wp) ::   zmxltst, zmxlday
76      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
77      REAL(wp) ::   zfact
78      CHARACTER (len=25) :: charout
79      REAL(wp), POINTER, DIMENSION(:,:  ) :: zstrn, zw2d, zmixnano, zmixdiat
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopeadn, zpislopeadd, zysopt, zw3d   
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprdia, zprbio, zprdch, zprnch   
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcad, zprofed, zprofen
83      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpronewn, zpronewd
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zmxl_fac, zmxl_chl
85      !!---------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
88      !
89      !  Allocate temporary workspace
90      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn )
91      CALL wrk_alloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
92      CALL wrk_alloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
93      CALL wrk_alloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
94      !
95      zprorcan(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
96      zprofen (:,:,:) = 0._wp ; zysopt  (:,:,:) = 0._wp
97      zpronewn(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
98      zprbio  (:,:,:) = 0._wp ; zprdch  (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
99      zmxl_fac(:,:,:) = 0._wp ; zmxl_chl(:,:,:) = 0._wp 
100
101      ! Computation of the optimal production
102      prmax(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:) 
103
104      ! compute the day length depending on latitude and the day
105      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
106      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
107
108      ! day length in hours
109      zstrn(:,:) = 0.
110      DO jj = 1, jpj
111         DO ji = 1, jpi
112            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
113            zargu = MAX( -1., MIN(  1., zargu ) )
114            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
115         END DO
116      END DO
117
118      ! Impact of the day duration and light intermittency on phytoplankton growth
119      DO jk = 1, jpkm1
120         DO jj = 1 ,jpj
121            DO ji = 1, jpi
122               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
123                  zval = MAX( 1., zstrn(ji,jj) )
124                  IF( gdept_n(ji,jj,jk) <= hmld(ji,jj) ) THEN
125                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
126                  ENDIF
127                  zmxl_chl(ji,jj,jk) = zval / 24.
128                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
129               ENDIF
130            END DO
131         END DO
132      END DO
133
134      zprbio(:,:,:) = prmax(:,:,:) * zmxl_fac(:,:,:)
135      zprdia(:,:,:) = zprbio(:,:,:)
136
137      ! Maximum light intensity
138      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
139
140      ! Computation of the P-I slope for nanos and diatoms
141      DO jk = 1, jpkm1
142         DO jj = 1, jpj
143            DO ji = 1, jpi
144               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
145                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
146                  zadap       = xadap * ztn / ( 2.+ ztn )
147                  zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
148                  zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
149                  !
150                  zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
151                  &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
152                  !
153                  zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
154                  &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
155               ENDIF
156            END DO
157         END DO
158      END DO
159
160      IF( ln_newprod ) THEN
161         DO jk = 1, jpkm1
162            DO jj = 1, jpj
163               DO ji = 1, jpi
164                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
165                      ! Computation of production function for Carbon
166                      !  ---------------------------------------------
167                      zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
168                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
169                      zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
170                      &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
171                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
172                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
173                      !  Computation of production function for Chlorophyll
174                      !--------------------------------------------------
175                      zpislopen = zpislopeadn(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
176                      zpisloped = zpislopeadd(ji,jj,jk) / ( prmax(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
177                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
178                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
179                  ENDIF
180               END DO
181            END DO
182         END DO
183      ELSE
184         DO jk = 1, jpkm1
185            DO jj = 1, jpj
186               DO ji = 1, jpi
187                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
188                      ! Computation of production function for Carbon
189                      !  ---------------------------------------------
190                      zpislopen = zpislopeadn(ji,jj,jk)  / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
191                      zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
192                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
193                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
194                      !  Computation of production function for Chlorophyll
195                      !--------------------------------------------------
196                      zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
197                      zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
198                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) ) )
199                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) ) )
200                  ENDIF
201               END DO
202            END DO
203         END DO
204      ENDIF
205
206      !  Computation of a proxy of the N/C ratio
207      !  ---------------------------------------
208      DO jk = 1, jpkm1
209         DO jj = 1, jpj
210            DO ji = 1, jpi
211                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
212                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
213                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
214                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
215                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
216                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
217            END DO
218         END DO
219      END DO
220
221
222      DO jk = 1, jpkm1
223         DO jj = 1, jpj
224            DO ji = 1, jpi
225
226                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
227                   !    Si/C of diatoms
228                   !    ------------------------
229                   !    Si/C increases with iron stress and silicate availability
230                   !    Si/C is arbitrariliy increased for very high Si concentrations
231                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
232                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
233                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
234                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
235                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
236                  IF (gphit(ji,jj) < -30 ) THEN
237                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
238                  ELSE
239                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
240                  ENDIF
241                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
242              ENDIF
243            END DO
244         END DO
245      END DO
246
247      !  Mixed-layer effect on production
248      !  Sea-ice effect on production
249
250      DO jk = 1, jpkm1
251         DO jj = 1, jpj
252            DO ji = 1, jpi
253               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
254               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
255            END DO
256         END DO
257      END DO
258
259      ! Computation of the various production terms
260      DO jk = 1, jpkm1
261         DO jj = 1, jpj
262            DO ji = 1, jpi
263               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
264                  !  production terms for nanophyto. (C)
265                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
266                  zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
267                  !
268                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) * fecnm + rtrn )
269                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
270                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
271                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
272                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
273                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
274                  !  production terms for diatoms (C)
275                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
276                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
277                  !
278                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) * fecdm + rtrn )
279                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
280                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
281                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
282                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
283                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
284               ENDIF
285            END DO
286         END DO
287      END DO
288
289      ! Computation of the chlorophyll production terms
290      DO jk = 1, jpkm1
291         DO jj = 1, jpj
292            DO ji = 1, jpi
293               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
294                  !  production terms for nanophyto. ( chlorophyll )
295                  znanotot = enano(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
296                  zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
297                  zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
298                  chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
299                  zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
300                                        & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
301                  !  production terms for diatoms ( chlorophyll )
302                  zdiattot = ediat(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
303                  zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
304                  zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
305                  chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * tsn(ji,jj,jk,jp_tem))) * (1. - 1.14 / 43.4 * 20.))
306                  zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
307                                        & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
308                  !   Update the arrays TRA which contain the Chla sources and sinks
309                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
310                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
311               ENDIF
312            END DO
313         END DO
314      END DO
315
316      !   Update the arrays TRA which contain the biological sources and sinks
317      DO jk = 1, jpkm1
318         DO jj = 1, jpj
319           DO ji =1 ,jpi
320              IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
321                 zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
322                 zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
323                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
324                 tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
325                 tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
326                 tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
327                 tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn
328                 tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
329                 tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd
330                 tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
331                 tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
332                 tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zdocprod
333                 tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
334                 &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
335                 !
336                 zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
337                 tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
338                 tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
339                 tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
340                 tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
341                 &                                         - rno3 * ( zproreg + zproreg2 )
342              ENDIF
343           END DO
344        END DO
345     END DO
346     !
347     IF( ln_ligand ) THEN
348         DO jk = 1, jpkm1
349            DO jj = 1, jpj
350              DO ji =1 ,jpi
351                 IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
352                    zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
353                    zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
354                    tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
355                 ENDIF
356              END DO
357           END DO
358        END DO
359     ENDIF
360
361
362    ! Total primary production per year
363    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
364         & tpp = glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
365
366    IF( lk_iomput ) THEN
367       IF( knt == nrdttrc ) THEN
368          CALL wrk_alloc( jpi, jpj,      zw2d )
369          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
370          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
371          !
372          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) )  THEN
373              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
374              CALL iom_put( "PPPHYN"  , zw3d )
375              !
376              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
377              CALL iom_put( "PPPHYD"  , zw3d )
378          ENDIF
379          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
380              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
381              CALL iom_put( "PPNEWN"  , zw3d )
382              !
383              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
384              CALL iom_put( "PPNEWD"  , zw3d )
385          ENDIF
386          IF( iom_use( "PBSi" ) )  THEN
387              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
388              CALL iom_put( "PBSi"  , zw3d )
389          ENDIF
390          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
391              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
392              CALL iom_put( "PFeN"  , zw3d )
393              !
394              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
395              CALL iom_put( "PFeD"  , zw3d )
396          ENDIF
397          IF( iom_use( "Mumax" ) )  THEN
398              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
399              CALL iom_put( "Mumax"  , zw3d )
400          ENDIF
401          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
402              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
403              CALL iom_put( "MuN"  , zw3d )
404              !
405              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
406              CALL iom_put( "MuD"  , zw3d )
407          ENDIF
408          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
409              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
410              CALL iom_put( "LNlight"  , zw3d )
411              !
412              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
413              CALL iom_put( "LDlight"  , zw3d )
414          ENDIF
415          IF( iom_use( "TPP" ) )  THEN
416              zw3d(:,:,:) = ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
417              CALL iom_put( "TPP"  , zw3d )
418          ENDIF
419          IF( iom_use( "TPNEW" ) )  THEN
420              zw3d(:,:,:) = ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
421              CALL iom_put( "TPNEW"  , zw3d )
422          ENDIF
423          IF( iom_use( "TPBFE" ) )  THEN
424              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
425              CALL iom_put( "TPBFE"  , zw3d )
426          ENDIF
427          IF( iom_use( "INTPPPHYN" ) .OR. iom_use( "INTPPPHYD" ) ) THEN 
428             zw2d(:,:) = 0.
429             DO jk = 1, jpkm1
430               zw2d(:,:) = zw2d(:,:) + zprorcan(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
431             ENDDO
432             CALL iom_put( "INTPPPHYN" , zw2d )
433             !
434             zw2d(:,:) = 0.
435             DO jk = 1, jpkm1
436                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
437             ENDDO
438             CALL iom_put( "INTPPPHYD" , zw2d )
439          ENDIF
440          IF( iom_use( "INTPP" ) ) THEN   
441             zw2d(:,:) = 0.
442             DO jk = 1, jpkm1
443                zw2d(:,:) = zw2d(:,:) + ( zprorcan(:,:,jk) + zprorcad(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
444             ENDDO
445             CALL iom_put( "INTPP" , zw2d )
446          ENDIF
447          IF( iom_use( "INTPNEW" ) ) THEN   
448             zw2d(:,:) = 0.
449             DO jk = 1, jpkm1
450                zw2d(:,:) = zw2d(:,:) + ( zpronewn(:,:,jk) + zpronewd(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
451             ENDDO
452             CALL iom_put( "INTPNEW" , zw2d )
453          ENDIF
454          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
455             zw2d(:,:) = 0.
456             DO jk = 1, jpkm1
457                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
458             ENDDO
459            CALL iom_put( "INTPBFE" , zw2d )
460          ENDIF
461          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
462             zw2d(:,:) = 0.
463             DO jk = 1, jpkm1
464                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
465             ENDDO
466             CALL iom_put( "INTPBSI" , zw2d )
467          ENDIF
468          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
469          !
470          CALL wrk_dealloc( jpi, jpj,      zw2d )
471          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
472       ENDIF
473     ENDIF
474
475     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
476         WRITE(charout, FMT="('prod')")
477         CALL prt_ctl_trc_info(charout)
478         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
479     ENDIF
480     !
481     CALL wrk_dealloc( jpi, jpj,  zmixnano, zmixdiat,    zstrn )
482     CALL wrk_dealloc( jpi, jpj, jpk, zpislopeadn, zpislopeadd, zprdia, zprbio, zprdch, zprnch, zysopt ) 
483     CALL wrk_dealloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
484     CALL wrk_dealloc( jpi, jpj, jpk, zprorcan, zprorcad, zprofed, zprofen, zpronewn, zpronewd )
485     !
486     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
487     !
488   END SUBROUTINE p4z_prod
489
490
491   SUBROUTINE p4z_prod_init
492      !!----------------------------------------------------------------------
493      !!                  ***  ROUTINE p4z_prod_init  ***
494      !!
495      !! ** Purpose :   Initialization of phytoplankton production parameters
496      !!
497      !! ** Method  :   Read the nampisprod namelist and check the parameters
498      !!      called at the first timestep (nittrc000)
499      !!
500      !! ** input   :   Namelist nampisprod
501      !!----------------------------------------------------------------------
502      !
503      NAMELIST/namp4zprod/ pislopen, pisloped, xadap, ln_newprod, bresp, excretn, excretd,  &
504         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
505      INTEGER :: ios                 ! Local integer output status for namelist read
506      !!----------------------------------------------------------------------
507
508      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
509      READ  ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901)
510901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zprod in reference namelist', lwp )
511
512      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
513      READ  ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 )
514902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zprod in configuration namelist', lwp )
515      IF(lwm) WRITE ( numonp, namp4zprod )
516
517      IF(lwp) THEN                         ! control print
518         WRITE(numout,*) ' '
519         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp4zprod'
520         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
521         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod    =', ln_newprod
522         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
523         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
524         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
525         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
526         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
527         IF( ln_newprod )  THEN
528            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
529            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
530         ENDIF
531         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
532         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
533         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
534         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
535         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
536      ENDIF
537      !
538      r1_rday   = 1._wp / rday 
539      texcretn  = 1._wp - excretn
540      texcretd  = 1._wp - excretd
541      tpp       = 0._wp
542      !
543   END SUBROUTINE p4z_prod_init
544
545
546   INTEGER FUNCTION p4z_prod_alloc()
547      !!----------------------------------------------------------------------
548      !!                     ***  ROUTINE p4z_prod_alloc  ***
549      !!----------------------------------------------------------------------
550      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
551      !
552      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
553      !
554   END FUNCTION p4z_prod_alloc
555   !!======================================================================
556END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.