source: branches/2016/dev_r7233_CMIP6_diags_trunk_version/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 7236

Last change on this file since 7236 was 7236, checked in by timgraham, 4 years ago

All changes related to diaptr (basin heat transports and transport components)

  • Property svn:keywords set to Id
File size: 14.8 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   !
26   USE wrk_nemo       ! Memory Allocation
27   USE timing         ! Timing
28   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
37   
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
39   !                                                           !  and in closed seas (orca 2 and 4 configurations)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
41   
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
52      &                                              ptb, pta, kjpt, ld_msc_ups )
53      !!----------------------------------------------------------------------
54      !!                    ***  ROUTINE tra_adv_mus  ***
55      !!
56      !! ** Purpose :   Compute the now trend due to total advection of tracers
57      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
58      !!              Conservation Laws) and add it to the general tracer trend.
59      !!
60      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
61      !!              ld_msc_ups=T :
62      !!
63      !! ** Action : - update pta  with the now advective tracer trends
64      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
65      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
66      !!
67      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
68      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
69      !!----------------------------------------------------------------------
70      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
71      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
74      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
75      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
79      !
80      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
81      INTEGER  ::   ierr                 ! local integer
82      REAL(wp) ::   zu, z0u, zzwx, zw    ! local scalars
83      REAL(wp) ::   zv, z0v, zzwy, z0w   !   -      -
84      REAL(wp) ::   zalpha               !   -      -
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zslpx, zslpy   ! 3D workspace
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwx  , zwy     ! -      -
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('tra_adv_mus')
90      !
91      CALL wrk_alloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
97         IF(lwp) WRITE(numout,*) '~~~~~~~'
98         IF(lwp) WRITE(numout,*)
99         !
100         ! Upstream / MUSCL scheme indicator
101         !
102         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
103         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
104         !
105         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
106            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
107            upsmsk(:,:) = 0._wp                             ! not upstream by default
108            !
109            DO jk = 1, jpkm1
110               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
111                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
112                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
113            END DO
114         ENDIF 
115         !
116      ENDIF 
117      !     
118      DO jn = 1, kjpt            !==  loop over the tracers  ==!
119         !
120         !                          !* Horizontal advective fluxes
121         !
122         !                                !-- first guess of the slopes
123         zwx(:,:,jpk) = 0._wp                   ! bottom values
124         zwy(:,:,jpk) = 0._wp 
125         DO jk = 1, jpkm1                       ! interior values
126            DO jj = 1, jpjm1     
127               DO ji = 1, fs_jpim1   ! vector opt.
128                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
129                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
130               END DO
131           END DO
132         END DO
133         CALL lbc_lnk( zwx, 'U', -1. )          ! lateral boundary conditions   (changed sign)
134         CALL lbc_lnk( zwy, 'V', -1. )
135         !                                !-- Slopes of tracer
136         zslpx(:,:,jpk) = 0._wp                 ! bottom values
137         zslpy(:,:,jpk) = 0._wp
138         DO jk = 1, jpkm1                       ! interior values
139            DO jj = 2, jpj
140               DO ji = fs_2, jpi   ! vector opt.
141                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
142                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
143                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
144                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
145               END DO
146            END DO
147         END DO
148         !
149         DO jk = 1, jpkm1                 !-- Slopes limitation
150            DO jj = 2, jpj
151               DO ji = fs_2, jpi   ! vector opt.
152                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
153                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
154                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
155                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
156                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
157                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
158               END DO
159           END DO
160         END DO
161         !
162         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
163            DO jj = 2, jpjm1
164               DO ji = fs_2, fs_jpim1   ! vector opt.
165                  ! MUSCL fluxes
166                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
167                  zalpha = 0.5 - z0u
168                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
169                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
170                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
171                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
172                  !
173                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
174                  zalpha = 0.5 - z0v
175                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
176                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
177                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
178                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
179               END DO
180            END DO
181         END DO
182         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
183         !
184         DO jk = 1, jpkm1                 !-- Tracer advective trend
185            DO jj = 2, jpjm1     
186               DO ji = fs_2, fs_jpim1   ! vector opt.
187                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
188                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
189                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
190               END DO
191           END DO
192         END DO       
193         !                                ! trend diagnostics
194         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.   &
195            &( cdtype == 'TRC' .AND. l_trdtrc )      )  THEN
196            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
197            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
198         END IF
199         !                                 ! "Poleward" heat and salt transports
200         IF( cdtype == 'TRA' .AND. ln_diaptr ) CALL dia_ptr_ohst_components( jn, 'adv', zwy(:,:,:)  )
201         !                                ! "Poleward" heat and salt transports
202         !
203         !                          !* Vertical advective fluxes
204         !
205         !                                !-- first guess of the slopes
206         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
207         zwx(:,:,jpk) = 0._wp
208         DO jk = 2, jpkm1                       ! interior values
209            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
210         END DO
211         !                                !-- Slopes of tracer
212         zslpx(:,:,1) = 0._wp                   ! surface values
213         DO jk = 2, jpkm1                       ! interior value
214            DO jj = 1, jpj
215               DO ji = 1, jpi
216                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
217                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
218               END DO
219            END DO
220         END DO
221         DO jk = 2, jpkm1                 !-- Slopes limitation
222            DO jj = 1, jpj                      ! interior values
223               DO ji = 1, jpi
224                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
225                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
226                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
227               END DO
228            END DO
229         END DO
230         DO jk = 1, jpk-2                 !-- vertical advective flux
231            DO jj = 2, jpjm1     
232               DO ji = fs_2, fs_jpim1   ! vector opt.
233                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
234                  zalpha = 0.5 + z0w
235                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
236                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
237                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
238                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
239               END DO
240            END DO
241         END DO
242         IF( ln_linssh ) THEN                   ! top values, linear free surface only
243            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
244               DO jj = 1, jpj
245                  DO ji = 1, jpi
246                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
247                  END DO
248               END DO   
249            ELSE                                      ! no cavities: only at the ocean surface
250               zwx(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
251            ENDIF
252         ENDIF
253         !
254         DO jk = 1, jpkm1                 !-- vertical advective trend
255            DO jj = 2, jpjm1     
256               DO ji = fs_2, fs_jpim1   ! vector opt.
257                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
258               END DO
259            END DO
260         END DO
261         !                                ! send trends for diagnostic
262         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.     &
263            &( cdtype == 'TRC' .AND. l_trdtrc )      )   &
264            CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
265         !
266      END DO                     ! end of tracer loop
267      !
268      CALL wrk_dealloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
269      !
270      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_mus')
271      !
272   END SUBROUTINE tra_adv_mus
273
274   !!======================================================================
275END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.