New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsbc.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsbc.F90 @ 7174

Last change on this file since 7174 was 7174, checked in by cetlod, 7 years ago

new top interface : minor improvments of PISCES
  • Property svn:keywords set to Id
File size: 27.5 KB
Line 
1MODULE p4zsbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8   !!   p4z_sbc        :  Read and interpolate time-varying nutrients fluxes
9   !!   p4z_sbc_init   :  Initialization of p4z_sbc
10   !!----------------------------------------------------------------------
11   USE oce_trc         !  shared variables between ocean and passive tracers
12   USE trc             !  passive tracers common variables
13   USE sms_pisces      !  PISCES Source Minus Sink variables
14   USE iom             !  I/O manager
15   USE fldread         !  time interpolation
16
17   IMPLICIT NONE
18   PRIVATE
19
20   PUBLIC   p4z_sbc
21   PUBLIC   p4z_sbc_init   
22
23   LOGICAL , PUBLIC  :: ln_dust     !: boolean for dust input from the atmosphere
24   LOGICAL , PUBLIC  :: ln_solub    !: boolean for variable solubility of atmospheric iron
25   LOGICAL , PUBLIC  :: ln_river    !: boolean for river input of nutrients
26   LOGICAL , PUBLIC  :: ln_ndepo    !: boolean for atmospheric deposition of N
27   LOGICAL , PUBLIC  :: ln_ironsed  !: boolean for Fe input from sediments
28   LOGICAL , PUBLIC  :: ln_hydrofe  !: boolean for Fe input from hydrothermal vents
29   LOGICAL , PUBLIC  :: ln_ironice  !: boolean for Fe input from sea ice
30   REAL(wp), PUBLIC  :: sedfeinput  !: Coastal release of Iron
31   REAL(wp), PUBLIC  :: dustsolub   !: Solubility of the dust
32   REAL(wp), PUBLIC  :: mfrac       !: Mineral Content of the dust
33   REAL(wp), PUBLIC  :: icefeinput  !: Iron concentration in sea ice
34   REAL(wp), PUBLIC  :: wdust       !: Sinking speed of the dust
35   REAL(wp), PUBLIC  :: nitrfix     !: Nitrogen fixation rate   
36   REAL(wp), PUBLIC  :: diazolight  !: Nitrogen fixation sensitivty to light
37   REAL(wp), PUBLIC  :: concfediaz  !: Fe half-saturation Cste for diazotrophs
38   REAL(wp)          :: hratio      !: Fe:3He ratio assumed for vent iron supply
39   REAL(wp), PUBLIC  :: fep_rats    !: Fep/Fer ratio from sed  sources
40   REAL(wp), PUBLIC  :: fep_rath    !: Fep/Fer ratio from hydro sources
41
42
43   LOGICAL , PUBLIC  :: ll_sbc
44
45   LOGICAL  ::  ll_solub
46
47   INTEGER , PARAMETER  :: jpriv  = 7   !: Maximum number of river input fields
48   INTEGER , PARAMETER  :: jr_dic = 1   !: index of dissolved inorganic carbon
49   INTEGER , PARAMETER  :: jr_doc = 2   !: index of dissolved organic carbon
50   INTEGER , PARAMETER  :: jr_din = 3   !: index of dissolved inorganic nitrogen
51   INTEGER , PARAMETER  :: jr_don = 4   !: index of dissolved organic nitrogen
52   INTEGER , PARAMETER  :: jr_dip = 5   !: index of dissolved inorganic phosporus
53   INTEGER , PARAMETER  :: jr_dop = 6   !: index of dissolved organic phosphorus
54   INTEGER , PARAMETER  :: jr_dsi = 7   !: index of dissolved silicate
55
56
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_solub      ! structure of input dust
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_river  ! structure of input riverdic
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ndepo     ! structure of input nitrogen deposition
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from hydrothermal vents
63
64   INTEGER , PARAMETER :: nbtimes = 365  !: maximum number of times record in a file
65   INTEGER  :: ntimes_dust, ntimes_riv, ntimes_ndep       ! number of time steps in a file
66   INTEGER  :: ntimes_solub, ntimes_hydro                 ! number of time steps in a file
67
68   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: dust, solub       !: dust fields
69   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdic, rivalk    !: river input fields
70   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdin, rivdip    !: river input fields
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdon, rivdop    !: river input fields
72   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdoc    !: river input fields
73   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdsi    !: river input fields
74   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: nitdep    !: atmospheric N deposition
75   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ironsed   !: Coastal supply of iron
76   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: hydrofe   !: Hydrothermal vent supply of iron
77
78   REAL(wp), PUBLIC :: sumdepsi, rivalkinput, rivdicinput, nitdepinput
79   REAL(wp), PUBLIC :: rivdininput, rivdipinput, rivdsiinput
80
81   !! * Substitutions
82#  include "vectopt_loop_substitute.h90"
83   !!----------------------------------------------------------------------
84   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
85   !! $Id$
86   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
87   !!----------------------------------------------------------------------
88CONTAINS
89
90   SUBROUTINE p4z_sbc( kt )
91      !!----------------------------------------------------------------------
92      !!                  ***  routine p4z_sbc  ***
93      !!
94      !! ** purpose :   read and interpolate the external sources of nutrients
95      !!
96      !! ** method  :   read the files and interpolate the appropriate variables
97      !!
98      !! ** input   :   external netcdf files
99      !!
100      !!----------------------------------------------------------------------
101      !! * arguments
102      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
103
104      !! * local declarations
105      INTEGER  :: ji,jj 
106      REAL(wp) :: zcoef, zyyss
107      !!---------------------------------------------------------------------
108      !
109      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc')
110
111      !
112      ! Compute dust at nit000 or only if there is more than 1 time record in dust file
113      IF( ln_dust ) THEN
114         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_dust > 1 ) ) THEN
115            CALL fld_read( kt, 1, sf_dust )
116            IF( nn_ice_tr == -1 .AND. .NOT. ln_ironice ) THEN
117               dust(:,:) = sf_dust(1)%fnow(:,:,1)
118            ELSE
119               dust(:,:) = sf_dust(1)%fnow(:,:,1) * ( 1.0 - fr_i(:,:) )
120            ENDIF
121         ENDIF
122      ENDIF
123
124      IF( ll_solub ) THEN
125         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_solub > 1 ) ) THEN
126            CALL fld_read( kt, 1, sf_solub )
127            solub(:,:) = sf_solub(1)%fnow(:,:,1)
128         ENDIF
129      ENDIF
130
131      ! N/P and Si releases due to coastal rivers
132      ! Compute river at nit000 or only if there is more than 1 time record in river file
133      ! -----------------------------------------
134      IF( ln_river ) THEN
135         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_riv > 1 ) ) THEN
136            CALL fld_read( kt, 1, sf_river )
137            IF( ln_p4z ) THEN
138               DO jj = 1, jpj
139                  DO ji = 1, jpi
140                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
141                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
142                        &              * 1.E3        / ( 12. * zcoef + rtrn )
143                     rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) + sf_river(jr_doc)%fnow(ji,jj,1) ) &
144                        &              * 1.E3         / ( 12. * zcoef + rtrn )
145                     rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) + sf_river(jr_don)%fnow(ji,jj,1) ) &
146                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn )
147                     rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) + sf_river(jr_dop)%fnow(ji,jj,1) ) &
148                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn )
149                     rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)                                    &
150                        &              * 1.E3        / ( 28.1 * zcoef + rtrn )
151                  END DO
152               END DO
153            ELSE    !  ln_p5z
154               DO jj = 1, jpj
155                  DO ji = 1, jpi
156                     zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
157                     rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
158                        &              * 1.E3        / ( 12. * zcoef + rtrn )
159                     rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) ) &
160                        &              * 1.E3 / ( 12. * zcoef + rtrn ) * tmask(ji,jj,1)
161                     rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) ) &
162                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
163                     rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) ) &
164                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
165                     rivdoc(ji,jj) = ( sf_river(jr_doc)%fnow(ji,jj,1) ) &
166                        &              * 1.E3 / ( 12. * zcoef + rtrn ) * tmask(ji,jj,1)
167                     rivdon(ji,jj) = ( sf_river(jr_don)%fnow(ji,jj,1) ) &
168                        &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn ) * tmask(ji,jj,1)
169                     rivdop(ji,jj) = ( sf_river(jr_dop)%fnow(ji,jj,1) ) &
170                        &              * 1.E3 / po4r / ( 31. * zcoef + rtrn ) * tmask(ji,jj,1)
171                  END DO
172               END DO
173            ENDIF
174         ENDIF
175      ENDIF
176
177      ! Compute N deposition at nit000 or only if there is more than 1 time record in N deposition file
178      IF( ln_ndepo ) THEN
179         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_ndep > 1 ) ) THEN
180             zcoef = rno3 * 14E6 * ryyss
181             CALL fld_read( kt, 1, sf_ndepo )
182             nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
183         ENDIF
184         IF( .NOT.ln_linssh ) THEN
185           zcoef = rno3 * 14E6 * ryyss
186           nitdep(:,:) = sf_ndepo(1)%fnow(:,:,1) / zcoef / e3t_n(:,:,1) 
187         ENDIF
188      ENDIF
189      !
190      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc')
191      !
192   END SUBROUTINE p4z_sbc
193
194   SUBROUTINE p4z_sbc_init
195
196      !!----------------------------------------------------------------------
197      !!                  ***  routine p4z_sbc_init  ***
198      !!
199      !! ** purpose :   initialization of the external sources of nutrients
200      !!
201      !! ** method  :   read the files and compute the budget
202      !!                called at the first timestep (nittrc000)
203      !!
204      !! ** input   :   external netcdf files
205      !!
206      !!----------------------------------------------------------------------
207      !
208      INTEGER  :: ji, jj, jk, jm, ifpr
209      INTEGER  :: ii0, ii1, ij0, ij1
210      INTEGER  :: numdust, numsolub, numriv, numiron, numdepo, numhydro
211      INTEGER  :: ierr, ierr1, ierr2, ierr3
212      INTEGER  :: ios                 ! Local integer output status for namelist read
213      INTEGER  :: ik50                !  last level where depth less than 50 m
214      INTEGER  :: isrow             ! index for ORCA1 starting row
215      REAL(wp) :: zexpide, zdenitide, zmaskt
216      REAL(wp) :: ztimes_dust, ztimes_riv, ztimes_ndep 
217      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
218      REAL(wp), DIMENSION(:), ALLOCATABLE :: rivinput
219      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zdust, zndepo, zriver, zcmask
220      !
221      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
222      TYPE(FLD_N), DIMENSION(jpriv) ::  slf_river    ! array of namelist informations on the fields to read
223      TYPE(FLD_N) ::   sn_dust, sn_solub, sn_ndepo, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
224      TYPE(FLD_N) ::   sn_riverdoc, sn_riverdic, sn_riverdsi   ! informations about the fields to be read
225      TYPE(FLD_N) ::   sn_riverdin, sn_riverdon, sn_riverdip, sn_riverdop
226      !
227      NAMELIST/nampissbc/cn_dir, sn_dust, sn_solub, sn_riverdic, sn_riverdoc, sn_riverdin, sn_riverdon,     &
228        &                sn_riverdip, sn_riverdop, sn_riverdsi, sn_ndepo, sn_ironsed, sn_hydrofe, &
229        &                ln_dust, ln_solub, ln_river, ln_ndepo, ln_ironsed, ln_ironice, ln_hydrofe,    &
230        &                sedfeinput, dustsolub, icefeinput, wdust, mfrac, nitrfix, diazolight, concfediaz, &
231        &                hratio, fep_rats, fep_rath, lgw_rath
232      !!----------------------------------------------------------------------
233      !
234      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc_init')
235      !
236      !                            !* set file information
237      REWIND( numnatp_ref )              ! Namelist nampissbc in reference namelist : Pisces external sources of nutrients
238      READ  ( numnatp_ref, nampissbc, IOSTAT = ios, ERR = 901)
239901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in reference namelist', lwp )
240
241      REWIND( numnatp_cfg )              ! Namelist nampissbc in configuration namelist : Pisces external sources of nutrients
242      READ  ( numnatp_cfg, nampissbc, IOSTAT = ios, ERR = 902 )
243902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in configuration namelist', lwp )
244      IF(lwm) WRITE ( numonp, nampissbc )
245
246      IF ( ( nn_ice_tr >= 0 ) .AND. ln_ironice ) THEN
247         IF(lwp) THEN
248            WRITE(numout,*) ' ln_ironice incompatible with nn_ice_tr = ', nn_ice_tr
249            WRITE(numout,*) ' Specify your sea ice iron concentration in nampisice instead '
250            WRITE(numout,*) ' ln_ironice is forced to .FALSE. '
251            ln_ironice = .FALSE.
252         ENDIF
253      ENDIF
254
255      IF(lwp) THEN
256         WRITE(numout,*) ' '
257         WRITE(numout,*) ' namelist : nampissbc '
258         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ '
259         WRITE(numout,*) '    dust input from the atmosphere           ln_dust     = ', ln_dust
260         WRITE(numout,*) '    Variable solubility of iron input        ln_solub    = ', ln_solub
261         WRITE(numout,*) '    river input of nutrients                 ln_river    = ', ln_river
262         WRITE(numout,*) '    atmospheric deposition of n              ln_ndepo    = ', ln_ndepo
263         WRITE(numout,*) '    Fe input from sediments                  ln_ironsed  = ', ln_ironsed
264         WRITE(numout,*) '    Fe input from seaice                     ln_ironice  = ', ln_ironice
265         WRITE(numout,*) '    fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
266         WRITE(numout,*) '    coastal release of iron                  sedfeinput  = ', sedfeinput
267         WRITE(numout,*) '    solubility of the dust                   dustsolub   = ', dustsolub
268         WRITE(numout,*) '    Mineral Fe content of the dust           mfrac       = ', mfrac
269         WRITE(numout,*) '    Iron concentration in sea ice            icefeinput  = ', icefeinput
270         WRITE(numout,*) '    sinking speed of the dust                wdust       = ', wdust
271         WRITE(numout,*) '    nitrogen fixation rate                   nitrfix     = ', nitrfix
272         WRITE(numout,*) '    nitrogen fixation sensitivty to light    diazolight  = ', diazolight
273         WRITE(numout,*) '    fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
274         WRITE(numout,*) '    Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
275         IF( ln_ligand ) THEN
276            WRITE(numout,*) '    Fep/Fer ratio from sed sources            fep_rats   = ', fep_rats
277            WRITE(numout,*) '    Fep/Fer ratio from sed hydro sources      fep_rath   = ', fep_rath
278            WRITE(numout,*) '    Weak ligand ratio from sed hydro sources  lgw_rath   = ', lgw_rath
279         ENDIF
280      END IF
281
282      IF( ln_dust .OR. ln_river .OR. ln_ndepo ) THEN  ;  ll_sbc = .TRUE.
283      ELSE                                            ;  ll_sbc = .FALSE.
284      ENDIF
285
286      IF( ln_dust .AND. ln_solub ) THEN               ;  ll_solub = .TRUE.
287      ELSE                                            ;  ll_solub = .FALSE.
288      ENDIF
289
290      ! set the number of level over which river runoffs are applied
291      ! online configuration : computed in sbcrnf
292      IF( lk_offline ) THEN
293        nk_rnf(:,:) = 1
294        h_rnf (:,:) = gdept_n(:,:,1)
295      ENDIF
296
297      ! dust input from the atmosphere
298      ! ------------------------------
299      IF( ln_dust ) THEN 
300         !
301         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
302         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
303         !
304         ALLOCATE( dust(jpi,jpj) )    ! allocation
305         !
306         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
307         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
308         !
309         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
310                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
311         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
312         !
313         IF( Agrif_Root() ) THEN   !  Only on the master grid
314            ! Get total input dust ; need to compute total atmospheric supply of Si in a year
315            CALL iom_open (  TRIM( sn_dust%clname ) , numdust )
316            CALL iom_gettime( numdust, zsteps, kntime=ntimes_dust)  ! get number of record in file
317            ALLOCATE( zdust(jpi,jpj,ntimes_dust) )
318            DO jm = 1, ntimes_dust
319               CALL iom_get( numdust, jpdom_data, TRIM( sn_dust%clvar ), zdust(:,:,jm), jm )
320            END DO
321            CALL iom_close( numdust )
322            ztimes_dust = 1._wp / FLOAT( ntimes_dust ) 
323            sumdepsi = 0.e0
324            DO jm = 1, ntimes_dust
325               sumdepsi = sumdepsi + glob_sum( zdust(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_dust )
326            ENDDO
327            sumdepsi = sumdepsi / ( nyear_len(1) * rday ) * 12. * 8.8 * 0.075 * mfrac / 28.1 
328            DEALLOCATE( zdust)
329         ENDIF
330      ELSE
331         sumdepsi  = 0._wp
332      END IF
333
334      ! Solubility of dust deposition of iron
335      ! Only if ln_dust and ln_solubility set to true (ll_solub = .true.)
336      ! -----------------------------------------------------------------
337      IF( ll_solub ) THEN
338         !
339         IF(lwp) WRITE(numout,*) '    initialize variable solubility of Fe '
340         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
341         !
342         ALLOCATE( solub(jpi,jpj) )    ! allocation
343         !
344         ALLOCATE( sf_solub(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
345         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_solub structure' )
346         !
347         CALL fld_fill( sf_solub, (/ sn_solub /), cn_dir, 'p4z_sed_init', 'Solubility of atm. iron ', 'nampissed' )
348                                   ALLOCATE( sf_solub(1)%fnow(jpi,jpj,1)   )
349         IF( sn_solub%ln_tint )    ALLOCATE( sf_solub(1)%fdta(jpi,jpj,1,2) )
350         ! get number of record in file
351         CALL iom_open (  TRIM( sn_solub%clname ) , numsolub )
352         CALL iom_gettime( numsolub, zsteps, kntime=ntimes_solub)  ! get number of record in file
353         CALL iom_close( numsolub )
354      ENDIF
355
356      ! nutrient input from rivers
357      ! --------------------------
358      IF( ln_river ) THEN
359         !
360         slf_river(jr_dic) = sn_riverdic  ;  slf_river(jr_doc) = sn_riverdoc  ;  slf_river(jr_din) = sn_riverdin 
361         slf_river(jr_don) = sn_riverdon  ;  slf_river(jr_dip) = sn_riverdip  ;  slf_river(jr_dop) = sn_riverdop
362         slf_river(jr_dsi) = sn_riverdsi 
363         !
364         ALLOCATE( rivdic(jpi,jpj), rivalk(jpi,jpj), rivdin(jpi,jpj), rivdip(jpi,jpj), rivdsi(jpi,jpj) ) 
365         IF( ln_p5z )  ALLOCATE( rivdon(jpi,jpj), rivdop(jpi,jpj), rivdoc(jpi,jpj) )
366         !
367         ALLOCATE( sf_river(jpriv), rivinput(jpriv), STAT=ierr1 )           !* allocate and fill sf_river (forcing structure) with sn_river_
368         rivinput(:) = 0.0
369
370         IF( ierr1 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_irver structure' )
371         !
372         CALL fld_fill( sf_river, slf_river, cn_dir, 'p4z_sed_init', 'Input from river ', 'nampissed' )
373         DO ifpr = 1, jpriv
374                                          ALLOCATE( sf_river(ifpr)%fnow(jpi,jpj,1  ) )
375            IF( slf_river(ifpr)%ln_tint ) ALLOCATE( sf_river(ifpr)%fdta(jpi,jpj,1,2) )
376         END DO
377         IF( Agrif_Root() ) THEN   !  Only on the master grid
378            ! Get total input rivers ; need to compute total river supply in a year
379            DO ifpr = 1, jpriv
380               CALL iom_open ( TRIM( slf_river(ifpr)%clname ), numriv )
381               CALL iom_gettime( numriv, zsteps, kntime=ntimes_riv)
382               ALLOCATE( zriver(jpi,jpj,ntimes_riv) )
383               DO jm = 1, ntimes_riv
384                  CALL iom_get( numriv, jpdom_data, TRIM( slf_river(ifpr)%clvar ), zriver(:,:,jm), jm )
385               END DO
386               CALL iom_close( numriv )
387               ztimes_riv = 1._wp / FLOAT(ntimes_riv) 
388               DO jm = 1, ntimes_riv
389                  rivinput(ifpr) = rivinput(ifpr) + glob_sum( zriver(:,:,jm) * tmask(:,:,1) * ztimes_riv ) 
390               END DO
391               DEALLOCATE( zriver)
392            END DO
393            ! N/P and Si releases due to coastal rivers
394            ! -----------------------------------------
395            rivdicinput = (rivinput(jr_dic) + rivinput(jr_doc) ) * 1E3 / 12._wp
396            rivdininput = (rivinput(jr_din) + rivinput(jr_don) ) * 1E3 / rno3 / 14._wp
397            rivdipinput = (rivinput(jr_dip) + rivinput(jr_dop) ) * 1E3 / po4r / 31._wp
398            rivdsiinput = rivinput(jr_dsi) * 1E3 / 28.1_wp
399            rivalkinput = rivinput(jr_dic) * 1E3 / 12._wp
400            !
401         ENDIF
402      ELSE
403         rivdicinput = 0._wp
404         rivdininput = 0._wp
405         rivdipinput = 0._wp
406         rivdsiinput = 0._wp
407         rivalkinput = 0._wp
408      END IF 
409      ! nutrient input from dust
410      ! ------------------------
411      IF( ln_ndepo ) THEN
412         !
413         IF(lwp) WRITE(numout,*) '    initialize the nutrient input by dust from ndeposition.orca.nc'
414         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
415         !
416         ALLOCATE( nitdep(jpi,jpj) )    ! allocation
417         !
418         ALLOCATE( sf_ndepo(1), STAT=ierr3 )           !* allocate and fill sf_sst (forcing structure) with sn_sst
419         IF( ierr3 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_ndepo structure' )
420         !
421         CALL fld_fill( sf_ndepo, (/ sn_ndepo /), cn_dir, 'p4z_sed_init', 'Nutrient atmospheric depositon ', 'nampissed' )
422                                   ALLOCATE( sf_ndepo(1)%fnow(jpi,jpj,1)   )
423         IF( sn_ndepo%ln_tint )    ALLOCATE( sf_ndepo(1)%fdta(jpi,jpj,1,2) )
424         !
425         IF( Agrif_Root() ) THEN   !  Only on the master grid
426            ! Get total input dust ; need to compute total atmospheric supply of N in a year
427            CALL iom_open ( TRIM( sn_ndepo%clname ), numdepo )
428            CALL iom_gettime( numdepo, zsteps, kntime=ntimes_ndep)
429            ALLOCATE( zndepo(jpi,jpj,ntimes_ndep) )
430            DO jm = 1, ntimes_ndep
431               CALL iom_get( numdepo, jpdom_data, TRIM( sn_ndepo%clvar ), zndepo(:,:,jm), jm )
432            END DO
433            CALL iom_close( numdepo )
434            ztimes_ndep = 1._wp / FLOAT( ntimes_ndep ) 
435            nitdepinput = 0._wp
436            DO jm = 1, ntimes_ndep
437              nitdepinput = nitdepinput + glob_sum( zndepo(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_ndep )
438            ENDDO
439            nitdepinput = nitdepinput / rno3 / 14E6 
440            DEALLOCATE( zndepo)
441         ENDIF
442      ELSE
443         nitdepinput = 0._wp
444      ENDIF
445
446      ! coastal and island masks
447      ! ------------------------
448      IF( ln_ironsed ) THEN     
449         !
450         IF(lwp) WRITE(numout,*) '    computation of an island mask to enhance coastal supply of iron'
451         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
452         !
453         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
454         !
455         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
456         ALLOCATE( zcmask(jpi,jpj,jpk) )
457         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
458         CALL iom_close( numiron )
459         !
460         ik50 = 5        !  last level where depth less than 50 m
461         DO jk = jpkm1, 1, -1
462            IF( gdept_1d(jk) > 50. )  ik50 = jk - 1
463         END DO
464         IF (lwp) WRITE(numout,*)
465         IF (lwp) WRITE(numout,*) ' Level corresponding to 50m depth ',  ik50,' ', gdept_1d(ik50+1)
466         IF (lwp) WRITE(numout,*)
467         DO jk = 1, ik50
468            DO jj = 2, jpjm1
469               DO ji = fs_2, fs_jpim1
470                  IF( tmask(ji,jj,jk) /= 0. ) THEN
471                     zmaskt = tmask(ji+1,jj,jk) * tmask(ji-1,jj,jk) * tmask(ji,jj+1,jk)    &
472                        &                       * tmask(ji,jj-1,jk) * tmask(ji,jj,jk+1)
473                     IF( zmaskt == 0. )   zcmask(ji,jj,jk ) = MAX( 0.1, zcmask(ji,jj,jk) ) 
474                  END IF
475               END DO
476            END DO
477         END DO
478         !
479         CALL lbc_lnk( zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
480         !
481         DO jk = 1, jpk
482            DO jj = 1, jpj
483               DO ji = 1, jpi
484                  zexpide   = MIN( 8.,( gdept_n(ji,jj,jk) / 500. )**(-1.5) )
485                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
486                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
487               END DO
488            END DO
489         END DO
490         ! Coastal supply of iron
491         ! -------------------------
492         ironsed(:,:,jpk) = 0._wp
493         DO jk = 1, jpkm1
494            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( e3t_0(:,:,jk) * rday )
495         END DO
496         DEALLOCATE( zcmask)
497      ENDIF
498      !
499      ! Iron from Hydrothermal vents
500      ! ------------------------
501      IF( ln_hydrofe ) THEN
502         !
503         IF(lwp) WRITE(numout,*) '    Input of iron from hydrothermal vents '
504         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
505         !
506         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
507         !
508         CALL iom_open ( TRIM( sn_hydrofe%clname ), numhydro )
509         CALL iom_get  ( numhydro, jpdom_data, TRIM( sn_hydrofe%clvar ), hydrofe(:,:,:), 1 )
510         CALL iom_close( numhydro )
511         !
512         DO jk = 1, jpk
513            hydrofe(:,:,jk) = ( hydrofe(:,:,jk) * hratio ) / ( e1e2t(:,:) * e3t_0(:,:,jk) * ryyss + rtrn ) / 1000._wp
514         ENDDO
515         !
516      ENDIF
517      !
518      IF( ll_sbc ) CALL p4z_sbc( nit000 ) 
519      !
520      IF(lwp) THEN
521         WRITE(numout,*)
522         WRITE(numout,*) '    Total input of elements from river supply'
523         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
524         WRITE(numout,*) '    N Supply   : ', rivdininput*rno3*1E3/1E12*14.,' TgN/yr'
525         WRITE(numout,*) '    Si Supply  : ', rivdsiinput*1E3/1E12*28.1,' TgSi/yr'
526         WRITE(numout,*) '    P Supply   : ', rivdipinput*1E3*po4r/1E12*31.,' TgP/yr'
527         WRITE(numout,*) '    Alk Supply : ', rivalkinput*1E3/1E12,' Teq/yr'
528         WRITE(numout,*) '    DIC Supply : ', rivdicinput*1E3*12./1E12,'TgC/yr'
529         WRITE(numout,*) 
530         WRITE(numout,*) '    Total input of elements from atmospheric supply'
531         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
532         WRITE(numout,*) '    N Supply   : ', nitdepinput*rno3*1E3/1E12*14.,' TgN/yr'
533         WRITE(numout,*) 
534      ENDIF
535      !
536      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc_init')
537      !
538   END SUBROUTINE p4z_sbc_init
539
540   !!======================================================================
541END MODULE p4zsbc
Note: See TracBrowser for help on using the repository browser.