New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zprod.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p5zprod.F90 @ 7162

Last change on this file since 7162 was 7162, checked in by cetlod, 7 years ago

new top interface : Add PISCES quota model
  • Property svn:executable set to *
File size: 37.3 KB
Line 
1MODULE p5zprod
2   !!======================================================================
3   !!                         ***  MODULE p5zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_prod       :   Compute the growth Rate of the two phytoplanktons groups
12   !!   p5z_prod_init  :   Initialization of the parameters for growth
13   !!   p5z_prod_alloc :   Allocate variables for growth
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE p5zlim          !  Co-limitations of differents nutrients
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p5z_prod         ! called in p5zbio.F90
26   PUBLIC   p5z_prod_init    ! called in trcsms_pisces.F90
27   PUBLIC   p5z_prod_alloc
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC ::  pislopen        !:
31   REAL(wp), PUBLIC ::  pislopep        !:
32   REAL(wp), PUBLIC ::  pisloped        !:
33   REAL(wp), PUBLIC ::  xadap           !:
34   REAL(wp), PUBLIC ::  excretn         !:
35   REAL(wp), PUBLIC ::  excretp         !:
36   REAL(wp), PUBLIC ::  excretd         !:
37   REAL(wp), PUBLIC ::  bresp           !:
38   REAL(wp), PUBLIC ::  thetanpm        !:
39   REAL(wp), PUBLIC ::  thetannm        !:
40   REAL(wp), PUBLIC ::  thetandm        !:
41   REAL(wp), PUBLIC ::  chlcmin         !:
42   REAL(wp), PUBLIC ::  grosip          !:
43   REAL(wp), PUBLIC ::  xlimmxln        !:
44   REAL(wp), PUBLIC ::  xlimmxlp        !:
45   REAL(wp), PUBLIC ::  xlimmxld        !:
46
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxn   !: optimal production = f(temperature)
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxp   !: optimal production = f(temperature)
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxd   !: optimal production = f(temperature)
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   zdaylen
51   
52   REAL(wp) :: r1_rday                !: 1 / rday
53   REAL(wp) :: texcretn               !: 1 - excret
54   REAL(wp) :: texcretp               !: 1 - excretp
55   REAL(wp) :: texcretd               !: 1 - excret2       
56
57   !!----------------------------------------------------------------------
58   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
59   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
60   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE p5z_prod( kt , knt )
65      !!---------------------------------------------------------------------
66      !!                     ***  ROUTINE p5z_prod  ***
67      !!
68      !! ** Purpose :   Compute the phytoplankton production depending on
69      !!              light, temperature and nutrient availability
70      !!
71      !! ** Method  : - ???
72      !!---------------------------------------------------------------------
73      !
74      INTEGER, INTENT(in) :: kt, knt
75      !
76      INTEGER  ::   ji, jj, jk
77      REAL(wp) ::   zsilfac, znanotot, zpicotot, zdiattot, zconctemp, zconctemp2
78      REAL(wp) ::   zration, zratiop, zratiof, zmax, zmax2, zsilim, ztn, zadap
79      REAL(wp) ::   zpronmax, zpropmax, zprofmax, zrat
80      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zprontot, zproptot, zprodtot
81      REAL(wp) ::   zprnutmax, zdocprod, zprochln, zprochld, zprochlp
82      REAL(wp) ::   zpislopen, zpislopep, zpisloped, thetannm_n, thetandm_n, thetanpm_n
83      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup
84      REAL(wp) ::   zfact, zrfact2
85      CHARACTER (len=25) :: charout
86      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixpico, zmixdiat, zstrn
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopeadn, zpislopeadp, zpislopeadd
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprbio, zprpic, zprdia, zysopt
89      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprchln, zprchlp, zprchld
90      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcap, zprorcad 
91      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprofed, zprofep, zprofen
92      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpronewn, zpronewp, zpronewd
93      REAL(wp), POINTER, DIMENSION(:,:,:) :: zproregn, zproregp, zproregd
94      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpropo4n, zpropo4p, zpropo4d
95      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprodopn, zprodopp, zprodopd
96      REAL(wp), POINTER, DIMENSION(:,:,:) :: zrespn, zrespp, zrespd, zprnut
97      REAL(wp), POINTER, DIMENSION(:,:,:) :: zcroissn, zcroissp, zcroissd
98      REAL(wp), POINTER, DIMENSION(:,:,:) :: zmxl_fac, zmxl_chl
99      REAL(wp), POINTER, DIMENSION(:,:,:) :: zw3d
100      REAL(wp), POINTER, DIMENSION(:,:  ) :: zw2d
101      !!---------------------------------------------------------------------
102      !
103      IF( nn_timing == 1 )  CALL timing_start('p5z_prod')
104      !
105      !  Allocate temporary workspace
106      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
107      CALL wrk_alloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
108      CALL wrk_alloc( jpi, jpj, jpk, zpislopeadn, zpislopeadp, zpislopeadd, zysopt ) 
109      CALL wrk_alloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
110      CALL wrk_alloc( jpi, jpj, jpk, zprofed, zprofep, zprofen )
111      CALL wrk_alloc( jpi, jpj, jpk, zpronewn, zpronewp, zpronewd, zproregn, zproregp, zproregd )
112      CALL wrk_alloc( jpi, jpj, jpk, zpropo4n, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
113      CALL wrk_alloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
114      CALL wrk_alloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
115      !
116      zprorcan(:,:,:) = 0._wp ; zprorcap(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp
117      zprofed (:,:,:) = 0._wp ; zprofep (:,:,:) = 0._wp ; zprofen (:,:,:) = 0._wp
118      zpronewn(:,:,:) = 0._wp ; zpronewp(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp
119      zproregn(:,:,:) = 0._wp ; zproregp(:,:,:) = 0._wp ; zproregd(:,:,:) = 0._wp 
120      zpropo4n(:,:,:) = 0._wp ; zpropo4p(:,:,:) = 0._wp ; zpropo4d(:,:,:) = 0._wp
121      zprdia  (:,:,:) = 0._wp ; zprpic  (:,:,:) = 0._wp ; zprbio  (:,:,:) = 0._wp
122      zysopt  (:,:,:) = 0._wp
123      zrespn  (:,:,:) = 0._wp ; zrespp  (:,:,:) = 0._wp ; zrespd  (:,:,:) = 0._wp 
124
125      ! Computation of the optimal production
126      prmaxn(:,:,:) = ( 0.65_wp * (1. + zpsino3 * qnpmax ) ) * r1_rday * tgfunc(:,:,:)
127      prmaxp(:,:,:) = 0.5 / 0.65 * prmaxn(:,:,:) 
128      prmaxd(:,:,:) = prmaxn(:,:,:) 
129      zprnut(:,:,:) = 0.65_wp * r1_rday * tgfunc(:,:,:)
130
131      ! compute the day length depending on latitude and the day
132      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
133      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
134
135      ! day length in hours
136      zstrn(:,:) = 0.
137      DO jj = 1, jpj
138         DO ji = 1, jpi
139            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
140            zargu = MAX( -1., MIN(  1., zargu ) )
141            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
142         END DO
143      END DO
144
145         ! Impact of the day duration on phytoplankton growth
146      DO jk = 1, jpkm1
147         DO jj = 1 ,jpj
148            DO ji = 1, jpi
149               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
150                  zval = MAX( 1., zstrn(ji,jj) )
151                  zmxl_fac(ji,jj,jk) = zval
152                  zmxl_chl(ji,jj,jk) = zval / 24.
153                  IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
154                     zval = MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
155                     zmxl_fac(ji,jj,jk) = zmxl_fac(ji,jj,jk) * zval
156                     zmxl_chl(ji,jj,jk) = zmxl_chl(ji,jj,jk) * zval
157                  ENDIF
158                  zmxl_fac(ji,jj,jk) = ( 1. - exp( -0.2 * zmxl_fac(ji,jj,jk) ) )
159                  zmxl_chl(ji,jj,jk) = zmxl_chl(ji,jj,jk)
160               ENDIF
161            END DO
162         END DO
163      END DO
164
165      zprbio(:,:,:) = prmaxn(:,:,:) * zmxl_fac(:,:,:)
166      zprdia(:,:,:) = prmaxd(:,:,:) * zmxl_fac(:,:,:)
167      zprpic(:,:,:) = prmaxp(:,:,:) * zmxl_fac(:,:,:)
168
169
170      ! Maximum light intensity
171      zdaylen(:,:) = MAX(1., zstrn(:,:)) / 24.
172      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
173      zstrn(:,:) = 24. / zstrn(:,:)
174
175      DO jk = 1, jpkm1
176         DO jj = 1, jpj
177            DO ji = 1, jpi
178               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
179                  ! Computation of the P-I slope for nanos and diatoms
180                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
181                  zadap       = xadap * ztn / ( 2.+ ztn )
182                  !
183                  zpislopeadn(ji,jj,jk) = pislopen * trb(ji,jj,jk,jpnch)    &
184                  &                       /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
185                  zpislopeadp(ji,jj,jk) = pislopep * ( 1. + zadap * EXP( -0.25 * epico(ji,jj,jk) ) )   &
186                  &                       * trb(ji,jj,jk,jppch) /( trb(ji,jj,jk,jppic) * 12. + rtrn)
187                  zpislopeadd(ji,jj,jk) = pisloped * trb(ji,jj,jk,jpdch)    &
188                     &                    /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
189                  !
190                  zpislopen = zpislopeadn(ji,jj,jk) / ( prmaxn(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
191                  zpislopep = zpislopeadp(ji,jj,jk) / ( prmaxp(ji,jj,jk) * rday * xlimpic(ji,jj,jk) + rtrn )
192                  zpisloped = zpislopeadd(ji,jj,jk) / ( prmaxd(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
193
194                  ! Computation of production function for Carbon
195                  !  ---------------------------------------------
196                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
197                  zprpic(ji,jj,jk) = zprpic(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) )  )
198                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
199
200                  ! Computation of production function for Chlorophyll
201                  !  -------------------------------------------------
202                  zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
203                  zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
204                  zpislopep = zpislopep * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
205                  zprchln(ji,jj,jk) = prmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
206                  zprchlp(ji,jj,jk) = prmaxp(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) )  )
207                  zprchld(ji,jj,jk) = prmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
208               ENDIF
209            END DO
210         END DO
211      END DO
212
213      DO jk = 1, jpkm1
214         DO jj = 1, jpj
215            DO ji = 1, jpi
216
217                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
218                  !    Si/C of diatoms
219                  !    ------------------------
220                  !    Si/C increases with iron stress and silicate availability
221                  !    Si/C is arbitrariliy increased for very high Si concentrations
222                  !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
223                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
224                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
225                  zsilfac = 3.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
226                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
227                  IF (gphit(ji,jj) < -30 ) THEN
228                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
229                  ELSE
230                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
231                  ENDIF
232                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
233              ENDIF
234            END DO
235         END DO
236      END DO
237
238      !  Sea-ice effect on production                                                                               
239      DO jk = 1, jpkm1
240         DO jj = 1, jpj
241            DO ji = 1, jpi
242               zprbio(ji,jj,jk)  = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
243               zprpic(ji,jj,jk)  = zprpic(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
244               zprdia(ji,jj,jk)  = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
245               zprnut(ji,jj,jk)  = zprnut(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
246            END DO
247         END DO
248      END DO
249
250      ! Computation of the various production terms of nanophytoplankton
251      DO jk = 1, jpkm1
252         DO jj = 1, jpj
253            DO ji = 1, jpi
254               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
255                  !  production terms for nanophyto.
256                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
257                  !
258                  zration = trb(ji,jj,jk,jpnph) / ( trb(ji,jj,jk,jpphy) + rtrn )
259                  zratiop = trb(ji,jj,jk,jppph) / ( trb(ji,jj,jk,jpphy) + rtrn )
260                  zratiof = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
261                  zprnutmax = zprnut(ji,jj,jk) * fvnuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpphy) * rfact2
262                  ! Uptake of nitrogen
263                  zrat = MIN( 1., zration / (xqnnmax(ji,jj,jk) + rtrn) ) 
264                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
265                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpnmin(ji,jj,jk) )   &
266                  &          / ( xqpnmax(ji,jj,jk) - xqpnmin(ji,jj,jk) ), xlimnfe(ji,jj,jk) ) )
267                  zpronewn(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xnanono3(ji,jj,jk)
268                  zproregn(ji,jj,jk) = zpronmax * xnanonh4(ji,jj,jk)
269                  ! Uptake of phosphorus
270                  zrat = MIN( 1., zratiop / (xqpnmax(ji,jj,jk) + rtrn) )
271                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
272                  zpropmax = zprnutmax * zmax * xlimnfe(ji,jj,jk)
273                  zpropo4n(ji,jj,jk) = zpropmax * xnanopo4(ji,jj,jk)
274                  zprodopn(ji,jj,jk) = zpropmax * xnanodop(ji,jj,jk)
275                  ! Uptake of iron
276                  zrat = MIN( 1., zratiof / qfnmax )
277                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
278                  zprofmax = zprnutmax * qfnmax * zmax
279                  zprofen(ji,jj,jk) = zprofmax * xnanofer(ji,jj,jk) * ( 3. - 2.4 * xlimnfe(ji,jj,jk)    &
280                  &          / ( xlimnfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xnanono3(ji,jj,jk) / ( rtrn  &
281                  &          + xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) ) * (1. - xnanofer(ji,jj,jk) ) )
282               ENDIF
283            END DO
284         END DO
285      END DO
286
287      ! Computation of the various production terms of picophytoplankton
288      DO jk = 1, jpkm1
289         DO jj = 1, jpj
290            DO ji = 1, jpi
291               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
292                  !  production terms for picophyto.
293                  zprorcap(ji,jj,jk) = zprpic(ji,jj,jk)  * xlimpic(ji,jj,jk) * trb(ji,jj,jk,jppic) * rfact2
294                  !
295                  zration = trb(ji,jj,jk,jpnpi) / ( trb(ji,jj,jk,jppic) + rtrn )
296                  zratiop = trb(ji,jj,jk,jpppi) / ( trb(ji,jj,jk,jppic) + rtrn )
297                  zratiof = trb(ji,jj,jk,jppfe) / ( trb(ji,jj,jk,jppic) + rtrn )
298                  zprnutmax = zprnut(ji,jj,jk) * fvpuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jppic) * rfact2
299                  ! Uptake of nitrogen
300                  zrat = MIN( 1., zration / (xqnpmax(ji,jj,jk) + rtrn) )
301                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
302                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqppmin(ji,jj,jk) )   &
303                  &          / ( xqppmax(ji,jj,jk) - xqppmin(ji,jj,jk) ), xlimpfe(ji,jj,jk) ) )
304                  zpronewp(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xpicono3(ji,jj,jk) 
305                  zproregp(ji,jj,jk) = zpronmax * xpiconh4(ji,jj,jk)
306                  ! Uptake of phosphorus
307                  zrat = MIN( 1., zratiop / (xqppmax(ji,jj,jk) + rtrn) )
308                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
309                  zpropmax = zprnutmax * zmax * xlimpfe(ji,jj,jk)
310                  zpropo4p(ji,jj,jk) = zpropmax * xpicopo4(ji,jj,jk)
311                  zprodopp(ji,jj,jk) = zpropmax * xpicodop(ji,jj,jk)
312                  ! Uptake of iron
313                  zrat = MIN( 1., zratiof / qfpmax )
314                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
315                  zprofmax = zprnutmax * qfpmax * zmax
316                  zprofep(ji,jj,jk) = zprofmax * xpicofer(ji,jj,jk) * ( 3. - 2.4 * xlimpfe(ji,jj,jk)   &
317                  &          / ( xlimpfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xpicono3(ji,jj,jk) / ( rtrn   &
318                  &          + xpicono3(ji,jj,jk) + xpiconh4(ji,jj,jk) ) * (1. - xpicofer(ji,jj,jk) ) )
319               ENDIF
320            END DO
321         END DO
322      END DO
323
324      ! Computation of the various production terms of diatoms
325      DO jk = 1, jpkm1
326         DO jj = 1, jpj
327            DO ji = 1, jpi
328               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
329                  !  production terms for diatomees
330                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
331                  ! Computation of the respiration term according to pahlow
332                  ! & oschlies (2013)
333                  !
334                  zration = trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn )
335                  zratiop = trb(ji,jj,jk,jppdi) / ( trb(ji,jj,jk,jpdia) + rtrn )
336                  zratiof = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
337                  zprnutmax = zprnut(ji,jj,jk) * fvduptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpdia) * rfact2
338                  ! Uptake of nitrogen
339                  zrat = MIN( 1., zration / (xqndmax(ji,jj,jk) + rtrn) )
340                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
341                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpdmin(ji,jj,jk) )   &
342                  &          / ( xqpdmax(ji,jj,jk) - xqpdmin(ji,jj,jk) ), xlimdfe(ji,jj,jk) ) )
343                  zpronewd(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xdiatno3(ji,jj,jk)
344                  zproregd(ji,jj,jk) = zpronmax * xdiatnh4(ji,jj,jk)
345                  ! Uptake of phosphorus
346                  zrat = MIN( 1., zratiop / (xqpdmax(ji,jj,jk) + rtrn) )
347                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
348                  zpropmax = zprnutmax * zmax * xlimdfe(ji,jj,jk)
349                  zpropo4d(ji,jj,jk) = zpropmax * xdiatpo4(ji,jj,jk)
350                  zprodopd(ji,jj,jk) = zpropmax * xdiatdop(ji,jj,jk)
351                  ! Uptake of iron
352                  zrat = MIN( 1., zratiof / qfdmax )
353                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
354                  zprofmax = zprnutmax * qfdmax * zmax
355                  zprofed(ji,jj,jk) = zprofmax * xdiatfer(ji,jj,jk) * ( 3. - 2.4 * xlimdfe(ji,jj,jk)     &
356                  &          / ( xlimdfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xdiatno3(ji,jj,jk) / ( rtrn   &
357                  &          + xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) ) * (1. - xdiatfer(ji,jj,jk) ) )
358               ENDIF
359            END DO
360         END DO
361      END DO
362
363      DO jk = 1, jpkm1
364         DO jj = 1, jpj
365            DO ji = 1, jpi
366               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
367                     !  production terms for nanophyto. ( chlorophyll )
368                  znanotot = enano(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
369                  zprod = rday * (zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)) * zprchln(ji,jj,jk) * xlimphy(ji,jj,jk)
370                  thetannm_n   = MIN ( thetannm, ( thetannm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem)))   &
371                  &               * (1. - 1.14 / 43.4 * 20.))
372                  zprochln = thetannm_n * zprod / ( zpislopeadn(ji,jj,jk) * znanotot + rtrn )
373                  zprochln = MAX(zprochln, chlcmin * 12. * zprorcan (ji,jj,jk) )
374                     !  production terms for picophyto. ( chlorophyll )
375                  zpicotot = epico(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
376                  zprod = rday * (zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)) * zprchlp(ji,jj,jk) * xlimpic(ji,jj,jk)
377                  thetanpm_n   = MIN ( thetanpm, ( thetanpm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem)))   &
378                  &               * (1. - 1.14 / 43.4 * 20.))
379                  zprochlp = thetanpm_n * zprod / ( zpislopeadp(ji,jj,jk) * zpicotot + rtrn )
380                  zprochlp = MAX(zprochlp, chlcmin * 12. * zprorcap(ji,jj,jk) )
381                  !  production terms for diatomees ( chlorophyll )
382                  zdiattot = ediat(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
383                  zprod = rday * (zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)) * zprchld(ji,jj,jk) * xlimdia(ji,jj,jk)
384                  thetandm_n   = MIN ( thetandm, ( thetandm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem)))   &
385                  &               * (1. - 1.14 / 43.4 * 20.))
386                  zprochld = thetandm_n * zprod / ( zpislopeadd(ji,jj,jk) * zdiattot + rtrn )
387                  zprochld = MAX(zprochld, chlcmin * 12. * zprorcad(ji,jj,jk) )
388                  !   Update the arrays TRA which contain the Chla sources and sinks
389                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
390                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
391                  tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) + zprochlp * texcretp
392               ENDIF
393            END DO
394         END DO
395      END DO
396
397      !   Update the arrays TRA which contain the biological sources and sinks
398      DO jk = 1, jpkm1
399         DO jj = 1, jpj
400           DO ji =1 ,jpi
401              zprontot = zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)
402              zproptot = zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)
403              zprodtot = zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)
404              zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
405              &          + excretp * zprorcap(ji,jj,jk)
406              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zpropo4n(ji,jj,jk) - zpropo4d(ji,jj,jk)  &
407              &                     - zpropo4p(ji,jj,jk)
408              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)  &
409              &                     - zpronewp(ji,jj,jk)
410              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproregn(ji,jj,jk) - zproregd(ji,jj,jk)  &
411              &                     - zproregp(ji,jj,jk)
412              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn    &
413                 &                  - zpsino3 * zpronewn(ji,jj,jk) - zpsinh4 * zproregn(ji,jj,jk)   &
414                 &                  - zrespn(ji,jj,jk) 
415              zcroissn(ji,jj,jk) = tra(ji,jj,jk,jpphy) / rfact2/ (trb(ji,jj,jk,jpphy) + rtrn)
416              tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) + zprontot * texcretn
417              tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) + zpropo4n(ji,jj,jk) * texcretn   &
418              &                     + zprodopn(ji,jj,jk) * texcretn
419              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
420              tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) + zprorcap(ji,jj,jk) * texcretp     &
421                 &                  - zpsino3 * zpronewp(ji,jj,jk) - zpsinh4 * zproregp(ji,jj,jk)   &
422                 &                  - zrespp(ji,jj,jk) 
423              zcroissp(ji,jj,jk) = tra(ji,jj,jk,jppic) / rfact2/ (trb(ji,jj,jk,jppic) + rtrn)
424              tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) + zproptot * texcretp
425              tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) + zpropo4p(ji,jj,jk) * texcretp   &
426              &                     + zprodopp(ji,jj,jk) * texcretp
427              tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) + zprofep(ji,jj,jk) * texcretp
428              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd   &
429                 &                  - zpsino3 * zpronewd(ji,jj,jk) - zpsinh4 * zproregd(ji,jj,jk)   &
430                 &                  - zrespd(ji,jj,jk) 
431              zcroissd(ji,jj,jk) = tra(ji,jj,jk,jpdia) / rfact2 / (trb(ji,jj,jk,jpdia) + rtrn)
432              tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) + zprodtot * texcretd
433              tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) + zpropo4d(ji,jj,jk) * texcretd   &
434              &                     + zprodopd(ji,jj,jk) * texcretd
435              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
436              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
437              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
438              &                     + excretp * zprorcap(ji,jj,jk)
439              tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + excretd * zprodtot + excretn * zprontot   &
440              &                     + excretp * zproptot
441              tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + excretd * zpropo4d(ji,jj,jk) + excretn * zpropo4n(ji,jj,jk)   &
442              &    - texcretn * zprodopn(ji,jj,jk) - texcretd * zprodopd(ji,jj,jk) + excretp * zpropo4p(ji,jj,jk)     &
443              &    - texcretp * zprodopp(ji,jj,jk)
444              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)   &
445                 &                + zproregp(ji,jj,jk) ) + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk)           &
446                 &                + zpronewd(ji,jj,jk) + zpronewp(ji,jj,jk) )   &
447                 &                - o2ut * ( zrespn(ji,jj,jk) + zrespp(ji,jj,jk) + zrespd(ji,jj,jk) )
448              zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
449              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
450              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
451              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk) - zprorcap(ji,jj,jk)  &
452              &                     + zpsino3 * zpronewn(ji,jj,jk) + zpsinh4 * zproregn(ji,jj,jk)   &
453              &                     + zpsino3 * zpronewp(ji,jj,jk) + zpsinh4 * zproregp(ji,jj,jk)   &
454              &                     + zpsino3 * zpronewd(ji,jj,jk) + zpsinh4 * zproregd(ji,jj,jk)  &
455              &                     + zrespn(ji,jj,jk) + zrespd(ji,jj,jk) + zrespp(ji,jj,jk) 
456              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk)  &
457              &                     + zpronewp(ji,jj,jk) ) - rno3 * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)     &
458              &                     + zproregp(ji,jj,jk) ) 
459          END DO
460        END DO
461     END DO
462     !
463     IF( ln_ligand ) THEN
464         DO jk = 1, jpkm1
465            DO jj = 1, jpj
466              DO ji =1 ,jpi
467                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk) + excretp * zprorcap(ji,jj,jk)
468                 zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
469                 tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
470              END DO
471           END DO
472        END DO
473     ENDIF
474
475
476     ! Total primary production per year
477
478    ! Total primary production per year
479    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
480      & tpp = glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) + zprorcap(:,:,:) ) * cvol(:,:,:) )
481
482    IF( lk_iomput ) THEN
483       IF( knt == nrdttrc ) THEN
484          CALL wrk_alloc( jpi, jpj,      zw2d )
485          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
486          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
487          !
488          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) .OR. iom_use( "PPPHYP" ) )  THEN
489              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
490              CALL iom_put( "PPPHYN"  , zw3d )
491              !
492              zw3d(:,:,:) = zprorcap(:,:,:) * zfact * tmask(:,:,:)  ! primary production by picophyto
493              CALL iom_put( "PPPHYP"  , zw3d )
494              !
495              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
496              CALL iom_put( "PPPHYD"  , zw3d )
497          ENDIF
498          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) .OR. iom_use( "PPNEWP" ) )  THEN
499              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
500              CALL iom_put( "PPNEWN"  , zw3d )
501              !
502              zw3d(:,:,:) = zpronewp(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by picophyto
503              CALL iom_put( "PPNEWP"  , zw3d )
504              !
505              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
506              CALL iom_put( "PPNEWD"  , zw3d )
507          ENDIF
508          IF( iom_use( "PBSi" ) )  THEN
509              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
510              CALL iom_put( "PBSi"  , zw3d )
511          ENDIF
512          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) .OR. iom_use( "PFeP" ) )  THEN
513              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
514              CALL iom_put( "PFeN"  , zw3d )
515              !
516              zw3d(:,:,:) = zprofep(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by picophyto
517              CALL iom_put( "PFeP"  , zw3d )
518              !
519              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
520              CALL iom_put( "PFeD"  , zw3d )
521          ENDIF
522          IF( iom_use( "Mumax" ) )  THEN
523              zw3d(:,:,:) = prmaxn(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
524              CALL iom_put( "Mumax"  , zw3d )
525          ENDIF
526          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) .OR. iom_use( "MuP" ) )  THEN
527              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
528              CALL iom_put( "MuN"  , zw3d )
529              !
530              zw3d(:,:,:) = zprpic(:,:,:) * xlimpic(:,:,:) * tmask(:,:,:)  ! Realized growth rate for picophyto
531              CALL iom_put( "MuP"  , zw3d )
532              !
533              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
534              CALL iom_put( "MuD"  , zw3d )
535          ENDIF
536          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) .OR. iom_use( "LPlight" ) )  THEN
537              zw3d(:,:,:) = zprbio (:,:,:) / (prmaxn(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
538              CALL iom_put( "LNlight"  , zw3d )
539              !
540              zw3d(:,:,:) = zprpic (:,:,:) / (prmaxp(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
541              CALL iom_put( "LPlight"  , zw3d )
542              !
543              zw3d(:,:,:) =  zprdia (:,:,:) / (prmaxd(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
544              CALL iom_put( "LDlight"  , zw3d )
545          ENDIF
546          IF( iom_use( "MunetN" ) .OR. iom_use( "MunetD" ) .OR. iom_use( "MunetP" ) )  THEN
547              zw3d(:,:,:) = zcroissn(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for nanophyto
548              CALL iom_put( "MunetN"  , zw3d )
549              !
550              zw3d(:,:,:) = zcroissp(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for picophyto
551              CALL iom_put( "MunetP"  , zw3d )
552              !
553              zw3d(:,:,:) = zcroissd(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for diatomes
554              CALL iom_put( "MunetD"  , zw3d )
555              !
556          ENDIF
557
558          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
559          !
560          CALL wrk_dealloc( jpi, jpj,      zw2d )
561          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
562       ENDIF
563     ENDIF
564
565      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
566         WRITE(charout, FMT="('prod')")
567         CALL prt_ctl_trc_info(charout)
568         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
569      ENDIF
570      !
571      CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
572      CALL wrk_dealloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
573      CALL wrk_dealloc( jpi, jpj, jpk, zpislopeadn, zpislopeadp, zpislopeadd, zysopt )                           
574      CALL wrk_dealloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
575      CALL wrk_dealloc( jpi, jpj, jpk, zprofed, zprofep, zprofen ) 
576      CALL wrk_dealloc( jpi, jpj, jpk, zpronewn, zpronewp, zpronewd, zproregn, zproregp, zproregd )
577      CALL wrk_dealloc( jpi, jpj, jpk, zpropo4n, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
578      CALL wrk_dealloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
579      CALL wrk_dealloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
580      !
581      IF( nn_timing == 1 )  CALL timing_stop('p5z_prod')
582      !
583   END SUBROUTINE p5z_prod
584
585
586   SUBROUTINE p5z_prod_init
587      !!----------------------------------------------------------------------
588      !!                  ***  ROUTINE p5z_prod_init  ***
589      !!
590      !! ** Purpose :   Initialization of phytoplankton production parameters
591      !!
592      !! ** Method  :   Read the nampisprod namelist and check the parameters
593      !!      called at the first timestep (nittrc000)
594      !!
595      !! ** input   :   Namelist nampisprod
596      !!----------------------------------------------------------------------
597      !
598      NAMELIST/namp5zprod/ pislopen, pislopep, pisloped, excretn, excretp, excretd,     &
599         &                 thetannm, thetanpm, thetandm, chlcmin, grosip, bresp, xadap, &
600         &                 xlimmxln, xlimmxlp, xlimmxld
601
602      INTEGER :: ios                 ! Local integer output status for namelist read
603      !!----------------------------------------------------------------------
604
605      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
606      READ  ( numnatp_ref, namp5zprod, IOSTAT = ios, ERR = 901)
607901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in reference namelist', lwp )
608
609      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
610      READ  ( numnatp_cfg, namp5zprod, IOSTAT = ios, ERR = 902 )
611902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in configuration namelist', lwp )
612      IF(lwm) WRITE ( numonp, namp5zprod )
613
614      IF(lwp) THEN                         ! control print
615         WRITE(numout,*) ' '
616         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp5zprod'
617         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
618         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
619         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
620         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
621         WRITE(numout,*) '    P-I slope  for picophytoplankton          pislopep     =', pislopep
622         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
623         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
624         WRITE(numout,*) '    excretion ratio of picophytoplankton      excretp      =', excretp
625         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
626         WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
627         WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
628         WRITE(numout,*) '    Minimum Chl/N in nanophytoplankton        thetannm     =', thetannm
629         WRITE(numout,*) '    Minimum Chl/N in picophytoplankton        thetanpm     =', thetanpm
630         WRITE(numout,*) '    Minimum Chl/N in diatoms                  thetandm     =', thetandm
631         WRITE(numout,*) '    Critical time scale for mixing (nano)     xlimmxln     =', xlimmxln
632         WRITE(numout,*) '    Critical time scale for mixing (pico)     xlimmxlp     =', xlimmxlp
633         WRITE(numout,*) '    Critical time scale for mixing (diatoms)  xlimmxld     =', xlimmxld
634      ENDIF
635      !
636      r1_rday   = 1._wp / rday 
637      texcretn  = 1._wp - excretn
638      texcretp  = 1._wp - excretp
639      texcretd  = 1._wp - excretd
640      tpp       = 0._wp
641      !
642   END SUBROUTINE p5z_prod_init
643
644
645   INTEGER FUNCTION p5z_prod_alloc()
646      !!----------------------------------------------------------------------
647      !!                     ***  ROUTINE p5z_prod_alloc  ***
648      !!----------------------------------------------------------------------
649      ALLOCATE( prmaxn(jpi,jpj,jpk), prmaxp(jpi,jpj,jpk), prmaxd(jpi,jpj,jpk),  &
650      &          zdaylen(jpi,jpj), STAT = p5z_prod_alloc )
651      !
652      IF( p5z_prod_alloc /= 0 ) CALL ctl_warn('p5z_prod_alloc : failed to allocate arrays.')
653      !
654   END FUNCTION p5z_prod_alloc
655   !!======================================================================
656END MODULE  p5zprod
Note: See TracBrowser for help on using the repository browser.