New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsbc.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsbc.F90 @ 7162

Last change on this file since 7162 was 7162, checked in by cetlod, 7 years ago

new top interface : Add PISCES quota model
  • Property svn:keywords set to Id
File size: 27.4 KB
Line 
1MODULE p4zsbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8   !!   p4z_sbc        :  Read and interpolate time-varying nutrients fluxes
9   !!   p4z_sbc_init   :  Initialization of p4z_sbc
10   !!----------------------------------------------------------------------
11   USE oce_trc         !  shared variables between ocean and passive tracers
12   USE trc             !  passive tracers common variables
13   USE sms_pisces      !  PISCES Source Minus Sink variables
14   USE iom             !  I/O manager
15   USE fldread         !  time interpolation
16
17   IMPLICIT NONE
18   PRIVATE
19
20   PUBLIC   p4z_sbc
21   PUBLIC   p4z_sbc_init   
22
23   LOGICAL , PUBLIC  :: ln_dust     !: boolean for dust input from the atmosphere
24   LOGICAL , PUBLIC  :: ln_solub    !: boolean for variable solubility of atmospheric iron
25   LOGICAL , PUBLIC  :: ln_river    !: boolean for river input of nutrients
26   LOGICAL , PUBLIC  :: ln_ndepo    !: boolean for atmospheric deposition of N
27   LOGICAL , PUBLIC  :: ln_ironsed  !: boolean for Fe input from sediments
28   LOGICAL , PUBLIC  :: ln_hydrofe  !: boolean for Fe input from hydrothermal vents
29   LOGICAL , PUBLIC  :: ln_ironice  !: boolean for Fe input from sea ice
30   REAL(wp), PUBLIC  :: sedfeinput  !: Coastal release of Iron
31   REAL(wp), PUBLIC  :: dustsolub   !: Solubility of the dust
32   REAL(wp), PUBLIC  :: mfrac       !: Mineral Content of the dust
33   REAL(wp), PUBLIC  :: icefeinput  !: Iron concentration in sea ice
34   REAL(wp), PUBLIC  :: wdust       !: Sinking speed of the dust
35   REAL(wp), PUBLIC  :: nitrfix     !: Nitrogen fixation rate   
36   REAL(wp), PUBLIC  :: diazolight  !: Nitrogen fixation sensitivty to light
37   REAL(wp), PUBLIC  :: concfediaz  !: Fe half-saturation Cste for diazotrophs
38   REAL(wp)          :: hratio      !: Fe:3He ratio assumed for vent iron supply
39   REAL(wp), PUBLIC  :: fep_rats    !: Fep/Fer ratio from sed  sources
40   REAL(wp), PUBLIC  :: fep_rath    !: Fep/Fer ratio from hydro sources
41
42
43   LOGICAL , PUBLIC  :: ll_sbc
44
45   LOGICAL  ::  ll_solub
46
47   INTEGER , PARAMETER  :: jpriv  = 7   !: Maximum number of river input fields
48   INTEGER , PARAMETER  :: jr_dic = 1   !: index of dissolved inorganic carbon
49   INTEGER , PARAMETER  :: jr_doc = 2   !: index of dissolved organic carbon
50   INTEGER , PARAMETER  :: jr_din = 3   !: index of dissolved inorganic nitrogen
51   INTEGER , PARAMETER  :: jr_don = 4   !: index of dissolved organic nitrogen
52   INTEGER , PARAMETER  :: jr_dip = 5   !: index of dissolved inorganic phosporus
53   INTEGER , PARAMETER  :: jr_dop = 6   !: index of dissolved organic phosphorus
54   INTEGER , PARAMETER  :: jr_dsi = 7   !: index of dissolved silicate
55
56
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_solub      ! structure of input dust
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_river  ! structure of input riverdic
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ndepo     ! structure of input nitrogen deposition
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from hydrothermal vents
63
64   INTEGER , PARAMETER :: nbtimes = 365  !: maximum number of times record in a file
65   INTEGER  :: ntimes_dust, ntimes_riv, ntimes_ndep       ! number of time steps in a file
66   INTEGER  :: ntimes_solub, ntimes_hydro                 ! number of time steps in a file
67
68   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: dust, solub       !: dust fields
69   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdic, rivalk    !: river input fields
70   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdin, rivdip    !: river input fields
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdon, rivdop    !: river input fields
72   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdoc    !: river input fields
73   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdsi    !: river input fields
74   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: nitdep    !: atmospheric N deposition
75   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ironsed   !: Coastal supply of iron
76   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: hydrofe   !: Hydrothermal vent supply of iron
77
78   REAL(wp), PUBLIC :: sumdepsi, rivalkinput, rivdicinput, nitdepinput
79   REAL(wp), PUBLIC :: rivdininput, rivdipinput, rivdsiinput
80
81   !! * Substitutions
82#  include "vectopt_loop_substitute.h90"
83   !!----------------------------------------------------------------------
84   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
85   !! $Id$
86   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
87   !!----------------------------------------------------------------------
88CONTAINS
89
90   SUBROUTINE p4z_sbc( kt )
91      !!----------------------------------------------------------------------
92      !!                  ***  routine p4z_sbc  ***
93      !!
94      !! ** purpose :   read and interpolate the external sources of nutrients
95      !!
96      !! ** method  :   read the files and interpolate the appropriate variables
97      !!
98      !! ** input   :   external netcdf files
99      !!
100      !!----------------------------------------------------------------------
101      !! * arguments
102      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
103
104      !! * local declarations
105      INTEGER  :: ji,jj 
106      REAL(wp) :: zcoef, zyyss
107      !!---------------------------------------------------------------------
108      !
109      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc')
110
111      !
112      ! Compute dust at nit000 or only if there is more than 1 time record in dust file
113      IF( ln_dust ) THEN
114         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_dust > 1 ) ) THEN
115            CALL fld_read( kt, 1, sf_dust )
116            IF( nn_ice_tr == -1 .AND. .NOT. ln_ironice ) THEN
117               dust(:,:) = sf_dust(1)%fnow(:,:,1)
118            ELSE
119               dust(:,:) = sf_dust(1)%fnow(:,:,1) * ( 1.0 - fr_i(:,:) )
120            ENDIF
121         ENDIF
122      ENDIF
123
124      IF( ll_solub ) THEN
125         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_solub > 1 ) ) THEN
126            CALL fld_read( kt, 1, sf_solub )
127            solub(:,:) = sf_solub(1)%fnow(:,:,1)
128         ENDIF
129      ENDIF
130
131      ! N/P and Si releases due to coastal rivers
132      ! Compute river at nit000 or only if there is more than 1 time record in river file
133      ! -----------------------------------------
134      IF( ln_river ) THEN
135         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_riv > 1 ) ) THEN
136            CALL fld_read( kt, 1, sf_river )
137            IF( ln_p4z ) THEN
138               DO jj = 1, jpj
139                  DO ji = 1, jpi
140                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
141                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
142                        &              * 1.E3        / ( 12. * zcoef + rtrn )
143                     rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) + sf_river(jr_doc)%fnow(ji,jj,1) ) &
144                        &              * 1.E3         / ( 12. * zcoef + rtrn )
145                     rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) + sf_river(jr_don)%fnow(ji,jj,1) ) &
146                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn )
147                     rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) + sf_river(jr_dop)%fnow(ji,jj,1) ) &
148                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn )
149                     rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)                                    &
150                        &              * 1.E3        / ( 28.1 * zcoef + rtrn )
151                  END DO
152               END DO
153            ELSE    !  ln_p5z
154               DO jj = 1, jpj
155                  DO ji = 1, jpi
156                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
157                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
158                        &              * 1.E3        / ( 12. * zcoef + rtrn )
159                     rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) ) &
160                        &              * 1.E3 / ( 12. * zcoef + rtrn ) * tmask(ji,jj,1)
161                     rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) ) &
162                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
163                     rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) ) &
164                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
165                     rivdoc(ji,jj) = ( sf_river(jr_doc)%fnow(ji,jj,1) ) &
166                        &              * 1.E3 / ( 12. * zcoef + rtrn ) * tmask(ji,jj,1)
167                     rivdon(ji,jj) = ( sf_river(jr_don)%fnow(ji,jj,1) ) &
168                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
169                     rivdop(ji,jj) = ( sf_river(jr_dop)%fnow(ji,jj,1) ) &
170                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
171                  END DO
172               END DO
173            ENDIF
174         ENDIF
175      ENDIF
176
177      ! Compute N deposition at nit000 or only if there is more than 1 time record in N deposition file
178      IF( ln_ndepo ) THEN
179         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_ndep > 1 ) ) THEN
180             zcoef = rno3 * 14E6 * ryyss
181             CALL fld_read( kt, 1, sf_ndepo )
182             nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
183         ENDIF
184         IF( .NOT.ln_linssh ) THEN
185           zcoef = rno3 * 14E6 * ryyss
186           nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
187         ENDIF
188      ENDIF
189      !
190      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc')
191      !
192   END SUBROUTINE p4z_sbc
193
194   SUBROUTINE p4z_sbc_init
195
196      !!----------------------------------------------------------------------
197      !!                  ***  routine p4z_sbc_init  ***
198      !!
199      !! ** purpose :   initialization of the external sources of nutrients
200      !!
201      !! ** method  :   read the files and compute the budget
202      !!                called at the first timestep (nittrc000)
203      !!
204      !! ** input   :   external netcdf files
205      !!
206      !!----------------------------------------------------------------------
207      !
208      INTEGER  :: ji, jj, jk, jm, ifpr
209      INTEGER  :: ii0, ii1, ij0, ij1
210      INTEGER  :: numdust, numsolub, numriv, numiron, numdepo, numhydro
211      INTEGER  :: ierr, ierr1, ierr2, ierr3
212      INTEGER  :: ios                 ! Local integer output status for namelist read
213      INTEGER  :: ik50                !  last level where depth less than 50 m
214      INTEGER  :: isrow             ! index for ORCA1 starting row
215      REAL(wp) :: zexpide, zdenitide, zmaskt
216      REAL(wp) :: ztimes_dust, ztimes_riv, ztimes_ndep 
217      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
218      REAL(wp), DIMENSION(:), ALLOCATABLE :: rivinput
219      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zdust, zndepo, zriver, zcmask
220      !
221      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
222      TYPE(FLD_N), DIMENSION(jpriv) ::  slf_river    ! array of namelist informations on the fields to read
223      TYPE(FLD_N) ::   sn_dust, sn_solub, sn_ndepo, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
224      TYPE(FLD_N) ::   sn_riverdoc, sn_riverdic, sn_riverdsi   ! informations about the fields to be read
225      TYPE(FLD_N) ::   sn_riverdin, sn_riverdon, sn_riverdip, sn_riverdop
226      !
227      NAMELIST/nampissbc/cn_dir, sn_dust, sn_solub, sn_riverdic, sn_riverdoc, sn_riverdin, sn_riverdon,     &
228        &                sn_riverdip, sn_riverdop, sn_riverdsi, sn_ndepo, sn_ironsed, sn_hydrofe, &
229        &                ln_dust, ln_solub, ln_river, ln_ndepo, ln_ironsed, ln_ironice, ln_hydrofe,    &
230        &                sedfeinput, dustsolub, icefeinput, wdust, mfrac, nitrfix, diazolight, concfediaz, &
231        &                hratio, fep_rats, fep_rath
232      !!----------------------------------------------------------------------
233      !
234      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc_init')
235      !
236      !                            !* set file information
237      REWIND( numnatp_ref )              ! Namelist nampissbc in reference namelist : Pisces external sources of nutrients
238      READ  ( numnatp_ref, nampissbc, IOSTAT = ios, ERR = 901)
239901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in reference namelist', lwp )
240
241      REWIND( numnatp_cfg )              ! Namelist nampissbc in configuration namelist : Pisces external sources of nutrients
242      READ  ( numnatp_cfg, nampissbc, IOSTAT = ios, ERR = 902 )
243902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in configuration namelist', lwp )
244      IF(lwm) WRITE ( numonp, nampissbc )
245
246      IF ( ( nn_ice_tr >= 0 ) .AND. ln_ironice ) THEN
247         IF(lwp) THEN
248            WRITE(numout,*) ' ln_ironice incompatible with nn_ice_tr = ', nn_ice_tr
249            WRITE(numout,*) ' Specify your sea ice iron concentration in nampisice instead '
250            WRITE(numout,*) ' ln_ironice is forced to .FALSE. '
251            ln_ironice = .FALSE.
252         ENDIF
253      ENDIF
254
255      IF(lwp) THEN
256         WRITE(numout,*) ' '
257         WRITE(numout,*) ' namelist : nampissbc '
258         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ '
259         WRITE(numout,*) '    dust input from the atmosphere           ln_dust     = ', ln_dust
260         WRITE(numout,*) '    Variable solubility of iron input        ln_solub    = ', ln_solub
261         WRITE(numout,*) '    river input of nutrients                 ln_river    = ', ln_river
262         WRITE(numout,*) '    atmospheric deposition of n              ln_ndepo    = ', ln_ndepo
263         WRITE(numout,*) '    Fe input from sediments                  ln_ironsed  = ', ln_ironsed
264         WRITE(numout,*) '    Fe input from seaice                     ln_ironice  = ', ln_ironice
265         WRITE(numout,*) '    fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
266         WRITE(numout,*) '    coastal release of iron                  sedfeinput  = ', sedfeinput
267         WRITE(numout,*) '    solubility of the dust                   dustsolub   = ', dustsolub
268         WRITE(numout,*) '    Mineral Fe content of the dust           mfrac       = ', mfrac
269         WRITE(numout,*) '    Iron concentration in sea ice            icefeinput  = ', icefeinput
270         WRITE(numout,*) '    sinking speed of the dust                wdust       = ', wdust
271         WRITE(numout,*) '    nitrogen fixation rate                   nitrfix     = ', nitrfix
272         WRITE(numout,*) '    nitrogen fixation sensitivty to light    diazolight  = ', diazolight
273         WRITE(numout,*) '    fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
274         WRITE(numout,*) '    Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
275         IF( ln_ligand ) THEN
276            WRITE(numout,*) '    Fep/Fer ratio from sed sources                       = ', fep_rats
277            WRITE(numout,*) '    Fep/Fer ratio from sed hydro sources                 = ', fep_rath
278         ENDIF
279      END IF
280
281      IF( ln_dust .OR. ln_river .OR. ln_ndepo ) THEN  ;  ll_sbc = .TRUE.
282      ELSE                                            ;  ll_sbc = .FALSE.
283      ENDIF
284
285      IF( ln_dust .AND. ln_solub ) THEN               ;  ll_solub = .TRUE.
286      ELSE                                            ;  ll_solub = .FALSE.
287      ENDIF
288
289      ! set the number of level over which river runoffs are applied
290      ! online configuration : computed in sbcrnf
291      IF( lk_offline ) THEN
292        nk_rnf(:,:) = 1
293        h_rnf (:,:) = gdept_n(:,:,1)
294      ENDIF
295
296      ! dust input from the atmosphere
297      ! ------------------------------
298      IF( ln_dust ) THEN 
299         !
300         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
301         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
302         !
303         ALLOCATE( dust(jpi,jpj) )    ! allocation
304         !
305         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
306         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
307         !
308         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
309                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
310         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
311         !
312         IF( Agrif_Root() ) THEN   !  Only on the master grid
313            ! Get total input dust ; need to compute total atmospheric supply of Si in a year
314            CALL iom_open (  TRIM( sn_dust%clname ) , numdust )
315            CALL iom_gettime( numdust, zsteps, kntime=ntimes_dust)  ! get number of record in file
316            ALLOCATE( zdust(jpi,jpj,ntimes_dust) )
317            DO jm = 1, ntimes_dust
318               CALL iom_get( numdust, jpdom_data, TRIM( sn_dust%clvar ), zdust(:,:,jm), jm )
319            END DO
320            CALL iom_close( numdust )
321            ztimes_dust = 1._wp / FLOAT( ntimes_dust ) 
322            sumdepsi = 0.e0
323            DO jm = 1, ntimes_dust
324               sumdepsi = sumdepsi + glob_sum( zdust(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_dust )
325            ENDDO
326            sumdepsi = sumdepsi / ( nyear_len(1) * rday ) * 12. * 8.8 * 0.075 * mfrac / 28.1 
327            DEALLOCATE( zdust)
328         ENDIF
329      ELSE
330         sumdepsi  = 0._wp
331      END IF
332
333      ! Solubility of dust deposition of iron
334      ! Only if ln_dust and ln_solubility set to true (ll_solub = .true.)
335      ! -----------------------------------------------------------------
336      IF( ll_solub ) THEN
337         !
338         IF(lwp) WRITE(numout,*) '    initialize variable solubility of Fe '
339         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
340         !
341         ALLOCATE( solub(jpi,jpj) )    ! allocation
342         !
343         ALLOCATE( sf_solub(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
344         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_solub structure' )
345         !
346         CALL fld_fill( sf_solub, (/ sn_solub /), cn_dir, 'p4z_sed_init', 'Solubility of atm. iron ', 'nampissed' )
347                                   ALLOCATE( sf_solub(1)%fnow(jpi,jpj,1)   )
348         IF( sn_solub%ln_tint )    ALLOCATE( sf_solub(1)%fdta(jpi,jpj,1,2) )
349         ! get number of record in file
350         CALL iom_open (  TRIM( sn_solub%clname ) , numsolub )
351         CALL iom_gettime( numsolub, zsteps, kntime=ntimes_solub)  ! get number of record in file
352         CALL iom_close( numsolub )
353      ENDIF
354
355      ! nutrient input from rivers
356      ! --------------------------
357      IF( ln_river ) THEN
358         !
359         slf_river(jr_dic) = sn_riverdic  ;  slf_river(jr_doc) = sn_riverdoc  ;  slf_river(jr_din) = sn_riverdin 
360         slf_river(jr_don) = sn_riverdon  ;  slf_river(jr_dip) = sn_riverdip  ;  slf_river(jr_dop) = sn_riverdop
361         slf_river(jr_dsi) = sn_riverdsi 
362         !
363         ALLOCATE( rivdic(jpi,jpj), rivalk(jpi,jpj), rivdin(jpi,jpj), rivdip(jpi,jpj), rivdsi(jpi,jpj) ) 
364         IF( ln_p5z )  ALLOCATE( rivdon(jpi,jpj), rivdop(jpi,jpj), rivdoc(jpi,jpj) )
365         !
366         ALLOCATE( sf_river(jpriv), rivinput(jpriv), STAT=ierr1 )           !* allocate and fill sf_river (forcing structure) with sn_river_
367         rivinput(:) = 0.0
368
369         IF( ierr1 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_irver structure' )
370         !
371         CALL fld_fill( sf_river, slf_river, cn_dir, 'p4z_sed_init', 'Input from river ', 'nampissed' )
372         DO ifpr = 1, jpriv
373                                          ALLOCATE( sf_river(ifpr)%fnow(jpi,jpj,1  ) )
374            IF( slf_river(ifpr)%ln_tint ) ALLOCATE( sf_river(ifpr)%fdta(jpi,jpj,1,2) )
375         END DO
376         IF( Agrif_Root() ) THEN   !  Only on the master grid
377            ! Get total input rivers ; need to compute total river supply in a year
378            DO ifpr = 1, jpriv
379               CALL iom_open ( TRIM( slf_river(ifpr)%clname ), numriv )
380               CALL iom_gettime( numriv, zsteps, kntime=ntimes_riv)
381               ALLOCATE( zriver(jpi,jpj,ntimes_riv) )
382               DO jm = 1, ntimes_riv
383                  CALL iom_get( numriv, jpdom_data, TRIM( slf_river(ifpr)%clvar ), zriver(:,:,jm), jm )
384               END DO
385               CALL iom_close( numriv )
386               ztimes_riv = 1._wp / FLOAT(ntimes_riv) 
387               DO jm = 1, ntimes_riv
388                  rivinput(ifpr) = rivinput(ifpr) + glob_sum( zriver(:,:,jm) * tmask(:,:,1) * ztimes_riv ) 
389               END DO
390               DEALLOCATE( zriver)
391            END DO
392            ! N/P and Si releases due to coastal rivers
393            ! -----------------------------------------
394            rivdicinput = (rivinput(jr_dic) + rivinput(jr_doc) ) * 1E3 / 12._wp
395            rivdininput = (rivinput(jr_din) + rivinput(jr_don) ) * 1E3 / rno3 / 14._wp
396            rivdipinput = (rivinput(jr_dip) + rivinput(jr_dop) ) * 1E3 / po4r / 31._wp
397            rivdsiinput = rivinput(jr_dsi) * 1E3 / 28.1_wp
398            rivalkinput = rivinput(jr_dic) * 1E3 / 12._wp
399            !
400         ENDIF
401      ELSE
402         rivdicinput = 0._wp
403         rivdininput = 0._wp
404         rivdipinput = 0._wp
405         rivdsiinput = 0._wp
406         rivalkinput = 0._wp
407      END IF 
408      ! nutrient input from dust
409      ! ------------------------
410      IF( ln_ndepo ) THEN
411         !
412         IF(lwp) WRITE(numout,*) '    initialize the nutrient input by dust from ndeposition.orca.nc'
413         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
414         !
415         ALLOCATE( nitdep(jpi,jpj) )    ! allocation
416         !
417         ALLOCATE( sf_ndepo(1), STAT=ierr3 )           !* allocate and fill sf_sst (forcing structure) with sn_sst
418         IF( ierr3 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_ndepo structure' )
419         !
420         CALL fld_fill( sf_ndepo, (/ sn_ndepo /), cn_dir, 'p4z_sed_init', 'Nutrient atmospheric depositon ', 'nampissed' )
421                                   ALLOCATE( sf_ndepo(1)%fnow(jpi,jpj,1)   )
422         IF( sn_ndepo%ln_tint )    ALLOCATE( sf_ndepo(1)%fdta(jpi,jpj,1,2) )
423         !
424         IF( Agrif_Root() ) THEN   !  Only on the master grid
425            ! Get total input dust ; need to compute total atmospheric supply of N in a year
426            CALL iom_open ( TRIM( sn_ndepo%clname ), numdepo )
427            CALL iom_gettime( numdepo, zsteps, kntime=ntimes_ndep)
428            ALLOCATE( zndepo(jpi,jpj,ntimes_ndep) )
429            DO jm = 1, ntimes_ndep
430               CALL iom_get( numdepo, jpdom_data, TRIM( sn_ndepo%clvar ), zndepo(:,:,jm), jm )
431            END DO
432            CALL iom_close( numdepo )
433            ztimes_ndep = 1._wp / FLOAT( ntimes_ndep ) 
434            nitdepinput = 0._wp
435            DO jm = 1, ntimes_ndep
436              nitdepinput = nitdepinput + glob_sum( zndepo(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_ndep )
437            ENDDO
438            nitdepinput = nitdepinput / rno3 / 14E6 
439            DEALLOCATE( zndepo)
440         ENDIF
441      ELSE
442         nitdepinput = 0._wp
443      ENDIF
444
445      ! coastal and island masks
446      ! ------------------------
447      IF( ln_ironsed ) THEN     
448         !
449         IF(lwp) WRITE(numout,*) '    computation of an island mask to enhance coastal supply of iron'
450         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
451         !
452         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
453         !
454         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
455         ALLOCATE( zcmask(jpi,jpj,jpk) )
456         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
457         CALL iom_close( numiron )
458         !
459         ik50 = 5        !  last level where depth less than 50 m
460         DO jk = jpkm1, 1, -1
461            IF( gdept_1d(jk) > 50. )  ik50 = jk - 1
462         END DO
463         IF (lwp) WRITE(numout,*)
464         IF (lwp) WRITE(numout,*) ' Level corresponding to 50m depth ',  ik50,' ', gdept_1d(ik50+1)
465         IF (lwp) WRITE(numout,*)
466         DO jk = 1, ik50
467            DO jj = 2, jpjm1
468               DO ji = fs_2, fs_jpim1
469                  IF( tmask(ji,jj,jk) /= 0. ) THEN
470                     zmaskt = tmask(ji+1,jj,jk) * tmask(ji-1,jj,jk) * tmask(ji,jj+1,jk)    &
471                        &                       * tmask(ji,jj-1,jk) * tmask(ji,jj,jk+1)
472                     IF( zmaskt == 0. )   zcmask(ji,jj,jk ) = MAX( 0.1, zcmask(ji,jj,jk) ) 
473                  END IF
474               END DO
475            END DO
476         END DO
477         !
478         CALL lbc_lnk( zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
479         !
480         DO jk = 1, jpk
481            DO jj = 1, jpj
482               DO ji = 1, jpi
483                  zexpide   = MIN( 8.,( gdept_n(ji,jj,jk) / 500. )**(-1.5) )
484                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
485                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
486               END DO
487            END DO
488         END DO
489         ! Coastal supply of iron
490         ! -------------------------
491         ironsed(:,:,jpk) = 0._wp
492         DO jk = 1, jpkm1
493            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( e3t_0(:,:,jk) * rday )
494         END DO
495         DEALLOCATE( zcmask)
496      ENDIF
497      !
498      ! Iron from Hydrothermal vents
499      ! ------------------------
500      IF( ln_hydrofe ) THEN
501         !
502         IF(lwp) WRITE(numout,*) '    Input of iron from hydrothermal vents '
503         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
504         !
505         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
506         !
507         CALL iom_open ( TRIM( sn_hydrofe%clname ), numhydro )
508         CALL iom_get  ( numhydro, jpdom_data, TRIM( sn_hydrofe%clvar ), hydrofe(:,:,:), 1 )
509         CALL iom_close( numhydro )
510         !
511         DO jk = 1, jpk
512            hydrofe(:,:,jk) = ( hydrofe(:,:,jk) * hratio ) / ( e1e2t(:,:) * e3t_0(:,:,jk) * ryyss + rtrn ) / 1000._wp
513         ENDDO
514         !
515      ENDIF
516      !
517      IF( ll_sbc ) CALL p4z_sbc( nit000 ) 
518      !
519      IF(lwp) THEN
520         WRITE(numout,*)
521         WRITE(numout,*) '    Total input of elements from river supply'
522         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
523         WRITE(numout,*) '    N Supply   : ', rivdininput*rno3*1E3/1E12*14.,' TgN/yr'
524         WRITE(numout,*) '    Si Supply  : ', rivdsiinput*1E3/1E12*28.1,' TgSi/yr'
525         WRITE(numout,*) '    P Supply   : ', rivdipinput*1E3*po4r/1E12*31.,' TgP/yr'
526         WRITE(numout,*) '    Alk Supply : ', rivalkinput*1E3/1E12,' Teq/yr'
527         WRITE(numout,*) '    DIC Supply : ', rivdicinput*1E3*12./1E12,'TgC/yr'
528         WRITE(numout,*) 
529         WRITE(numout,*) '    Total input of elements from atmospheric supply'
530         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
531         WRITE(numout,*) '    N Supply   : ', nitdepinput*rno3*1E3/1E12*14.,' TgN/yr'
532         WRITE(numout,*) 
533      ENDIF
534      !
535      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc_init')
536      !
537   END SUBROUTINE p4z_sbc_init
538
539   !!======================================================================
540END MODULE p4zsbc
Note: See TracBrowser for help on using the repository browser.