New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsbc.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsbc.F90 @ 7068

Last change on this file since 7068 was 7068, checked in by cetlod, 8 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782
  • Property svn:keywords set to Id
File size: 25.2 KB
Line 
1MODULE p4zsbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8   !!   p4z_sbc        :  Read and interpolate time-varying nutrients fluxes
9   !!   p4z_sbc_init   :  Initialization of p4z_sbc
10   !!----------------------------------------------------------------------
11   USE oce_trc         !  shared variables between ocean and passive tracers
12   USE trc             !  passive tracers common variables
13   USE sms_pisces      !  PISCES Source Minus Sink variables
14   USE iom             !  I/O manager
15   USE fldread         !  time interpolation
16
17   IMPLICIT NONE
18   PRIVATE
19
20   PUBLIC   p4z_sbc
21   PUBLIC   p4z_sbc_init   
22
23   LOGICAL , PUBLIC  :: ln_dust     !: boolean for dust input from the atmosphere
24   LOGICAL , PUBLIC  :: ln_solub    !: boolean for variable solubility of atmospheric iron
25   LOGICAL , PUBLIC  :: ln_river    !: boolean for river input of nutrients
26   LOGICAL , PUBLIC  :: ln_ndepo    !: boolean for atmospheric deposition of N
27   LOGICAL , PUBLIC  :: ln_ironsed  !: boolean for Fe input from sediments
28   LOGICAL , PUBLIC  :: ln_hydrofe  !: boolean for Fe input from hydrothermal vents
29   LOGICAL , PUBLIC  :: ln_ironice  !: boolean for Fe input from sea ice
30   REAL(wp), PUBLIC  :: sedfeinput  !: Coastal release of Iron
31   REAL(wp), PUBLIC  :: dustsolub   !: Solubility of the dust
32   REAL(wp), PUBLIC  :: mfrac       !: Mineral Content of the dust
33   REAL(wp), PUBLIC  :: icefeinput  !: Iron concentration in sea ice
34   REAL(wp), PUBLIC  :: wdust       !: Sinking speed of the dust
35   REAL(wp), PUBLIC  :: nitrfix     !: Nitrogen fixation rate   
36   REAL(wp), PUBLIC  :: diazolight  !: Nitrogen fixation sensitivty to light
37   REAL(wp), PUBLIC  :: concfediaz  !: Fe half-saturation Cste for diazotrophs
38   REAL(wp)          :: hratio      !: Fe:3He ratio assumed for vent iron supply
39
40   LOGICAL , PUBLIC  :: ll_sbc
41
42   LOGICAL  ::  ll_solub
43
44   INTEGER , PARAMETER  :: jpriv  = 7   !: Maximum number of river input fields
45   INTEGER , PARAMETER  :: jr_dic = 1   !: index of dissolved inorganic carbon
46   INTEGER , PARAMETER  :: jr_doc = 2   !: index of dissolved organic carbon
47   INTEGER , PARAMETER  :: jr_din = 3   !: index of dissolved inorganic nitrogen
48   INTEGER , PARAMETER  :: jr_don = 4   !: index of dissolved organic nitrogen
49   INTEGER , PARAMETER  :: jr_dip = 5   !: index of dissolved inorganic phosporus
50   INTEGER , PARAMETER  :: jr_dop = 6   !: index of dissolved organic phosphorus
51   INTEGER , PARAMETER  :: jr_dsi = 7   !: index of dissolved silicate
52
53
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_solub      ! structure of input dust
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_river  ! structure of input riverdic
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ndepo     ! structure of input nitrogen deposition
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from hydrothermal vents
60
61   INTEGER , PARAMETER :: nbtimes = 365  !: maximum number of times record in a file
62   INTEGER  :: ntimes_dust, ntimes_riv, ntimes_ndep       ! number of time steps in a file
63   INTEGER  :: ntimes_solub, ntimes_hydro                 ! number of time steps in a file
64
65   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: dust, solub       !: dust fields
66   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdic, rivalk    !: river input fields
67   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdin, rivdip    !: river input fields
68   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdsi    !: river input fields
69   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: nitdep    !: atmospheric N deposition
70   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ironsed   !: Coastal supply of iron
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: hydrofe   !: Hydrothermal vent supply of iron
72
73   REAL(wp), PUBLIC :: sumdepsi, rivalkinput, rivdicinput, nitdepinput
74   REAL(wp), PUBLIC :: rivdininput, rivdipinput, rivdsiinput
75
76   !! * Substitutions
77#  include "vectopt_loop_substitute.h90"
78   !!----------------------------------------------------------------------
79   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
80   !! $Id$
81   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
82   !!----------------------------------------------------------------------
83CONTAINS
84
85   SUBROUTINE p4z_sbc( kt )
86      !!----------------------------------------------------------------------
87      !!                  ***  routine p4z_sbc  ***
88      !!
89      !! ** purpose :   read and interpolate the external sources of nutrients
90      !!
91      !! ** method  :   read the files and interpolate the appropriate variables
92      !!
93      !! ** input   :   external netcdf files
94      !!
95      !!----------------------------------------------------------------------
96      !! * arguments
97      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
98
99      !! * local declarations
100      INTEGER  :: ji,jj 
101      REAL(wp) :: zcoef, zyyss
102      !!---------------------------------------------------------------------
103      !
104      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc')
105
106      !
107      ! Compute dust at nit000 or only if there is more than 1 time record in dust file
108      IF( ln_dust ) THEN
109         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_dust > 1 ) ) THEN
110            CALL fld_read( kt, 1, sf_dust )
111            IF( nn_ice_tr == -1 .AND. .NOT. ln_ironice ) THEN
112               dust(:,:) = sf_dust(1)%fnow(:,:,1)
113            ELSE
114               dust(:,:) = sf_dust(1)%fnow(:,:,1) * ( 1.0 - fr_i(:,:) )
115            ENDIF
116         ENDIF
117      ENDIF
118
119      IF( ll_solub ) THEN
120         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_solub > 1 ) ) THEN
121            CALL fld_read( kt, 1, sf_solub )
122            solub(:,:) = sf_solub(1)%fnow(:,:,1)
123         ENDIF
124      ENDIF
125
126      ! N/P and Si releases due to coastal rivers
127      ! Compute river at nit000 or only if there is more than 1 time record in river file
128      ! -----------------------------------------
129      IF( ln_river ) THEN
130         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_riv > 1 ) ) THEN
131            CALL fld_read( kt, 1, sf_river )
132            DO jj = 1, jpj
133               DO ji = 1, jpi
134                  zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
135                  rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
136                     &              * 1.E3        / ( 12. * zcoef + rtrn )
137                  rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) + sf_river(jr_doc)%fnow(ji,jj,1) ) &
138                     &              * 1.E3         / ( 12. * zcoef + rtrn )
139                  rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) + sf_river(jr_don)%fnow(ji,jj,1) ) &
140                     &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn )
141                  rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) + sf_river(jr_dop)%fnow(ji,jj,1) ) &
142                     &              * 1.E3 / po4r / ( 31. * zcoef + rtrn )
143                  rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)                                    &
144                     &              * 1.E3        / ( 28.1 * zcoef + rtrn )
145               END DO
146            END DO
147         ENDIF
148      ENDIF
149
150      ! Compute N deposition at nit000 or only if there is more than 1 time record in N deposition file
151      IF( ln_ndepo ) THEN
152         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_ndep > 1 ) ) THEN
153             zcoef = rno3 * 14E6 * ryyss
154             CALL fld_read( kt, 1, sf_ndepo )
155             nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
156         ENDIF
157         IF( .NOT.ln_linssh ) THEN
158           zcoef = rno3 * 14E6 * ryyss
159           nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
160         ENDIF
161      ENDIF
162      !
163      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc')
164      !
165   END SUBROUTINE p4z_sbc
166
167   SUBROUTINE p4z_sbc_init
168
169      !!----------------------------------------------------------------------
170      !!                  ***  routine p4z_sbc_init  ***
171      !!
172      !! ** purpose :   initialization of the external sources of nutrients
173      !!
174      !! ** method  :   read the files and compute the budget
175      !!                called at the first timestep (nittrc000)
176      !!
177      !! ** input   :   external netcdf files
178      !!
179      !!----------------------------------------------------------------------
180      !
181      INTEGER  :: ji, jj, jk, jm, ifpr
182      INTEGER  :: ii0, ii1, ij0, ij1
183      INTEGER  :: numdust, numsolub, numriv, numiron, numdepo, numhydro
184      INTEGER  :: ierr, ierr1, ierr2, ierr3
185      INTEGER  :: ios                 ! Local integer output status for namelist read
186      INTEGER  :: ik50                !  last level where depth less than 50 m
187      INTEGER  :: isrow             ! index for ORCA1 starting row
188      REAL(wp) :: zexpide, zdenitide, zmaskt
189      REAL(wp) :: ztimes_dust, ztimes_riv, ztimes_ndep 
190      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
191      REAL(wp), DIMENSION(:), ALLOCATABLE :: rivinput
192      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zdust, zndepo, zriver, zcmask
193      !
194      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
195      TYPE(FLD_N), DIMENSION(jpriv) ::  slf_river    ! array of namelist informations on the fields to read
196      TYPE(FLD_N) ::   sn_dust, sn_solub, sn_ndepo, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
197      TYPE(FLD_N) ::   sn_riverdoc, sn_riverdic, sn_riverdsi   ! informations about the fields to be read
198      TYPE(FLD_N) ::   sn_riverdin, sn_riverdon, sn_riverdip, sn_riverdop
199      !
200      NAMELIST/nampissbc/cn_dir, sn_dust, sn_solub, sn_riverdic, sn_riverdoc, sn_riverdin, sn_riverdon,     &
201        &                sn_riverdip, sn_riverdop, sn_riverdsi, sn_ndepo, sn_ironsed, sn_hydrofe, &
202        &                ln_dust, ln_solub, ln_river, ln_ndepo, ln_ironsed, ln_ironice, ln_hydrofe,    &
203        &                sedfeinput, dustsolub, icefeinput, wdust, mfrac, nitrfix, diazolight, concfediaz, hratio
204      !!----------------------------------------------------------------------
205      !
206      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc_init')
207      !
208      !                            !* set file information
209      REWIND( numnatp_ref )              ! Namelist nampissbc in reference namelist : Pisces external sources of nutrients
210      READ  ( numnatp_ref, nampissbc, IOSTAT = ios, ERR = 901)
211901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in reference namelist', lwp )
212
213      REWIND( numnatp_cfg )              ! Namelist nampissbc in configuration namelist : Pisces external sources of nutrients
214      READ  ( numnatp_cfg, nampissbc, IOSTAT = ios, ERR = 902 )
215902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in configuration namelist', lwp )
216      IF(lwm) WRITE ( numonp, nampissbc )
217
218      IF ( ( nn_ice_tr >= 0 ) .AND. ln_ironice ) THEN
219         IF(lwp) THEN
220            WRITE(numout,*) ' ln_ironice incompatible with nn_ice_tr = ', nn_ice_tr
221            WRITE(numout,*) ' Specify your sea ice iron concentration in nampisice instead '
222            WRITE(numout,*) ' ln_ironice is forced to .FALSE. '
223            ln_ironice = .FALSE.
224         ENDIF
225      ENDIF
226
227      IF(lwp) THEN
228         WRITE(numout,*) ' '
229         WRITE(numout,*) ' namelist : nampissbc '
230         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ '
231         WRITE(numout,*) '    dust input from the atmosphere           ln_dust     = ', ln_dust
232         WRITE(numout,*) '    Variable solubility of iron input        ln_solub    = ', ln_solub
233         WRITE(numout,*) '    river input of nutrients                 ln_river    = ', ln_river
234         WRITE(numout,*) '    atmospheric deposition of n              ln_ndepo    = ', ln_ndepo
235         WRITE(numout,*) '    Fe input from sediments                  ln_ironsed  = ', ln_ironsed
236         WRITE(numout,*) '    Fe input from seaice                     ln_ironice  = ', ln_ironice
237         WRITE(numout,*) '    fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
238         WRITE(numout,*) '    coastal release of iron                  sedfeinput  = ', sedfeinput
239         WRITE(numout,*) '    solubility of the dust                   dustsolub   = ', dustsolub
240         WRITE(numout,*) '    Mineral Fe content of the dust           mfrac       = ', mfrac
241         WRITE(numout,*) '    Iron concentration in sea ice            icefeinput  = ', icefeinput
242         WRITE(numout,*) '    sinking speed of the dust                wdust       = ', wdust
243         WRITE(numout,*) '    nitrogen fixation rate                   nitrfix     = ', nitrfix
244         WRITE(numout,*) '    nitrogen fixation sensitivty to light    diazolight  = ', diazolight
245         WRITE(numout,*) '    fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
246         WRITE(numout,*) '    Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
247      END IF
248
249      IF( ln_dust .OR. ln_river .OR. ln_ndepo ) THEN  ;  ll_sbc = .TRUE.
250      ELSE                                            ;  ll_sbc = .FALSE.
251      ENDIF
252
253      IF( ln_dust .AND. ln_solub ) THEN               ;  ll_solub = .TRUE.
254      ELSE                                            ;  ll_solub = .FALSE.
255      ENDIF
256
257      ! set the number of level over which river runoffs are applied
258      ! online configuration : computed in sbcrnf
259      IF( lk_offline ) THEN
260        nk_rnf(:,:) = 1
261        h_rnf (:,:) = gdept_n(:,:,1)
262      ENDIF
263
264      ! dust input from the atmosphere
265      ! ------------------------------
266      IF( ln_dust ) THEN 
267         !
268         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
269         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
270         !
271         ALLOCATE( dust(jpi,jpj) )    ! allocation
272         !
273         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
274         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
275         !
276         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
277                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
278         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
279         !
280         IF( Agrif_Root() ) THEN   !  Only on the master grid
281            ! Get total input dust ; need to compute total atmospheric supply of Si in a year
282            CALL iom_open (  TRIM( sn_dust%clname ) , numdust )
283            CALL iom_gettime( numdust, zsteps, kntime=ntimes_dust)  ! get number of record in file
284            ALLOCATE( zdust(jpi,jpj,ntimes_dust) )
285            DO jm = 1, ntimes_dust
286               CALL iom_get( numdust, jpdom_data, TRIM( sn_dust%clvar ), zdust(:,:,jm), jm )
287            END DO
288            CALL iom_close( numdust )
289            ztimes_dust = 1._wp / FLOAT( ntimes_dust ) 
290            sumdepsi = 0.e0
291            DO jm = 1, ntimes_dust
292               sumdepsi = sumdepsi + glob_sum( zdust(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_dust )
293            ENDDO
294            sumdepsi = sumdepsi / ( nyear_len(1) * rday ) * 12. * 8.8 * 0.075 * mfrac / 28.1 
295            DEALLOCATE( zdust)
296         ENDIF
297      ELSE
298         sumdepsi  = 0._wp
299      END IF
300
301      ! Solubility of dust deposition of iron
302      ! Only if ln_dust and ln_solubility set to true (ll_solub = .true.)
303      ! -----------------------------------------------------------------
304      IF( ll_solub ) THEN
305         !
306         IF(lwp) WRITE(numout,*) '    initialize variable solubility of Fe '
307         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
308         !
309         ALLOCATE( solub(jpi,jpj) )    ! allocation
310         !
311         ALLOCATE( sf_solub(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
312         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_solub structure' )
313         !
314         CALL fld_fill( sf_solub, (/ sn_solub /), cn_dir, 'p4z_sed_init', 'Solubility of atm. iron ', 'nampissed' )
315                                   ALLOCATE( sf_solub(1)%fnow(jpi,jpj,1)   )
316         IF( sn_solub%ln_tint )    ALLOCATE( sf_solub(1)%fdta(jpi,jpj,1,2) )
317         ! get number of record in file
318         CALL iom_open (  TRIM( sn_solub%clname ) , numsolub )
319         CALL iom_gettime( numsolub, zsteps, kntime=ntimes_solub)  ! get number of record in file
320         CALL iom_close( numsolub )
321      ENDIF
322
323      ! nutrient input from rivers
324      ! --------------------------
325      IF( ln_river ) THEN
326         !
327         slf_river(jr_dic) = sn_riverdic  ;  slf_river(jr_doc) = sn_riverdoc  ;  slf_river(jr_din) = sn_riverdin 
328         slf_river(jr_don) = sn_riverdon  ;  slf_river(jr_dip) = sn_riverdip  ;  slf_river(jr_dop) = sn_riverdop
329         slf_river(jr_dsi) = sn_riverdsi 
330         !
331         ALLOCATE( rivdic(jpi,jpj), rivalk(jpi,jpj), rivdin(jpi,jpj), rivdip(jpi,jpj), rivdsi(jpi,jpj) ) 
332         !
333         ALLOCATE( sf_river(jpriv), rivinput(jpriv), STAT=ierr1 )           !* allocate and fill sf_river (forcing structure) with sn_river_
334         rivinput(:) = 0.0
335
336         IF( ierr1 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_irver structure' )
337         !
338         CALL fld_fill( sf_river, slf_river, cn_dir, 'p4z_sed_init', 'Input from river ', 'nampissed' )
339         DO ifpr = 1, jpriv
340                                          ALLOCATE( sf_river(ifpr)%fnow(jpi,jpj,1  ) )
341            IF( slf_river(ifpr)%ln_tint ) ALLOCATE( sf_river(ifpr)%fdta(jpi,jpj,1,2) )
342         END DO
343         IF( Agrif_Root() ) THEN   !  Only on the master grid
344            ! Get total input rivers ; need to compute total river supply in a year
345            DO ifpr = 1, jpriv
346               CALL iom_open ( TRIM( slf_river(ifpr)%clname ), numriv )
347               CALL iom_gettime( numriv, zsteps, kntime=ntimes_riv)
348               ALLOCATE( zriver(jpi,jpj,ntimes_riv) )
349               DO jm = 1, ntimes_riv
350                  CALL iom_get( numriv, jpdom_data, TRIM( slf_river(ifpr)%clvar ), zriver(:,:,jm), jm )
351               END DO
352               CALL iom_close( numriv )
353               ztimes_riv = 1._wp / FLOAT(ntimes_riv) 
354               DO jm = 1, ntimes_riv
355                  rivinput(ifpr) = rivinput(ifpr) + glob_sum( zriver(:,:,jm) * tmask(:,:,1) * ztimes_riv ) 
356               END DO
357               DEALLOCATE( zriver)
358            END DO
359            ! N/P and Si releases due to coastal rivers
360            ! -----------------------------------------
361            rivdicinput = (rivinput(jr_dic) + rivinput(jr_doc) ) * 1E3 / 12._wp
362            rivdininput = (rivinput(jr_din) + rivinput(jr_don) ) * 1E3 / rno3 / 14._wp
363            rivdipinput = (rivinput(jr_dip) + rivinput(jr_dop) ) * 1E3 / po4r / 31._wp
364            rivdsiinput = rivinput(jr_dsi) * 1E3 / 28.1_wp
365            rivalkinput = rivinput(jr_dic) * 1E3 / 12._wp
366            !
367         ENDIF
368      ELSE
369         rivdicinput = 0._wp
370         rivdininput = 0._wp
371         rivdipinput = 0._wp
372         rivdsiinput = 0._wp
373         rivalkinput = 0._wp
374      END IF 
375      ! nutrient input from dust
376      ! ------------------------
377      IF( ln_ndepo ) THEN
378         !
379         IF(lwp) WRITE(numout,*) '    initialize the nutrient input by dust from ndeposition.orca.nc'
380         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
381         !
382         ALLOCATE( nitdep(jpi,jpj) )    ! allocation
383         !
384         ALLOCATE( sf_ndepo(1), STAT=ierr3 )           !* allocate and fill sf_sst (forcing structure) with sn_sst
385         IF( ierr3 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_ndepo structure' )
386         !
387         CALL fld_fill( sf_ndepo, (/ sn_ndepo /), cn_dir, 'p4z_sed_init', 'Nutrient atmospheric depositon ', 'nampissed' )
388                                   ALLOCATE( sf_ndepo(1)%fnow(jpi,jpj,1)   )
389         IF( sn_ndepo%ln_tint )    ALLOCATE( sf_ndepo(1)%fdta(jpi,jpj,1,2) )
390         !
391         IF( Agrif_Root() ) THEN   !  Only on the master grid
392            ! Get total input dust ; need to compute total atmospheric supply of N in a year
393            CALL iom_open ( TRIM( sn_ndepo%clname ), numdepo )
394            CALL iom_gettime( numdepo, zsteps, kntime=ntimes_ndep)
395            ALLOCATE( zndepo(jpi,jpj,ntimes_ndep) )
396            DO jm = 1, ntimes_ndep
397               CALL iom_get( numdepo, jpdom_data, TRIM( sn_ndepo%clvar ), zndepo(:,:,jm), jm )
398            END DO
399            CALL iom_close( numdepo )
400            ztimes_ndep = 1._wp / FLOAT( ntimes_ndep ) 
401            nitdepinput = 0._wp
402            DO jm = 1, ntimes_ndep
403              nitdepinput = nitdepinput + glob_sum( zndepo(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_ndep )
404            ENDDO
405            nitdepinput = nitdepinput / rno3 / 14E6 
406            DEALLOCATE( zndepo)
407         ENDIF
408      ELSE
409         nitdepinput = 0._wp
410      ENDIF
411
412      ! coastal and island masks
413      ! ------------------------
414      IF( ln_ironsed ) THEN     
415         !
416         IF(lwp) WRITE(numout,*) '    computation of an island mask to enhance coastal supply of iron'
417         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
418         !
419         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
420         !
421         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
422         ALLOCATE( zcmask(jpi,jpj,jpk) )
423         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
424         CALL iom_close( numiron )
425         !
426         ik50 = 5        !  last level where depth less than 50 m
427         DO jk = jpkm1, 1, -1
428            IF( gdept_1d(jk) > 50. )  ik50 = jk - 1
429         END DO
430         IF (lwp) WRITE(numout,*)
431         IF (lwp) WRITE(numout,*) ' Level corresponding to 50m depth ',  ik50,' ', gdept_1d(ik50+1)
432         IF (lwp) WRITE(numout,*)
433         DO jk = 1, ik50
434            DO jj = 2, jpjm1
435               DO ji = fs_2, fs_jpim1
436                  IF( tmask(ji,jj,jk) /= 0. ) THEN
437                     zmaskt = tmask(ji+1,jj,jk) * tmask(ji-1,jj,jk) * tmask(ji,jj+1,jk)    &
438                        &                       * tmask(ji,jj-1,jk) * tmask(ji,jj,jk+1)
439                     IF( zmaskt == 0. )   zcmask(ji,jj,jk ) = MAX( 0.1, zcmask(ji,jj,jk) ) 
440                  END IF
441               END DO
442            END DO
443         END DO
444         !
445         CALL lbc_lnk( zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
446         !
447         DO jk = 1, jpk
448            DO jj = 1, jpj
449               DO ji = 1, jpi
450                  zexpide   = MIN( 8.,( gdept_n(ji,jj,jk) / 500. )**(-1.5) )
451                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
452                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
453               END DO
454            END DO
455         END DO
456         ! Coastal supply of iron
457         ! -------------------------
458         ironsed(:,:,jpk) = 0._wp
459         DO jk = 1, jpkm1
460            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( e3t_0(:,:,jk) * rday )
461         END DO
462         DEALLOCATE( zcmask)
463      ENDIF
464      !
465      ! Iron from Hydrothermal vents
466      ! ------------------------
467      IF( ln_hydrofe ) THEN
468         !
469         IF(lwp) WRITE(numout,*) '    Input of iron from hydrothermal vents '
470         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
471         !
472         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
473         !
474         CALL iom_open ( TRIM( sn_hydrofe%clname ), numhydro )
475         CALL iom_get  ( numhydro, jpdom_data, TRIM( sn_hydrofe%clvar ), hydrofe(:,:,:), 1 )
476         CALL iom_close( numhydro )
477         !
478         DO jk = 1, jpk
479            hydrofe(:,:,jk) = ( hydrofe(:,:,jk) * hratio ) / ( e1e2t(:,:) * e3t_0(:,:,jk) * ryyss + rtrn ) / 1000._wp
480         ENDDO
481         !
482      ENDIF
483      !
484      IF( ll_sbc ) CALL p4z_sbc( nit000 ) 
485      !
486      IF(lwp) THEN
487         WRITE(numout,*)
488         WRITE(numout,*) '    Total input of elements from river supply'
489         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
490         WRITE(numout,*) '    N Supply   : ', rivdininput*rno3*1E3/1E12*14.,' TgN/yr'
491         WRITE(numout,*) '    Si Supply  : ', rivdsiinput*1E3/1E12*28.1,' TgSi/yr'
492         WRITE(numout,*) '    P Supply   : ', rivdipinput*1E3*po4r/1E12*31.,' TgP/yr'
493         WRITE(numout,*) '    Alk Supply : ', rivalkinput*1E3/1E12,' Teq/yr'
494         WRITE(numout,*) '    DIC Supply : ', rivdicinput*1E3*12./1E12,'TgC/yr'
495         WRITE(numout,*) 
496         WRITE(numout,*) '    Total input of elements from atmospheric supply'
497         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
498         WRITE(numout,*) '    N Supply   : ', nitdepinput*rno3*1E3/1E12*14.,' TgN/yr'
499         WRITE(numout,*) 
500      ENDIF
501      !
502      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc_init')
503      !
504   END SUBROUTINE p4z_sbc_init
505
506   !!======================================================================
507END MODULE p4zsbc
Note: See TracBrowser for help on using the repository browser.