New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

dynhpg.F90 in branches/2016/dev_v3_6_STABLE_OMP/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

Context Navigation

source: branches/2016/dev_v3_6_STABLE_OMP/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 6712

Last change on this file since 6712 was 6712, checked in by mocavero, 8 years ago
update some OMP directives
Property svn:keywords set to `Id`
File size: 70.0 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!!----------------------------------------------------------------------
20
21	!!----------------------------------------------------------------------
22	!! dyn_hpg : update the momentum trend with the now horizontal
23	!! gradient of the hydrostatic pressure
24	!! dyn_hpg_init : initialisation and control of options
25	!! hpg_zco : z-coordinate scheme
26	!! hpg_zps : z-coordinate plus partial steps (interpolation)
27	!! hpg_sco : s-coordinate (standard jacobian formulation)
28	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
29	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
30	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
31	!!----------------------------------------------------------------------
32	USE oce ! ocean dynamics and tracers
33	USE sbc_oce ! surface variable (only for the flag with ice shelf)
34	USE dom_oce ! ocean space and time domain
35	USE phycst ! physical constants
36	USE trd_oce ! trends: ocean variables
37	USE trddyn ! trend manager: dynamics
38	!
39	USE in_out_manager ! I/O manager
40	USE prtctl ! Print control
41	USE lbclnk ! lateral boundary condition
42	USE lib_mpp ! MPP library
43	USE eosbn2 ! compute density
44	USE wrk_nemo ! Memory Allocation
45	USE timing ! Timing
46
47	IMPLICIT NONE
48	PRIVATE
49
50	PUBLIC dyn_hpg ! routine called by step module
51	PUBLIC dyn_hpg_init ! routine called by opa module
52
53	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
54	LOGICAL , PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
55	LOGICAL , PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
56	LOGICAL , PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
57	LOGICAL , PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
58	LOGICAL , PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
59	LOGICAL , PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
60	LOGICAL , PUBLIC :: ln_dynhpg_imp !: semi-implicite hpg flag
61
62	INTEGER , PUBLIC :: nhpg = 0 ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
63
64	!! * Substitutions
65	# include "domzgr_substitute.h90"
66	# include "vectopt_loop_substitute.h90"
67	!!----------------------------------------------------------------------
68	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
69	!! $Id$
70	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
71	!!----------------------------------------------------------------------
72	CONTAINS
73
74	SUBROUTINE dyn_hpg( kt )
75	!!---------------------------------------------------------------------
76	!! * ROUTINE dyn_hpg *
77	!!
78	!! ** Method : Call the hydrostatic pressure gradient routine
79	!! using the scheme defined in the namelist
80	!!
81	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
82	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
83	!!----------------------------------------------------------------------
84	INTEGER, INTENT(in) :: kt ! ocean time-step index
85	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv
86	!!----------------------------------------------------------------------
87	!
88	IF( nn_timing == 1 ) CALL timing_start('dyn_hpg')
89	!
90	IF( l_trddyn ) THEN ! Temporary saving of ua and va trends (l_trddyn)
91	CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
92	ztrdu(:,:,:) = ua(:,:,:)
93	ztrdv(:,:,:) = va(:,:,:)
94	ENDIF
95	!
96	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
97	CASE ( 0 ) ; CALL hpg_zco ( kt ) ! z-coordinate
98	CASE ( 1 ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
99	CASE ( 2 ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
100	CASE ( 3 ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
101	CASE ( 4 ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
102	CASE ( 5 ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
103	END SELECT
104	!
105	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
106	ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
107	ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
108	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
109	CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
110	ENDIF
111	!
112	IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg - Ua: ', mask1=umask, &
113	& tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
114	!
115	IF( nn_timing == 1 ) CALL timing_stop('dyn_hpg')
116	!
117	END SUBROUTINE dyn_hpg
118
119
120	SUBROUTINE dyn_hpg_init
121	!!----------------------------------------------------------------------
122	!! * ROUTINE dyn_hpg_init *
123	!!
124	!! ** Purpose : initializations for the hydrostatic pressure gradient
125	!! computation and consistency control
126	!!
127	!! ** Action : Read the namelist namdyn_hpg and check the consistency
128	!! with the type of vertical coordinate used (zco, zps, sco)
129	!!----------------------------------------------------------------------
130	INTEGER :: ioptio = 0 ! temporary integer
131	INTEGER :: ios ! Local integer output status for namelist read
132	!!
133	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
134	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
135	!!----------------------------------------------------------------------
136	!
137	REWIND( numnam_ref ) ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
138	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
139	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
140
141	REWIND( numnam_cfg ) ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
142	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
143	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
144	IF(lwm) WRITE ( numond, namdyn_hpg )
145	!
146	IF(lwp) THEN ! Control print
147	WRITE(numout,*)
148	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
149	WRITE(numout,*) '~~~~~~~~~~~~'
150	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
151	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
152	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
153	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
154	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
155	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
156	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
157	WRITE(numout,*) ' time stepping: centered (F) or semi-implicit (T) ln_dynhpg_imp = ', ln_dynhpg_imp
158	ENDIF
159	!
160	IF( ln_hpg_djc ) &
161	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
162	& currently disabled (bugs under investigation). Please select &
163	& either ln_hpg_sco or ln_hpg_prj instead')
164	!
165	IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
166	& CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
167	& the standard jacobian formulation hpg_sco or &
168	& the pressure jacobian formulation hpg_prj')
169
170	IF( ln_hpg_isf .AND. .NOT. ln_isfcav ) &
171	& CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
172	IF( .NOT. ln_hpg_isf .AND. ln_isfcav ) &
173	& CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
174	!
175	! ! Set nhpg from ln_hpg_... flags
176	IF( ln_hpg_zco ) nhpg = 0
177	IF( ln_hpg_zps ) nhpg = 1
178	IF( ln_hpg_sco ) nhpg = 2
179	IF( ln_hpg_djc ) nhpg = 3
180	IF( ln_hpg_prj ) nhpg = 4
181	IF( ln_hpg_isf ) nhpg = 5
182	!
183	! ! Consistency check
184	ioptio = 0
185	IF( ln_hpg_zco ) ioptio = ioptio + 1
186	IF( ln_hpg_zps ) ioptio = ioptio + 1
187	IF( ln_hpg_sco ) ioptio = ioptio + 1
188	IF( ln_hpg_djc ) ioptio = ioptio + 1
189	IF( ln_hpg_prj ) ioptio = ioptio + 1
190	IF( ln_hpg_isf ) ioptio = ioptio + 1
191	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
192	!
193	! initialisation of ice load
194	riceload(:,:)=0.0
195	!
196	END SUBROUTINE dyn_hpg_init
197
198
199	SUBROUTINE hpg_zco( kt )
200	!!---------------------------------------------------------------------
201	!! * ROUTINE hpg_zco *
202	!!
203	!! ** Method : z-coordinate case, levels are horizontal surfaces.
204	!! The now hydrostatic pressure gradient at a given level, jk,
205	!! is computed by taking the vertical integral of the in-situ
206	!! density gradient along the model level from the suface to that
207	!! level: zhpi = grav .....
208	!! zhpj = grav .....
209	!! add it to the general momentum trend (ua,va).
210	!! ua = ua - 1/e1u * zhpi
211	!! va = va - 1/e2v * zhpj
212	!!
213	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
214	!!----------------------------------------------------------------------
215	INTEGER, INTENT(in) :: kt ! ocean time-step index
216	!!
217	INTEGER :: ji, jj, jk ! dummy loop indices
218	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
219	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
220	!!----------------------------------------------------------------------
221	!
222	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
223	!
224	IF( kt == nit000 ) THEN
225	IF(lwp) WRITE(numout,*)
226	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
227	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
228	ENDIF
229
230	zcoef0 = - grav * 0.5_wp ! Local constant initialization
231
232	! Surface value
233	DO jj = 2, jpjm1
234	DO ji = fs_2, fs_jpim1 ! vector opt.
235	zcoef1 = zcoef0 * fse3w(ji,jj,1)
236	! hydrostatic pressure gradient
237	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
238	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
239	! add to the general momentum trend
240	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
241	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
242	END DO
243	END DO
244
245	!
246	! interior value (2=<jk=<jpkm1)
247	DO jk = 2, jpkm1
248	!$OMP PARALLEL DO private(ji,jj, zcoef1)
249	DO jj = 2, jpjm1
250	DO ji = fs_2, fs_jpim1 ! vector opt.
251	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
252	! hydrostatic pressure gradient
253	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
254	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
255	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
256
257	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
258	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
259	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
260	! add to the general momentum trend
261	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
262	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
263	END DO
264	END DO
265	END DO
266	!
267	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
268	!
269	END SUBROUTINE hpg_zco
270
271
272	SUBROUTINE hpg_zps( kt )
273	!!---------------------------------------------------------------------
274	!! * ROUTINE hpg_zps *
275	!!
276	!! ** Method : z-coordinate plus partial steps case. blahblah...
277	!!
278	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
279	!!----------------------------------------------------------------------
280	INTEGER, INTENT(in) :: kt ! ocean time-step index
281	!!
282	INTEGER :: ji, jj, jk ! dummy loop indices
283	INTEGER :: iku, ikv ! temporary integers
284	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
285	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
286	!!----------------------------------------------------------------------
287	!
288	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
289	!
290	IF( kt == nit000 ) THEN
291	IF(lwp) WRITE(numout,*)
292	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
293	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
294	ENDIF
295
296
297	! Local constant initialization
298	zcoef0 = - grav * 0.5_wp
299
300	! Surface value (also valid in partial step case)
301	!$OMP PARALLEL DO private(ji,jj, zcoef1)
302	DO jj = 2, jpjm1
303	DO ji = fs_2, fs_jpim1 ! vector opt.
304	zcoef1 = zcoef0 * fse3w(ji,jj,1)
305	! hydrostatic pressure gradient
306	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
307	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
308	! add to the general momentum trend
309	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
310	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
311	END DO
312	END DO
313
314
315	! interior value (2=<jk=<jpkm1)
316	DO jk = 2, jpkm1
317	!$OMP PARALLEL DO private(ji,jj, zcoef1)
318	DO jj = 2, jpjm1
319	DO ji = fs_2, fs_jpim1 ! vector opt.
320	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
321	! hydrostatic pressure gradient
322	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
323	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
324	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
325
326	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
327	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
328	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
329	! add to the general momentum trend
330	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
331	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
332	END DO
333	END DO
334	END DO
335
336
337	! partial steps correction at the last level (use gru & grv computed in zpshde.F90)
338	DO jj = 2, jpjm1
339	DO ji = 2, jpim1
340	iku = mbku(ji,jj)
341	ikv = mbkv(ji,jj)
342	zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj ,iku) )
343	zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji ,jj+1,ikv) )
344	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
345	ua (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) ! subtract old value
346	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
347	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
348	ua (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
349	ENDIF
350	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
351	va (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) ! subtract old value
352	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
353	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
354	va (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
355	ENDIF
356	END DO
357	END DO
358	!
359	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
360	!
361	END SUBROUTINE hpg_zps
362
363	SUBROUTINE hpg_sco( kt )
364	!!---------------------------------------------------------------------
365	!! * ROUTINE hpg_sco *
366	!!
367	!! ** Method : s-coordinate case. Jacobian scheme.
368	!! The now hydrostatic pressure gradient at a given level, jk,
369	!! is computed by taking the vertical integral of the in-situ
370	!! density gradient along the model level from the suface to that
371	!! level. s-coordinates (ln_sco): a corrective term is added
372	!! to the horizontal pressure gradient :
373	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
374	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
375	!! add it to the general momentum trend (ua,va).
376	!! ua = ua - 1/e1u * zhpi
377	!! va = va - 1/e2v * zhpj
378	!!
379	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
380	!!----------------------------------------------------------------------
381	INTEGER, INTENT(in) :: kt ! ocean time-step index
382	!!
383	INTEGER :: ji, jj, jk ! dummy loop indices
384	REAL(wp) :: zcoef0, zuap, zvap, znad ! temporary scalars
385	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
386	!!----------------------------------------------------------------------
387	!
388	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
389	!
390	IF( kt == nit000 ) THEN
391	IF(lwp) WRITE(numout,*)
392	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
393	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
394	ENDIF
395
396	! Local constant initialization
397	zcoef0 = - grav * 0.5_wp
398	! To use density and not density anomaly
399	IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
400	ELSE ; znad = 0._wp ! Fixed volume
401	ENDIF
402
403	! Surface value
404	DO jj = 2, jpjm1
405	DO ji = fs_2, fs_jpim1 ! vector opt.
406	! hydrostatic pressure gradient along s-surfaces
407	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj ,1) * ( znad + rhd(ji+1,jj ,1) ) &
408	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
409	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji ,jj+1,1) * ( znad + rhd(ji ,jj+1,1) ) &
410	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
411	! s-coordinate pressure gradient correction
412	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
413	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
414	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
415	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
416	! add to the general momentum trend
417	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
418	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
419	END DO
420	END DO
421
422	! interior value (2=<jk=<jpkm1)
423	DO jk = 2, jpkm1
424	DO jj = 2, jpjm1
425	DO ji = fs_2, fs_jpim1 ! vector opt.
426	! hydrostatic pressure gradient along s-surfaces
427	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
428	& * ( fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
429	& - fse3w(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
430	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
431	& * ( fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
432	& - fse3w(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
433	! s-coordinate pressure gradient correction
434	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
435	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
436	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
437	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
438	! add to the general momentum trend
439	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
440	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
441	END DO
442	END DO
443	END DO
444	!
445	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
446	!
447	END SUBROUTINE hpg_sco
448
449	SUBROUTINE hpg_isf( kt )
450	!!---------------------------------------------------------------------
451	!! * ROUTINE hpg_sco *
452	!!
453	!! ** Method : s-coordinate case. Jacobian scheme.
454	!! The now hydrostatic pressure gradient at a given level, jk,
455	!! is computed by taking the vertical integral of the in-situ
456	!! density gradient along the model level from the suface to that
457	!! level. s-coordinates (ln_sco): a corrective term is added
458	!! to the horizontal pressure gradient :
459	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
460	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
461	!! add it to the general momentum trend (ua,va).
462	!! ua = ua - 1/e1u * zhpi
463	!! va = va - 1/e2v * zhpj
464	!! iceload is added and partial cell case are added to the top and bottom
465	!!
466	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
467	!!----------------------------------------------------------------------
468	INTEGER, INTENT(in) :: kt ! ocean time-step index
469	!!
470	INTEGER :: ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j ! dummy loop indices
471	REAL(wp) :: zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1 ! temporary scalars
472	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj, zrhd
473	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztstop
474	REAL(wp), POINTER, DIMENSION(:,:) :: ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
475	!!----------------------------------------------------------------------
476	!
477	CALL wrk_alloc( jpi,jpj, 2, ztstop)
478	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
479	CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
480	!
481	IF( kt == nit000 ) THEN
482	IF(lwp) WRITE(numout,*)
483	IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
484	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
485	ENDIF
486
487	! Local constant initialization
488	zcoef0 = - grav * 0.5_wp
489	! To use density and not density anomaly
490	! IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
491	! ELSE ; znad = 0._wp ! Fixed volume
492	! ENDIF
493	znad=1._wp
494	! iniitialised to 0. zhpi zhpi
495	zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
496
497	!==================================================================================
498	!=====Compute iceload and contribution of the half first wet layer =================
499	!===================================================================================
500
501	! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
502	ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
503
504	! compute density of the water displaced by the ice shelf
505	zrhd = rhd ! save rhd
506	DO jk = 1, jpk
507	zdept(:,:)=gdept_1d(jk)
508	CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
509	END DO
510	WHERE ( tmask(:,:,:) == 1._wp)
511	rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
512	END WHERE
513
514	! compute rhd at the ice/oce interface (ice shelf side)
515	CALL eos(ztstop,risfdep,zrhdtop_isf)
516
517	! compute rhd at the ice/oce interface (ocean side)
518	DO ji=1,jpi
519	DO jj=1,jpj
520	ikt=mikt(ji,jj)
521	ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
522	ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
523	END DO
524	END DO
525	CALL eos(ztstop,risfdep,zrhdtop_oce)
526	!
527	! Surface value + ice shelf gradient
528	! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
529	ziceload = 0._wp
530	DO jj = 1, jpj
531	DO ji = 1, jpi ! vector opt.
532	ikt=mikt(ji,jj)
533	ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
534	DO jk=2,ikt-1
535	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
536	& * (1._wp - tmask(ji,jj,jk))
537	END DO
538	IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
539	& * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
540	END DO
541	END DO
542	riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:) ! need to be saved for diaar5
543	! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
544	DO jj = 2, jpjm1
545	DO ji = fs_2, fs_jpim1 ! vector opt.
546	ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
547	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
548	! we assume ISF is in isostatic equilibrium
549	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj ,iktp1i) &
550	& * ( 2._wp * znad + rhd(ji+1,jj ,iktp1i) + zrhdtop_oce(ji+1,jj ) ) &
551	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
552	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
553	& + ( ziceload(ji+1,jj) - ziceload(ji,jj)) )
554	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji ,jj+1,iktp1j) &
555	& * ( 2._wp * znad + rhd(ji ,jj+1,iktp1j) + zrhdtop_oce(ji ,jj+1) ) &
556	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
557	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
558	& + ( ziceload(ji,jj+1) - ziceload(ji,jj) ) )
559	! s-coordinate pressure gradient correction (=0 if z coordinate)
560	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
561	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
562	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
563	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
564	! add to the general momentum trend
565	ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
566	va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
567	END DO
568	END DO
569	!==================================================================================
570	!===== Compute partial cell contribution for the top cell =========================
571	!==================================================================================
572	DO jj = 2, jpjm1
573	DO ji = fs_2, fs_jpim1 ! vector opt.
574	iku = miku(ji,jj) ;
575	zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
576	ze3wu = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
577	! u direction
578	IF ( iku .GT. 1 ) THEN
579	! case iku
580	zhpi(ji,jj,iku) = zcoef0 / e1u(ji,jj) * ze3wu &
581	& * ( rhd (ji+1,jj,iku) + rhd (ji,jj,iku) &
582	& + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
583	! corrective term ( = 0 if z coordinate )
584	zuap = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
585	! zhpi will be added in interior loop
586	ua(ji,jj,iku) = ua(ji,jj,iku) + zuap
587	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
588	IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj) = zhpi(ji,jj,iku)
589
590	! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
591	zhpiint = zcoef0 / e1u(ji,jj) &
592	& * ( fse3w(ji+1,jj ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad) &
593	& + (rhd(ji+1,jj,iku ) + znad) ) * tmask(ji+1,jj,iku) &
594	& - fse3w(ji ,jj ,iku+1) * ( (rhd(ji ,jj,iku+1) + znad) &
595	& + (rhd(ji ,jj,iku ) + znad) ) * tmask(ji ,jj,iku) )
596	zhpi(ji,jj,iku+1) = zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint
597	END IF
598
599	! v direction
600	ikv = mikv(ji,jj)
601	ze3wv = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
602	IF ( ikv .GT. 1 ) THEN
603	! case ikv
604	zhpj(ji,jj,ikv) = zcoef0 / e2v(ji,jj) * ze3wv &
605	& * ( rhd(ji,jj+1,ikv) + rhd (ji,jj,ikv) &
606	& + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
607	! corrective term ( = 0 if z coordinate )
608	zvap = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
609	! zhpi will be added in interior loop
610	va(ji,jj,ikv) = va(ji,jj,ikv) + zvap
611	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
612	IF (mbkv(ji,jj) == ikv + 1) zpshpj(ji,jj) = zhpj(ji,jj,ikv)
613
614	! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
615	zhpjint = zcoef0 / e2v(ji,jj) &
616	& * ( fse3w(ji ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad) &
617	& + (rhd(ji,jj+1,ikv ) + znad) ) * tmask(ji,jj+1,ikv) &
618	& - fse3w(ji ,jj ,ikv+1) * ( (rhd(ji,jj ,ikv+1) + znad) &
619	& + (rhd(ji,jj ,ikv ) + znad) ) * tmask(ji,jj ,ikv) )
620	zhpj(ji,jj,ikv+1) = zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
621	END IF
622	END DO
623	END DO
624
625	!==================================================================================
626	!===== Compute interior value =====================================================
627	!==================================================================================
628
629	DO jj = 2, jpjm1
630	DO ji = fs_2, fs_jpim1 ! vector opt.
631	iku=miku(ji,jj); ikv=mikv(ji,jj)
632	DO jk = 2, jpkm1
633	! hydrostatic pressure gradient along s-surfaces
634	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
635	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1) &
636	& + zcoef0 / e1u(ji,jj) &
637	& * ( fse3w(ji+1,jj ,jk) * ( (rhd(ji+1,jj,jk ) + znad) &
638	& + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1) &
639	& - fse3w(ji ,jj ,jk) * ( (rhd(ji ,jj,jk ) + znad) &
640	& + (rhd(ji ,jj,jk-1) + znad) ) * tmask(ji ,jj,jk-1) )
641	! s-coordinate pressure gradient correction
642	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
643	zuap = - zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
644	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
645	ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
646
647	! hydrostatic pressure gradient along s-surfaces
648	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
649	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1) &
650	& + zcoef0 / e2v(ji,jj) &
651	& * ( fse3w(ji ,jj+1,jk) * ( (rhd(ji,jj+1,jk ) + znad) &
652	& + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1) &
653	& - fse3w(ji ,jj ,jk) * ( (rhd(ji,jj ,jk ) + znad) &
654	& + (rhd(ji,jj ,jk-1) + znad) ) * tmask(ji,jj ,jk-1) )
655	! s-coordinate pressure gradient correction
656	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
657	zvap = - zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
658	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
659	! add to the general momentum trend
660	va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
661	END DO
662	END DO
663	END DO
664
665	!==================================================================================
666	!===== Compute bottom cell contribution (partial cell) ============================
667	!==================================================================================
668
669	DO jj = 2, jpjm1
670	DO ji = 2, jpim1
671	iku = mbku(ji,jj)
672	ikv = mbkv(ji,jj)
673
674	IF (iku .GT. 1) THEN
675	! remove old value (interior case)
676	zuap = -zcoef0 * ( rhd (ji+1,jj ,iku) + rhd (ji,jj,iku) + 2._wp * znad ) &
677	& * ( fsde3w(ji+1,jj ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
678	ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
679	! put new value
680	! -zpshpi to avoid double contribution of the partial step in the top layer
681	zuap = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj) / e1u(ji,jj)
682	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj)
683	ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
684	END IF
685	! v direction
686	IF (ikv .GT. 1) THEN
687	! remove old value (interior case)
688	zvap = -zcoef0 * ( rhd (ji ,jj+1,ikv) + rhd (ji,jj,ikv) + 2._wp * znad ) &
689	& * ( fsde3w(ji ,jj+1,ikv) - fsde3w(ji,jj,ikv) ) / e2v(ji,jj)
690	va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
691	! put new value
692	! -zpshpj to avoid double contribution of the partial step in the top layer
693	zvap = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj) / e2v(ji,jj)
694	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)
695	va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
696	END IF
697	END DO
698	END DO
699
700	! set back to original density value into the ice shelf cell (maybe useless because it is masked)
701	rhd = zrhd
702	!
703	CALL wrk_dealloc( jpi,jpj,2, ztstop)
704	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
705	CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
706	!
707	END SUBROUTINE hpg_isf
708
709
710	SUBROUTINE hpg_djc( kt )
711	!!---------------------------------------------------------------------
712	!! * ROUTINE hpg_djc *
713	!!
714	!! ** Method : Density Jacobian with Cubic polynomial scheme
715	!!
716	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
717	!!----------------------------------------------------------------------
718	INTEGER, INTENT(in) :: kt ! ocean time-step index
719	!!
720	INTEGER :: ji, jj, jk ! dummy loop indices
721	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
722	REAL(wp) :: z1_10, cffu, cffx ! " "
723	REAL(wp) :: z1_12, cffv, cffy ! " "
724	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
725	REAL(wp), POINTER, DIMENSION(:,:,:) :: dzx, dzy, dzz, dzu, dzv, dzw
726	REAL(wp), POINTER, DIMENSION(:,:,:) :: drhox, drhoy, drhoz, drhou, drhov, drhow
727	REAL(wp), POINTER, DIMENSION(:,:,:) :: rho_i, rho_j, rho_k
728	!!----------------------------------------------------------------------
729	!
730	CALL wrk_alloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
731	CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
732	CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
733	!
734
735	IF( kt == nit000 ) THEN
736	IF(lwp) WRITE(numout,*)
737	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
738	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
739	ENDIF
740
741	! Local constant initialization
742	zcoef0 = - grav * 0.5_wp
743	z1_10 = 1._wp / 10._wp
744	z1_12 = 1._wp / 12._wp
745
746	!----------------------------------------------------------------------------------------
747	! compute and store in provisional arrays elementary vertical and horizontal differences
748	!----------------------------------------------------------------------------------------
749
750	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
751
752	DO jk = 2, jpkm1
753	DO jj = 2, jpjm1
754	DO ji = fs_2, fs_jpim1 ! vector opt.
755	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
756	dzz (ji,jj,jk) = fsde3w(ji ,jj ,jk) - fsde3w(ji,jj,jk-1)
757	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
758	dzx (ji,jj,jk) = fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk )
759	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
760	dzy (ji,jj,jk) = fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk )
761	END DO
762	END DO
763	END DO
764
765	!-------------------------------------------------------------------------
766	! compute harmonic averages using eq. 5.18
767	!-------------------------------------------------------------------------
768	zep = 1.e-15
769
770	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
771	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
772
773	DO jk = 2, jpkm1
774	DO jj = 2, jpjm1
775	DO ji = fs_2, fs_jpim1 ! vector opt.
776	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
777
778	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
779	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
780
781	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
782	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
783
784	IF( cffw > zep) THEN
785	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
786	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
787	ELSE
788	drhow(ji,jj,jk) = 0._wp
789	ENDIF
790
791	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
792	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
793
794	IF( cffu > zep ) THEN
795	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
796	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
797	ELSE
798	drhou(ji,jj,jk ) = 0._wp
799	ENDIF
800
801	IF( cffx > zep ) THEN
802	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
803	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
804	ELSE
805	dzu(ji,jj,jk) = 0._wp
806	ENDIF
807
808	IF( cffv > zep ) THEN
809	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
810	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
811	ELSE
812	drhov(ji,jj,jk) = 0._wp
813	ENDIF
814
815	IF( cffy > zep ) THEN
816	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
817	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
818	ELSE
819	dzv(ji,jj,jk) = 0._wp
820	ENDIF
821
822	END DO
823	END DO
824	END DO
825
826	!----------------------------------------------------------------------------------
827	! apply boundary conditions at top and bottom using 5.36-5.37
828	!----------------------------------------------------------------------------------
829	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
830	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
831	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
832
833	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
834	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
835	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
836
837
838	!--------------------------------------------------------------
839	! Upper half of top-most grid box, compute and store
840	!-------------------------------------------------------------
841
842	!!bug gm : e3w-de3w = 0.5*e3w .... and de3w(2)-de3w(1)=e3w(2) .... to be verified
843	! true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
844
845	DO jj = 2, jpjm1
846	DO ji = fs_2, fs_jpim1 ! vector opt.
847	rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) ) &
848	& * ( rhd(ji,jj,1) &
849	& + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) ) &
850	& * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) ) &
851	& / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) ) )
852	END DO
853	END DO
854
855	!!bug gm : here also, simplification is possible
856	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
857
858	DO jk = 2, jpkm1
859	DO jj = 2, jpjm1
860	DO ji = fs_2, fs_jpim1 ! vector opt.
861
862	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
863	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) ) &
864	& - grav * z1_10 * ( &
865	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
866	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
867	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
868	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
869	& )
870
871	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
872	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) ) &
873	& - grav* z1_10 * ( &
874	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
875	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
876	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
877	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
878	& )
879
880	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
881	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) ) &
882	& - grav* z1_10 * ( &
883	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
884	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
885	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
886	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
887	& )
888
889	END DO
890	END DO
891	END DO
892	CALL lbc_lnk(rho_k,'W',1.)
893	CALL lbc_lnk(rho_i,'U',1.)
894	CALL lbc_lnk(rho_j,'V',1.)
895
896
897	! ---------------
898	! Surface value
899	! ---------------
900	DO jj = 2, jpjm1
901	DO ji = fs_2, fs_jpim1 ! vector opt.
902	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
903	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
904	! add to the general momentum trend
905	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
906	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
907	END DO
908	END DO
909
910	! ----------------
911	! interior value (2=<jk=<jpkm1)
912	! ----------------
913	DO jk = 2, jpkm1
914	DO jj = 2, jpjm1
915	DO ji = fs_2, fs_jpim1 ! vector opt.
916	! hydrostatic pressure gradient along s-surfaces
917	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
918	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
919	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) / e1u(ji,jj)
920	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
921	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
922	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) / e2v(ji,jj)
923	! add to the general momentum trend
924	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
925	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
926	END DO
927	END DO
928	END DO
929	!
930	CALL wrk_dealloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
931	CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
932	CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
933	!
934	END SUBROUTINE hpg_djc
935
936
937	SUBROUTINE hpg_prj( kt )
938	!!---------------------------------------------------------------------
939	!! * ROUTINE hpg_prj *
940	!!
941	!! ** Method : s-coordinate case.
942	!! A Pressure-Jacobian horizontal pressure gradient method
943	!! based on the constrained cubic-spline interpolation for
944	!! all vertical coordinate systems
945	!!
946	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
947	!!----------------------------------------------------------------------
948	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
949	INTEGER, INTENT(in) :: kt ! ocean time-step index
950	!!
951	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
952	REAL(wp) :: zcoef0, znad ! temporary scalars
953	!!
954	!! The local variables for the correction term
955	INTEGER :: jk1, jis, jid, jjs, jjd
956	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
957	REAL(wp) :: zrhdt1
958	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
959	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdept, zrhh
960	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
961	REAL(wp), POINTER, DIMENSION(:,:) :: zsshu_n, zsshv_n
962	!!----------------------------------------------------------------------
963	!
964	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
965	CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
966	CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
967	!
968	IF( kt == nit000 ) THEN
969	IF(lwp) WRITE(numout,*)
970	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
971	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
972	ENDIF
973
974	!!----------------------------------------------------------------------
975	! Local constant initialization
976	zcoef0 = - grav
977	znad = 0.0_wp
978	IF( lk_vvl ) znad = 1._wp
979
980	! Clean 3-D work arrays
981	zhpi(:,:,:) = 0._wp
982	zrhh(:,:,:) = rhd(:,:,:)
983
984	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
985	DO jj = 1, jpj
986	DO ji = 1, jpi
987	jk = mbathy(ji,jj)
988	IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
989	ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
990	ELSE IF(jk < jpkm1) THEN
991	DO jkk = jk+1, jpk
992	zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk), fsde3w(ji,jj,jkk-1), &
993	fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
994	END DO
995	ENDIF
996	END DO
997	END DO
998
999	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1000	DO jj = 1, jpj
1001	DO ji = 1, jpi
1002	zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1003	END DO
1004	END DO
1005
1006	DO jk = 2, jpk
1007	DO jj = 1, jpj
1008	DO ji = 1, jpi
1009	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1010	END DO
1011	END DO
1012	END DO
1013
1014	fsp(:,:,:) = zrhh (:,:,:)
1015	xsp(:,:,:) = zdept(:,:,:)
1016
1017	! Construct the vertical density profile with the
1018	! constrained cubic spline interpolation
1019	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1020	CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1021
1022	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1023	DO jj = 2, jpj
1024	DO ji = 2, jpi
1025	zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1026	bsp(ji,jj,1), csp(ji,jj,1), &
1027	dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1028
1029	! assuming linear profile across the top half surface layer
1030	zhpi(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) * zrhdt1
1031	END DO
1032	END DO
1033
1034	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1035	DO jk = 2, jpkm1
1036	DO jj = 2, jpj
1037	DO ji = 2, jpi
1038	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1039	integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1040	asp(ji,jj,jk-1), bsp(ji,jj,jk-1), &
1041	csp(ji,jj,jk-1), dsp(ji,jj,jk-1))
1042	END DO
1043	END DO
1044	END DO
1045
1046	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1047
1048	! Prepare zsshu_n and zsshv_n
1049	DO jj = 2, jpjm1
1050	DO ji = 2, jpim1
1051	zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1052	& r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1053	zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1054	& r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1055	END DO
1056	END DO
1057
1058	DO jj = 2, jpjm1
1059	DO ji = 2, jpim1
1060	zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad)
1061	zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1062	END DO
1063	END DO
1064
1065	DO jk = 2, jpkm1
1066	DO jj = 2, jpjm1
1067	DO ji = 2, jpim1
1068	zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1069	zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1070	END DO
1071	END DO
1072	END DO
1073
1074	DO jk = 1, jpkm1
1075	DO jj = 2, jpjm1
1076	DO ji = 2, jpim1
1077	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1078	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1079	END DO
1080	END DO
1081	END DO
1082
1083	DO jk = 1, jpkm1
1084	DO jj = 2, jpjm1
1085	DO ji = 2, jpim1
1086	zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1087	zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1088	zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1089	zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1090	END DO
1091	END DO
1092	END DO
1093
1094
1095	DO jk = 1, jpkm1
1096	DO jj = 2, jpjm1
1097	DO ji = 2, jpim1
1098	zpwes = 0._wp; zpwed = 0._wp
1099	zpnss = 0._wp; zpnsd = 0._wp
1100	zuijk = zu(ji,jj,jk)
1101	zvijk = zv(ji,jj,jk)
1102
1103	!!!!! for u equation
1104	IF( jk <= mbku(ji,jj) ) THEN
1105	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1106	jis = ji + 1; jid = ji
1107	ELSE
1108	jis = ji; jid = ji +1
1109	ENDIF
1110
1111	! integrate the pressure on the shallow side
1112	jk1 = jk
1113	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1114	IF( jk1 == mbku(ji,jj) ) THEN
1115	zuijk = -zdept(jis,jj,jk1)
1116	EXIT
1117	ENDIF
1118	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1119	zpwes = zpwes + &
1120	integ_spline(zdept(jis,jj,jk1), zdeps, &
1121	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1122	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1123	jk1 = jk1 + 1
1124	END DO
1125
1126	! integrate the pressure on the deep side
1127	jk1 = jk
1128	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1129	IF( jk1 == 1 ) THEN
1130	zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1131	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1132	bsp(jid,jj,1), csp(jid,jj,1), &
1133	dsp(jid,jj,1)) * zdeps
1134	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1135	EXIT
1136	ENDIF
1137	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1138	zpwed = zpwed + &
1139	integ_spline(zdeps, zdept(jid,jj,jk1), &
1140	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1141	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1142	jk1 = jk1 - 1
1143	END DO
1144
1145	! update the momentum trends in u direction
1146
1147	zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1148	IF( lk_vvl ) THEN
1149	zdpdx2 = zcoef0 / e1u(ji,jj) * &
1150	( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1151	ELSE
1152	zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1153	ENDIF
1154
1155	ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1156	& umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1157	ENDIF
1158
1159	!!!!! for v equation
1160	IF( jk <= mbkv(ji,jj) ) THEN
1161	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1162	jjs = jj + 1; jjd = jj
1163	ELSE
1164	jjs = jj ; jjd = jj + 1
1165	ENDIF
1166
1167	! integrate the pressure on the shallow side
1168	jk1 = jk
1169	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1170	IF( jk1 == mbkv(ji,jj) ) THEN
1171	zvijk = -zdept(ji,jjs,jk1)
1172	EXIT
1173	ENDIF
1174	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1175	zpnss = zpnss + &
1176	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1177	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1178	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1179	jk1 = jk1 + 1
1180	END DO
1181
1182	! integrate the pressure on the deep side
1183	jk1 = jk
1184	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1185	IF( jk1 == 1 ) THEN
1186	zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1187	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1188	bsp(ji,jjd,1), csp(ji,jjd,1), &
1189	dsp(ji,jjd,1) ) * zdeps
1190	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1191	EXIT
1192	ENDIF
1193	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1194	zpnsd = zpnsd + &
1195	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1196	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1197	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1198	jk1 = jk1 - 1
1199	END DO
1200
1201
1202	! update the momentum trends in v direction
1203
1204	zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1205	IF( lk_vvl ) THEN
1206	zdpdy2 = zcoef0 / e2v(ji,jj) * &
1207	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1208	ELSE
1209	zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1210	ENDIF
1211
1212	va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1213	& vmask(ji,jj,jk)tmask(ji,jj,jk)tmask(ji,jj+1,jk)
1214	ENDIF
1215
1216
1217	END DO
1218	END DO
1219	END DO
1220	!
1221	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1222	CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1223	CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1224	!
1225	END SUBROUTINE hpg_prj
1226
1227
1228	SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1229	!!----------------------------------------------------------------------
1230	!! * ROUTINE cspline *
1231	!!
1232	!! ** Purpose : constrained cubic spline interpolation
1233	!!
1234	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1235	!!
1236	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1237	!!----------------------------------------------------------------------
1238	IMPLICIT NONE
1239	REAL(wp), DIMENSION(:,:,:), INTENT(in) :: fsp, xsp ! value and coordinate
1240	REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1241	! the interpoated function
1242	INTEGER, INTENT(in) :: polynomial_type ! 1: cubic spline
1243	! 2: Linear
1244	!
1245	INTEGER :: ji, jj, jk ! dummy loop indices
1246	INTEGER :: jpi, jpj, jpkm1
1247	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1248	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1249	REAL(wp) :: zdf(size(fsp,3))
1250	!!----------------------------------------------------------------------
1251
1252	jpi = size(fsp,1)
1253	jpj = size(fsp,2)
1254	jpkm1 = size(fsp,3) - 1
1255
1256
1257	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1258	DO ji = 1, jpi
1259	DO jj = 1, jpj
1260	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1261	! DO jk = 2, jpkm1-1
1262	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1263	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1264	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1265	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1266	!
1267	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1268	!
1269	! IF(zdf1 * zdf2 <= 0._wp) THEN
1270	! zdf(jk) = 0._wp
1271	! ELSE
1272	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1273	! ENDIF
1274	! END DO
1275
1276	!!Simply geometric average
1277	DO jk = 2, jpkm1-1
1278	zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1279	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1280
1281	IF(zdf1 * zdf2 <= 0._wp) THEN
1282	zdf(jk) = 0._wp
1283	ELSE
1284	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1285	ENDIF
1286	END DO
1287
1288	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1289	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1290	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1291	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1292	& 0.5_wp * zdf(jpkm1 - 1)
1293
1294	DO jk = 1, jpkm1 - 1
1295	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1296	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1297	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1298	zddf1 = -2._wp * ztmp1 + ztmp2
1299	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1300	zddf2 = 2._wp * ztmp1 - ztmp2
1301
1302	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1303	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1304	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1305	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1306	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1307	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1308	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1309	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1310	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1311	END DO
1312	END DO
1313	END DO
1314
1315	ELSE IF (polynomial_type == 2) THEN ! Linear
1316	DO ji = 1, jpi
1317	DO jj = 1, jpj
1318	DO jk = 1, jpkm1-1
1319	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1320	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1321
1322	dsp(ji,jj,jk) = 0._wp
1323	csp(ji,jj,jk) = 0._wp
1324	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1325	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1326	END DO
1327	END DO
1328	END DO
1329
1330	ELSE
1331	CALL ctl_stop( 'invalid polynomial type in cspline' )
1332	ENDIF
1333
1334	END SUBROUTINE cspline
1335
1336
1337	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1338	!!----------------------------------------------------------------------
1339	!! * ROUTINE interp1 *
1340	!!
1341	!! ** Purpose : 1-d linear interpolation
1342	!!
1343	!! ** Method : interpolation is straight forward
1344	!! extrapolation is also permitted (no value limit)
1345	!!----------------------------------------------------------------------
1346	IMPLICIT NONE
1347	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1348	REAL(wp) :: f ! result of the interpolation (extrapolation)
1349	REAL(wp) :: zdeltx
1350	!!----------------------------------------------------------------------
1351
1352	zdeltx = xr - xl
1353	IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1354	f = 0.5_wp * (fl + fr)
1355	ELSE
1356	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1357	ENDIF
1358
1359	END FUNCTION interp1
1360
1361
1362	FUNCTION interp2(x, a, b, c, d) RESULT(f)
1363	!!----------------------------------------------------------------------
1364	!! * ROUTINE interp1 *
1365	!!
1366	!! ** Purpose : 1-d constrained cubic spline interpolation
1367	!!
1368	!! ** Method : cubic spline interpolation
1369	!!
1370	!!----------------------------------------------------------------------
1371	IMPLICIT NONE
1372	REAL(wp), INTENT(in) :: x, a, b, c, d
1373	REAL(wp) :: f ! value from the interpolation
1374	!!----------------------------------------------------------------------
1375
1376	f = a + x* ( b + x * ( c + d * x ) )
1377
1378	END FUNCTION interp2
1379
1380
1381	FUNCTION interp3(x, a, b, c, d) RESULT(f)
1382	!!----------------------------------------------------------------------
1383	!! * ROUTINE interp1 *
1384	!!
1385	!! ** Purpose : Calculate the first order of deriavtive of
1386	!! a cubic spline function y=a+bx+cx^2+d*x^3
1387	!!
1388	!! ** Method : f=dy/dx=b+2cx+3dx^2
1389	!!
1390	!!----------------------------------------------------------------------
1391	IMPLICIT NONE
1392	REAL(wp), INTENT(in) :: x, a, b, c, d
1393	REAL(wp) :: f ! value from the interpolation
1394	!!----------------------------------------------------------------------
1395
1396	f = b + x * ( 2._wp * c + 3._wp * d * x)
1397
1398	END FUNCTION interp3
1399
1400
1401	FUNCTION integ_spline(xl, xr, a, b, c, d) RESULT(f)
1402	!!----------------------------------------------------------------------
1403	!! * ROUTINE interp1 *
1404	!!
1405	!! ** Purpose : 1-d constrained cubic spline integration
1406	!!
1407	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1408	!!
1409	!!----------------------------------------------------------------------
1410	IMPLICIT NONE
1411	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1412	REAL(wp) :: za1, za2, za3
1413	REAL(wp) :: f ! integration result
1414	!!----------------------------------------------------------------------
1415
1416	za1 = 0.5_wp * b
1417	za2 = c / 3.0_wp
1418	za3 = 0.25_wp * d
1419
1420	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1421	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1422
1423	END FUNCTION integ_spline
1424
1425	!!======================================================================
1426	END MODULE dynhpg
1427

Note: See TracBrowser for help on using the repository browser.

Download in other formats: