New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 6746

Last change on this file since 6746 was 6746, checked in by clem, 8 years ago

landfast ice parameterization + update from trunk + removing useless dom_ice.F90 and limmsh.F90 and limwri_dimg.h90
  • Property svn:keywords set to Id
File size: 36.3 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! LIM: sea-ice variables
25   USE sbc_oce        ! Surface boundary condition: ocean fields
26   USE sbc_ice        ! Surface boundary condition: ice fields
27   USE thd_ice        ! LIM thermodynamic sea-ice variables
28   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
29   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
30   USE limthd_da      ! LIM: thermodynamics, lateral melting
31   USE limthd_sal     ! LIM: thermodynamics, ice salinity
32   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
33   USE limthd_lac     ! LIM-3 lateral accretion
34   USE limitd_th      ! remapping thickness distribution
35   USE limtab         ! LIM: 1D <==> 2D transformation
36   USE limvar         ! LIM: sea-ice variables
37   USE lbclnk         ! lateral boundary condition - MPP links
38   USE lib_mpp        ! MPP library
39   USE wrk_nemo       ! work arrays
40   USE in_out_manager ! I/O manager
41   USE prtctl         ! Print control
42   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
43   USE timing         ! Timing
44   USE limcons        ! conservation tests
45   USE limctl
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   lim_thd         ! called by limstp module
51   PUBLIC   lim_thd_init    ! called by sbc_lim_init
52
53   !! * Substitutions
54#  include "domzgr_substitute.h90"
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !!
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
86      INTEGER  :: ii, ij           ! temporary dummy loop index
87      REAL(wp) :: zfric_u, zqld, zqfr
88      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
89      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
90      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
91      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
92      !
93      !!-------------------------------------------------------------------
94
95      IF( nn_timing == 1 )  CALL timing_start('limthd')
96
97      CALL wrk_alloc( jpi,jpj, zu_io, zv_io, zfric )
98
99      IF( kt == nit000 .AND. lwp ) THEN
100         WRITE(numout,*)'' 
101         WRITE(numout,*)' lim_thd '
102         WRITE(numout,*)' ~~~~~~~~'
103      ENDIF
104     
105      ! conservation test
106      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
107
108      CALL lim_var_glo2eqv
109
110      !---------------------------------------------!
111      ! computation of friction velocity at T points
112      !---------------------------------------------!
113      IF( ln_limdyn ) THEN
114         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
115         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
116         DO jj = 2, jpjm1 
117            DO ji = fs_2, fs_jpim1
118               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
119                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
120                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
121            END DO
122         END DO
123      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
124         DO jj = 2, jpjm1
125            DO ji = fs_2, fs_jpim1
126               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
127                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
128                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
129            END DO
130         END DO
131      ENDIF
132      CALL lbc_lnk( zfric, 'T',  1. )
133      !
134      !----------------------------------!
135      ! Initialization and units change
136      !----------------------------------!
137      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
138
139      ! Change the units of heat content; from J/m2 to J/m3
140      DO jl = 1, jpl
141         DO jk = 1, nlay_i
142            DO jj = 1, jpj
143               DO ji = 1, jpi
144                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
145                  !Energy of melting q(S,T) [J.m-3]
146                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
147               END DO
148            END DO
149         END DO
150         DO jk = 1, nlay_s
151            DO jj = 1, jpj
152               DO ji = 1, jpi
153                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
154                  !Energy of melting q(S,T) [J.m-3]
155                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
156               END DO
157            END DO
158         END DO
159      END DO
160
161      !--------------------------------------------------------------------!
162      ! Partial computation of forcing for the thermodynamic sea ice model
163      !--------------------------------------------------------------------!
164      DO jj = 1, jpj
165         DO ji = 1, jpi
166            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
167            !
168            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
169            !           !  practically no "direct lateral ablation"
170            !           
171            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
172            !           !  temperature and turbulent mixing (McPhee, 1992)
173            !
174            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
175            zqld =  tmask(ji,jj,1) * rdt_ice *  &
176               &    ( pfrld(ji,jj) * qsr_oce(ji,jj) * frq_m(ji,jj) + pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
177
178            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
179            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
180
181            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
182            zfric_u      = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
183            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
184            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
185            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
186            !                        the freezing point, so that we do not have SST < T_freeze
187            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
188
189            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
190            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
191
192            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
193            IF( zqld > 0._wp ) THEN
194               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
195               qlead(ji,jj) = 0._wp
196            ELSE
197               fhld (ji,jj) = 0._wp
198            ENDIF
199            !
200            ! Net heat flux on top of the ice-ocean [W.m-2]
201            ! ---------------------------------------------
202            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
203         END DO
204      END DO
205     
206      ! In case we bypass open-water ice formation
207      IF( .NOT. ln_limdO )  qlead(:,:) = 0._wp
208      ! In case we bypass growing/melting from top and bottom: we suppose ice is impermeable => ocean is isolated from atmosphere
209      IF( .NOT. ln_limdH )  hfx_in(:,:) = pfrld(:,:) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:)
210      IF( .NOT. ln_limdH )  fhtur (:,:) = 0._wp  ;  fhld  (:,:) = 0._wp
211
212      ! ---------------------------------------------------------------------
213      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
214      ! ---------------------------------------------------------------------
215      !     First  step here              :  non solar + precip - qlead - qturb
216      !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
217      !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
218      DO jj = 1, jpj
219         DO ji = 1, jpi
220            hfx_out(ji,jj) =   pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
221               &             - qlead(ji,jj) * r1_rdtice                         &  ! heat flux taken from the ocean where there is open water ice formation
222               &             - at_i(ji,jj) * fhtur(ji,jj)                       &  ! heat flux taken by turbulence
223               &             - at_i(ji,jj) *  fhld(ji,jj)                          ! heat flux taken during bottom growth/melt
224                                                                                   !    (fhld should be 0 while bott growth)
225         END DO
226      END DO
227         
228      !------------------------------------------------------------------------------!
229      ! Thermodynamic computation (only on grid points covered by ice)
230      !------------------------------------------------------------------------------!
231      DO jl = 1, jpl      !loop over ice categories
232
233         ! select ice covered grid points
234         nbpb = 0
235         DO jj = 1, jpj
236            DO ji = 1, jpi
237               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
238                  nbpb      = nbpb  + 1
239                  npb(nbpb) = (jj - 1) * jpi + ji
240               ENDIF
241            END DO
242         END DO
243
244         ! debug point to follow
245         jiindex_1d = 0
246         IF( ln_icectl ) THEN
247            DO ji = mi0(iiceprt), mi1(iiceprt)
248               DO jj = mj0(jiceprt), mj1(jiceprt)
249                  jiindex_1d = (jj - 1) * jpi + ji
250                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
251               END DO
252            END DO
253         ENDIF
254
255         IF( lk_mpp )         CALL mpp_ini_ice( nbpb , numout )
256
257         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
258            !                                                               
259            s_i_new   (:) = 0._wp ; dh_s_tot (:) = 0._wp                     ! --- some init --- !
260            dh_i_surf (:) = 0._wp ; dh_i_bott(:) = 0._wp
261            dh_snowice(:) = 0._wp ; dh_i_sub (:) = 0._wp
262
263                              CALL lim_thd_1d2d( nbpb, jl, 1 )               ! --- Move to 1D arrays --- !
264            !
265            IF( ln_limdH )    CALL lim_thd_dif( 1, nbpb )                    ! --- Ice/Snow Temperature profile --- !
266            !
267            IF( ln_limdH )    CALL lim_thd_dh( 1, nbpb )                     ! --- Ice/Snow thickness --- !   
268            !
269            IF( ln_limdH )    CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) )  ! --- Ice enthalpy remapping --- !
270            !
271                              CALL lim_thd_sal( 1, nbpb )                    ! --- Ice salinity --- !   
272            !
273                              CALL lim_thd_temp( 1, nbpb )                   ! --- temperature update --- !
274            !
275            IF( ln_limdH ) THEN
276               IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
277                              CALL lim_thd_lam( 1, nbpb )                    ! --- extra lateral melting if monocat --- !
278               END IF
279            END IF
280            !
281                              CALL lim_thd_1d2d( nbpb, jl, 2 )               ! --- Move to 2D arrays --- !
282            !
283            IF( lk_mpp )      CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
284         ENDIF
285         !
286      END DO !jl
287
288      IF( ln_limdA)           CALL lim_thd_da                                ! --- lateral melting --- !
289
290      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
291      DO jl = 1, jpl
292         DO jk = 1, nlay_i
293            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
294         END DO
295         DO jk = 1, nlay_s
296            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
297         END DO
298      END DO
299 
300      ! Change thickness to volume
301      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
302      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
303      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
304
305      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting)
306      DO jl  = 1, jpl
307         DO jj = 1, jpj
308            DO ji = 1, jpi
309               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
310               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
311            END DO
312         END DO
313      END DO
314
315      CALL lim_var_zapsmall
316
317      ! control checks
318      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
319      !
320      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
321
322      !------------------------------------------------!
323      !  Transport ice between thickness categories
324      !------------------------------------------------!
325      ! Given thermodynamic growth rates, transport ice between thickness categories.
326      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
327
328      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
329
330      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
331
332      !------------------------------------------------!
333      !  Add frazil ice growing in leads
334      !------------------------------------------------!
335      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
336
337      IF( ln_limdO )     CALL lim_thd_lac
338     
339      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
340
341      ! Control print
342      IF(ln_ctl) THEN
343         CALL lim_var_glo2eqv
344
345         CALL prt_ctl_info(' ')
346         CALL prt_ctl_info(' - Cell values : ')
347         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
348         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_itd_th  : cell area :')
349         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
350         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
351         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
352         DO jl = 1, jpl
353            CALL prt_ctl_info(' ')
354            CALL prt_ctl_info(' - Category : ', ivar1=jl)
355            CALL prt_ctl_info('   ~~~~~~~~~~')
356            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
357            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
358            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
359            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
360            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
361            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
362            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
363            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
364            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
365            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
366            DO jk = 1, nlay_i
367               CALL prt_ctl_info(' ')
368               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
369               CALL prt_ctl_info('   ~~~~~~~')
370               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
371               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
372            END DO
373         END DO
374      ENDIF
375      !
376      CALL wrk_dealloc( jpi,jpj, zu_io, zv_io, zfric )
377      !
378      IF( nn_timing == 1 )  CALL timing_stop('limthd')
379
380   END SUBROUTINE lim_thd 
381
382 
383   SUBROUTINE lim_thd_temp( kideb, kiut )
384      !!-----------------------------------------------------------------------
385      !!                   ***  ROUTINE lim_thd_temp ***
386      !!                 
387      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
388      !!
389      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
390      !!-------------------------------------------------------------------
391      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
392      !!
393      INTEGER  ::   ji, jk   ! dummy loop indices
394      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
395      !!-------------------------------------------------------------------
396      ! Recover ice temperature
397      DO jk = 1, nlay_i
398         DO ji = kideb, kiut
399            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
400            ! Conversion q(S,T) -> T (second order equation)
401            zaaa          =  cpic
402            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
403            zccc          =  lfus * ( ztmelts - rt0 )
404            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
405            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
406           
407            ! mask temperature
408            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
409            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
410         END DO
411      END DO
412
413   END SUBROUTINE lim_thd_temp
414
415   SUBROUTINE lim_thd_lam( kideb, kiut )
416      !!-----------------------------------------------------------------------
417      !!                   ***  ROUTINE lim_thd_lam ***
418      !!                 
419      !! ** Purpose :   Lateral melting in case monocategory
420      !!                          ( dA = A/2h dh )
421      !!-----------------------------------------------------------------------
422      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
423      INTEGER             ::   ji                 ! dummy loop indices
424      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
425      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
426      REAL(wp)            ::   zvi, zvs           ! ice/snow volumes
427
428      DO ji = kideb, kiut
429         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) + dh_i_sub(ji) )
430         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
431            zvi          = a_i_1d(ji) * ht_i_1d(ji)
432            zvs          = a_i_1d(ji) * ht_s_1d(ji)
433            ! lateral melting = concentration change
434            zhi_bef     = ht_i_1d(ji) - zdh_mel
435            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
436            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
437            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
438            ! adjust thickness
439            ht_i_1d(ji) = zvi / a_i_1d(ji)           
440            ht_s_1d(ji) = zvs / a_i_1d(ji)           
441            ! retrieve total concentration
442            at_i_1d(ji) = a_i_1d(ji)
443         END IF
444      END DO
445     
446   END SUBROUTINE lim_thd_lam
447
448   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
449      !!-----------------------------------------------------------------------
450      !!                   ***  ROUTINE lim_thd_1d2d ***
451      !!                 
452      !! ** Purpose :   move arrays from 1d to 2d and the reverse
453      !!-----------------------------------------------------------------------
454      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D
455                                        ! 2= from 1D to 2D
456      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
457      INTEGER, INTENT(in) ::   jl       ! ice cat
458      INTEGER             ::   jk       ! dummy loop indices
459
460      SELECT CASE( kn )
461
462      CASE( 1 )
463
464         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
465         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
466         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
467         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
468         
469         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
470         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
471         DO jk = 1, nlay_s
472            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
473            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
474         END DO
475         DO jk = 1, nlay_i
476            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
477            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
478            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
479         END DO
480         
481         CALL tab_2d_1d( nbpb, qprec_ice_1d(1:nbpb), qprec_ice(:,:) , jpi, jpj, npb(1:nbpb) )
482         CALL tab_2d_1d( nbpb, qevap_ice_1d(1:nbpb), qevap_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
483         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
484         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
485         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
486         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
487         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
488         CALL tab_2d_1d( nbpb, evap_ice_1d (1:nbpb), evap_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
489         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
490         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
491         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
492         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
493         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
494         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
495         
496         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
497         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
498         
499         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
500         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
501         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
502         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
503         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
504         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
505         
506         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
507         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
508         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
509         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
510         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
511         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
512         CALL tab_2d_1d( nbpb, sfx_sub_1d (1:nbpb), sfx_sub         , jpi, jpj,npb(1:nbpb) )
513 
514         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
515         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
516         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
517         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
518         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
519         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
520         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
521         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
522         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
523         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
524         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
525         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
526         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
527
528      CASE( 2 )
529
530         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
531         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
532         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
533         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
534         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
535         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
536         DO jk = 1, nlay_s
537            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
538            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
539         END DO
540         DO jk = 1, nlay_i
541            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
542            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
543            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
544         END DO
545         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
546         
547         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
548         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
549         
550         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
551         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
552         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
553         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
554         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
555         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
556         
557         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
558         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
559         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
560         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
561         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
562         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
563         CALL tab_1d_2d( nbpb, sfx_sub       , npb, sfx_sub_1d(1:nbpb)   , jpi, jpj )       
564 
565         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
566         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
567         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
568         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
569         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
570         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
571         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
572         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
573         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
574         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
575         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
576         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
577         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
578         !
579         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
580         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
581         !         
582      END SELECT
583
584   END SUBROUTINE lim_thd_1d2d
585
586
587   SUBROUTINE lim_thd_init
588      !!-----------------------------------------------------------------------
589      !!                   ***  ROUTINE lim_thd_init ***
590      !!                 
591      !! ** Purpose :   Physical constants and parameters linked to the ice
592      !!              thermodynamics
593      !!
594      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
595      !!              parameter values called at the first timestep (nit000)
596      !!
597      !! ** input   :   Namelist namicether
598      !!-------------------------------------------------------------------
599      INTEGER  ::   ios                 ! Local integer output status for namelist read
600      NAMELIST/namicethd/ rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon,ln_it_qnsice,nn_monocat,  &
601         &                ln_limdH, rn_betas,                                                          &
602         &                ln_limdA, rn_beta, rn_dmin,                                                  &
603         &                ln_limdO, rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb, rn_himin
604      !!-------------------------------------------------------------------
605      !
606      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
607      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
608901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
609
610      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
611      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
612902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
613      IF(lwm) WRITE ( numoni, namicethd )
614      !
615      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
616         nn_monocat = 0
617         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
618      ENDIF
619      !
620      IF(lwp) THEN                          ! control print
621         WRITE(numout,*)
622         WRITE(numout,*) 'lim_thd_init : Ice Thermodynamics'
623         WRITE(numout,*) '~~~~~~~~~~~~~'
624         WRITE(numout,*)'   -- limthd_dif --'
625         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
626         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
627         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
628         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
629         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
630         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
631         WRITE(numout,*)'   -- limthd_dh --'
632         WRITE(numout,*)'      activate ice thick change from top/bot (T) or not (F)   ln_limdH     = ', ln_limdH
633         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
634         WRITE(numout,*)'   -- limthd_da --'
635         WRITE(numout,*)'      activate lateral melting (T) or not (F)                 ln_limdA     = ', ln_limdA
636         WRITE(numout,*)'      Coef. beta for lateral melting param.                   rn_beta      = ', rn_beta
637         WRITE(numout,*)'      Minimum floe diameter for lateral melting param.        rn_dmin      = ', rn_dmin
638         WRITE(numout,*)'   -- limthd_lac --'
639         WRITE(numout,*)'      activate ice growth in open-water (T) or not (F)        ln_limdO     = ', ln_limdO
640         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
641         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
642         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
643         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
644         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
645         WRITE(numout,*)'   -- limitd_th --'
646         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
647         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
648      ENDIF
649      !
650   END SUBROUTINE lim_thd_init
651
652#else
653   !!----------------------------------------------------------------------
654   !!   Default option         Dummy module          NO  LIM3 sea-ice model
655   !!----------------------------------------------------------------------
656#endif
657
658   !!======================================================================
659END MODULE limthd
Note: See TracBrowser for help on using the repository browser.