New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

dynhpg.F90 in branches/2016/dev_v3_6_STABLE_OMP/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

Context Navigation

source: branches/2016/dev_v3_6_STABLE_OMP/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 6508

Last change on this file since 6508 was 6508, checked in by dkuts, 8 years ago
First version of OMP changes, partly ported from previous branch
Property svn:keywords set to `Id`
File size: 70.0 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!!----------------------------------------------------------------------
20
21	!!----------------------------------------------------------------------
22	!! dyn_hpg : update the momentum trend with the now horizontal
23	!! gradient of the hydrostatic pressure
24	!! dyn_hpg_init : initialisation and control of options
25	!! hpg_zco : z-coordinate scheme
26	!! hpg_zps : z-coordinate plus partial steps (interpolation)
27	!! hpg_sco : s-coordinate (standard jacobian formulation)
28	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
29	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
30	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
31	!!----------------------------------------------------------------------
32	USE oce ! ocean dynamics and tracers
33	USE sbc_oce ! surface variable (only for the flag with ice shelf)
34	USE dom_oce ! ocean space and time domain
35	USE phycst ! physical constants
36	USE trd_oce ! trends: ocean variables
37	USE trddyn ! trend manager: dynamics
38	!
39	USE in_out_manager ! I/O manager
40	USE prtctl ! Print control
41	USE lbclnk ! lateral boundary condition
42	USE lib_mpp ! MPP library
43	USE eosbn2 ! compute density
44	USE wrk_nemo ! Memory Allocation
45	USE timing ! Timing
46
47	IMPLICIT NONE
48	PRIVATE
49
50	PUBLIC dyn_hpg ! routine called by step module
51	PUBLIC dyn_hpg_init ! routine called by opa module
52
53	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
54	LOGICAL , PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
55	LOGICAL , PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
56	LOGICAL , PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
57	LOGICAL , PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
58	LOGICAL , PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
59	LOGICAL , PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
60	LOGICAL , PUBLIC :: ln_dynhpg_imp !: semi-implicite hpg flag
61
62	INTEGER , PUBLIC :: nhpg = 0 ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
63
64	!! * Substitutions
65	# include "domzgr_substitute.h90"
66	# include "vectopt_loop_substitute.h90"
67	!!----------------------------------------------------------------------
68	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
69	!! $Id$
70	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
71	!!----------------------------------------------------------------------
72	CONTAINS
73
74	SUBROUTINE dyn_hpg( kt )
75	!!---------------------------------------------------------------------
76	!! * ROUTINE dyn_hpg *
77	!!
78	!! ** Method : Call the hydrostatic pressure gradient routine
79	!! using the scheme defined in the namelist
80	!!
81	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
82	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
83	!!----------------------------------------------------------------------
84	INTEGER, INTENT(in) :: kt ! ocean time-step index
85	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv
86	!!----------------------------------------------------------------------
87	!
88	IF( nn_timing == 1 ) CALL timing_start('dyn_hpg')
89	!
90	IF( l_trddyn ) THEN ! Temporary saving of ua and va trends (l_trddyn)
91	CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
92	ztrdu(:,:,:) = ua(:,:,:)
93	ztrdv(:,:,:) = va(:,:,:)
94	ENDIF
95	!
96	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
97	CASE ( 0 ) ; CALL hpg_zco ( kt ) ! z-coordinate
98	CASE ( 1 ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
99	CASE ( 2 ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
100	CASE ( 3 ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
101	CASE ( 4 ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
102	CASE ( 5 ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
103	END SELECT
104	!
105	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
106	ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
107	ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
108	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
109	CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
110	ENDIF
111	!
112	IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg - Ua: ', mask1=umask, &
113	& tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
114	!
115	IF( nn_timing == 1 ) CALL timing_stop('dyn_hpg')
116	!
117	END SUBROUTINE dyn_hpg
118
119
120	SUBROUTINE dyn_hpg_init
121	!!----------------------------------------------------------------------
122	!! * ROUTINE dyn_hpg_init *
123	!!
124	!! ** Purpose : initializations for the hydrostatic pressure gradient
125	!! computation and consistency control
126	!!
127	!! ** Action : Read the namelist namdyn_hpg and check the consistency
128	!! with the type of vertical coordinate used (zco, zps, sco)
129	!!----------------------------------------------------------------------
130	INTEGER :: ioptio = 0 ! temporary integer
131	INTEGER :: ios ! Local integer output status for namelist read
132	!!
133	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
134	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
135	!!----------------------------------------------------------------------
136	!
137	REWIND( numnam_ref ) ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
138	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
139	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
140
141	REWIND( numnam_cfg ) ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
142	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
143	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
144	IF(lwm) WRITE ( numond, namdyn_hpg )
145	!
146	IF(lwp) THEN ! Control print
147	WRITE(numout,*)
148	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
149	WRITE(numout,*) '~~~~~~~~~~~~'
150	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
151	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
152	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
153	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
154	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
155	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
156	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
157	WRITE(numout,*) ' time stepping: centered (F) or semi-implicit (T) ln_dynhpg_imp = ', ln_dynhpg_imp
158	ENDIF
159	!
160	IF( ln_hpg_djc ) &
161	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
162	& currently disabled (bugs under investigation). Please select &
163	& either ln_hpg_sco or ln_hpg_prj instead')
164	!
165	IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
166	& CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
167	& the standard jacobian formulation hpg_sco or &
168	& the pressure jacobian formulation hpg_prj')
169
170	IF( ln_hpg_isf .AND. .NOT. ln_isfcav ) &
171	& CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
172	IF( .NOT. ln_hpg_isf .AND. ln_isfcav ) &
173	& CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
174	!
175	! ! Set nhpg from ln_hpg_... flags
176	IF( ln_hpg_zco ) nhpg = 0
177	IF( ln_hpg_zps ) nhpg = 1
178	IF( ln_hpg_sco ) nhpg = 2
179	IF( ln_hpg_djc ) nhpg = 3
180	IF( ln_hpg_prj ) nhpg = 4
181	IF( ln_hpg_isf ) nhpg = 5
182	!
183	! ! Consistency check
184	ioptio = 0
185	IF( ln_hpg_zco ) ioptio = ioptio + 1
186	IF( ln_hpg_zps ) ioptio = ioptio + 1
187	IF( ln_hpg_sco ) ioptio = ioptio + 1
188	IF( ln_hpg_djc ) ioptio = ioptio + 1
189	IF( ln_hpg_prj ) ioptio = ioptio + 1
190	IF( ln_hpg_isf ) ioptio = ioptio + 1
191	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
192	!
193	! initialisation of ice load
194	riceload(:,:)=0.0
195	!
196	END SUBROUTINE dyn_hpg_init
197
198
199	SUBROUTINE hpg_zco( kt )
200	!!---------------------------------------------------------------------
201	!! * ROUTINE hpg_zco *
202	!!
203	!! ** Method : z-coordinate case, levels are horizontal surfaces.
204	!! The now hydrostatic pressure gradient at a given level, jk,
205	!! is computed by taking the vertical integral of the in-situ
206	!! density gradient along the model level from the suface to that
207	!! level: zhpi = grav .....
208	!! zhpj = grav .....
209	!! add it to the general momentum trend (ua,va).
210	!! ua = ua - 1/e1u * zhpi
211	!! va = va - 1/e2v * zhpj
212	!!
213	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
214	!!----------------------------------------------------------------------
215	INTEGER, INTENT(in) :: kt ! ocean time-step index
216	!!
217	INTEGER :: ji, jj, jk ! dummy loop indices
218	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
219	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
220	!!----------------------------------------------------------------------
221	!
222	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
223	!
224	IF( kt == nit000 ) THEN
225	IF(lwp) WRITE(numout,*)
226	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
227	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
228	ENDIF
229
230	zcoef0 = - grav * 0.5_wp ! Local constant initialization
231
232	! Surface value
233	DO jj = 2, jpjm1
234	DO ji = fs_2, fs_jpim1 ! vector opt.
235	zcoef1 = zcoef0 * fse3w(ji,jj,1)
236	! hydrostatic pressure gradient
237	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
238	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
239	! add to the general momentum trend
240	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
241	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
242	END DO
243	END DO
244
245	!
246	! interior value (2=<jk=<jpkm1)
247	DO jk = 2, jpkm1
248	!$OMP PARALLEL DO private(ji,jj, zcoef1)
249	DO jj = 2, jpjm1
250	DO ji = fs_2, fs_jpim1 ! vector opt.
251	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
252	! hydrostatic pressure gradient
253	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
254	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
255	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
256
257	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
258	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
259	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
260	! add to the general momentum trend
261	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
262	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
263	END DO
264	END DO
265	END DO
266	!
267	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
268	!
269	END SUBROUTINE hpg_zco
270
271
272	SUBROUTINE hpg_zps( kt )
273	!!---------------------------------------------------------------------
274	!! * ROUTINE hpg_zps *
275	!!
276	!! ** Method : z-coordinate plus partial steps case. blahblah...
277	!!
278	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
279	!!----------------------------------------------------------------------
280	INTEGER, INTENT(in) :: kt ! ocean time-step index
281	!!
282	INTEGER :: ji, jj, jk ! dummy loop indices
283	INTEGER :: iku, ikv ! temporary integers
284	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
285	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
286	!!----------------------------------------------------------------------
287	!
288	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
289	!
290	IF( kt == nit000 ) THEN
291	IF(lwp) WRITE(numout,*)
292	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
293	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
294	ENDIF
295
296
297	! Local constant initialization
298	zcoef0 = - grav * 0.5_wp
299
300	! Surface value (also valid in partial step case)
301	!$OMP PARALLEL DO private(ji,jj, zcoef1)
302	DO jj = 2, jpjm1
303	DO ji = fs_2, fs_jpim1 ! vector opt.
304	zcoef1 = zcoef0 * fse3w(ji,jj,1)
305	! hydrostatic pressure gradient
306	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
307	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
308	! add to the general momentum trend
309	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
310	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
311	END DO
312	END DO
313
314
315	! interior value (2=<jk=<jpkm1)
316	!$OMP PARALLEL DO private(ji,jj, zcoef1)
317	DO jk = 2, jpkm1
318	DO jj = 2, jpjm1
319	DO ji = fs_2, fs_jpim1 ! vector opt.
320	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
321	! hydrostatic pressure gradient
322	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
323	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
324	&
325	- ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
326
327	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
328	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
329	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
330	! add to the general momentum trend
331	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
332	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
333	END DO
334	END DO
335	END DO
336
337
338	! partial steps correction at the last level (use gru & grv computed in zpshde.F90)
339	DO jj = 2, jpjm1
340	DO ji = 2, jpim1
341	iku = mbku(ji,jj)
342	ikv = mbkv(ji,jj)
343	zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj ,iku) )
344	zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji ,jj+1,ikv) )
345	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
346	ua (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) ! subtract old value
347	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
348	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
349	ua (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
350	ENDIF
351	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
352	va (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) ! subtract old value
353	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
354	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
355	va (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
356	ENDIF
357	END DO
358	END DO
359	!
360	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
361	!
362	END SUBROUTINE hpg_zps
363
364	SUBROUTINE hpg_sco( kt )
365	!!---------------------------------------------------------------------
366	!! * ROUTINE hpg_sco *
367	!!
368	!! ** Method : s-coordinate case. Jacobian scheme.
369	!! The now hydrostatic pressure gradient at a given level, jk,
370	!! is computed by taking the vertical integral of the in-situ
371	!! density gradient along the model level from the suface to that
372	!! level. s-coordinates (ln_sco): a corrective term is added
373	!! to the horizontal pressure gradient :
374	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
375	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
376	!! add it to the general momentum trend (ua,va).
377	!! ua = ua - 1/e1u * zhpi
378	!! va = va - 1/e2v * zhpj
379	!!
380	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
381	!!----------------------------------------------------------------------
382	INTEGER, INTENT(in) :: kt ! ocean time-step index
383	!!
384	INTEGER :: ji, jj, jk ! dummy loop indices
385	REAL(wp) :: zcoef0, zuap, zvap, znad ! temporary scalars
386	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
387	!!----------------------------------------------------------------------
388	!
389	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
390	!
391	IF( kt == nit000 ) THEN
392	IF(lwp) WRITE(numout,*)
393	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
394	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
395	ENDIF
396
397	! Local constant initialization
398	zcoef0 = - grav * 0.5_wp
399	! To use density and not density anomaly
400	IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
401	ELSE ; znad = 0._wp ! Fixed volume
402	ENDIF
403
404	! Surface value
405	DO jj = 2, jpjm1
406	DO ji = fs_2, fs_jpim1 ! vector opt.
407	! hydrostatic pressure gradient along s-surfaces
408	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj ,1) * ( znad + rhd(ji+1,jj ,1) ) &
409	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
410	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji ,jj+1,1) * ( znad + rhd(ji ,jj+1,1) ) &
411	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
412	! s-coordinate pressure gradient correction
413	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
414	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
415	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
416	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
417	! add to the general momentum trend
418	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
419	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
420	END DO
421	END DO
422
423	! interior value (2=<jk=<jpkm1)
424	DO jk = 2, jpkm1
425	DO jj = 2, jpjm1
426	DO ji = fs_2, fs_jpim1 ! vector opt.
427	! hydrostatic pressure gradient along s-surfaces
428	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
429	& * ( fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
430	& - fse3w(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
431	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
432	& * ( fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
433	& - fse3w(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
434	! s-coordinate pressure gradient correction
435	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
436	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
437	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
438	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
439	! add to the general momentum trend
440	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
441	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
442	END DO
443	END DO
444	END DO
445	!
446	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
447	!
448	END SUBROUTINE hpg_sco
449
450	SUBROUTINE hpg_isf( kt )
451	!!---------------------------------------------------------------------
452	!! * ROUTINE hpg_sco *
453	!!
454	!! ** Method : s-coordinate case. Jacobian scheme.
455	!! The now hydrostatic pressure gradient at a given level, jk,
456	!! is computed by taking the vertical integral of the in-situ
457	!! density gradient along the model level from the suface to that
458	!! level. s-coordinates (ln_sco): a corrective term is added
459	!! to the horizontal pressure gradient :
460	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
461	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
462	!! add it to the general momentum trend (ua,va).
463	!! ua = ua - 1/e1u * zhpi
464	!! va = va - 1/e2v * zhpj
465	!! iceload is added and partial cell case are added to the top and bottom
466	!!
467	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
468	!!----------------------------------------------------------------------
469	INTEGER, INTENT(in) :: kt ! ocean time-step index
470	!!
471	INTEGER :: ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j ! dummy loop indices
472	REAL(wp) :: zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1 ! temporary scalars
473	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj, zrhd
474	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztstop
475	REAL(wp), POINTER, DIMENSION(:,:) :: ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
476	!!----------------------------------------------------------------------
477	!
478	CALL wrk_alloc( jpi,jpj, 2, ztstop)
479	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
480	CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
481	!
482	IF( kt == nit000 ) THEN
483	IF(lwp) WRITE(numout,*)
484	IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
485	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
486	ENDIF
487
488	! Local constant initialization
489	zcoef0 = - grav * 0.5_wp
490	! To use density and not density anomaly
491	! IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
492	! ELSE ; znad = 0._wp ! Fixed volume
493	! ENDIF
494	znad=1._wp
495	! iniitialised to 0. zhpi zhpi
496	zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
497
498	!==================================================================================
499	!=====Compute iceload and contribution of the half first wet layer =================
500	!===================================================================================
501
502	! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
503	ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
504
505	! compute density of the water displaced by the ice shelf
506	zrhd = rhd ! save rhd
507	DO jk = 1, jpk
508	zdept(:,:)=gdept_1d(jk)
509	CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
510	END DO
511	WHERE ( tmask(:,:,:) == 1._wp)
512	rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
513	END WHERE
514
515	! compute rhd at the ice/oce interface (ice shelf side)
516	CALL eos(ztstop,risfdep,zrhdtop_isf)
517
518	! compute rhd at the ice/oce interface (ocean side)
519	DO ji=1,jpi
520	DO jj=1,jpj
521	ikt=mikt(ji,jj)
522	ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
523	ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
524	END DO
525	END DO
526	CALL eos(ztstop,risfdep,zrhdtop_oce)
527	!
528	! Surface value + ice shelf gradient
529	! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
530	ziceload = 0._wp
531	DO jj = 1, jpj
532	DO ji = 1, jpi ! vector opt.
533	ikt=mikt(ji,jj)
534	ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
535	DO jk=2,ikt-1
536	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
537	& * (1._wp - tmask(ji,jj,jk))
538	END DO
539	IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
540	& * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
541	END DO
542	END DO
543	riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:) ! need to be saved for diaar5
544	! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
545	DO jj = 2, jpjm1
546	DO ji = fs_2, fs_jpim1 ! vector opt.
547	ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
548	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
549	! we assume ISF is in isostatic equilibrium
550	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj ,iktp1i) &
551	& * ( 2._wp * znad + rhd(ji+1,jj ,iktp1i) + zrhdtop_oce(ji+1,jj ) ) &
552	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
553	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
554	& + ( ziceload(ji+1,jj) - ziceload(ji,jj)) )
555	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji ,jj+1,iktp1j) &
556	& * ( 2._wp * znad + rhd(ji ,jj+1,iktp1j) + zrhdtop_oce(ji ,jj+1) ) &
557	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
558	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
559	& + ( ziceload(ji,jj+1) - ziceload(ji,jj) ) )
560	! s-coordinate pressure gradient correction (=0 if z coordinate)
561	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
562	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
563	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
564	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
565	! add to the general momentum trend
566	ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
567	va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
568	END DO
569	END DO
570	!==================================================================================
571	!===== Compute partial cell contribution for the top cell =========================
572	!==================================================================================
573	DO jj = 2, jpjm1
574	DO ji = fs_2, fs_jpim1 ! vector opt.
575	iku = miku(ji,jj) ;
576	zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
577	ze3wu = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
578	! u direction
579	IF ( iku .GT. 1 ) THEN
580	! case iku
581	zhpi(ji,jj,iku) = zcoef0 / e1u(ji,jj) * ze3wu &
582	& * ( rhd (ji+1,jj,iku) + rhd (ji,jj,iku) &
583	& + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
584	! corrective term ( = 0 if z coordinate )
585	zuap = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
586	! zhpi will be added in interior loop
587	ua(ji,jj,iku) = ua(ji,jj,iku) + zuap
588	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
589	IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj) = zhpi(ji,jj,iku)
590
591	! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
592	zhpiint = zcoef0 / e1u(ji,jj) &
593	& * ( fse3w(ji+1,jj ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad) &
594	& + (rhd(ji+1,jj,iku ) + znad) ) * tmask(ji+1,jj,iku) &
595	& - fse3w(ji ,jj ,iku+1) * ( (rhd(ji ,jj,iku+1) + znad) &
596	& + (rhd(ji ,jj,iku ) + znad) ) * tmask(ji ,jj,iku) )
597	zhpi(ji,jj,iku+1) = zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint
598	END IF
599
600	! v direction
601	ikv = mikv(ji,jj)
602	ze3wv = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
603	IF ( ikv .GT. 1 ) THEN
604	! case ikv
605	zhpj(ji,jj,ikv) = zcoef0 / e2v(ji,jj) * ze3wv &
606	& * ( rhd(ji,jj+1,ikv) + rhd (ji,jj,ikv) &
607	& + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
608	! corrective term ( = 0 if z coordinate )
609	zvap = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
610	! zhpi will be added in interior loop
611	va(ji,jj,ikv) = va(ji,jj,ikv) + zvap
612	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
613	IF (mbkv(ji,jj) == ikv + 1) zpshpj(ji,jj) = zhpj(ji,jj,ikv)
614
615	! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
616	zhpjint = zcoef0 / e2v(ji,jj) &
617	& * ( fse3w(ji ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad) &
618	& + (rhd(ji,jj+1,ikv ) + znad) ) * tmask(ji,jj+1,ikv) &
619	& - fse3w(ji ,jj ,ikv+1) * ( (rhd(ji,jj ,ikv+1) + znad) &
620	& + (rhd(ji,jj ,ikv ) + znad) ) * tmask(ji,jj ,ikv) )
621	zhpj(ji,jj,ikv+1) = zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
622	END IF
623	END DO
624	END DO
625
626	!==================================================================================
627	!===== Compute interior value =====================================================
628	!==================================================================================
629
630	DO jj = 2, jpjm1
631	DO ji = fs_2, fs_jpim1 ! vector opt.
632	iku=miku(ji,jj); ikv=mikv(ji,jj)
633	DO jk = 2, jpkm1
634	! hydrostatic pressure gradient along s-surfaces
635	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
636	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1) &
637	& + zcoef0 / e1u(ji,jj) &
638	& * ( fse3w(ji+1,jj ,jk) * ( (rhd(ji+1,jj,jk ) + znad) &
639	& + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1) &
640	& - fse3w(ji ,jj ,jk) * ( (rhd(ji ,jj,jk ) + znad) &
641	& + (rhd(ji ,jj,jk-1) + znad) ) * tmask(ji ,jj,jk-1) )
642	! s-coordinate pressure gradient correction
643	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
644	zuap = - zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
645	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
646	ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
647
648	! hydrostatic pressure gradient along s-surfaces
649	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
650	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1) &
651	& + zcoef0 / e2v(ji,jj) &
652	& * ( fse3w(ji ,jj+1,jk) * ( (rhd(ji,jj+1,jk ) + znad) &
653	& + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1) &
654	& - fse3w(ji ,jj ,jk) * ( (rhd(ji,jj ,jk ) + znad) &
655	& + (rhd(ji,jj ,jk-1) + znad) ) * tmask(ji,jj ,jk-1) )
656	! s-coordinate pressure gradient correction
657	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
658	zvap = - zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
659	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
660	! add to the general momentum trend
661	va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
662	END DO
663	END DO
664	END DO
665
666	!==================================================================================
667	!===== Compute bottom cell contribution (partial cell) ============================
668	!==================================================================================
669
670	DO jj = 2, jpjm1
671	DO ji = 2, jpim1
672	iku = mbku(ji,jj)
673	ikv = mbkv(ji,jj)
674
675	IF (iku .GT. 1) THEN
676	! remove old value (interior case)
677	zuap = -zcoef0 * ( rhd (ji+1,jj ,iku) + rhd (ji,jj,iku) + 2._wp * znad ) &
678	& * ( fsde3w(ji+1,jj ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
679	ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
680	! put new value
681	! -zpshpi to avoid double contribution of the partial step in the top layer
682	zuap = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj) / e1u(ji,jj)
683	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj)
684	ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
685	END IF
686	! v direction
687	IF (ikv .GT. 1) THEN
688	! remove old value (interior case)
689	zvap = -zcoef0 * ( rhd (ji ,jj+1,ikv) + rhd (ji,jj,ikv) + 2._wp * znad ) &
690	& * ( fsde3w(ji ,jj+1,ikv) - fsde3w(ji,jj,ikv) ) / e2v(ji,jj)
691	va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
692	! put new value
693	! -zpshpj to avoid double contribution of the partial step in the top layer
694	zvap = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj) / e2v(ji,jj)
695	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)
696	va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
697	END IF
698	END DO
699	END DO
700
701	! set back to original density value into the ice shelf cell (maybe useless because it is masked)
702	rhd = zrhd
703	!
704	CALL wrk_dealloc( jpi,jpj,2, ztstop)
705	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
706	CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
707	!
708	END SUBROUTINE hpg_isf
709
710
711	SUBROUTINE hpg_djc( kt )
712	!!---------------------------------------------------------------------
713	!! * ROUTINE hpg_djc *
714	!!
715	!! ** Method : Density Jacobian with Cubic polynomial scheme
716	!!
717	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
718	!!----------------------------------------------------------------------
719	INTEGER, INTENT(in) :: kt ! ocean time-step index
720	!!
721	INTEGER :: ji, jj, jk ! dummy loop indices
722	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
723	REAL(wp) :: z1_10, cffu, cffx ! " "
724	REAL(wp) :: z1_12, cffv, cffy ! " "
725	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
726	REAL(wp), POINTER, DIMENSION(:,:,:) :: dzx, dzy, dzz, dzu, dzv, dzw
727	REAL(wp), POINTER, DIMENSION(:,:,:) :: drhox, drhoy, drhoz, drhou, drhov, drhow
728	REAL(wp), POINTER, DIMENSION(:,:,:) :: rho_i, rho_j, rho_k
729	!!----------------------------------------------------------------------
730	!
731	CALL wrk_alloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
732	CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
733	CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
734	!
735
736	IF( kt == nit000 ) THEN
737	IF(lwp) WRITE(numout,*)
738	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
739	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
740	ENDIF
741
742	! Local constant initialization
743	zcoef0 = - grav * 0.5_wp
744	z1_10 = 1._wp / 10._wp
745	z1_12 = 1._wp / 12._wp
746
747	!----------------------------------------------------------------------------------------
748	! compute and store in provisional arrays elementary vertical and horizontal differences
749	!----------------------------------------------------------------------------------------
750
751	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
752
753	DO jk = 2, jpkm1
754	DO jj = 2, jpjm1
755	DO ji = fs_2, fs_jpim1 ! vector opt.
756	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
757	dzz (ji,jj,jk) = fsde3w(ji ,jj ,jk) - fsde3w(ji,jj,jk-1)
758	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
759	dzx (ji,jj,jk) = fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk )
760	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
761	dzy (ji,jj,jk) = fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk )
762	END DO
763	END DO
764	END DO
765
766	!-------------------------------------------------------------------------
767	! compute harmonic averages using eq. 5.18
768	!-------------------------------------------------------------------------
769	zep = 1.e-15
770
771	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
772	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
773
774	DO jk = 2, jpkm1
775	DO jj = 2, jpjm1
776	DO ji = fs_2, fs_jpim1 ! vector opt.
777	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
778
779	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
780	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
781
782	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
783	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
784
785	IF( cffw > zep) THEN
786	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
787	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
788	ELSE
789	drhow(ji,jj,jk) = 0._wp
790	ENDIF
791
792	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
793	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
794
795	IF( cffu > zep ) THEN
796	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
797	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
798	ELSE
799	drhou(ji,jj,jk ) = 0._wp
800	ENDIF
801
802	IF( cffx > zep ) THEN
803	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
804	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
805	ELSE
806	dzu(ji,jj,jk) = 0._wp
807	ENDIF
808
809	IF( cffv > zep ) THEN
810	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
811	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
812	ELSE
813	drhov(ji,jj,jk) = 0._wp
814	ENDIF
815
816	IF( cffy > zep ) THEN
817	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
818	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
819	ELSE
820	dzv(ji,jj,jk) = 0._wp
821	ENDIF
822
823	END DO
824	END DO
825	END DO
826
827	!----------------------------------------------------------------------------------
828	! apply boundary conditions at top and bottom using 5.36-5.37
829	!----------------------------------------------------------------------------------
830	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
831	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
832	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
833
834	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
835	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
836	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
837
838
839	!--------------------------------------------------------------
840	! Upper half of top-most grid box, compute and store
841	!-------------------------------------------------------------
842
843	!!bug gm : e3w-de3w = 0.5*e3w .... and de3w(2)-de3w(1)=e3w(2) .... to be verified
844	! true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
845
846	DO jj = 2, jpjm1
847	DO ji = fs_2, fs_jpim1 ! vector opt.
848	rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) ) &
849	& * ( rhd(ji,jj,1) &
850	& + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) ) &
851	& * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) ) &
852	& / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) ) )
853	END DO
854	END DO
855
856	!!bug gm : here also, simplification is possible
857	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
858
859	DO jk = 2, jpkm1
860	DO jj = 2, jpjm1
861	DO ji = fs_2, fs_jpim1 ! vector opt.
862
863	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
864	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) ) &
865	& - grav * z1_10 * ( &
866	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
867	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
868	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
869	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
870	& )
871
872	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
873	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) ) &
874	& - grav* z1_10 * ( &
875	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
876	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
877	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
878	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
879	& )
880
881	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
882	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) ) &
883	& - grav* z1_10 * ( &
884	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
885	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
886	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
887	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
888	& )
889
890	END DO
891	END DO
892	END DO
893	CALL lbc_lnk(rho_k,'W',1.)
894	CALL lbc_lnk(rho_i,'U',1.)
895	CALL lbc_lnk(rho_j,'V',1.)
896
897
898	! ---------------
899	! Surface value
900	! ---------------
901	DO jj = 2, jpjm1
902	DO ji = fs_2, fs_jpim1 ! vector opt.
903	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
904	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
905	! add to the general momentum trend
906	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
907	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
908	END DO
909	END DO
910
911	! ----------------
912	! interior value (2=<jk=<jpkm1)
913	! ----------------
914	DO jk = 2, jpkm1
915	DO jj = 2, jpjm1
916	DO ji = fs_2, fs_jpim1 ! vector opt.
917	! hydrostatic pressure gradient along s-surfaces
918	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
919	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
920	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) / e1u(ji,jj)
921	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
922	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
923	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) / e2v(ji,jj)
924	! add to the general momentum trend
925	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
926	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
927	END DO
928	END DO
929	END DO
930	!
931	CALL wrk_dealloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
932	CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
933	CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
934	!
935	END SUBROUTINE hpg_djc
936
937
938	SUBROUTINE hpg_prj( kt )
939	!!---------------------------------------------------------------------
940	!! * ROUTINE hpg_prj *
941	!!
942	!! ** Method : s-coordinate case.
943	!! A Pressure-Jacobian horizontal pressure gradient method
944	!! based on the constrained cubic-spline interpolation for
945	!! all vertical coordinate systems
946	!!
947	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
948	!!----------------------------------------------------------------------
949	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
950	INTEGER, INTENT(in) :: kt ! ocean time-step index
951	!!
952	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
953	REAL(wp) :: zcoef0, znad ! temporary scalars
954	!!
955	!! The local variables for the correction term
956	INTEGER :: jk1, jis, jid, jjs, jjd
957	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
958	REAL(wp) :: zrhdt1
959	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
960	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdept, zrhh
961	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
962	REAL(wp), POINTER, DIMENSION(:,:) :: zsshu_n, zsshv_n
963	!!----------------------------------------------------------------------
964	!
965	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
966	CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
967	CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
968	!
969	IF( kt == nit000 ) THEN
970	IF(lwp) WRITE(numout,*)
971	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
972	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
973	ENDIF
974
975	!!----------------------------------------------------------------------
976	! Local constant initialization
977	zcoef0 = - grav
978	znad = 0.0_wp
979	IF( lk_vvl ) znad = 1._wp
980
981	! Clean 3-D work arrays
982	zhpi(:,:,:) = 0._wp
983	zrhh(:,:,:) = rhd(:,:,:)
984
985	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
986	DO jj = 1, jpj
987	DO ji = 1, jpi
988	jk = mbathy(ji,jj)
989	IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
990	ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
991	ELSE IF(jk < jpkm1) THEN
992	DO jkk = jk+1, jpk
993	zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk), fsde3w(ji,jj,jkk-1), &
994	fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
995	END DO
996	ENDIF
997	END DO
998	END DO
999
1000	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1001	DO jj = 1, jpj
1002	DO ji = 1, jpi
1003	zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1004	END DO
1005	END DO
1006
1007	DO jk = 2, jpk
1008	DO jj = 1, jpj
1009	DO ji = 1, jpi
1010	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1011	END DO
1012	END DO
1013	END DO
1014
1015	fsp(:,:,:) = zrhh (:,:,:)
1016	xsp(:,:,:) = zdept(:,:,:)
1017
1018	! Construct the vertical density profile with the
1019	! constrained cubic spline interpolation
1020	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1021	CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1022
1023	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1024	DO jj = 2, jpj
1025	DO ji = 2, jpi
1026	zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1027	bsp(ji,jj,1), csp(ji,jj,1), &
1028	dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1029
1030	! assuming linear profile across the top half surface layer
1031	zhpi(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) * zrhdt1
1032	END DO
1033	END DO
1034
1035	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1036	DO jk = 2, jpkm1
1037	DO jj = 2, jpj
1038	DO ji = 2, jpi
1039	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1040	integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1041	asp(ji,jj,jk-1), bsp(ji,jj,jk-1), &
1042	csp(ji,jj,jk-1), dsp(ji,jj,jk-1))
1043	END DO
1044	END DO
1045	END DO
1046
1047	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1048
1049	! Prepare zsshu_n and zsshv_n
1050	DO jj = 2, jpjm1
1051	DO ji = 2, jpim1
1052	zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1053	& r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1054	zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1055	& r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1056	END DO
1057	END DO
1058
1059	DO jj = 2, jpjm1
1060	DO ji = 2, jpim1
1061	zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad)
1062	zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1063	END DO
1064	END DO
1065
1066	DO jk = 2, jpkm1
1067	DO jj = 2, jpjm1
1068	DO ji = 2, jpim1
1069	zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1070	zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1071	END DO
1072	END DO
1073	END DO
1074
1075	DO jk = 1, jpkm1
1076	DO jj = 2, jpjm1
1077	DO ji = 2, jpim1
1078	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1079	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1080	END DO
1081	END DO
1082	END DO
1083
1084	DO jk = 1, jpkm1
1085	DO jj = 2, jpjm1
1086	DO ji = 2, jpim1
1087	zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1088	zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1089	zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1090	zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1091	END DO
1092	END DO
1093	END DO
1094
1095
1096	DO jk = 1, jpkm1
1097	DO jj = 2, jpjm1
1098	DO ji = 2, jpim1
1099	zpwes = 0._wp; zpwed = 0._wp
1100	zpnss = 0._wp; zpnsd = 0._wp
1101	zuijk = zu(ji,jj,jk)
1102	zvijk = zv(ji,jj,jk)
1103
1104	!!!!! for u equation
1105	IF( jk <= mbku(ji,jj) ) THEN
1106	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1107	jis = ji + 1; jid = ji
1108	ELSE
1109	jis = ji; jid = ji +1
1110	ENDIF
1111
1112	! integrate the pressure on the shallow side
1113	jk1 = jk
1114	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1115	IF( jk1 == mbku(ji,jj) ) THEN
1116	zuijk = -zdept(jis,jj,jk1)
1117	EXIT
1118	ENDIF
1119	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1120	zpwes = zpwes + &
1121	integ_spline(zdept(jis,jj,jk1), zdeps, &
1122	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1123	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1124	jk1 = jk1 + 1
1125	END DO
1126
1127	! integrate the pressure on the deep side
1128	jk1 = jk
1129	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1130	IF( jk1 == 1 ) THEN
1131	zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1132	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1133	bsp(jid,jj,1), csp(jid,jj,1), &
1134	dsp(jid,jj,1)) * zdeps
1135	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1136	EXIT
1137	ENDIF
1138	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1139	zpwed = zpwed + &
1140	integ_spline(zdeps, zdept(jid,jj,jk1), &
1141	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1142	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1143	jk1 = jk1 - 1
1144	END DO
1145
1146	! update the momentum trends in u direction
1147
1148	zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1149	IF( lk_vvl ) THEN
1150	zdpdx2 = zcoef0 / e1u(ji,jj) * &
1151	( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1152	ELSE
1153	zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1154	ENDIF
1155
1156	ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1157	& umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1158	ENDIF
1159
1160	!!!!! for v equation
1161	IF( jk <= mbkv(ji,jj) ) THEN
1162	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1163	jjs = jj + 1; jjd = jj
1164	ELSE
1165	jjs = jj ; jjd = jj + 1
1166	ENDIF
1167
1168	! integrate the pressure on the shallow side
1169	jk1 = jk
1170	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1171	IF( jk1 == mbkv(ji,jj) ) THEN
1172	zvijk = -zdept(ji,jjs,jk1)
1173	EXIT
1174	ENDIF
1175	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1176	zpnss = zpnss + &
1177	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1178	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1179	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1180	jk1 = jk1 + 1
1181	END DO
1182
1183	! integrate the pressure on the deep side
1184	jk1 = jk
1185	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1186	IF( jk1 == 1 ) THEN
1187	zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1188	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1189	bsp(ji,jjd,1), csp(ji,jjd,1), &
1190	dsp(ji,jjd,1) ) * zdeps
1191	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1192	EXIT
1193	ENDIF
1194	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1195	zpnsd = zpnsd + &
1196	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1197	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1198	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1199	jk1 = jk1 - 1
1200	END DO
1201
1202
1203	! update the momentum trends in v direction
1204
1205	zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1206	IF( lk_vvl ) THEN
1207	zdpdy2 = zcoef0 / e2v(ji,jj) * &
1208	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1209	ELSE
1210	zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1211	ENDIF
1212
1213	va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1214	& vmask(ji,jj,jk)tmask(ji,jj,jk)tmask(ji,jj+1,jk)
1215	ENDIF
1216
1217
1218	END DO
1219	END DO
1220	END DO
1221	!
1222	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1223	CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1224	CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1225	!
1226	END SUBROUTINE hpg_prj
1227
1228
1229	SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1230	!!----------------------------------------------------------------------
1231	!! * ROUTINE cspline *
1232	!!
1233	!! ** Purpose : constrained cubic spline interpolation
1234	!!
1235	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1236	!!
1237	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1238	!!----------------------------------------------------------------------
1239	IMPLICIT NONE
1240	REAL(wp), DIMENSION(:,:,:), INTENT(in) :: fsp, xsp ! value and coordinate
1241	REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1242	! the interpoated function
1243	INTEGER, INTENT(in) :: polynomial_type ! 1: cubic spline
1244	! 2: Linear
1245	!
1246	INTEGER :: ji, jj, jk ! dummy loop indices
1247	INTEGER :: jpi, jpj, jpkm1
1248	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1249	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1250	REAL(wp) :: zdf(size(fsp,3))
1251	!!----------------------------------------------------------------------
1252
1253	jpi = size(fsp,1)
1254	jpj = size(fsp,2)
1255	jpkm1 = size(fsp,3) - 1
1256
1257
1258	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1259	DO ji = 1, jpi
1260	DO jj = 1, jpj
1261	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1262	! DO jk = 2, jpkm1-1
1263	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1264	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1265	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1266	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1267	!
1268	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1269	!
1270	! IF(zdf1 * zdf2 <= 0._wp) THEN
1271	! zdf(jk) = 0._wp
1272	! ELSE
1273	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1274	! ENDIF
1275	! END DO
1276
1277	!!Simply geometric average
1278	DO jk = 2, jpkm1-1
1279	zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1280	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1281
1282	IF(zdf1 * zdf2 <= 0._wp) THEN
1283	zdf(jk) = 0._wp
1284	ELSE
1285	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1286	ENDIF
1287	END DO
1288
1289	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1290	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1291	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1292	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1293	& 0.5_wp * zdf(jpkm1 - 1)
1294
1295	DO jk = 1, jpkm1 - 1
1296	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1297	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1298	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1299	zddf1 = -2._wp * ztmp1 + ztmp2
1300	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1301	zddf2 = 2._wp * ztmp1 - ztmp2
1302
1303	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1304	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1305	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1306	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1307	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1308	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1309	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1310	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1311	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1312	END DO
1313	END DO
1314	END DO
1315
1316	ELSE IF (polynomial_type == 2) THEN ! Linear
1317	DO ji = 1, jpi
1318	DO jj = 1, jpj
1319	DO jk = 1, jpkm1-1
1320	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1321	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1322
1323	dsp(ji,jj,jk) = 0._wp
1324	csp(ji,jj,jk) = 0._wp
1325	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1326	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1327	END DO
1328	END DO
1329	END DO
1330
1331	ELSE
1332	CALL ctl_stop( 'invalid polynomial type in cspline' )
1333	ENDIF
1334
1335	END SUBROUTINE cspline
1336
1337
1338	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1339	!!----------------------------------------------------------------------
1340	!! * ROUTINE interp1 *
1341	!!
1342	!! ** Purpose : 1-d linear interpolation
1343	!!
1344	!! ** Method : interpolation is straight forward
1345	!! extrapolation is also permitted (no value limit)
1346	!!----------------------------------------------------------------------
1347	IMPLICIT NONE
1348	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1349	REAL(wp) :: f ! result of the interpolation (extrapolation)
1350	REAL(wp) :: zdeltx
1351	!!----------------------------------------------------------------------
1352
1353	zdeltx = xr - xl
1354	IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1355	f = 0.5_wp * (fl + fr)
1356	ELSE
1357	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1358	ENDIF
1359
1360	END FUNCTION interp1
1361
1362
1363	FUNCTION interp2(x, a, b, c, d) RESULT(f)
1364	!!----------------------------------------------------------------------
1365	!! * ROUTINE interp1 *
1366	!!
1367	!! ** Purpose : 1-d constrained cubic spline interpolation
1368	!!
1369	!! ** Method : cubic spline interpolation
1370	!!
1371	!!----------------------------------------------------------------------
1372	IMPLICIT NONE
1373	REAL(wp), INTENT(in) :: x, a, b, c, d
1374	REAL(wp) :: f ! value from the interpolation
1375	!!----------------------------------------------------------------------
1376
1377	f = a + x* ( b + x * ( c + d * x ) )
1378
1379	END FUNCTION interp2
1380
1381
1382	FUNCTION interp3(x, a, b, c, d) RESULT(f)
1383	!!----------------------------------------------------------------------
1384	!! * ROUTINE interp1 *
1385	!!
1386	!! ** Purpose : Calculate the first order of deriavtive of
1387	!! a cubic spline function y=a+bx+cx^2+d*x^3
1388	!!
1389	!! ** Method : f=dy/dx=b+2cx+3dx^2
1390	!!
1391	!!----------------------------------------------------------------------
1392	IMPLICIT NONE
1393	REAL(wp), INTENT(in) :: x, a, b, c, d
1394	REAL(wp) :: f ! value from the interpolation
1395	!!----------------------------------------------------------------------
1396
1397	f = b + x * ( 2._wp * c + 3._wp * d * x)
1398
1399	END FUNCTION interp3
1400
1401
1402	FUNCTION integ_spline(xl, xr, a, b, c, d) RESULT(f)
1403	!!----------------------------------------------------------------------
1404	!! * ROUTINE interp1 *
1405	!!
1406	!! ** Purpose : 1-d constrained cubic spline integration
1407	!!
1408	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1409	!!
1410	!!----------------------------------------------------------------------
1411	IMPLICIT NONE
1412	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1413	REAL(wp) :: za1, za2, za3
1414	REAL(wp) :: f ! integration result
1415	!!----------------------------------------------------------------------
1416
1417	za1 = 0.5_wp * b
1418	za2 = c / 3.0_wp
1419	za3 = 0.25_wp * d
1420
1421	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1422	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1423
1424	END FUNCTION integ_spline
1425
1426	!!======================================================================
1427	END MODULE dynhpg
1428

Note: See TracBrowser for help on using the repository browser.

Download in other formats: