New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcana.F90 in branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC/sbcana.F90 @ 7077

Last change on this file since 7077 was 7077, checked in by clem, 8 years ago

enable analytic forcings with LIM3. It requires a change in namelist_ref.
  • Property svn:keywords set to Id
File size: 20.8 KB
Line 
1MODULE sbcana
2   !!======================================================================
3   !!                       ***  MODULE  sbcana  ***
4   !! Ocean forcing:  analytical momentum, heat and freshwater forcings
5   !!=====================================================================
6   !! History :  3.0   ! 2006-06  (G. Madec)  Original code
7   !!            3.2   ! 2009-07  (G. Madec)  Style only
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ana  : set an analytical ocean forcing
12   !!   sbc_gyre : set the GYRE configuration analytical forcing
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! Surface boundary condition: ocean fields
17   USE sbc_ice         ! Surface boundary condition: ice   fields
18   USE phycst          ! physical constants
19   USE in_out_manager  ! I/O manager
20   USE lib_mpp         ! distribued memory computing library
21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
22   USE lib_fortran
23   USE wrk_nemo
24#if defined key_lim3
25   USE ice, ONLY       : pfrld, a_i_b
26   USE limthd_dh       ! for CALL lim_thd_snwblow
27#endif
28   
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_ana         ! routine called in sbcmod module
33   PUBLIC   sbc_gyre        ! routine called in sbcmod module
34#if defined key_lim3
35   PUBLIC   ana_ice_tau     ! routine called in sbc_ice_lim module
36   PUBLIC   ana_ice_flx     ! routine called in sbc_ice_lim module
37#endif
38
39   !                       !!* Namelist namsbc_ana *
40   ! --- oce variables --- !
41   INTEGER  ::   nn_tau000 ! nb of time-step during which the surface stress
42   !                       ! increase from 0 to its nominal value
43   REAL(wp) ::   rn_utau0  ! constant wind stress value in i-direction
44   REAL(wp) ::   rn_vtau0  ! constant wind stress value in j-direction
45   REAL(wp) ::   rn_qns0   ! non solar heat flux
46   REAL(wp) ::   rn_qsr0   !     solar heat flux
47   REAL(wp) ::   rn_emp0   ! net freshwater flux
48   ! --- ice variables --- !
49   REAL(wp) ::   rn_iutau0 ! constant wind stress value in i-direction over ice
50   REAL(wp) ::   rn_ivtau0 ! constant wind stress value in j-direction over ice
51   REAL(wp) ::   rn_iqns0  ! non solar heat flux over ice
52   REAL(wp) ::   rn_iqsr0  !     solar heat flux over ice
53   REAL(wp) ::   rn_sprec0 ! snow precip
54   REAL(wp) ::   rn_ievap0 ! sublimation
55   
56   !! * Substitutions
57#  include "domzgr_substitute.h90"
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE sbc_ana( kt )
67      !!---------------------------------------------------------------------
68      !!                    ***  ROUTINE sbc_ana ***
69      !!             
70      !! ** Purpose :   provide at each time-step the ocean surface boundary
71      !!              condition, i.e. the momentum, heat and freshwater fluxes.
72      !!
73      !! ** Method  :   Constant and uniform surface forcing specified from
74      !!              namsbc_ana namelist parameters. All the fluxes are time
75      !!              independant except the stresses which increase from zero
76      !!              during the first nn_tau000 time-step
77      !!
78      !! ** Action  : - set the ocean surface boundary condition, i.e. 
79      !!                   utau, vtau, taum, wndm, qns, qsr, emp, sfx
80      !!----------------------------------------------------------------------
81      INTEGER, INTENT(in) ::   kt   ! ocean time step
82      !
83      INTEGER  ::   ios                   ! local integer
84      REAL(wp) ::   zrhoa  = 1.22_wp      ! air density kg/m3
85      REAL(wp) ::   zcdrag = 1.5e-3_wp    ! drag coefficient
86      REAL(wp) ::   zfact, ztx            ! local scalars
87      REAL(wp) ::   zcoef, zty, zmod      !   -      -
88      !!
89      NAMELIST/namsbc_ana/ nn_tau000, rn_utau0, rn_vtau0, rn_qns0, rn_qsr0, rn_emp0,  &
90         &                 rn_iutau0, rn_ivtau0, rn_iqsr0, rn_iqns0, rn_sprec0, rn_ievap0
91      !!---------------------------------------------------------------------
92      !
93      IF( kt == nit000 ) THEN
94         !
95         REWIND( numnam_ref )              ! Namelist namsbc_ana in reference namelist : Analytical surface fluxes
96         READ  ( numnam_ref, namsbc_ana, IOSTAT = ios, ERR = 901)
97901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ana in reference namelist', lwp )
98
99         REWIND( numnam_cfg )              ! Namelist namsbc_ana in configuration namelist : Analytical surface fluxes
100         READ  ( numnam_cfg, namsbc_ana, IOSTAT = ios, ERR = 902 )
101902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ana in configuration namelist', lwp )
102         IF(lwm) WRITE ( numond, namsbc_ana )
103         !
104         IF(lwp) WRITE(numout,*)' '
105         IF(lwp) WRITE(numout,*)' sbc_ana : Constant surface fluxes read in namsbc_ana namelist'
106         IF(lwp) WRITE(numout,*)' ~~~~~~~ '
107         IF(lwp) WRITE(numout,*)'              spin up of the stress         nn_tau000 = ', nn_tau000 , ' time-steps'
108         IF(lwp) WRITE(numout,*)'              constant i-stress             rn_utau0  = ', rn_utau0  , ' N/m2'
109         IF(lwp) WRITE(numout,*)'              constant j-stress             rn_vtau0  = ', rn_vtau0  , ' N/m2'
110         IF(lwp) WRITE(numout,*)'              non solar heat flux           rn_qns0   = ', rn_qns0   , ' W/m2'
111         IF(lwp) WRITE(numout,*)'              solar heat flux               rn_qsr0   = ', rn_qsr0   , ' W/m2'
112         IF(lwp) WRITE(numout,*)'              net freshwater flux           rn_emp0   = ', rn_emp0   , ' Kg/m2/s'
113         IF(lwp) WRITE(numout,*)'              constant ice-atm stress       rn_iutau0 = ', rn_iutau0 , ' N/m2'
114         IF(lwp) WRITE(numout,*)'              constant ice-atm stress       rn_ivtau0 = ', rn_ivtau0 , ' N/m2'
115         IF(lwp) WRITE(numout,*)'              solar heat flux over ice      rn_iqsr0  = ', rn_iqsr0  , ' W/m2'
116         IF(lwp) WRITE(numout,*)'              non solar heat flux over ice  rn_iqns0  = ', rn_iqns0  , ' W/m2'
117         IF(lwp) WRITE(numout,*)'              snow precip                   rn_sprec0 = ', rn_sprec0 , ' Kg/m2/s'
118         IF(lwp) WRITE(numout,*)'              sublimation                   rn_ievap0 = ', rn_ievap0 , ' Kg/m2/s'
119         !
120         nn_tau000 = MAX( nn_tau000, 1 )     ! must be >= 1
121         !
122         utau(:,:) = rn_utau0
123         vtau(:,:) = rn_vtau0
124         taum(:,:) = SQRT ( rn_utau0 * rn_utau0 + rn_vtau0 * rn_vtau0 )
125         wndm(:,:) = SQRT ( taum(1,1) /  ( zrhoa * zcdrag ) )
126         !
127         emp (:,:) = rn_emp0
128         sfx (:,:) = 0.0_wp
129         qns (:,:) = rn_qns0 - emp(:,:) * sst_m(:,:) * rcp      ! including heat content associated with mass flux at SST
130         qsr (:,:) = rn_qsr0
131         !         
132      ENDIF
133
134      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN 
135         !
136         IF( kt <= nn_tau000 ) THEN       ! Increase the stress to its nominal value
137            !                             ! during the first nn_tau000 time-steps
138            zfact = 0.5 * (  1. - COS( rpi * REAL( kt, wp ) / REAL( nn_tau000, wp ) )  )
139            zcoef = 1. / ( zrhoa * zcdrag ) 
140            ztx   = zfact * rn_utau0
141            zty   = zfact * rn_vtau0
142            zmod  = SQRT( ztx * ztx + zty * zty )
143            utau(:,:) = ztx
144            vtau(:,:) = zty
145            taum(:,:) = zmod
146            zmod = SQRT( zmod * zcoef )
147            wndm(:,:) = zmod
148         ENDIF
149         !                                ! update heat and fresh water fluxes
150         !                                ! as they may have been changed by sbcssr module
151         emp (:,:) = rn_emp0              ! NB: qns changes with SST if emp /= 0
152         sfx (:,:) = 0._wp
153         qns (:,:) = rn_qns0 - emp(:,:) * sst_m(:,:) * rcp
154         qsr (:,:) = rn_qsr0
155         !
156      ENDIF
157      !
158   END SUBROUTINE sbc_ana
159
160#if defined key_lim3
161   SUBROUTINE ana_ice_tau
162      !!---------------------------------------------------------------------
163      !!                     ***  ROUTINE ana_ice_tau  ***
164      !!
165      !! ** Purpose :   provide the surface boundary (momentum) condition over sea-ice
166      !!---------------------------------------------------------------------
167      utau_ice(:,:) = rn_iutau0
168      vtau_ice(:,:) = rn_ivtau0
169     
170   END SUBROUTINE ana_ice_tau
171   
172   SUBROUTINE ana_ice_flx
173      !!---------------------------------------------------------------------
174      !!                     ***  ROUTINE ana_ice_flx  ***
175      !!
176      !! ** Purpose :   provide the surface boundary (flux) condition over sea-ice
177      !!---------------------------------------------------------------------
178      REAL(wp), DIMENSION(:,:), POINTER ::   zsnw       ! snw distribution after wind blowing
179      !!---------------------------------------------------------------------
180      CALL wrk_alloc( jpi,jpj, zsnw ) 
181
182      ! ocean variables (renaming)
183      emp_oce (:,:)   = rn_emp0
184      qsr_oce (:,:)   = rn_qsr0
185      qns_oce (:,:)   = rn_qns0
186     
187      ! ice variables
188      alb_ice (:,:,:) = 0.7_wp ! useless
189      qsr_ice (:,:,:) = rn_iqsr0
190      qns_ice (:,:,:) = rn_iqns0
191      sprecip (:,:)   = rn_sprec0
192      evap_ice(:,:,:) = rn_ievap0
193
194      ! ice variables deduced from above
195      zsnw(:,:) = 0._wp
196      CALL lim_thd_snwblow( pfrld, zsnw )  ! snow distribution over ice after wind blowing
197      emp_ice  (:,:)   = SUM( a_i_b(:,:,:) * evap_ice(:,:,:), dim=3 ) - sprecip(:,:) * zsnw
198      emp_oce  (:,:)   = emp_oce(:,:) - sprecip(:,:) * (1._wp - zsnw )
199      qevap_ice(:,:,:) =   0._wp
200      qprec_ice(:,:)   =   rhosn * ( sst_m(:,:) * cpic - lfus ) * tmask(:,:,1) ! in J/m3
201      qemp_oce (:,:)   = - emp_oce(:,:) * sst_m(:,:) * rcp
202      qemp_ice (:,:)   =   sprecip(:,:) * zsnw * ( sst_m(:,:) * cpic - lfus ) * tmask(:,:,1) ! solid precip (only)
203
204      ! total fluxes
205      emp_tot (:,:) = emp_ice  + emp_oce 
206      qns_tot (:,:) = pfrld(:,:) * qns_oce(:,:) + SUM( a_i_b(:,:,:) * qns_ice(:,:,:), dim=3 ) + qemp_ice(:,:) + qemp_oce(:,:)
207      qsr_tot (:,:) = pfrld(:,:) * qsr_oce(:,:) + SUM( a_i_b(:,:,:) * qsr_ice(:,:,:), dim=3 )
208
209      !--------------------------------------------------------------------
210      ! FRACTIONs of net shortwave radiation which is not absorbed in the
211      ! thin surface layer and penetrates inside the ice cover
212      ! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 )
213      fr1_i0(:,:) = ( 0.18 * ( 1.0 - cldf_ice ) + 0.35 * cldf_ice )
214      fr2_i0(:,:) = ( 0.82 * ( 1.0 - cldf_ice ) + 0.65 * cldf_ice )
215
216      CALL wrk_dealloc( jpi,jpj, zsnw ) 
217     
218   END SUBROUTINE ana_ice_flx
219#endif
220
221   
222   SUBROUTINE sbc_gyre( kt )
223      !!---------------------------------------------------------------------
224      !!                    ***  ROUTINE sbc_ana ***
225      !!             
226      !! ** Purpose :   provide at each time-step the GYRE surface boundary
227      !!              condition, i.e. the momentum, heat and freshwater fluxes.
228      !!
229      !! ** Method  :   analytical seasonal cycle for GYRE configuration.
230      !!                CAUTION : never mask the surface stress field !
231      !!
232      !! ** Action  : - set the ocean surface boundary condition, i.e.   
233      !!                   utau, vtau, taum, wndm, qns, qsr, emp, sfx
234      !!
235      !! Reference : Hazeleger, W., and S. Drijfhout, JPO, 30, 677-695, 2000.
236      !!----------------------------------------------------------------------
237      INTEGER, INTENT(in) ::   kt          ! ocean time step
238      !!
239      INTEGER  ::   ji, jj                 ! dummy loop indices
240      INTEGER  ::   zyear0                 ! initial year
241      INTEGER  ::   zmonth0                ! initial month
242      INTEGER  ::   zday0                  ! initial day
243      INTEGER  ::   zday_year0             ! initial day since january 1st
244      REAL(wp) ::   ztau     , ztau_sais   ! wind intensity and of the seasonal cycle
245      REAL(wp) ::   ztime                  ! time in hour
246      REAL(wp) ::   ztimemax , ztimemin    ! 21th June, and 21th decem. if date0 = 1st january
247      REAL(wp) ::   ztimemax1, ztimemin1   ! 21th June, and 21th decem. if date0 = 1st january
248      REAL(wp) ::   ztimemax2, ztimemin2   ! 21th June, and 21th decem. if date0 = 1st january
249      REAL(wp) ::   ztaun                  ! intensity
250      REAL(wp) ::   zemp_s, zemp_n, zemp_sais, ztstar
251      REAL(wp) ::   zcos_sais1, zcos_sais2, ztrp, zconv, t_star
252      REAL(wp) ::   zsumemp, zsurf
253      REAL(wp) ::   zrhoa  = 1.22         ! Air density kg/m3
254      REAL(wp) ::   zcdrag = 1.5e-3       ! drag coefficient
255      REAL(wp) ::   ztx, zty, zmod, zcoef ! temporary variables
256      REAL(wp) ::   zyydd                 ! number of days in one year
257      !!---------------------------------------------------------------------
258      zyydd = REAL(nyear_len(1),wp)
259
260      ! ---------------------------- !
261      !  heat and freshwater fluxes  !
262      ! ---------------------------- !
263      !same temperature, E-P as in HAZELEGER 2000
264
265      zyear0     =   ndate0 / 10000                             ! initial year
266      zmonth0    = ( ndate0 - zyear0 * 10000 ) / 100            ! initial month
267      zday0      =   ndate0 - zyear0 * 10000 - zmonth0 * 100    ! initial day betwen 1 and 30
268      zday_year0 = ( zmonth0 - 1 ) * 30.+zday0                  ! initial day betwen 1 and 360
269
270      ! current day (in hours) since january the 1st of the current year
271      ztime = REAL( kt ) * rdt / (rmmss * rhhmm)   &       !  total incrementation (in hours)
272         &      - (nyear  - 1) * rjjhh * zyydd             !  minus years since beginning of experiment (in hours)
273
274      ztimemax1 = ((5.*30.)+21.)* 24.                      ! 21th june     at 24h in hours
275      ztimemin1 = ztimemax1 + rjjhh * zyydd / 2            ! 21th december        in hours
276      ztimemax2 = ((6.*30.)+21.)* 24.                      ! 21th july     at 24h in hours
277      ztimemin2 = ztimemax2 - rjjhh * zyydd / 2            ! 21th january         in hours
278      !                                                    ! NB: rjjhh * zyydd / 4 = one seasonal cycle in hours
279
280      ! amplitudes
281      zemp_S    = 0.7       ! intensity of COS in the South
282      zemp_N    = 0.8       ! intensity of COS in the North
283      zemp_sais = 0.1
284      zTstar    = 28.3      ! intemsity from 28.3 a -5 deg
285
286      ! 1/2 period between 21th June and 21th December and between 21th July and 21th January
287      zcos_sais1 = COS( (ztime - ztimemax1) / (ztimemin1 - ztimemax1) * rpi ) 
288      zcos_sais2 = COS( (ztime - ztimemax2) / (ztimemax2 - ztimemin2) * rpi )
289
290      ztrp= - 40.e0        ! retroaction term on heat fluxes (W/m2/K)
291      zconv = 3.16e-5      ! convertion factor: 1 m/yr => 3.16e-5 mm/s
292      DO jj = 1, jpj
293         DO ji = 1, jpi
294            ! domain from 15 deg to 50 deg between 27 and 28  degC at 15N, -3
295            ! and 13 degC at 50N 53.5 + or - 11 = 1/4 period :
296            ! 64.5 in summer, 42.5 in winter
297            t_star = zTstar * ( 1 + 1. / 50. * zcos_sais2 )                &
298               &                    * COS( rpi * (gphit(ji,jj) - 5.)               &
299               &                    / ( 53.5 * ( 1 + 11 / 53.5 * zcos_sais2 ) * 2.) )
300            ! 23.5 deg : tropics
301            qsr (ji,jj) =  230 * COS( 3.1415 * ( gphit(ji,jj) - 23.5 * zcos_sais1 ) / ( 0.9 * 180 ) )
302            qns (ji,jj) = ztrp * ( tsb(ji,jj,1,jp_tem) - t_star ) - qsr(ji,jj)
303            IF( gphit(ji,jj) >= 14.845 .AND. 37.2 >= gphit(ji,jj) ) THEN    ! zero at 37.8 deg, max at 24.6 deg
304               emp  (ji,jj) =   zemp_S * zconv   &
305                  &         * SIN( rpi / 2 * (gphit(ji,jj) - 37.2) / (24.6 - 37.2) )  &
306                  &         * ( 1 - zemp_sais / zemp_S * zcos_sais1)
307            ELSE
308               emp (ji,jj) =  - zemp_N * zconv   &
309                  &         * SIN( rpi / 2 * (gphit(ji,jj) - 37.2) / (46.8 - 37.2) )  &
310                  &         * ( 1 - zemp_sais / zemp_N * zcos_sais1 )
311            ENDIF
312         END DO
313      END DO
314
315      ! Compute the emp flux such as its integration on the whole domain at each time is zero
316      IF( nbench /= 1 ) THEN
317         zsumemp = GLOB_SUM( emp(:,:) ) 
318         zsurf   = GLOB_SUM( tmask(:,:,1) ) 
319         ! Default GYRE configuration
320         zsumemp = zsumemp / zsurf
321      ELSE
322         ! Benchmark GYRE configuration (to allow the bit to bit comparison between Mpp/Mono case)
323         zsumemp = 0.e0   ;    zsurf = 0.e0
324      ENDIF
325
326      ! freshwater (mass flux) and update of qns with heat content of emp
327      emp (:,:) = emp(:,:) - zsumemp * tmask(:,:,1)        ! freshwater flux (=0 in domain average)
328      sfx (:,:) = 0.0_wp                                   ! no salt flux
329      qns (:,:) = qns(:,:) - emp(:,:) * sst_m(:,:) * rcp   ! evap and precip are at SST
330
331
332      ! ---------------------------- !
333      !       momentum fluxes        !
334      ! ---------------------------- !
335      ! same wind as in Wico
336      !test date0 : ndate0 = 010203
337      zyear0  =   ndate0 / 10000
338      zmonth0 = ( ndate0 - zyear0 * 10000 ) / 100
339      zday0   =   ndate0 - zyear0 * 10000 - zmonth0 * 100
340      !Calculates nday_year, day since january 1st
341      zday_year0 = (zmonth0-1)*30.+zday0
342
343      !accumulates days of previous months of this year
344      ! day (in hours) since january the 1st
345      ztime = FLOAT( kt ) * rdt / (rmmss * rhhmm)  &  ! incrementation in hour
346         &     - (nyear - 1) * rjjhh * zyydd          !  - nber of hours the precedent years
347      ztimemax = ((5.*30.)+21.)* 24.               ! 21th june     in hours
348      ztimemin = ztimemax + rjjhh * zyydd / 2      ! 21th december in hours
349      !                                            ! NB: rjjhh * zyydd / 4 = 1 seasonal cycle in hours
350
351      ! mean intensity at 0.105 ; srqt(2) because projected with 45deg angle
352      ztau = 0.105 / SQRT( 2. )
353      ! seasonal oscillation intensity
354      ztau_sais = 0.015
355      ztaun = ztau - ztau_sais * COS( (ztime - ztimemax) / (ztimemin - ztimemax) * rpi )
356      DO jj = 1, jpj
357         DO ji = 1, jpi
358           ! domain from 15deg to 50deg and 1/2 period along 14deg
359           ! so 5/4 of half period with seasonal cycle
360           utau(ji,jj) = - ztaun * SIN( rpi * (gphiu(ji,jj) - 15.) / (29.-15.) )
361           vtau(ji,jj) =   ztaun * SIN( rpi * (gphiv(ji,jj) - 15.) / (29.-15.) )
362         END DO
363      END DO
364
365      ! module of wind stress and wind speed at T-point
366      zcoef = 1. / ( zrhoa * zcdrag ) 
367!CDIR NOVERRCHK
368      DO jj = 2, jpjm1
369!CDIR NOVERRCHK
370         DO ji = fs_2, fs_jpim1   ! vect. opt.
371            ztx = utau(ji-1,jj  ) + utau(ji,jj) 
372            zty = vtau(ji  ,jj-1) + vtau(ji,jj) 
373            zmod = 0.5 * SQRT( ztx * ztx + zty * zty )
374            taum(ji,jj) = zmod
375            wndm(ji,jj) = SQRT( zmod * zcoef )
376         END DO
377      END DO
378      CALL lbc_lnk( taum(:,:), 'T', 1. )   ;   CALL lbc_lnk( wndm(:,:), 'T', 1. )
379
380      ! ---------------------------------- !
381      !  control print at first time-step  !
382      ! ---------------------------------- !
383      IF( kt == nit000 .AND. lwp ) THEN
384         WRITE(numout,*)
385         WRITE(numout,*)'sbc_gyre : analytical surface fluxes for GYRE configuration'               
386         WRITE(numout,*)'~~~~~~~~ ' 
387         WRITE(numout,*)'           nyear      = ', nyear
388         WRITE(numout,*)'           nmonth     = ', nmonth
389         WRITE(numout,*)'           nday       = ', nday
390         WRITE(numout,*)'           nday_year  = ', nday_year
391         WRITE(numout,*)'           ztime      = ', ztime
392         WRITE(numout,*)'           ztimemax   = ', ztimemax
393         WRITE(numout,*)'           ztimemin   = ', ztimemin
394         WRITE(numout,*)'           ztimemax1  = ', ztimemax1
395         WRITE(numout,*)'           ztimemin1  = ', ztimemin1
396         WRITE(numout,*)'           ztimemax2  = ', ztimemax2
397         WRITE(numout,*)'           ztimemin2  = ', ztimemin2
398         WRITE(numout,*)'           zyear0     = ', zyear0
399         WRITE(numout,*)'           zmonth0    = ', zmonth0
400         WRITE(numout,*)'           zday0      = ', zday0
401         WRITE(numout,*)'           zday_year0 = ', zday_year0
402         WRITE(numout,*)'           zyydd      = ', zyydd
403         WRITE(numout,*)'           zemp_S     = ', zemp_S
404         WRITE(numout,*)'           zemp_N     = ', zemp_N
405         WRITE(numout,*)'           zemp_sais  = ', zemp_sais
406         WRITE(numout,*)'           zTstar     = ', zTstar
407         WRITE(numout,*)'           zsumemp    = ', zsumemp
408         WRITE(numout,*)'           zsurf      = ', zsurf
409         WRITE(numout,*)'           ztrp       = ', ztrp
410         WRITE(numout,*)'           zconv      = ', zconv
411         WRITE(numout,*)'           ndastp     = ', ndastp
412         WRITE(numout,*)'           adatrj     = ', adatrj
413      ENDIF
414      !
415   END SUBROUTINE sbc_gyre
416
417   !!======================================================================
418END MODULE sbcana
Note: See TracBrowser for help on using the repository browser.