New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini_pisces.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/trcini_pisces.F90 @ 7068

Last change on this file since 7068 was 7068, checked in by cetlod, 8 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782
  • Property svn:keywords set to Id
File size: 12.1 KB
Line 
1MODULE trcini_pisces
2   !!======================================================================
3   !!                         ***  MODULE trcini_pisces  ***
4   !! TOP :   initialisation of the PISCES biochemical model
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. Maier-Reiner) Original code
7   !!              -   !  1999-10  (O. Aumont, C. Le Quere)
8   !!              -   !  2002     (O. Aumont)  PISCES
9   !!             1.0  !  2005-03  (O. Aumont, A. El Moussaoui) F90
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec) from trcini.pisces.h90
11   !!             3.5  !  2012-05  (C. Ethe) Merge PISCES-LOBSTER
12   !!----------------------------------------------------------------------
13   !! trc_ini_pisces   : PISCES biochemical model initialisation
14   !!----------------------------------------------------------------------
15   USE par_trc         ! TOP parameters
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   trc_ini_pisces   ! called by trcini.F90 module
24
25   !!----------------------------------------------------------------------
26   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
27   !! $Id$
28   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
29   !!----------------------------------------------------------------------
30CONTAINS
31
32   SUBROUTINE trc_ini_pisces
33      !!----------------------------------------------------------------------
34      !!                   ***  ROUTINE trc_ini_pisces ***
35      !!
36      !! ** Purpose :   Initialisation of the PISCES biochemical model
37      !!----------------------------------------------------------------------
38
39      IF( ln_p4z ) THEN  ;   CALL p4z_ini   !  PISCES
40      ELSE               ;   CALL p2z_ini   !  LOBSTER
41      ENDIF
42
43   END SUBROUTINE trc_ini_pisces
44
45   SUBROUTINE p4z_ini
46      !!----------------------------------------------------------------------
47      !!                   ***  ROUTINE p4z_ini ***
48      !!
49      !! ** Purpose :   Initialisation of the PISCES biochemical model
50      !!----------------------------------------------------------------------
51      !
52      USE p4zsms          ! Main P4Z routine
53      USE p4zche          !  Chemical model
54      USE p4zsink         !  vertical flux of particulate matter due to sinking
55      USE p4zopt          !  optical model
56      USE p4zsbc          !  Boundary conditions
57      USE p4zfechem       !  Iron chemistry
58      USE p4zrem          !  Remineralisation of organic matter
59      USE p4zflx          !  Gas exchange
60      USE p4zlim          !  Co-limitations of differents nutrients
61      USE p4zprod         !  Growth rate of the 2 phyto groups
62      USE p4zmicro        !  Sources and sinks of microzooplankton
63      USE p4zmeso         !  Sources and sinks of mesozooplankton
64      USE p4zmort         !  Mortality terms for phytoplankton
65      USE p4zlys          !  Calcite saturation
66      USE p4zsed          !  Sedimentation & burial
67      !
68      REAL(wp), SAVE :: sco2   =  2.312e-3_wp
69      REAL(wp), SAVE :: alka0  =  2.426e-3_wp
70      REAL(wp), SAVE :: oxyg0  =  177.6e-6_wp 
71      REAL(wp), SAVE :: po4    =  2.165e-6_wp 
72      REAL(wp), SAVE :: bioma0 =  1.000e-8_wp 
73      REAL(wp), SAVE :: silic1 =  91.51e-6_wp 
74      REAL(wp), SAVE :: no3    =  30.9e-6_wp * 7.625_wp
75      !
76      INTEGER  ::  ji, jj, jk, jn, ierr
77      REAL(wp) ::  zcaralk, zbicarb, zco3
78      REAL(wp) ::  ztmas, ztmas1
79      CHARACTER(len = 20)  ::  cltra
80
81      !!----------------------------------------------------------------------
82
83      IF(lwp) WRITE(numout,*)
84      IF(lwp) WRITE(numout,*) ' p4z_ini :   PISCES biochemical model initialisation'
85      IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
86
87                                                 ! Allocate PISCES arrays
88      ierr =         sms_pisces_alloc()         
89      ierr = ierr +  p4z_che_alloc()
90      ierr = ierr +  p4z_sink_alloc()
91      ierr = ierr +  p4z_opt_alloc()
92      ierr = ierr +  p4z_prod_alloc()
93      ierr = ierr +  p4z_rem_alloc()
94      ierr = ierr +  p4z_flx_alloc()
95      ierr = ierr +  p4z_sed_alloc()
96      !
97      IF( lk_mpp    )   CALL mpp_sum( ierr )
98      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'pisces_alloc: unable to allocate PISCES arrays' )
99      !
100      ryyss    = nyear_len(1) * rday    ! number of seconds per year
101      r1_ryyss = 1. / ryyss
102      !
103
104      ! assign an index in trc arrays for each prognostic variables
105      DO jn = 1, jptra
106        cltra = ctrcnm(jn) 
107        IF( cltra == 'DIC'      )   jpdic = jn      !: dissolved inoganic carbon concentration
108        IF( cltra == 'Alkalini' )   jptal = jn      !: total alkalinity
109        IF( cltra == 'O2'       )   jpoxy = jn      !: oxygen carbon concentration
110        IF( cltra == 'CaCO3'    )   jpcal = jn      !: calcite  concentration
111        IF( cltra == 'PO4'      )   jppo4 = jn      !: phosphate concentration
112        IF( cltra == 'POC'      )   jppoc = jn      !: small particulate organic phosphate concentration
113        IF( cltra == 'Si'       )   jpsil = jn      !: silicate concentration
114        IF( cltra == 'PHY'      )   jpphy = jn      !: phytoplancton concentration
115        IF( cltra == 'ZOO'      )   jpzoo = jn      !: zooplancton concentration
116        IF( cltra == 'DOC'      )   jpdoc = jn      !: dissolved organic carbon concentration
117        IF( cltra == 'PHY2'     )   jpdia = jn      !: Diatoms Concentration
118        IF( cltra == 'ZOO2'     )   jpmes = jn      !: Mesozooplankton Concentration
119        IF( cltra == 'DSi'      )   jpdsi = jn      !: Diatoms Silicate Concentration
120        IF( cltra == 'Fer'      )   jpfer = jn      !: Iron Concentration
121        IF( cltra == 'BFe'      )   jpbfe = jn      !: Big iron particles Concentration
122        IF( cltra == 'GOC'      )   jpgoc = jn      !: Big particulate organic phosphate concentration
123        IF( cltra == 'SFe'      )   jpsfe = jn      !: Small iron particles Concentration
124        IF( cltra == 'DFe'      )   jpdfe = jn      !: Diatoms iron Concentration
125        IF( cltra == 'GSi'      )   jpgsi = jn      !: (big) Silicate Concentration
126        IF( cltra == 'NFe'      )   jpnfe = jn      !: Nano iron Concentration
127        IF( cltra == 'NCHL'     )   jpnch = jn      !: Nano Chlorophyll Concentration
128        IF( cltra == 'DCHL'     )   jpdch = jn      !: Diatoms Chlorophyll Concentration
129        IF( cltra == 'NO3'      )   jpno3 = jn      !: Nitrates Concentration
130        IF( cltra == 'NH4'      )   jpnh4 = jn      !: Ammonium Concentration
131      ENDDO
132
133      CALL p4z_sms_init       !  Maint routine
134      !                                            ! Time-step
135
136      ! Set biological ratios
137      ! ---------------------
138      rno3    =  16._wp / 122._wp
139      po4r    =   1._wp / 122._wp
140      o2nit   =  32._wp / 122._wp
141      o2ut    = 133._wp / 122._wp
142      rdenit  =  ( ( o2ut + o2nit ) * 0.80 - rno3 - rno3 * 0.60 ) / rno3
143      rdenita =   3._wp /  5._wp
144
145
146      ! Initialization of tracer concentration in case of  no restart
147      !--------------------------------------------------------------
148      IF( .NOT.ln_rsttr ) THEN 
149         trn(:,:,:,jpdic) = sco2
150         trn(:,:,:,jpdoc) = bioma0
151         trn(:,:,:,jptal) = alka0
152         trn(:,:,:,jpoxy) = oxyg0
153         trn(:,:,:,jpcal) = bioma0
154         trn(:,:,:,jppo4) = po4 / po4r
155         trn(:,:,:,jppoc) = bioma0
156         trn(:,:,:,jpgoc) = bioma0
157         trn(:,:,:,jpbfe) = bioma0 * 5.e-6
158         trn(:,:,:,jpsil) = silic1
159         trn(:,:,:,jpdsi) = bioma0 * 0.15
160         trn(:,:,:,jpgsi) = bioma0 * 5.e-6
161         trn(:,:,:,jpphy) = bioma0
162         trn(:,:,:,jpdia) = bioma0
163         trn(:,:,:,jpzoo) = bioma0
164         trn(:,:,:,jpmes) = bioma0
165         trn(:,:,:,jpfer) = 0.6E-9
166         trn(:,:,:,jpsfe) = bioma0 * 5.e-6
167         trn(:,:,:,jpdfe) = bioma0 * 5.e-6
168         trn(:,:,:,jpnfe) = bioma0 * 5.e-6
169         trn(:,:,:,jpnch) = bioma0 * 12. / 55.
170         trn(:,:,:,jpdch) = bioma0 * 12. / 55.
171         trn(:,:,:,jpno3) = no3
172         trn(:,:,:,jpnh4) = bioma0
173
174         ! initialize the half saturation constant for silicate
175         ! ----------------------------------------------------
176         xksi(:,:)    = 2.e-6
177         xksimax(:,:) = xksi(:,:)
178      END IF
179
180
181      CALL p4z_sink_init      !  vertical flux of particulate organic matter
182      CALL p4z_opt_init       !  Optic: PAR in the water column
183      CALL p4z_lim_init       !  co-limitations by the various nutrients
184      CALL p4z_prod_init      !  phytoplankton growth rate over the global ocean.
185      CALL p4z_sbc_init       !  boundary conditions
186      CALL p4z_fechem_init    !  Iron chemistry
187      CALL p4z_rem_init       !  remineralisation
188      CALL p4z_mort_init      !  phytoplankton mortality
189      CALL p4z_micro_init     !  microzooplankton
190      CALL p4z_meso_init      !  mesozooplankton
191      CALL p4z_lys_init       !  calcite saturation
192      CALL p4z_flx_init       !  gas exchange
193
194      ndayflxtr = 0
195
196      IF(lwp) WRITE(numout,*) 
197      IF(lwp) WRITE(numout,*) 'Initialization of PISCES tracers done'
198      IF(lwp) WRITE(numout,*) 
199      !
200   END SUBROUTINE p4z_ini
201
202   SUBROUTINE p2z_ini
203      !!----------------------------------------------------------------------
204      !!                   ***  ROUTINE p2z_ini ***
205      !!
206      !! ** Purpose :   Initialisation of the LOBSTER biochemical model
207      !!----------------------------------------------------------------------
208      !
209      USE p2zopt
210      USE p2zexp
211      USE p2zbio
212      USE p2zsed
213      !
214      INTEGER  ::  ji, jj, jk, jn, ierr
215      CHARACTER(len = 10)  ::  cltra
216      !!----------------------------------------------------------------------
217
218      IF(lwp) WRITE(numout,*)
219      IF(lwp) WRITE(numout,*) ' p2z_ini :   LOBSTER biochemical model initialisation'
220      IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
221
222      ierr =        sms_pisces_alloc()         
223      ierr = ierr + p2z_exp_alloc()
224      !
225      IF( lk_mpp    )   CALL mpp_sum( ierr )
226      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'p2z_ini: unable to allocate LOBSTER arrays' )
227
228      DO jn = 1, jptra
229        cltra = ctrcnm(jn) 
230        IF( cltra == 'DET' )   jpdet = jn       !: detritus                    [mmoleN/m3]
231        IF( cltra == 'ZOO' )   jpzoo = jn       !: zooplancton concentration   [mmoleN/m3]
232        IF( cltra == 'PHY' )   jpphy = jn       !: phytoplancton concentration [mmoleN/m3]
233        IF( cltra == 'NO3' )   jpno3 = jn       !: nitrate concentration       [mmoleN/m3]
234        IF( cltra == 'NH4' )   jpnh4 = jn       !: ammonium concentration      [mmoleN/m3]
235        IF( cltra == 'DOM' )   jpdom = jn       !: dissolved organic matter    [mmoleN/m3]
236      ENDDO
237
238      jpkb = 10        !  last level where depth less than 200 m
239      DO jk = jpkm1, 1, -1
240         IF( gdept_1d(jk) > 200. ) jpkb = jk 
241      END DO
242      IF (lwp) WRITE(numout,*)
243      IF (lwp) WRITE(numout,*) ' first vertical layers where biology is active (200m depth ) ', jpkb
244      IF (lwp) WRITE(numout,*)
245      jpkbm1 = jpkb - 1
246      !
247
248
249      ! LOBSTER initialisation for GYRE : init NO3=f(density) by asklod AS Kremeur 2005-07
250      ! ----------------------
251      IF( .NOT. ln_rsttr ) THEN             ! in case of  no restart
252         trn(:,:,:,jpdet) = 0.1 * tmask(:,:,:)
253         trn(:,:,:,jpzoo) = 0.1 * tmask(:,:,:)
254         trn(:,:,:,jpnh4) = 0.1 * tmask(:,:,:)
255         trn(:,:,:,jpphy) = 0.1 * tmask(:,:,:)
256         trn(:,:,:,jpdom) = 1.0 * tmask(:,:,:)
257         WHERE( rhd(:,:,:) <= 24.5e-3 )  ;  trn(:,:,:,jpno3) = 2._wp * tmask(:,:,:)
258         ELSE WHERE                      ;  trn(:,:,:,jpno3) = ( 15.55 * ( rhd(:,:,:) * 1000. ) - 380.11 ) * tmask(:,:,:)
259         END WHERE                       
260      ENDIF
261      !                       !  Namelist read
262      CALL p2z_opt_init       !  Optics parameters
263      CALL p2z_sed_init       !  sedimentation
264      CALL p2z_bio_init       !  biology
265      CALL p2z_exp_init       !  export
266      !
267      IF(lwp) WRITE(numout,*) 
268      IF(lwp) WRITE(numout,*) 'Initialization of LOBSTER tracers done'
269      IF(lwp) WRITE(numout,*) 
270      !
271   END SUBROUTINE p2z_ini
272
273   !!======================================================================
274END MODULE trcini_pisces
Note: See TracBrowser for help on using the repository browser.