source: branches/2016/dev_r7233_CMIP6_diags_trunk_version/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_fct.F90 @ 7236

Last change on this file since 7236 was 7236, checked in by timgraham, 4 years ago

All changes related to diaptr (basin heat transports and transport components)

  • Property svn:keywords set to Id
File size: 40.6 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!  tra_adv_fct_zts: update the tracer trend with a 3D advective trends using a 2nd order FCT scheme
12   !!                   with sub-time-stepping in the vertical direction
13   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
14   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE trc_oce        ! share passive tracers/Ocean variables
19   USE trd_oce        ! trends: ocean variables
20   USE trdtra         ! tracers trends
21   USE diaptr         ! poleward transport diagnostics
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_fct        ! routine called by traadv.F90
34   PUBLIC   tra_adv_fct_zts    ! routine called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! routine called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
50      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_adv_fct  ***
53      !!
54      !! **  Purpose :   Compute the now trend due to total advection of tracers
55      !!               and add it to the general trend of tracer equations
56      !!
57      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
58      !!               (choice through the value of kn_fct)
59      !!               - on the vertical the 4th order is a compact scheme
60      !!               - corrected flux (monotonic correction)
61      !!
62      !! ** Action : - update pta  with the now advective tracer trends
63      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
64      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
65      !!----------------------------------------------------------------------
66      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
70      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
71      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
72      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
73      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
76      !
77      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
78      REAL(wp) ::   ztra                                     ! local scalar
79      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
80      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
81      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
82      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdx, ztrdy, ztrd, zptry
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct')
86      !
87      CALL wrk_alloc( jpi,jpj,jpk,   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
88      !
89      IF( kt == kit000 )  THEN
90         IF(lwp) WRITE(numout,*)
91         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
92         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
93      ENDIF
94      !
95      l_trd = .FALSE.
96      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
97      !
98      IF( l_trd )  THEN
99         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
100         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
101      ENDIF
102      !
103      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
104         CALL wrk_alloc( jpi, jpj, jpk, zptry )
105         zptry(:,:,:) = 0._wp
106      ENDIF
107      !                          ! surface & bottom value : flux set to zero one for all
108      zwz(:,:, 1 ) = 0._wp           
109      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
110      !
111      zwi(:,:,:) = 0._wp       
112      !
113      DO jn = 1, kjpt            !==  loop over the tracers  ==!
114         !
115         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
116         !                    !* upstream tracer flux in the i and j direction
117         DO jk = 1, jpkm1
118            DO jj = 1, jpjm1
119               DO ji = 1, fs_jpim1   ! vector opt.
120                  ! upstream scheme
121                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
122                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
123                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
124                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
125                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
126                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
127               END DO
128            END DO
129         END DO
130         !                    !* upstream tracer flux in the k direction *!
131         DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
132            DO jj = 1, jpj
133               DO ji = 1, jpi
134                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
135                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
136                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
137               END DO
138            END DO
139         END DO
140         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
141            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
142               DO jj = 1, jpj
143                  DO ji = 1, jpi
144                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
145                  END DO
146               END DO   
147            ELSE                             ! no cavities: only at the ocean surface
148               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
149            ENDIF
150         ENDIF
151         !               
152         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
153            DO jj = 2, jpjm1
154               DO ji = fs_2, fs_jpim1   ! vector opt.
155                  !                             ! total intermediate advective trends
156                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
157                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
158                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
159                  !                             ! update and guess with monotonic sheme
160                  pta(ji,jj,jk,jn) =                     pta(ji,jj,jk,jn) +        ztra   / e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
161                  zwi(ji,jj,jk)    = ( e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + p2dt * ztra ) / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
162               END DO
163            END DO
164         END DO
165         CALL lbc_lnk( zwi, 'T', 1. )  ! Lateral boundary conditions on zwi  (unchanged sign)
166         !               
167         IF( l_trd )  THEN             ! trend diagnostics (contribution of upstream fluxes)
168            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
169         END IF
170         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
171         IF( cdtype == 'TRA' .AND. ln_diaptr )    zptry(:,:,:) = zwy(:,:,:) 
172         !
173         !        !==  anti-diffusive flux : high order minus low order  ==!
174         !
175         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
176         !
177         CASE(  2  )                   !- 2nd order centered
178            DO jk = 1, jpkm1
179               DO jj = 1, jpjm1
180                  DO ji = 1, fs_jpim1   ! vector opt.
181                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
182                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
183                  END DO
184               END DO
185            END DO
186            !
187         CASE(  4  )                   !- 4th order centered
188            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
189            zltv(:,:,jpk) = 0._wp
190            DO jk = 1, jpkm1                 ! Laplacian
191               DO jj = 1, jpjm1                    ! 1st derivative (gradient)
192                  DO ji = 1, fs_jpim1   ! vector opt.
193                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
194                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
195                  END DO
196               END DO
197               DO jj = 2, jpjm1                    ! 2nd derivative * 1/ 6
198                  DO ji = fs_2, fs_jpim1   ! vector opt.
199                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
200                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
201                  END DO
202               END DO
203            END DO
204            CALL lbc_lnk( zltu, 'T', 1. )   ;    CALL lbc_lnk( zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
205            !
206            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
207               DO jj = 1, jpjm1
208                  DO ji = 1, fs_jpim1   ! vector opt.
209                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
210                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
211                     !                                                  ! C4 minus upstream advective fluxes
212                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
213                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
214                  END DO
215               END DO
216            END DO         
217            !
218         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
219            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
220            ztv(:,:,jpk) = 0._wp
221            DO jk = 1, jpkm1                 ! 1st derivative (gradient)
222               DO jj = 1, jpjm1
223                  DO ji = 1, fs_jpim1   ! vector opt.
224                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
225                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
226                  END DO
227               END DO
228            END DO
229            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
230            !
231            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
232               DO jj = 2, jpjm1
233                  DO ji = 2, fs_jpim1   ! vector opt.
234                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
235                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
236                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
237                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
238                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
239                     !                                                  ! C4 minus upstream advective fluxes
240                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
241                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
242                  END DO
243               END DO
244            END DO
245            !
246         END SELECT
247         !                     
248         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
249         !
250         CASE(  2  )                   !- 2nd order centered
251            DO jk = 2, jpkm1   
252               DO jj = 2, jpjm1
253                  DO ji = fs_2, fs_jpim1
254                     zwz(ji,jj,jk) =  (  pwn(ji,jj,jk) * 0.5_wp * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
255                        &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
256                  END DO
257               END DO
258            END DO
259            !
260         CASE(  4  )                   !- 4th order COMPACT
261            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )   ! zwt = COMPACT interpolation of T at w-point
262            DO jk = 2, jpkm1
263               DO jj = 2, jpjm1
264                  DO ji = fs_2, fs_jpim1
265                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
266                  END DO
267               END DO
268            END DO
269            !
270         END SELECT
271         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
272            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
273         ENDIF
274         !
275         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
276         CALL lbc_lnk( zwz, 'W',  1. )
277         !
278         !        !==  monotonicity algorithm  ==!
279         !
280         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
281         !
282         !        !==  final trend with corrected fluxes  ==!
283         !
284         DO jk = 1, jpkm1
285            DO jj = 2, jpjm1
286               DO ji = fs_2, fs_jpim1   ! vector opt. 
287                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
288                     &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
289                     &                                   + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
290                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
291               END DO
292            END DO
293         END DO
294         !
295         IF( l_trd ) THEN     ! trend diagnostics (contribution of upstream fluxes)
296            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
297            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
298            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
299            !
300            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
301            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
302            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
303            !
304            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
305         END IF
306         !                    ! "Poleward" heat and salt transports (contribution of upstream fluxes)
307         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
308            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
309            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
310         ENDIF
311         !
312      END DO                     ! end of tracer loop
313      !
314      CALL wrk_dealloc( jpi,jpj,jpk,    zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
315      IF( cdtype == 'TRA' .AND. ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, zptry )
316      !
317      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct')
318      !
319   END SUBROUTINE tra_adv_fct
320
321
322   SUBROUTINE tra_adv_fct_zts( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
323      &                                                  ptb, ptn, pta, kjpt, kn_fct_zts )
324      !!----------------------------------------------------------------------
325      !!                  ***  ROUTINE tra_adv_fct_zts  ***
326      !!
327      !! **  Purpose :   Compute the now trend due to total advection of
328      !!       tracers and add it to the general trend of tracer equations
329      !!
330      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
331      !!       corrected flux (monotonic correction). This version use sub-
332      !!       timestepping for the vertical advection which increases stability
333      !!       when vertical metrics are small.
334      !!       note: - this advection scheme needs a leap-frog time scheme
335      !!
336      !! ** Action : - update (pta) with the now advective tracer trends
337      !!             - save the trends
338      !!----------------------------------------------------------------------
339      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
340      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
341      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
342      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
343      INTEGER                              , INTENT(in   ) ::   kn_fct_zts      ! number of number of vertical sub-timesteps
344      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
345      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
346      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
347      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
348      !
349      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
350      REAL(wp)                                             ::   zr_p2dt         ! reciprocal of tracer timestep
351      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
352      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
353      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
354      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
355      REAL(wp) ::   ztra            ! local scalar
356      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
357      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
358      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zwx_sav , zwy_sav
359      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zwi, zwx, zwy, zwz, zhdiv, zwzts, zwz_sav
360      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   ztrdx, ztrdy, ztrdz
361      REAL(wp), POINTER, DIMENSION(:,:,:) :: zptry
362      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrs
363      !!----------------------------------------------------------------------
364      !
365      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct_zts')
366      !
367      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
368      CALL wrk_alloc( jpi,jpj,jpk,         zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
369      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
370      !
371      IF( kt == kit000 )  THEN
372         IF(lwp) WRITE(numout,*)
373         IF(lwp) WRITE(numout,*) 'tra_adv_fct_zts : 2nd order FCT scheme with ', kn_fct_zts, ' vertical sub-timestep on ', cdtype
374         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
375      ENDIF
376      !
377      l_trd = .FALSE.
378      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
379      !
380      IF( l_trd )  THEN
381         CALL wrk_alloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
382         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
383      ENDIF
384      !
385      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
386         CALL wrk_alloc( jpi, jpj,jpk, zptry )
387         zptry(:,:,:) = 0._wp
388      ENDIF
389      zwi(:,:,:) = 0._wp
390      z_rzts = 1._wp / REAL( kn_fct_zts, wp )
391      zr_p2dt = 1._wp / p2dt
392      !
393      ! surface & Bottom value : flux set to zero for all tracers
394      zwz(:,:, 1 ) = 0._wp
395      zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
396      zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
397      !
398      !                                                          ! ===========
399      DO jn = 1, kjpt                                            ! tracer loop
400         !                                                       ! ===========
401         !
402         ! Upstream advection with initial mass fluxes & intermediate update
403         DO jk = 1, jpkm1        ! upstream tracer flux in the i and j direction
404            DO jj = 1, jpjm1
405               DO ji = 1, fs_jpim1   ! vector opt.
406                  ! upstream scheme
407                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
408                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
409                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
410                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
411                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
412                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
413               END DO
414            END DO
415         END DO
416         !                       ! upstream tracer flux in the k direction
417         DO jk = 2, jpkm1              ! Interior value
418            DO jj = 1, jpj
419               DO ji = 1, jpi
420                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
421                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
422                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
423               END DO
424            END DO
425         END DO
426         IF( ln_linssh ) THEN          ! top value : linear free surface case only (as zwz is multiplied by wmask)
427            IF( ln_isfcav ) THEN             ! ice-shelf cavities: top value
428               DO jj = 1, jpj
429                  DO ji = 1, jpi
430                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn) 
431                  END DO
432               END DO   
433            ELSE                             ! no cavities, surface value
434               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
435            ENDIF
436         ENDIF
437         !
438         DO jk = 1, jpkm1         ! total advective trend
439            DO jj = 2, jpjm1
440               DO ji = fs_2, fs_jpim1   ! vector opt.
441                  !                             ! total intermediate advective trends
442                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
443                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
444                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   ) * r1_e1e2t(ji,jj)
445                  !                             ! update and guess with monotonic sheme
446                  pta(ji,jj,jk,jn) =                     pta(ji,jj,jk,jn) +        ztra   / e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
447                  zwi(ji,jj,jk)    = ( e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + p2dt * ztra ) / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
448               END DO
449            END DO
450         END DO
451         !                           
452         CALL lbc_lnk( zwi, 'T', 1. )     ! Lateral boundary conditions on zwi  (unchanged sign)
453         !               
454         IF( l_trd )  THEN                ! trend diagnostics (contribution of upstream fluxes)
455            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
456         END IF
457         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
458         IF( cdtype == 'TRA' .AND. ln_diaptr )  zptry(:,:,:) = zwy(:,:,:)
459
460         ! 3. anti-diffusive flux : high order minus low order
461         ! ---------------------------------------------------
462
463         DO jk = 1, jpkm1                    !* horizontal anti-diffusive fluxes
464            !
465            DO jj = 1, jpjm1
466               DO ji = 1, fs_jpim1   ! vector opt.
467                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
468                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
469                  !
470                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
471                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
472               END DO
473            END DO
474            !
475            DO jj = 2, jpjm1                    ! partial horizontal divergence
476               DO ji = fs_2, fs_jpim1
477                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
478                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
479               END DO
480            END DO
481            !
482            DO jj = 1, jpjm1
483               DO ji = 1, fs_jpim1   ! vector opt.
484                  zwx(ji,jj,jk) = zwx(ji,jj,jk) - zwx_sav(ji,jj)
485                  zwy(ji,jj,jk) = zwy(ji,jj,jk) - zwy_sav(ji,jj)
486               END DO
487            END DO
488         END DO
489         !
490         !                                !* vertical anti-diffusive flux
491         zwz_sav(:,:,:)   = zwz(:,:,:)
492         ztrs   (:,:,:,1) = ptb(:,:,:,jn)
493         ztrs   (:,:,1,2) = ptb(:,:,1,jn)
494         ztrs   (:,:,1,3) = ptb(:,:,1,jn)
495         zwzts  (:,:,:)   = 0._wp
496         !
497         DO jl = 1, kn_fct_zts                  ! Start of sub timestepping loop
498            !
499            IF( jl == 1 ) THEN                        ! Euler forward to kick things off
500               jtb = 1   ;   jtn = 1   ;   jta = 2
501               zts(:) = p2dt * z_rzts
502               jtaken = MOD( kn_fct_zts + 1 , 2)            ! Toggle to collect every second flux
503               !                                            ! starting at jl =1 if kn_fct_zts is odd;
504               !                                            ! starting at jl =2 otherwise
505            ELSEIF( jl == 2 ) THEN                    ! First leapfrog step
506               jtb = 1   ;   jtn = 2   ;   jta = 3
507               zts(:) = 2._wp * p2dt * z_rzts
508            ELSE                                      ! Shuffle pointers for subsequent leapfrog steps
509               jtb = MOD(jtb,3) + 1
510               jtn = MOD(jtn,3) + 1
511               jta = MOD(jta,3) + 1
512            ENDIF
513            DO jk = 2, jpkm1                          ! interior value
514               DO jj = 2, jpjm1
515                  DO ji = fs_2, fs_jpim1
516                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) ) * wmask(ji,jj,jk)
517                     IF( jtaken == 0 )   zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk) * zts(jk)    ! Accumulate time-weighted vertcal flux
518                  END DO
519               END DO
520            END DO
521            IF( ln_linssh ) THEN                    ! top value (only in linear free surface case)
522               IF( ln_isfcav ) THEN                      ! ice-shelf cavities
523                  DO jj = 1, jpj
524                     DO ji = 1, jpi
525                        zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
526                     END DO
527                  END DO   
528               ELSE                                      ! no ocean cavities
529                  zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
530               ENDIF
531            ENDIF
532            !
533            jtaken = MOD( jtaken + 1 , 2 )
534            !
535            DO jk = 2, jpkm1                             ! total advective trends
536               DO jj = 2, jpjm1
537                  DO ji = fs_2, fs_jpim1
538                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb)                                                 &
539                        &               - zts(jk) * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji,jj,jk+1) )   &
540                        &                         * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
541                  END DO
542               END DO
543            END DO
544            !
545         END DO
546
547         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
548            DO jj = 2, jpjm1
549               DO ji = fs_2, fs_jpim1
550                  zwz(ji,jj,jk) = ( zwzts(ji,jj,jk) * zr_p2dt - zwz_sav(ji,jj,jk) ) * wmask(ji,jj,jk)
551               END DO
552            END DO
553         END DO
554         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
555         CALL lbc_lnk( zwz, 'W',  1. )
556
557         ! 4. monotonicity algorithm
558         ! -------------------------
559         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
560
561
562         ! 5. final trend with corrected fluxes
563         ! ------------------------------------
564         DO jk = 1, jpkm1
565            DO jj = 2, jpjm1
566               DO ji = fs_2, fs_jpim1   ! vector opt. 
567                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (   zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )       &
568                     &                                    + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   )   &
569                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
570               END DO
571            END DO
572         END DO
573
574         !                                 ! trend diagnostics (contribution of upstream fluxes)
575         IF( l_trd )  THEN
576            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
577            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
578            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
579            !
580            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
581            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
582            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
583            !
584            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
585         END IF
586         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
587         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
588            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:) 
589            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
590         ENDIF
591         !
592      END DO
593      !
594      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
595      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
596      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
597      IF( cdtype == 'TRA' .AND. ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, zptry )
598      !
599      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct_zts')
600      !
601   END SUBROUTINE tra_adv_fct_zts
602
603
604   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
605      !!---------------------------------------------------------------------
606      !!                    ***  ROUTINE nonosc  ***
607      !!     
608      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
609      !!       scheme and the before field by a nonoscillatory algorithm
610      !!
611      !! **  Method  :   ... ???
612      !!       warning : pbef and paft must be masked, but the boundaries
613      !!       conditions on the fluxes are not necessary zalezak (1979)
614      !!       drange (1995) multi-dimensional forward-in-time and upstream-
615      !!       in-space based differencing for fluid
616      !!----------------------------------------------------------------------
617      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
618      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
619      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
620      !
621      INTEGER  ::   ji, jj, jk   ! dummy loop indices
622      INTEGER  ::   ikm1         ! local integer
623      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
624      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
625      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
626      !!----------------------------------------------------------------------
627      !
628      IF( nn_timing == 1 )  CALL timing_start('nonosc')
629      !
630      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
631      !
632      zbig  = 1.e+40_wp
633      zrtrn = 1.e-15_wp
634      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
635
636      ! Search local extrema
637      ! --------------------
638      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
639      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
640         &        paft * tmask - zbig * ( 1._wp - tmask )  )
641      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
642         &        paft * tmask + zbig * ( 1._wp - tmask )  )
643
644      DO jk = 1, jpkm1
645         ikm1 = MAX(jk-1,1)
646         DO jj = 2, jpjm1
647            DO ji = fs_2, fs_jpim1   ! vector opt.
648
649               ! search maximum in neighbourhood
650               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
651                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
652                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
653                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
654
655               ! search minimum in neighbourhood
656               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
657                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
658                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
659                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
660
661               ! positive part of the flux
662               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
663                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
664                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
665
666               ! negative part of the flux
667               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
668                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
669                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
670
671               ! up & down beta terms
672               zbt = e1e2t(ji,jj) * e3t_n(ji,jj,jk) / p2dt
673               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
674               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
675            END DO
676         END DO
677      END DO
678      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
679
680      ! 3. monotonic flux in the i & j direction (paa & pbb)
681      ! ----------------------------------------
682      DO jk = 1, jpkm1
683         DO jj = 2, jpjm1
684            DO ji = fs_2, fs_jpim1   ! vector opt.
685               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
686               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
687               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
688               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
689
690               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
691               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
692               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
693               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
694
695      ! monotonic flux in the k direction, i.e. pcc
696      ! -------------------------------------------
697               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
698               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
699               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
700               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
701            END DO
702         END DO
703      END DO
704      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
705      !
706      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
707      !
708      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
709      !
710   END SUBROUTINE nonosc
711
712
713   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
714      !!----------------------------------------------------------------------
715      !!                  ***  ROUTINE interp_4th_cpt  ***
716      !!
717      !! **  Purpose :   Compute the interpolation of tracer at w-point
718      !!
719      !! **  Method  :   4th order compact interpolation
720      !!----------------------------------------------------------------------
721      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
722      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
723      !
724      INTEGER :: ji, jj, jk   ! dummy loop integers
725      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
726      !!----------------------------------------------------------------------
727     
728      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
729         DO jj = 1, jpj
730            DO ji = 1, jpi
731               zwd (ji,jj,jk) = 4._wp
732               zwi (ji,jj,jk) = 1._wp
733               zws (ji,jj,jk) = 1._wp
734               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
735               !
736               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
737                  zwd (ji,jj,jk) = 1._wp
738                  zwi (ji,jj,jk) = 0._wp
739                  zws (ji,jj,jk) = 0._wp
740                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
741               ENDIF
742            END DO
743         END DO
744      END DO
745      !
746      jk=2                                            ! Switch to second order centered at top
747      DO jj=1,jpj
748         DO ji=1,jpi
749            zwd (ji,jj,jk) = 1._wp
750            zwi (ji,jj,jk) = 0._wp
751            zws (ji,jj,jk) = 0._wp
752            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
753         END DO
754      END DO   
755      !
756      !                       !==  tridiagonal solve  ==!
757      DO jj = 1, jpj                ! first recurrence
758         DO ji = 1, jpi
759            zwt(ji,jj,2) = zwd(ji,jj,2)
760         END DO
761      END DO
762      DO jk = 3, jpkm1
763         DO jj = 1, jpj
764            DO ji = 1, jpi
765               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
766            END DO
767         END DO
768      END DO
769      !
770      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
771         DO ji = 1, jpi
772            pt_out(ji,jj,2) = zwrm(ji,jj,2)
773         END DO
774      END DO
775      DO jk = 3, jpkm1
776         DO jj = 1, jpj
777            DO ji = 1, jpi
778               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
779            END DO
780         END DO
781      END DO
782
783      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
784         DO ji = 1, jpi
785            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
786         END DO
787      END DO
788      DO jk = jpk-2, 2, -1
789         DO jj = 1, jpj
790            DO ji = 1, jpi
791               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
792            END DO
793         END DO
794      END DO
795      !   
796   END SUBROUTINE interp_4th_cpt
797   
798   !!======================================================================
799END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.