New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/TRP/trcadv.F90 @ 7162

Last change on this file since 7162 was 7162, checked in by cetlod, 7 years ago

new top interface : Add PISCES quota model
  • Property svn:keywords set to Id
File size: 14.6 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2010-06  (C. Ethe)   Adapted to passive tracers
8   !!            3.7  !  2014-05  (G. Madec, C. Ethe)  Add 2nd/4th order cases for CEN and FCT schemes
9   !!----------------------------------------------------------------------
10#if defined key_top
11   !!----------------------------------------------------------------------
12   !!   'key_top'                                                TOP models
13   !!----------------------------------------------------------------------
14   !!   trc_adv       : compute ocean tracer advection trend
15   !!   trc_adv_ini   : control the different options of advection scheme
16   !!----------------------------------------------------------------------
17   USE oce_trc        ! ocean dynamics and active tracers
18   USE trc            ! ocean passive tracers variables
19   USE traadv_cen     ! centered scheme           (tra_adv_cen  routine)
20   USE traadv_fct     ! FCT      scheme           (tra_adv_fct  routine)
21   USE traadv_mus     ! MUSCL    scheme           (tra_adv_mus  routine)
22   USE traadv_ubs     ! UBS      scheme           (tra_adv_ubs  routine)
23   USE traadv_qck     ! QUICKEST scheme           (tra_adv_qck  routine)
24   USE traadv_mle     ! ML eddy induced velocity  (tra_adv_mle  routine)
25   USE ldftra         ! lateral diffusion coefficient on tracers
26   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
27   !
28   USE prtctl_trc     ! Print control
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   trc_adv       
34   PUBLIC   trc_adv_ini 
35
36   !                            !!* Namelist namtrc_adv *
37   LOGICAL ::   ln_trcadv_cen    ! centered scheme flag
38   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
39   LOGICAL ::   ln_trcadv_fct    ! FCT scheme flag
40   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
41   INTEGER ::      nn_fct_zts           ! >=1 : 2nd order FCT with vertical sub-timestepping
42   LOGICAL ::   ln_trcadv_mus    ! MUSCL scheme flag
43   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
44   LOGICAL ::   ln_trcadv_ubs    ! UBS scheme flag
45   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
46   LOGICAL ::   ln_trcadv_qck    ! QUICKEST scheme flag
47
48   !                                        ! choices of advection scheme:
49   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
50   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
51   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
52   INTEGER, PARAMETER ::   np_FCT_zts = 3   ! 2nd order FCT scheme with vertical sub-timestepping
53   INTEGER, PARAMETER ::   np_MUS     = 4   ! MUSCL scheme
54   INTEGER, PARAMETER ::   np_UBS     = 5   ! 3rd order Upstream Biased Scheme
55   INTEGER, PARAMETER ::   np_QCK     = 6   ! QUICK scheme
56
57   INTEGER ::              nadv             ! chosen advection scheme
58   !
59   !! * Substitutions
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/TOP 3.7 , NEMO Consortium (2015)
63   !! $Id$
64   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE trc_adv( kt )
69      !!----------------------------------------------------------------------
70      !!                  ***  ROUTINE trc_adv  ***
71      !!
72      !! ** Purpose :   compute the ocean tracer advection trend.
73      !!
74      !! ** Method  : - Update the tracer with the advection term following nadv
75      !!----------------------------------------------------------------------
76      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
77      !
78      INTEGER ::   jk   ! dummy loop index
79      CHARACTER (len=22) ::   charout
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn  ! effective velocity
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )   CALL timing_start('trc_adv')
84      !
85      CALL wrk_alloc( jpi,jpj,jpk,   zun, zvn, zwn )
86      !                                               !==  effective transport  ==!
87      DO jk = 1, jpkm1
88         zun(:,:,jk) = e2u  (:,:) * e3u_n(:,:,jk) * un(:,:,jk)                   ! eulerian transport
89         zvn(:,:,jk) = e1v  (:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
90         zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
91      END DO
92      !
93      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                 ! add z-tilde and/or vvl corrections
94         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
95         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
96      ENDIF
97      !
98      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   & 
99         &              CALL ldf_eiv_trp( kt, nittrc000, zun, zvn, zwn, 'TRC' )  ! add the eiv transport
100      !
101      IF( ln_mle    )   CALL tra_adv_mle( kt, nittrc000, zun, zvn, zwn, 'TRC' )  ! add the mle transport
102      !
103      zun(:,:,jpk) = 0._wp                                                       ! no transport trough the bottom
104      zvn(:,:,jpk) = 0._wp
105      zwn(:,:,jpk) = 0._wp
106      !
107      !
108      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
109      !
110      CASE ( np_CEN )                                    ! Centered : 2nd / 4th order
111         CALL tra_adv_cen    ( kt, nittrc000,'TRC',       zun, zvn, zwn     , trn, tra, jptra, nn_cen_h, nn_cen_v )
112      CASE ( np_FCT )                                    ! FCT      : 2nd / 4th order
113         CALL tra_adv_fct    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra, nn_fct_h, nn_fct_v )
114      CASE ( np_FCT_zts )                                ! 2nd order FCT with vertical time-splitting
115         CALL tra_adv_fct_zts( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra        , nn_fct_zts )
116      CASE ( np_MUS )                                    ! MUSCL
117         CALL tra_adv_mus    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb,      tra, jptra        , ln_mus_ups ) 
118      CASE ( np_UBS )                                    ! UBS
119         CALL tra_adv_ubs    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra        , nn_ubs_v   )
120      CASE ( np_QCK )                                    ! QUICKEST
121         CALL tra_adv_qck    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra                     )
122      !
123      END SELECT
124      !                 
125      IF( ln_ctl )   THEN                             !== print mean trends (used for debugging)
126         WRITE(charout, FMT="('adv ')")  ;  CALL prt_ctl_trc_info(charout)
127                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
128      END IF
129      !
130      CALL wrk_dealloc( jpi,jpj,jpk,   zun, zvn, zwn )
131      !
132      IF( nn_timing == 1 )  CALL timing_stop('trc_adv')
133      !
134   END SUBROUTINE trc_adv
135
136
137   SUBROUTINE trc_adv_ini
138      !!---------------------------------------------------------------------
139      !!                  ***  ROUTINE trc_adv_ini  ***
140      !!               
141      !! ** Purpose : Control the consistency between namelist options for
142      !!              passive tracer advection schemes and set nadv
143      !!----------------------------------------------------------------------
144      INTEGER ::   ioptio
145      INTEGER ::  ios                 ! Local integer output status for namelist read
146      !!
147      NAMELIST/namtrc_adv/ ln_trcadv_cen, nn_cen_h, nn_cen_v,               &   ! CEN
148         &                 ln_trcadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts,   &   ! FCT
149         &                 ln_trcadv_mus,                     ln_mus_ups,   &   ! MUSCL
150         &                 ln_trcadv_ubs,           nn_ubs_v,               &   ! UBS
151         &                 ln_trcadv_qck                                        ! QCK
152      !!----------------------------------------------------------------------
153      !
154      REWIND( numnat_ref )              !  namtrc_adv in reference namelist
155      READ  ( numnat_ref, namtrc_adv, IOSTAT = ios, ERR = 901)
156901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_adv in reference namelist', lwp )
157
158      REWIND( numnat_cfg )              ! namtrc_adv in configuration namelist
159      READ  ( numnat_cfg, namtrc_adv, IOSTAT = ios, ERR = 902 )
160902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_adv in configuration namelist', lwp )
161      IF(lwm) WRITE ( numont, namtrc_adv )
162
163      IF(lwp) THEN                    ! Namelist print
164         WRITE(numout,*)
165         WRITE(numout,*) 'trc_adv_ini : choice/control of the tracer advection scheme'
166         WRITE(numout,*) '~~~~~~~~~~~'
167         WRITE(numout,*) '   Namelist namtrc_adv : chose a advection scheme for tracers'
168         WRITE(numout,*) '      centered scheme                           ln_trcadv_cen = ', ln_trcadv_cen
169         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
170         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
171         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_trcadv_fct = ', ln_trcadv_fct
172         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
173         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
174         WRITE(numout,*) '            2nd order + vertical sub-timestepping  nn_fct_zts = ', nn_fct_zts
175         WRITE(numout,*) '      MUSCL scheme                              ln_trcadv_mus = ', ln_trcadv_mus
176         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
177         WRITE(numout,*) '      UBS scheme                                ln_trcadv_ubs = ', ln_trcadv_ubs
178         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
179         WRITE(numout,*) '      QUICKEST scheme                           ln_trcadv_qck = ', ln_trcadv_qck
180      ENDIF
181      !
182
183      ioptio = 0                       !==  Parameter control  ==!
184      IF( ln_trcadv_cen )   ioptio = ioptio + 1
185      IF( ln_trcadv_fct )   ioptio = ioptio + 1
186      IF( ln_trcadv_mus )   ioptio = ioptio + 1
187      IF( ln_trcadv_ubs )   ioptio = ioptio + 1
188      IF( ln_trcadv_qck )   ioptio = ioptio + 1
189
190      !
191      IF( ioptio == 0 ) THEN
192         nadv = np_NO_adv
193         CALL ctl_warn( 'trc_adv_init: You are running without tracer advection.' )
194      ENDIF
195      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtrc_adv' )
196      !
197      IF( ln_trcadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &
198                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
199        CALL ctl_stop( 'trc_adv_init: CEN scheme, choose 2nd or 4th order' )
200      ENDIF
201      IF( ln_trcadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &
202                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
203        CALL ctl_stop( 'trc_adv_init: FCT scheme, choose 2nd or 4th order' )
204      ENDIF
205      IF( ln_trcadv_fct .AND. nn_fct_zts > 0 ) THEN
206         IF( nn_fct_h == 4 ) THEN
207            nn_fct_h = 2
208            CALL ctl_stop( 'trc_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
209         ENDIF
210         IF( .NOT.ln_linssh ) THEN
211            CALL ctl_stop( 'trc_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
212         ENDIF
213         IF( nn_fct_zts == 1 )   CALL ctl_warn( 'trc_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
214      ENDIF
215      IF( ln_trcadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN
216        CALL ctl_stop( 'trc_adv_init: UBS scheme, choose 2nd or 4th order' )
217      ENDIF
218      IF( ln_trcadv_ubs .AND. nn_ubs_v == 4 ) THEN
219         CALL ctl_warn( 'trc_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
220      ENDIF
221      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
222         IF(  ln_trcadv_cen .AND. nn_cen_v /= 4    .OR.   &                            ! NO 4th order with ISF
223            & ln_trcadv_fct .AND. nn_fct_v /= 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
224      ENDIF
225      !
226      !                                !==  used advection scheme  ==!
227      !                                      ! set nadv
228      IF( ln_trcadv_cen                      )   nadv = np_CEN
229      IF( ln_trcadv_fct                      )   nadv = np_FCT
230      IF( ln_trcadv_fct .AND. nn_fct_zts > 0 )   nadv = np_FCT_zts
231      IF( ln_trcadv_mus                      )   nadv = np_MUS
232      IF( ln_trcadv_ubs                      )   nadv = np_UBS
233      IF( ln_trcadv_qck                      )   nadv = np_QCK
234      !
235      IF(lwp) THEN                   ! Print the choice
236         WRITE(numout,*)
237         IF( nadv == np_NO_adv  )   WRITE(numout,*) '         NO passive tracer advection'
238         IF( nadv == np_CEN     )   WRITE(numout,*) '         CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
239            &                                                                        ' Vertical   order: ', nn_cen_v
240         IF( nadv == np_FCT     )   WRITE(numout,*) '         FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
241            &                                                                       ' Vertical   order: ', nn_fct_v
242         IF( nadv == np_FCT_zts )   WRITE(numout,*) '         use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
243         IF( nadv == np_MUS     )   WRITE(numout,*) '         MUSCL    scheme is used'
244         IF( nadv == np_UBS     )   WRITE(numout,*) '         UBS      scheme is used'
245         IF( nadv == np_QCK     )   WRITE(numout,*) '         QUICKEST scheme is used'
246      ENDIF
247      !
248   END SUBROUTINE trc_adv_ini
249   
250#else
251   !!----------------------------------------------------------------------
252   !!   Default option                                         Empty module
253   !!----------------------------------------------------------------------
254CONTAINS
255   SUBROUTINE trc_adv( kt )
256      INTEGER, INTENT(in) :: kt
257      WRITE(*,*) 'trc_adv: You should not have seen this print! error?', kt
258   END SUBROUTINE trc_adv
259#endif
260
261  !!======================================================================
262END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.