New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 6515

Last change on this file since 6515 was 6515, checked in by clem, 8 years ago

implement several developments for LIM3: new advection scheme (ultimate-macho, not yet perfect) ; lateral ice melt ; enabling/disabling thermo and dyn with namelist options ; simplifications (including a clarified namelist)
  • Property svn:keywords set to Id
File size: 36.3 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! LIM: sea-ice variables
25   USE sbc_oce        ! Surface boundary condition: ocean fields
26   USE sbc_ice        ! Surface boundary condition: ice fields
27   USE thd_ice        ! LIM thermodynamic sea-ice variables
28   USE dom_ice        ! LIM sea-ice domain
29   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
30   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
31   USE limthd_da      ! LIM: thermodynamics, lateral melting
32   USE limthd_sal     ! LIM: thermodynamics, ice salinity
33   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
34   USE limthd_lac     ! LIM-3 lateral accretion
35   USE limitd_th      ! remapping thickness distribution
36   USE limtab         ! LIM: 1D <==> 2D transformation
37   USE limvar         ! LIM: sea-ice variables
38   USE lbclnk         ! lateral boundary condition - MPP links
39   USE lib_mpp        ! MPP library
40   USE wrk_nemo       ! work arrays
41   USE in_out_manager ! I/O manager
42   USE prtctl         ! Print control
43   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
44   USE timing         ! Timing
45   USE limcons        ! conservation tests
46   USE limctl
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   lim_thd         ! called by limstp module
52   PUBLIC   lim_thd_init    ! called by sbc_lim_init
53
54   !! * Substitutions
55#  include "domzgr_substitute.h90"
56#  include "vectopt_loop_substitute.h90"
57   !!----------------------------------------------------------------------
58   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
59   !! $Id$
60   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE lim_thd( kt )
65      !!-------------------------------------------------------------------
66      !!                ***  ROUTINE lim_thd  ***       
67      !! 
68      !! ** Purpose : This routine manages ice thermodynamics
69      !!         
70      !! ** Action : - Initialisation of some variables
71      !!             - Some preliminary computation (oceanic heat flux
72      !!               at the ice base, snow acc.,heat budget of the leads)
73      !!             - selection of the icy points and put them in an array
74      !!             - call lim_thd_dif  for vertical heat diffusion
75      !!             - call lim_thd_dh   for vertical ice growth and melt
76      !!             - call lim_thd_ent  for enthalpy remapping
77      !!             - call lim_thd_sal  for ice desalination
78      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
79      !!             - back to the geographic grid
80      !!     
81      !! ** References :
82      !!---------------------------------------------------------------------
83      INTEGER, INTENT(in) :: kt    ! number of iteration
84      !!
85      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
86      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
87      INTEGER  :: ii, ij           ! temporary dummy loop index
88      REAL(wp) :: zfric_u, zqld, zqfr
89      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
90      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
91      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
92      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
93      !
94      !!-------------------------------------------------------------------
95
96      IF( nn_timing == 1 )  CALL timing_start('limthd')
97
98      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
99
100      IF( kt == nit000 .AND. lwp ) THEN
101         WRITE(numout,*)'' 
102         WRITE(numout,*)' lim_thd '
103         WRITE(numout,*)' ~~~~~~~~'
104      ENDIF
105     
106      ! conservation test
107      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
108
109      CALL lim_var_glo2eqv
110
111      !---------------------------------------------!
112      ! computation of friction velocity at T points
113      !---------------------------------------------!
114      IF( ln_limdyn ) THEN
115         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
116         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
117         DO jj = 2, jpjm1 
118            DO ji = fs_2, fs_jpim1
119               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
120                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
121                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
122            END DO
123         END DO
124      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
125         DO jj = 2, jpjm1
126            DO ji = fs_2, fs_jpim1
127               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
128                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
129                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
130            END DO
131         END DO
132      ENDIF
133      CALL lbc_lnk( zfric, 'T',  1. )
134      !
135      !----------------------------------!
136      ! Initialization and units change
137      !----------------------------------!
138      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
139
140      ! Change the units of heat content; from J/m2 to J/m3
141      DO jl = 1, jpl
142         DO jk = 1, nlay_i
143            DO jj = 1, jpj
144               DO ji = 1, jpi
145                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
146                  !Energy of melting q(S,T) [J.m-3]
147                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
148               END DO
149            END DO
150         END DO
151         DO jk = 1, nlay_s
152            DO jj = 1, jpj
153               DO ji = 1, jpi
154                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
155                  !Energy of melting q(S,T) [J.m-3]
156                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
157               END DO
158            END DO
159         END DO
160      END DO
161
162      !--------------------------------------------------------------------!
163      ! Partial computation of forcing for the thermodynamic sea ice model
164      !--------------------------------------------------------------------!
165      DO jj = 1, jpj
166         DO ji = 1, jpi
167            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
168            !
169            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
170            !           !  practically no "direct lateral ablation"
171            !           
172            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
173            !           !  temperature and turbulent mixing (McPhee, 1992)
174            !
175            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
176            zqld =  tmask(ji,jj,1) * rdt_ice *  &
177               &    ( pfrld(ji,jj) * qsr_oce(ji,jj) * frq_m(ji,jj) + pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
178
179            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
180            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
181
182            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
183            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
184            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
185            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
186            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
187            !                        the freezing point, so that we do not have SST < T_freeze
188            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
189
190            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
191            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
192
193            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
194            IF( zqld > 0._wp ) THEN
195               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
196               qlead(ji,jj) = 0._wp
197            ELSE
198               fhld (ji,jj) = 0._wp
199            ENDIF
200            !
201            ! Net heat flux on top of the ice-ocean [W.m-2]
202            ! ---------------------------------------------
203            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
204         END DO
205      END DO
206     
207      ! In case we bypass open-water ice formation
208      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
209      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
210      IF( .NOT. ln_limdH )  hfx_in(:,:) = pfrld(:,:) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
211      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
212
213      ! ---------------------------------------------------------------------
214      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
215      ! ---------------------------------------------------------------------
216      !     First  step here              :  non solar + precip - qlead - qturb
217      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
218      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
219      DO jj = 1, jpj
220         DO ji = 1, jpi
221            hfx_out(ji,jj) =   pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
222               &             - qlead(ji,jj) * r1_rdtice                         &  ! heat flux taken from the ocean where there is open water ice formation
223               &             - at_i(ji,jj) * fhtur(ji,jj)                       &  ! heat flux taken by turbulence
224               &             - at_i(ji,jj) *  fhld(ji,jj)                          ! heat flux taken during bottom growth/melt
225                                                                                   !    (fhld should be 0 while bott growth)
226         END DO
227      END DO
228         
229      !------------------------------------------------------------------------------!
230      ! Thermodynamic computation (only on grid points covered by ice)
231      !------------------------------------------------------------------------------!
232      DO jl = 1, jpl      !loop over ice categories
233
234         ! select ice covered grid points
235         nbpb = 0
236         DO jj = 1, jpj
237            DO ji = 1, jpi
238               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
239                  nbpb      = nbpb  + 1
240                  npb(nbpb) = (jj - 1) * jpi + ji
241               ENDIF
242            END DO
243         END DO
244
245         ! debug point to follow
246         jiindex_1d = 0
247         IF( ln_icectl ) THEN
248            DO ji = mi0(iiceprt), mi1(iiceprt)
249               DO jj = mj0(jiceprt), mj1(jiceprt)
250                  jiindex_1d = (jj - 1) * jpi + ji
251                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
252               END DO
253            END DO
254         ENDIF
255
256         IF( lk_mpp )         CALL mpp_ini_ice( nbpb , numout )
257
258         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
259            !                                                               
260            s_i_new   (:) = 0._wp ; dh_s_tot (:) = 0._wp                     ! --- some init --- !
261            dh_i_surf (:) = 0._wp ; dh_i_bott(:) = 0._wp
262            dh_snowice(:) = 0._wp ; dh_i_sub (:) = 0._wp
263
264                              CALL lim_thd_1d2d( nbpb, jl, 1 )               ! --- Move to 1D arrays --- !
265            !
266            IF( ln_limdH )    CALL lim_thd_dif( 1, nbpb )                    ! --- Ice/Snow Temperature profile --- !
267            !
268            IF( ln_limdH )    CALL lim_thd_dh( 1, nbpb )                     ! --- Ice/Snow thickness --- !   
269            !
270            IF( ln_limdH )    CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) )  ! --- Ice enthalpy remapping --- !
271            !
272                              CALL lim_thd_sal( 1, nbpb )                    ! --- Ice salinity --- !   
273            !
274                              CALL lim_thd_temp( 1, nbpb )                   ! --- temperature update --- !
275            !
276            IF( ln_limdH ) THEN
277               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
278                              CALL lim_thd_lam( 1, nbpb )                    ! --- extra lateral melting if monocat --- !
279               END IF
280            END IF
281            !
282                              CALL lim_thd_1d2d( nbpb, jl, 2 )               ! --- Move to 2D arrays --- !
283            !
284            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
285         ENDIF
286         !
287      END DO !jl
288
289      IF( ln_limdA)           CALL lim_thd_da                                ! --- lateral melting --- !
290
291      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
292      DO jl = 1, jpl
293         DO jk = 1, nlay_i
294            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
295         END DO
296         DO jk = 1, nlay_s
297            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
298         END DO
299      END DO
300 
301      ! Change thickness to volume
302      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
303      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
304      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
305
306      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
307      DO jl  = 1, jpl
308         DO jj = 1, jpj
309            DO ji = 1, jpi
310               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
311               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
312            END DO
313         END DO
314      END DO
315
316      CALL lim_var_zapsmall
317
318      ! control checks
319      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
320      !
321      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
322
323      !------------------------------------------------!
324      !  Transport ice between thickness categories
325      !------------------------------------------------!
326      ! Given thermodynamic growth rates, transport ice between thickness categories.
327      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
328
329      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
330
331      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
332
333      !------------------------------------------------!
334      !  Add frazil ice growing in leads
335      !------------------------------------------------!
336      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
337
338      IF( ln_limdO )     CALL lim_thd_lac
339     
340      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
341
342      ! Control print
343      IF(ln_ctl) THEN
344         CALL lim_var_glo2eqv
345
346         CALL prt_ctl_info(' ')
347         CALL prt_ctl_info(' - Cell values : ')
348         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
349         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_itd_th  : cell area :')
350         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
351         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
352         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
353         DO jl = 1, jpl
354            CALL prt_ctl_info(' ')
355            CALL prt_ctl_info(' - Category : ', ivar1=jl)
356            CALL prt_ctl_info('   ~~~~~~~~~~')
357            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
358            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
359            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
360            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
361            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
362            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
363            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
364            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
365            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
366            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
367            DO jk = 1, nlay_i
368               CALL prt_ctl_info(' ')
369               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
370               CALL prt_ctl_info('   ~~~~~~~')
371               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
372               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
373            END DO
374         END DO
375      ENDIF
376      !
377      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
378      !
379      IF( nn_timing == 1 )  CALL timing_stop('limthd')
380
381   END SUBROUTINE lim_thd 
382
383 
384   SUBROUTINE lim_thd_temp( kideb, kiut )
385      !!-----------------------------------------------------------------------
386      !!                   ***  ROUTINE lim_thd_temp ***
387      !!                 
388      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
389      !!
390      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
391      !!-------------------------------------------------------------------
392      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
393      !!
394      INTEGER  ::   ji, jk   ! dummy loop indices
395      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
396      !!-------------------------------------------------------------------
397      ! Recover ice temperature
398      DO jk = 1, nlay_i
399         DO ji = kideb, kiut
400            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
401            ! Conversion q(S,T) -> T (second order equation)
402            zaaa          =  cpic
403            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
404            zccc          =  lfus * ( ztmelts - rt0 )
405            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
406            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
407           
408            ! mask temperature
409            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
410            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
411         END DO
412      END DO
413
414   END SUBROUTINE lim_thd_temp
415
416   SUBROUTINE lim_thd_lam( kideb, kiut )
417      !!-----------------------------------------------------------------------
418      !!                   ***  ROUTINE lim_thd_lam ***
419      !!                 
420      !! ** Purpose :   Lateral melting in case monocategory
421      !!                          ( dA = A/2h dh )
422      !!-----------------------------------------------------------------------
423      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
424      INTEGER             ::   ji                 ! dummy loop indices
425      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
426      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
427      REAL(wp)            ::   zvi, zvs           ! ice/snow volumes
428
429      DO ji = kideb, kiut
430         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
431         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
432            zvi          = a_i_1d(ji) * ht_i_1d(ji)
433            zvs          = a_i_1d(ji) * ht_s_1d(ji)
434            ! lateral melting = concentration change
435            zhi_bef     = ht_i_1d(ji) - zdh_mel
436            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
437            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
438            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
439            ! adjust thickness
440            ht_i_1d(ji) = zvi / a_i_1d(ji)           
441            ht_s_1d(ji) = zvs / a_i_1d(ji)           
442            ! retrieve total concentration
443            at_i_1d(ji) = a_i_1d(ji)
444         END IF
445      END DO
446     
447   END SUBROUTINE lim_thd_lam
448
449   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
450      !!-----------------------------------------------------------------------
451      !!                   ***  ROUTINE lim_thd_1d2d ***
452      !!                 
453      !! ** Purpose :   move arrays from 1d to 2d and the reverse
454      !!-----------------------------------------------------------------------
455      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D
456                                        ! 2= from 1D to 2D
457      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
458      INTEGER, INTENT(in) ::   jl       ! ice cat
459      INTEGER             ::   jk       ! dummy loop indices
460
461      SELECT CASE( kn )
462
463      CASE( 1 )
464
465         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
466         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
467         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
468         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
469         
470         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
471         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
472         DO jk = 1, nlay_s
473            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
474            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
475         END DO
476         DO jk = 1, nlay_i
477            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
478            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
479            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
480         END DO
481         
482         CALL tab_2d_1d( nbpb, qprec_ice_1d(1:nbpb), qprec_ice(:,:) , jpi, jpj, npb(1:nbpb) )
483         CALL tab_2d_1d( nbpb, qevap_ice_1d(1:nbpb), qevap_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
484         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
485         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
486         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
487         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
488         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
489         CALL tab_2d_1d( nbpb, evap_ice_1d (1:nbpb), evap_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
490         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
491         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
492         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
493         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
494         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
495         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
496         
497         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
498         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
499         
500         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
501         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
502         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
503         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
504         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
505         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
506         
507         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
508         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
509         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
510         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
511         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
512         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
513         CALL tab_2d_1d( nbpb, sfx_sub_1d (1:nbpb), sfx_sub         , jpi, jpj,npb(1:nbpb) )
514 
515         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
516         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
517         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
518         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
519         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
520         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
521         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
522         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
523         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
524         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
525         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
526         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
527         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
528
529      CASE( 2 )
530
531         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
532         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
533         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
534         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
535         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
536         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
537         DO jk = 1, nlay_s
538            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
539            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
540         END DO
541         DO jk = 1, nlay_i
542            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
543            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
544            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
545         END DO
546         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
547         
548         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
549         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
550         
551         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
552         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
553         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
554         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
555         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
556         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
557         
558         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
559         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
560         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
561         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
562         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
563         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
564         CALL tab_1d_2d( nbpb, sfx_sub       , npb, sfx_sub_1d(1:nbpb)   , jpi, jpj )       
565 
566         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
567         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
568         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
569         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
570         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
571         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
572         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
573         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
574         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
575         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
576         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
577         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
578         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
579         !
580         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
581         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
582         !         
583      END SELECT
584
585   END SUBROUTINE lim_thd_1d2d
586
587
588   SUBROUTINE lim_thd_init
589      !!-----------------------------------------------------------------------
590      !!                   ***  ROUTINE lim_thd_init ***
591      !!                 
592      !! ** Purpose :   Physical constants and parameters linked to the ice
593      !!              thermodynamics
594      !!
595      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
596      !!              parameter values called at the first timestep (nit000)
597      !!
598      !! ** input   :   Namelist namicether
599      !!-------------------------------------------------------------------
600      INTEGER  ::   ios                 ! Local integer output status for namelist read
601      NAMELIST/namicethd/ rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon,ln_it_qnsice,nn_monocat,  &
602         &                ln_limdH, rn_betas,                                                          &
603         &                ln_limdA, rn_beta, rn_dmin,                                                  &
604         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin
605      !!-------------------------------------------------------------------
606      !
607      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
608      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
609901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
610
611      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
612      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
613902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
614      IF(lwm) WRITE ( numoni, namicethd )
615      !
616      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
617         nn_monocat = 0
618         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
619      ENDIF
620      !
621      IF(lwp) THEN                          ! control print
622         WRITE(numout,*)
623         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
624         WRITE(numout,*) '~~~~~~~~~~~~~'
625         WRITE(numout,*)'   -- limthd_dif --'
626         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
627         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
628         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
629         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
630         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
631         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
632         WRITE(numout,*)'   -- limthd_dh --'
633         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
634         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
635         WRITE(numout,*)'   -- limthd_da --'
636         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
637         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
638         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
639         WRITE(numout,*)'   -- limthd_lac --'
640         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
641         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
642         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
643         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
644         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
645         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
646         WRITE(numout,*)'   -- limitd_th --'
647         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
648         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
649      ENDIF
650      !
651   END SUBROUTINE lim_thd_init
652
653#else
654   !!----------------------------------------------------------------------
655   !!   Default option         Dummy module          NO  LIM3 sea-ice model
656   !!----------------------------------------------------------------------
657#endif
658
659   !!======================================================================
660END MODULE limthd
Note: See TracBrowser for help on using the repository browser.