source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/trcstp.F90 @ 7041

Last change on this file since 7041 was 7041, checked in by cetlod, 4 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782

  • Property svn:keywords set to Id
File size: 9.4 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!----------------------------------------------------------------------
8#if defined key_top
9   !!----------------------------------------------------------------------
10   !!   trc_stp      : passive tracer system time-stepping
11   !!----------------------------------------------------------------------
12   USE oce_trc          ! ocean dynamics and active tracers variables
13   USE sbc_oce
14   USE trc
15   USE trctrp           ! passive tracers transport
16   USE trcsms           ! passive tracers sources and sinks
17   USE trcwri
18   USE trcrst
19   USE trdtrc_oce
20   USE trdmxl_trc
21   USE prtctl_trc       ! Print control for debbuging
22   USE iom
23   USE in_out_manager
24   USE trcsub
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   trc_stp    ! called by step
30
31   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr ! save qsr during TOP time-step
32   REAL(wp) :: rdt_sampl
33   INTEGER  :: nb_rec_per_day
34   REAL(wp) :: rsecfst, rseclast
35   LOGICAL  :: llnew
36
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE trc_stp( kt )
45      !!-------------------------------------------------------------------
46      !!                     ***  ROUTINE trc_stp  ***
47      !!                     
48      !! ** Purpose : Time loop of opa for passive tracer
49      !!
50      !! ** Method  :
51      !!              Compute the passive tracers trends
52      !!              Update the passive tracers
53      !!-------------------------------------------------------------------
54      INTEGER, INTENT( in ) ::  kt      ! ocean time-step index
55      INTEGER               ::  jk, jn  ! dummy loop indices
56      REAL(wp)              ::  ztrai
57      CHARACTER (len=25)    ::  charout 
58
59      !!-------------------------------------------------------------------
60      !
61      IF( nn_timing == 1 )   CALL timing_start('trc_stp')
62      !
63      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
64      !
65      IF( .NOT.ln_linssh ) THEN                                           ! update ocean volume due to ssh temporal evolution
66         DO jk = 1, jpk
67            cvol(:,:,jk) = e1e2t(:,:) * e3t_n(:,:,jk) * tmask(:,:,jk)
68         END DO
69         areatot         = glob_sum( cvol(:,:,:) )
70      ENDIF
71      !
72      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
73      !   
74      IF( nn_dttrc /= 1 )   CALL trc_sub_stp( kt )  ! averaging physical variables for sub-stepping
75      !   
76      IF( MOD( kt , nn_dttrc ) == 0 ) THEN      ! only every nn_dttrc time step
77         !
78         IF(ln_ctl) THEN
79            WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
80            CALL prt_ctl_trc_info(charout)
81         ENDIF
82         !
83         tra(:,:,:,:) = 0.e0
84         !
85                                   CALL trc_rst_opn  ( kt )       ! Open tracer restart file
86         IF( lrst_trc )            CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
87                                   CALL trc_wri      ( kt )       ! output of passive tracers with iom I/O manager
88                                   CALL trc_sms      ( kt )       ! tracers: sinks and sources
89                                   CALL trc_trp      ( kt )       ! transport of passive tracers
90         IF( kt == nittrc000 ) THEN
91            CALL iom_close( numrtr )       ! close input tracer restart file
92            IF(lwm) CALL FLUSH( numont )   ! flush namelist output
93         ENDIF
94         IF( lrst_trc )            CALL trc_rst_wri  ( kt )       ! write tracer restart file
95         IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt )       ! trends: Mixed-layer
96         !
97         IF( nn_dttrc /= 1   )     CALL trc_sub_reset( kt )       ! resetting physical variables when sub-stepping
98         !
99      ENDIF
100      !
101      ztrai = 0._wp                                                   !  content of all tracers
102      DO jn = 1, jptra
103         ztrai = ztrai + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
104      END DO
105      IF( lwp ) WRITE(numstr,9300) kt,  ztrai / areatot
1069300  FORMAT(i10,D23.16)
107      !
108      IF( nn_timing == 1 )   CALL timing_stop('trc_stp')
109      !
110   END SUBROUTINE trc_stp
111
112   SUBROUTINE trc_mean_qsr( kt )
113      !!----------------------------------------------------------------------
114      !!             ***  ROUTINE trc_mean_qsr  ***
115      !!
116      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
117      !!               of diurnal cycle
118      !!
119      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
120      !!              is greater than 1 hour ) and then, compute the  mean with
121      !!              a moving average over 24 hours.
122      !!              In coupled mode, the sampling is done at every coupling frequency
123      !!----------------------------------------------------------------------
124      INTEGER, INTENT(in) ::   kt
125      INTEGER  :: jn
126      REAL(wp) :: zkt
127      CHARACTER(len=1)               ::   cl1                      ! 1 character
128      CHARACTER(len=2)               ::   cl2                      ! 2 characters
129
130      IF( kt == nittrc000 ) THEN
131         IF( ln_cpl )  THEN 
132            rdt_sampl = rday / ncpl_qsr_freq
133            nb_rec_per_day = ncpl_qsr_freq
134         ELSE 
135            rdt_sampl = MAX( 3600., rdttrc )
136            nb_rec_per_day = INT( rday / rdt_sampl )
137         ENDIF
138         !
139         IF( lwp ) THEN
140            WRITE(numout,*) 
141            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
142            WRITE(numout,*) 
143         ENDIF
144         !
145         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
146         !
147         !                                            !* Restart: read in restart file
148         IF( ln_rsttr .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0 .AND. &
149                            iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0 .AND. &
150                            iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0 ) THEN
151            CALL iom_get( numrtr, 'ktdcy', zkt )   !  A mean of qsr
152            rsecfst = INT( zkt ) * rdttrc
153            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
154            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
155            DO jn = 1, nb_rec_per_day 
156             IF( jn <= 9 )  THEN
157               WRITE(cl1,'(i1)') jn
158               CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
159             ELSE
160               WRITE(cl2,'(i2.2)') jn
161               CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
162             ENDIF
163           ENDDO
164         ELSE                                         !* no restart: set from nit000 values
165            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
166            rsecfst  = kt * rdttrc
167            !
168            qsr_mean(:,:) = qsr(:,:)
169            DO jn = 1, nb_rec_per_day
170               qsr_arr(:,:,jn) = qsr_mean(:,:)
171            ENDDO
172         ENDIF
173         !
174      ENDIF
175      !
176      rseclast = kt * rdttrc
177      !
178      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
179      IF( llnew ) THEN
180          IF( lwp ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', kt, &
181             &                      ' time = ', rseclast/3600.,'hours '
182          rsecfst = rseclast
183          DO jn = 1, nb_rec_per_day - 1
184             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
185          ENDDO
186          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
187          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
188      ENDIF
189      !
190      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
191         IF(lwp) WRITE(numout,*)
192         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
193         IF(lwp) WRITE(numout,*) '~~~~~~~'
194         zkt = REAL( kt, wp )
195         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt )
196          DO jn = 1, nb_rec_per_day 
197             IF( jn <= 9 )  THEN
198               WRITE(cl1,'(i1)') jn
199               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
200             ELSE
201               WRITE(cl2,'(i2.2)') jn
202               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
203             ENDIF
204         ENDDO
205         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
206      ENDIF
207      !
208   END SUBROUTINE trc_mean_qsr
209
210#else
211   !!----------------------------------------------------------------------
212   !!   Default key                                     NO passive tracers
213   !!----------------------------------------------------------------------
214CONTAINS
215   SUBROUTINE trc_stp( kt )        ! Empty routine
216      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
217   END SUBROUTINE trc_stp
218#endif
219
220   !!======================================================================
221END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.