New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcblk_core.F90 in branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC/sbcblk_core.F90 @ 6824

Last change on this file since 6824 was 6824, checked in by clem, 8 years ago

update from trunk
  • Property svn:keywords set to Id
File size: 54.8 KB
Line 
1MODULE sbcblk_core
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_core  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2004-08  (U. Schweckendiek)  Original code
7   !!            2.0  !  2005-04  (L. Brodeau, A.M. Treguier) additions:
8   !!                           -  new bulk routine for efficiency
9   !!                           -  WINDS ARE NOW ASSUMED TO BE AT T POINTS in input files !!!!
10   !!                           -  file names and file characteristics in namelist
11   !!                           -  Implement reading of 6-hourly fields
12   !!            3.0  !  2006-06  (G. Madec) sbc rewritting
13   !!             -   !  2006-12  (L. Brodeau) Original code for turb_core_2z
14   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
15   !!            3.3  !  2010-10  (S. Masson)  add diurnal cycle
16   !!            3.4  !  2011-11  (C. Harris) Fill arrays required by CICE
17   !!            3.7  !  2014-06  (L. Brodeau) simplification and optimization of CORE bulk
18   !!            4.0  !  2016-06  (C. Rousset) Add new param of drags with sea-ice (Lupkes at al 2012)
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   sbc_blk_core    : bulk formulation as ocean surface boundary condition (forced mode, CORE bulk formulea)
23   !!   blk_oce_core    : computes momentum, heat and freshwater fluxes over ocean
24   !!   blk_ice_core    : computes momentum, heat and freshwater fluxes over ice
25   !!   turb_core_2z    : Computes turbulent transfert coefficients
26   !!   cd_neutral_10m  : Estimate of the neutral drag coefficient at 10m
27   !!   psi_m           : universal profile stability function for momentum
28   !!   psi_h           : universal profile stability function for temperature and humidity
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE phycst          ! physical constants
33   USE fldread         ! read input fields
34   USE sbc_oce         ! Surface boundary condition: ocean fields
35   USE cyclone         ! Cyclone 10m wind form trac of cyclone centres
36   USE sbcdcy          ! surface boundary condition: diurnal cycle
37   USE iom             ! I/O manager library
38   USE in_out_manager  ! I/O manager
39   USE lib_mpp         ! distribued memory computing library
40   USE wrk_nemo        ! work arrays
41   USE timing          ! Timing
42   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
43   USE prtctl          ! Print control
44   USE sbcwave, ONLY   :  cdn_wave ! wave module
45   USE sbc_ice         ! Surface boundary condition: ice fields
46   USE lib_fortran     ! to use key_nosignedzero
47#if defined key_lim3
48   USE ice, ONLY       : u_ice, v_ice, jpl, pfrld, a_i_b, at_i_b
49   USE limthd_dh       ! for CALL lim_thd_snwblow
50#elif defined key_lim2
51   USE ice_2, ONLY     : u_ice, v_ice
52   USE par_ice_2
53#endif
54
55   IMPLICIT NONE
56   PRIVATE
57
58   PUBLIC   sbc_blk_core         ! routine called in sbcmod module
59#if defined key_lim2 || defined key_lim3
60   PUBLIC   blk_ice_core_tau     ! routine called in sbc_ice_lim module
61   PUBLIC   blk_ice_core_flx     ! routine called in sbc_ice_lim module
62#endif
63   PUBLIC   turb_core_2z         ! routine called in sbcblk_mfs module
64
65   INTEGER , PARAMETER ::   jpfld   = 9           ! maximum number of files to read
66   INTEGER , PARAMETER ::   jp_wndi = 1           ! index of 10m wind velocity (i-component) (m/s)    at T-point
67   INTEGER , PARAMETER ::   jp_wndj = 2           ! index of 10m wind velocity (j-component) (m/s)    at T-point
68   INTEGER , PARAMETER ::   jp_humi = 3           ! index of specific humidity               ( % )
69   INTEGER , PARAMETER ::   jp_qsr  = 4           ! index of solar heat                      (W/m2)
70   INTEGER , PARAMETER ::   jp_qlw  = 5           ! index of Long wave                       (W/m2)
71   INTEGER , PARAMETER ::   jp_tair = 6           ! index of 10m air temperature             (Kelvin)
72   INTEGER , PARAMETER ::   jp_prec = 7           ! index of total precipitation (rain+snow) (Kg/m2/s)
73   INTEGER , PARAMETER ::   jp_snow = 8           ! index of snow (solid prcipitation)       (kg/m2/s)
74   INTEGER , PARAMETER ::   jp_tdif = 9           ! index of tau diff associated to HF tau   (N/m2)   at T-point
75
76   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf   ! structure of input fields (file informations, fields read)
77
78   !                                             !!! CORE bulk parameters
79   REAL(wp), PARAMETER ::   rhoa   =    1.22        ! air density
80   REAL(wp), PARAMETER ::   cpa    = 1000.5         ! specific heat of air
81   REAL(wp), PARAMETER ::   Lv     =    2.5e6       ! latent heat of vaporization
82   REAL(wp), PARAMETER ::   Ls     =    2.839e6     ! latent heat of sublimation
83   REAL(wp), PARAMETER ::   Stef   =    5.67e-8     ! Stefan Boltzmann constant
84   REAL(wp), PARAMETER ::   Cd_ice =    1.4e-3      ! transfer coefficient over ice
85   REAL(wp), PARAMETER ::   albo   =    0.066       ! ocean albedo assumed to be constant
86
87   !                                  !!* Namelist namsbc_core : CORE bulk parameters
88   LOGICAL  ::   ln_taudif   ! logical flag to use the "mean of stress module - module of mean stress" data
89   REAL(wp) ::   rn_pfac     ! multiplication factor for precipitation
90   REAL(wp) ::   rn_efac     ! multiplication factor for evaporation (clem)
91   REAL(wp) ::   rn_vfac     ! multiplication factor for ice/ocean velocity in the calculation of wind stress (clem)
92   REAL(wp) ::   rn_zqt      ! z(q,t) : height of humidity and temperature measurements
93   REAL(wp) ::   rn_zu       ! z(u)   : height of wind measurements
94   LOGICAL  ::   ln_Cd_L12 = .FALSE. !  Modify the drag ice-atm and oce-atm depending on ice concentration (from Lupkes et al. JGR2012)
95
96   !
97   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   Cd_oce   ! air-ocean drag (clem)
98   
99   !! * Substitutions
100#  include "domzgr_substitute.h90"
101#  include "vectopt_loop_substitute.h90"
102   !!----------------------------------------------------------------------
103   !! NEMO/OPA 3.7 , NEMO-consortium (2014)
104   !! $Id$
105   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
106   !!----------------------------------------------------------------------
107CONTAINS
108
109   INTEGER FUNCTION sbc_blk_core_alloc()
110      !!-------------------------------------------------------------------
111      !!             ***  ROUTINE sbc_blk_core_alloc (clem) ***
112      !!-------------------------------------------------------------------
113      ALLOCATE( Cd_oce(jpi,jpj) , STAT=sbc_blk_core_alloc )
114      !
115      IF( lk_mpp                  )   CALL mpp_sum( sbc_blk_core_alloc )
116      IF( sbc_blk_core_alloc /= 0 )   CALL ctl_warn('sbc_blk_core_alloc: failed to allocate arrays')
117   END FUNCTION sbc_blk_core_alloc
118
119   
120   SUBROUTINE sbc_blk_core( kt )
121      !!---------------------------------------------------------------------
122      !!                    ***  ROUTINE sbc_blk_core  ***
123      !!
124      !! ** Purpose :   provide at each time step the surface ocean fluxes
125      !!      (momentum, heat, freshwater and runoff)
126      !!
127      !! ** Method  : (1) READ each fluxes in NetCDF files:
128      !!      the 10m wind velocity (i-component) (m/s)    at T-point
129      !!      the 10m wind velocity (j-component) (m/s)    at T-point
130      !!      the 10m or 2m specific humidity     ( % )
131      !!      the solar heat                      (W/m2)
132      !!      the Long wave                       (W/m2)
133      !!      the 10m or 2m air temperature       (Kelvin)
134      !!      the total precipitation (rain+snow) (Kg/m2/s)
135      !!      the snow (solid prcipitation)       (kg/m2/s)
136      !!      the tau diff associated to HF tau   (N/m2)   at T-point   (ln_taudif=T)
137      !!              (2) CALL blk_oce_core
138      !!
139      !!      C A U T I O N : never mask the surface stress fields
140      !!                      the stress is assumed to be in the (i,j) mesh referential
141      !!
142      !! ** Action  :   defined at each time-step at the air-sea interface
143      !!              - utau, vtau  i- and j-component of the wind stress
144      !!              - taum        wind stress module at T-point
145      !!              - wndm        wind speed  module at T-point over free ocean or leads in presence of sea-ice
146      !!              - qns, qsr    non-solar and solar heat fluxes
147      !!              - emp         upward mass flux (evapo. - precip.)
148      !!              - sfx         salt flux due to freezing/melting (non-zero only if ice is present)
149      !!                            (set in limsbc(_2).F90)
150      !!
151      !! ** References :   Large & Yeager, 2004 / Large & Yeager, 2008
152      !!                   Brodeau et al. Ocean Modelling 2010
153      !!----------------------------------------------------------------------
154      INTEGER, INTENT(in) ::   kt   ! ocean time step
155      !
156      INTEGER  ::   ierror   ! return error code
157      INTEGER  ::   ifpr     ! dummy loop indice
158      INTEGER  ::   jfld     ! dummy loop arguments
159      INTEGER  ::   ios      ! Local integer output status for namelist read
160      !
161      CHARACTER(len=100) ::  cn_dir   !   Root directory for location of core files
162      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i     ! array of namelist informations on the fields to read
163      TYPE(FLD_N) ::   sn_wndi, sn_wndj, sn_humi, sn_qsr       ! informations about the fields to be read
164      TYPE(FLD_N) ::   sn_qlw , sn_tair, sn_prec, sn_snow      !   "                                 "
165      TYPE(FLD_N) ::   sn_tdif                                 !   "                                 "
166      NAMELIST/namsbc_core/ cn_dir , ln_taudif, rn_pfac, rn_efac, rn_vfac,  &
167         &                  sn_wndi, sn_wndj, sn_humi  , sn_qsr ,           &
168         &                  sn_qlw , sn_tair, sn_prec  , sn_snow,           &
169         &                  sn_tdif, rn_zqt,  rn_zu    , ln_Cd_L12
170      !!---------------------------------------------------------------------
171      !
172      !                                         ! ====================== !
173      IF( kt == nit000 ) THEN                   !  First call kt=nit000  !
174         !                                      ! ====================== !
175         !
176         !                                      ! allocate sbc_blk_core array (clem)
177         IF( sbc_blk_core_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_blk_core : unable to allocate standard arrays' )
178         !
179         REWIND( numnam_ref )              ! Namelist namsbc_core in reference namelist : CORE bulk parameters
180         READ  ( numnam_ref, namsbc_core, IOSTAT = ios, ERR = 901)
181901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_core in reference namelist', lwp )
182         !
183         REWIND( numnam_cfg )              ! Namelist namsbc_core in configuration namelist : CORE bulk parameters
184         READ  ( numnam_cfg, namsbc_core, IOSTAT = ios, ERR = 902 )
185902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_core in configuration namelist', lwp )
186
187         IF(lwm) WRITE( numond, namsbc_core )
188         !                                         ! check: do we plan to use ln_dm2dc with non-daily forcing?
189         IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 )   &
190            &   CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' )
191         IF( ln_dm2dc .AND. sn_qsr%ln_tint ) THEN
192            CALL ctl_warn( 'sbc_blk_core: ln_dm2dc is taking care of the temporal interpolation of daily qsr',   &
193               &         '              ==> We force time interpolation = .false. for qsr' )
194            sn_qsr%ln_tint = .false.
195         ENDIF
196         !                                         ! store namelist information in an array
197         slf_i(jp_wndi) = sn_wndi   ;   slf_i(jp_wndj) = sn_wndj
198         slf_i(jp_qsr ) = sn_qsr    ;   slf_i(jp_qlw ) = sn_qlw
199         slf_i(jp_tair) = sn_tair   ;   slf_i(jp_humi) = sn_humi
200         slf_i(jp_prec) = sn_prec   ;   slf_i(jp_snow) = sn_snow
201         slf_i(jp_tdif) = sn_tdif
202         !
203         lhftau = ln_taudif                        ! do we use HF tau information?
204         jfld = jpfld - COUNT( (/.NOT. lhftau/) )
205         !
206         ALLOCATE( sf(jfld), STAT=ierror )         ! set sf structure
207         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_blk_core: unable to allocate sf structure' )
208         DO ifpr= 1, jfld
209            ALLOCATE( sf(ifpr)%fnow(jpi,jpj,1) )
210            IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf(ifpr)%fdta(jpi,jpj,1,2) )
211         END DO
212         !                                         ! fill sf with slf_i and control print
213         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_core', 'flux formulation for ocean surface boundary condition', 'namsbc_core' )
214         !
215         sfx(:,:) = 0._wp                          ! salt flux; zero unless ice is present (computed in limsbc(_2).F90)
216         !
217      ENDIF
218
219      CALL fld_read( kt, nn_fsbc, sf )             ! input fields provided at the current time-step
220
221      !                                            ! compute the surface ocean fluxes using CORE bulk formulea
222      IF( MOD( kt - 1, nn_fsbc ) == 0 )   CALL blk_oce_core( kt, sf, sst_m, ssu_m, ssv_m )
223
224#if defined key_cice
225      IF( MOD( kt - 1, nn_fsbc ) == 0 )   THEN
226         qlw_ice(:,:,1)   = sf(jp_qlw)%fnow(:,:,1) 
227         IF( ln_dm2dc ) THEN  ;  qsr_ice(:,:,1) = sbc_dcy(sf(jp_qsr)%fnow(:,:,1) )
228         ELSE                 ;  qsr_ice(:,:,1) = sf(jp_qsr)%fnow(:,:,1)
229         ENDIF 
230         tatm_ice(:,:)    = sf(jp_tair)%fnow(:,:,1)         
231         qatm_ice(:,:)    = sf(jp_humi)%fnow(:,:,1)
232         tprecip(:,:)     = sf(jp_prec)%fnow(:,:,1) * rn_pfac
233         sprecip(:,:)     = sf(jp_snow)%fnow(:,:,1) * rn_pfac
234         wndi_ice(:,:)    = sf(jp_wndi)%fnow(:,:,1)
235         wndj_ice(:,:)    = sf(jp_wndj)%fnow(:,:,1)
236      ENDIF
237#endif
238      !
239   END SUBROUTINE sbc_blk_core
240   
241   
242   SUBROUTINE blk_oce_core( kt, sf, pst, pu, pv )
243      !!---------------------------------------------------------------------
244      !!                     ***  ROUTINE blk_core  ***
245      !!
246      !! ** Purpose :   provide the momentum, heat and freshwater fluxes at
247      !!      the ocean surface at each time step
248      !!
249      !! ** Method  :   CORE bulk formulea for the ocean using atmospheric
250      !!      fields read in sbc_read
251      !!
252      !! ** Outputs : - utau    : i-component of the stress at U-point  (N/m2)
253      !!              - vtau    : j-component of the stress at V-point  (N/m2)
254      !!              - taum    : Wind stress module at T-point         (N/m2)
255      !!              - wndm    : Wind speed module at T-point          (m/s)
256      !!              - qsr     : Solar heat flux over the ocean        (W/m2)
257      !!              - qns     : Non Solar heat flux over the ocean    (W/m2)
258      !!              - emp     : evaporation minus precipitation       (kg/m2/s)
259      !!
260      !!  ** Nota  :   sf has to be a dummy argument for AGRIF on NEC
261      !!---------------------------------------------------------------------
262      INTEGER  , INTENT(in   )                 ::   kt    ! time step index
263      TYPE(fld), INTENT(inout), DIMENSION(:)   ::   sf    ! input data
264      REAL(wp) , INTENT(in)   , DIMENSION(:,:) ::   pst   ! surface temperature                      [Celcius]
265      REAL(wp) , INTENT(in)   , DIMENSION(:,:) ::   pu    ! surface current at U-point (i-component) [m/s]
266      REAL(wp) , INTENT(in)   , DIMENSION(:,:) ::   pv    ! surface current at V-point (j-component) [m/s]
267      !
268      INTEGER  ::   ji, jj               ! dummy loop indices
269      REAL(wp) ::   zcoef_qsatw, zztmp   ! local variable
270      REAL(wp), DIMENSION(:,:), POINTER ::   zwnd_i, zwnd_j    ! wind speed components at T-point
271      REAL(wp), DIMENSION(:,:), POINTER ::   zqsatw            ! specific humidity at pst
272      REAL(wp), DIMENSION(:,:), POINTER ::   zqlw, zqsb        ! long wave and sensible heat fluxes
273      REAL(wp), DIMENSION(:,:), POINTER ::   zqla, zevap       ! latent heat fluxes and evaporation
274      REAL(wp), DIMENSION(:,:), POINTER ::   Cd                ! transfer coefficient for momentum      (tau)
275      REAL(wp), DIMENSION(:,:), POINTER ::   Ch                ! transfer coefficient for sensible heat (Q_sens)
276      REAL(wp), DIMENSION(:,:), POINTER ::   Ce                ! tansfert coefficient for evaporation   (Q_lat)
277      REAL(wp), DIMENSION(:,:), POINTER ::   zst               ! surface temperature in Kelvin
278      REAL(wp), DIMENSION(:,:), POINTER ::   zt_zu             ! air temperature at wind speed height
279      REAL(wp), DIMENSION(:,:), POINTER ::   zq_zu             ! air spec. hum.  at wind speed height
280      !!---------------------------------------------------------------------
281      !
282      IF( nn_timing == 1 )  CALL timing_start('blk_oce_core')
283      !
284      CALL wrk_alloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zqlw, zqsb, zqla, zevap )
285      CALL wrk_alloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu )
286      !
287      ! local scalars ( place there for vector optimisation purposes)
288      zcoef_qsatw = 0.98 * 640380. / rhoa
289     
290      zst(:,:) = pst(:,:) + rt0      ! convert SST from Celcius to Kelvin (and set minimum value far above 0 K)
291
292      ! ----------------------------------------------------------------------------- !
293      !      0   Wind components and module at T-point relative to the moving ocean   !
294      ! ----------------------------------------------------------------------------- !
295
296      ! ... components ( U10m - U_oce ) at T-point (unmasked)
297      zwnd_i(:,:) = 0.e0 
298      zwnd_j(:,:) = 0.e0
299#if defined key_cyclone
300      CALL wnd_cyc( kt, zwnd_i, zwnd_j )    ! add analytical tropical cyclone (Vincent et al. JGR 2012)
301      DO jj = 2, jpjm1
302         DO ji = fs_2, fs_jpim1   ! vect. opt.
303            sf(jp_wndi)%fnow(ji,jj,1) = sf(jp_wndi)%fnow(ji,jj,1) + zwnd_i(ji,jj)
304            sf(jp_wndj)%fnow(ji,jj,1) = sf(jp_wndj)%fnow(ji,jj,1) + zwnd_j(ji,jj)
305         END DO
306      END DO
307#endif
308      DO jj = 2, jpjm1
309         DO ji = fs_2, fs_jpim1   ! vect. opt.
310            zwnd_i(ji,jj) = (  sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pu(ji-1,jj  ) + pu(ji,jj) )  )
311            zwnd_j(ji,jj) = (  sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pv(ji  ,jj-1) + pv(ji,jj) )  )
312         END DO
313      END DO
314      CALL lbc_lnk( zwnd_i(:,:) , 'T', -1. )
315      CALL lbc_lnk( zwnd_j(:,:) , 'T', -1. )
316      ! ... scalar wind ( = | U10m - U_oce | ) at T-point (masked)
317      wndm(:,:) = SQRT(  zwnd_i(:,:) * zwnd_i(:,:)   &
318         &             + zwnd_j(:,:) * zwnd_j(:,:)  ) * tmask(:,:,1)
319
320      ! ----------------------------------------------------------------------------- !
321      !      I   Radiative FLUXES                                                     !
322      ! ----------------------------------------------------------------------------- !
323
324      ! ocean albedo assumed to be constant + modify now Qsr to include the diurnal cycle                    ! Short Wave
325      zztmp = 1. - albo
326      IF( ln_dm2dc ) THEN   ;   qsr(:,:) = zztmp * sbc_dcy( sf(jp_qsr)%fnow(:,:,1) ) * tmask(:,:,1)
327      ELSE                  ;   qsr(:,:) = zztmp *          sf(jp_qsr)%fnow(:,:,1)   * tmask(:,:,1)
328      ENDIF
329
330      zqlw(:,:) = (  sf(jp_qlw)%fnow(:,:,1) - Stef * zst(:,:)*zst(:,:)*zst(:,:)*zst(:,:)  ) * tmask(:,:,1)   ! Long  Wave
331      ! ----------------------------------------------------------------------------- !
332      !     II    Turbulent FLUXES                                                    !
333      ! ----------------------------------------------------------------------------- !
334
335      ! ... specific humidity at SST and IST
336      zqsatw(:,:) = zcoef_qsatw * EXP( -5107.4 / zst(:,:) )
337
338      ! ... NCAR Bulk formulae, computation of Cd, Ch, Ce at T-point :
339      CALL turb_core_2z( rn_zqt, rn_zu, zst, sf(jp_tair)%fnow, zqsatw, sf(jp_humi)%fnow, wndm,   &
340         &               Cd, Ch, Ce, zt_zu, zq_zu )
341   
342      ! Make ocean-atm. drag dependent on ice concentration (see Lupkes et al. 2012) (clem)
343#if defined key_lim3
344      IF( ln_Cd_L12 ) THEN
345
346         Cd_oce(:,:) = Cd(:,:)    ! record value of pure ocean-atm. drag
347
348         CALL Cdn10_Lupkes2012( Cd )  ! calculate new drag from Lupkes(2012) equations
349
350      ENDIF
351#endif
352     
353      ! ... tau module, i and j component
354      DO jj = 1, jpj
355         DO ji = 1, jpi
356            zztmp = rhoa * wndm(ji,jj) * Cd(ji,jj)
357            taum  (ji,jj) = zztmp * wndm  (ji,jj)
358            zwnd_i(ji,jj) = zztmp * zwnd_i(ji,jj)
359            zwnd_j(ji,jj) = zztmp * zwnd_j(ji,jj)
360         END DO
361      END DO
362
363      ! ... add the HF tau contribution to the wind stress module?
364      IF( lhftau ) THEN
365         taum(:,:) = taum(:,:) + sf(jp_tdif)%fnow(:,:,1)
366      ENDIF
367      CALL iom_put( "taum_oce", taum )   ! output wind stress module
368
369      ! ... utau, vtau at U- and V_points, resp.
370      !     Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines
371      !     Note the use of MAX(tmask(i,j),tmask(i+1,j) is to mask tau over ice shelves
372      DO jj = 1, jpjm1
373         DO ji = 1, fs_jpim1
374            utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj  ) ) &
375               &          * MAX(tmask(ji,jj,1),tmask(ji+1,jj,1))
376            vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji  ,jj+1) ) &
377               &          * MAX(tmask(ji,jj,1),tmask(ji,jj+1,1))
378         END DO
379      END DO
380      CALL lbc_lnk( utau(:,:), 'U', -1. )
381      CALL lbc_lnk( vtau(:,:), 'V', -1. )
382
383   
384      !  Turbulent fluxes over ocean
385      ! -----------------------------
386      IF( ABS( rn_zu - rn_zqt) < 0.01_wp ) THEN
387         !! q_air and t_air are (or "are almost") given at 10m (wind reference height)
388         zevap(:,:) = rn_efac*MAX( 0._wp,     rhoa*Ce(:,:)*( zqsatw(:,:) - sf(jp_humi)%fnow(:,:,1) )*wndm(:,:) ) ! Evaporation
389         zqsb (:,:) =                     cpa*rhoa*Ch(:,:)*( zst   (:,:) - sf(jp_tair)%fnow(:,:,1) )*wndm(:,:)   ! Sensible Heat
390      ELSE
391         !! q_air and t_air are not given at 10m (wind reference height)
392         ! Values of temp. and hum. adjusted to height of wind during bulk algorithm iteration must be used!!!
393         zevap(:,:) = rn_efac*MAX( 0._wp,     rhoa*Ce(:,:)*( zqsatw(:,:) - zq_zu(:,:) )*wndm(:,:) )   ! Evaporation
394         zqsb (:,:) =                     cpa*rhoa*Ch(:,:)*( zst   (:,:) - zt_zu(:,:) )*wndm(:,:)     ! Sensible Heat
395      ENDIF
396      zqla (:,:) = Lv * zevap(:,:)                                                              ! Latent Heat
397
398      IF(ln_ctl) THEN
399         CALL prt_ctl( tab2d_1=zqla  , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=Ce , clinfo2=' Ce  : ' )
400         CALL prt_ctl( tab2d_1=zqsb  , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=Ch , clinfo2=' Ch  : ' )
401         CALL prt_ctl( tab2d_1=zqlw  , clinfo1=' blk_oce_core: zqlw   : ', tab2d_2=qsr, clinfo2=' qsr : ' )
402         CALL prt_ctl( tab2d_1=zqsatw, clinfo1=' blk_oce_core: zqsatw : ', tab2d_2=zst, clinfo2=' zst : ' )
403         CALL prt_ctl( tab2d_1=utau  , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
404            &          tab2d_2=vtau  , clinfo2=              ' vtau : '  , mask2=vmask )
405         CALL prt_ctl( tab2d_1=wndm  , clinfo1=' blk_oce_core: wndm   : ')
406         CALL prt_ctl( tab2d_1=zst   , clinfo1=' blk_oce_core: zst    : ')
407      ENDIF
408       
409      ! ----------------------------------------------------------------------------- !
410      !     III    Total FLUXES                                                       !
411      ! ----------------------------------------------------------------------------- !
412      !
413      emp (:,:) = (  zevap(:,:)                                          &   ! mass flux (evap. - precip.)
414         &         - sf(jp_prec)%fnow(:,:,1) * rn_pfac  ) * tmask(:,:,1)
415      !
416      qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)                                &   ! Downward Non Solar
417         &     - sf(jp_snow)%fnow(:,:,1) * rn_pfac * lfus                         &   ! remove latent melting heat for solid precip
418         &     - zevap(:,:) * pst(:,:) * rcp                                      &   ! remove evap heat content at SST
419         &     + ( sf(jp_prec)%fnow(:,:,1) - sf(jp_snow)%fnow(:,:,1) ) * rn_pfac  &   ! add liquid precip heat content at Tair
420         &     * ( sf(jp_tair)%fnow(:,:,1) - rt0 ) * rcp                          &
421         &     + sf(jp_snow)%fnow(:,:,1) * rn_pfac                                &   ! add solid  precip heat content at min(Tair,Tsnow)
422         &     * ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic * tmask(:,:,1)
423      !
424#if defined key_lim3
425      qns_oce(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)                                ! non solar without emp (only needed by LIM3)
426      qsr_oce(:,:) = qsr(:,:)
427#endif
428      !
429      IF ( nn_ice == 0 ) THEN
430         CALL iom_put( "qlw_oce" ,   zqlw )                 ! output downward longwave heat over the ocean
431         CALL iom_put( "qsb_oce" , - zqsb )                 ! output downward sensible heat over the ocean
432         CALL iom_put( "qla_oce" , - zqla )                 ! output downward latent   heat over the ocean
433         CALL iom_put( "qemp_oce",   qns-zqlw+zqsb+zqla )   ! output downward heat content of E-P over the ocean
434         CALL iom_put( "qns_oce" ,   qns  )                 ! output downward non solar heat over the ocean
435         CALL iom_put( "qsr_oce" ,   qsr  )                 ! output downward solar heat over the ocean
436         CALL iom_put( "qt_oce"  ,   qns+qsr )              ! output total downward heat over the ocean
437         tprecip(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac   ! output total precipitation [kg/m2/s]
438         sprecip(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac   ! output solid precipitation [kg/m2/s]
439         CALL iom_put( 'snowpre', sprecip * 86400. )        ! Snow
440         CALL iom_put( 'precip' , tprecip * 86400. )        ! Total precipitation
441      ENDIF
442      !
443      IF(ln_ctl) THEN
444         CALL prt_ctl(tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=zqlw , clinfo2=' zqlw  : ')
445         CALL prt_ctl(tab2d_1=zqla , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=qsr  , clinfo2=' qsr   : ')
446         CALL prt_ctl(tab2d_1=pst  , clinfo1=' blk_oce_core: pst    : ', tab2d_2=emp  , clinfo2=' emp   : ')
447         CALL prt_ctl(tab2d_1=utau , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
448            &         tab2d_2=vtau , clinfo2=              ' vtau  : ' , mask2=vmask )
449      ENDIF
450      !
451      CALL wrk_dealloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zqlw, zqsb, zqla, zevap )
452      CALL wrk_dealloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu )
453      !
454      IF( nn_timing == 1 )  CALL timing_stop('blk_oce_core')
455      !
456   END SUBROUTINE blk_oce_core
457 
458   
459#if defined key_lim2 || defined key_lim3
460   SUBROUTINE blk_ice_core_tau
461      !!---------------------------------------------------------------------
462      !!                     ***  ROUTINE blk_ice_core_tau  ***
463      !!
464      !! ** Purpose :   provide the surface boundary condition over sea-ice
465      !!
466      !! ** Method  :   compute momentum using CORE bulk
467      !!                formulea, ice variables and read atmospheric fields.
468      !!                NB: ice drag coefficient is assumed to be a constant
469      !!---------------------------------------------------------------------
470      INTEGER  ::   ji, jj    ! dummy loop indices
471      REAL(wp) ::   zwnorm_f, zwndi_f , zwndj_f               ! relative wind module and components at F-point
472      REAL(wp) ::             zwndi_t , zwndj_t               ! relative wind components at T-point
473      REAL(wp), DIMENSION(:,:), POINTER ::   Cd               ! transfer coefficient for momentum      (tau)
474      !!---------------------------------------------------------------------
475      !
476      IF( nn_timing == 1 )  CALL timing_start('blk_ice_core_tau')
477      !
478      CALL wrk_alloc( jpi,jpj, Cd )
479
480      Cd(:,:) = Cd_ice
481     
482      ! Make ice-atm. drag dependent on ice concentration (see Lupkes et al. 2012) (clem)
483#if defined key_lim3
484      IF( ln_Cd_L12 ) THEN
485
486         CALL Cdn10_Lupkes2012( Cd ) ! calculate new drag from Lupkes(2012) equations
487
488      ENDIF
489#endif
490
491!!gm brutal....
492      utau_ice  (:,:) = 0._wp
493      vtau_ice  (:,:) = 0._wp
494      wndm_ice  (:,:) = 0._wp
495!!gm end
496
497      ! ----------------------------------------------------------------------------- !
498      !    Wind components and module relative to the moving ocean ( U10m - U_ice )   !
499      ! ----------------------------------------------------------------------------- !
500      SELECT CASE( cp_ice_msh )
501      CASE( 'I' )                  ! B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
502         !                           and scalar wind at T-point ( = | U10m - U_ice | ) (masked)
503         DO jj = 2, jpjm1
504            DO ji = 2, jpim1   ! B grid : NO vector opt
505               ! ... scalar wind at I-point (fld being at T-point)
506               zwndi_f = 0.25 * (  sf(jp_wndi)%fnow(ji-1,jj  ,1) + sf(jp_wndi)%fnow(ji  ,jj  ,1)   &
507                  &              + sf(jp_wndi)%fnow(ji-1,jj-1,1) + sf(jp_wndi)%fnow(ji  ,jj-1,1)  ) - rn_vfac * u_ice(ji,jj)
508               zwndj_f = 0.25 * (  sf(jp_wndj)%fnow(ji-1,jj  ,1) + sf(jp_wndj)%fnow(ji  ,jj  ,1)   &
509                  &              + sf(jp_wndj)%fnow(ji-1,jj-1,1) + sf(jp_wndj)%fnow(ji  ,jj-1,1)  ) - rn_vfac * v_ice(ji,jj)
510               zwnorm_f = rhoa * Cd(ji,jj) * SQRT( zwndi_f * zwndi_f + zwndj_f * zwndj_f )
511               ! ... ice stress at I-point
512               utau_ice(ji,jj) = zwnorm_f * zwndi_f
513               vtau_ice(ji,jj) = zwnorm_f * zwndj_f
514               ! ... scalar wind at T-point (fld being at T-point)
515               zwndi_t = sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.25 * (  u_ice(ji,jj+1) + u_ice(ji+1,jj+1)   &
516                  &                                                    + u_ice(ji,jj  ) + u_ice(ji+1,jj  )  )
517               zwndj_t = sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.25 * (  v_ice(ji,jj+1) + v_ice(ji+1,jj+1)   &
518                  &                                                    + v_ice(ji,jj  ) + v_ice(ji+1,jj  )  )
519               wndm_ice(ji,jj) = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
520            END DO
521         END DO
522         CALL lbc_lnk( utau_ice, 'I', -1. )
523         CALL lbc_lnk( vtau_ice, 'I', -1. )
524         CALL lbc_lnk( wndm_ice, 'T',  1. )
525         !
526      CASE( 'C' )                  ! C-grid ice dynamics :   U & V-points (same as ocean)
527         DO jj = 2, jpj
528            DO ji = fs_2, jpi   ! vect. opt.
529               zwndi_t = (  sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( u_ice(ji-1,jj  ) + u_ice(ji,jj) )  )
530               zwndj_t = (  sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( v_ice(ji  ,jj-1) + v_ice(ji,jj) )  )
531               wndm_ice(ji,jj) = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
532            END DO
533         END DO
534         DO jj = 2, jpjm1
535            DO ji = fs_2, fs_jpim1   ! vect. opt.
536               utau_ice(ji,jj) = rhoa * Cd(ji,jj) * 0.5_wp * ( wndm_ice(ji+1,jj  ) + wndm_ice(ji,jj) )                          &
537                  &          * ( 0.5 * (sf(jp_wndi)%fnow(ji+1,jj,1) + sf(jp_wndi)%fnow(ji,jj,1) ) - rn_vfac * u_ice(ji,jj) )
538               vtau_ice(ji,jj) = rhoa * Cd(ji,jj) * 0.5_wp * ( wndm_ice(ji,jj+1  ) + wndm_ice(ji,jj) )                          &
539                  &          * ( 0.5 * (sf(jp_wndj)%fnow(ji,jj+1,1) + sf(jp_wndj)%fnow(ji,jj,1) ) - rn_vfac * v_ice(ji,jj) )
540            END DO
541         END DO
542         CALL lbc_lnk( utau_ice, 'U', -1. )
543         CALL lbc_lnk( vtau_ice, 'V', -1. )
544         CALL lbc_lnk( wndm_ice, 'T',  1. )
545         !
546      END SELECT
547
548      IF(ln_ctl) THEN
549         CALL prt_ctl(tab2d_1=utau_ice  , clinfo1=' blk_ice_core: utau_ice : ', tab2d_2=vtau_ice  , clinfo2=' vtau_ice : ')
550         CALL prt_ctl(tab2d_1=wndm_ice  , clinfo1=' blk_ice_core: wndm_ice : ')
551      ENDIF
552
553      CALL wrk_dealloc( jpi,jpj, Cd )
554
555      IF( nn_timing == 1 )  CALL timing_stop('blk_ice_core_tau')
556     
557   END SUBROUTINE blk_ice_core_tau
558
559
560   SUBROUTINE blk_ice_core_flx( ptsu, palb )
561      !!---------------------------------------------------------------------
562      !!                     ***  ROUTINE blk_ice_core_flx  ***
563      !!
564      !! ** Purpose :   provide the surface boundary condition over sea-ice
565      !!
566      !! ** Method  :   compute heat and freshwater exchanged
567      !!                between atmosphere and sea-ice using CORE bulk
568      !!                formulea, ice variables and read atmmospheric fields.
569      !!
570      !! caution : the net upward water flux has with mm/day unit
571      !!---------------------------------------------------------------------
572      REAL(wp), DIMENSION(:,:,:), INTENT(in)  ::   ptsu          ! sea ice surface temperature
573      REAL(wp), DIMENSION(:,:,:), INTENT(in)  ::   palb          ! ice albedo (all skies)
574      !!
575      INTEGER  ::   ji, jj, jl    ! dummy loop indices
576      REAL(wp) ::   zst2, zst3
577      REAL(wp) ::   zcoef_dqlw, zcoef_dqla, zcoef_dqsb
578      REAL(wp) ::   zztmp, z1_lsub                               ! temporary variable
579      !!
580      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_qlw             ! long wave heat flux over ice
581      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_qsb             ! sensible  heat flux over ice
582      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_dqlw            ! long wave heat sensitivity over ice
583      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_dqsb            ! sensible  heat sensitivity over ice
584      REAL(wp), DIMENSION(:,:)  , POINTER ::   zevap, zsnw       ! evaporation and snw distribution after wind blowing (LIM3)
585      !!---------------------------------------------------------------------
586      !
587      IF( nn_timing == 1 )  CALL timing_start('blk_ice_core_flx')
588      !
589      CALL wrk_alloc( jpi,jpj,jpl, z_qlw, z_qsb, z_dqlw, z_dqsb ) 
590
591      ! local scalars ( place there for vector optimisation purposes)
592      zcoef_dqlw   = 4.0 * 0.95 * Stef
593      zcoef_dqla   = -Ls * Cd_ice * 11637800. * (-5897.8)
594      zcoef_dqsb   = rhoa * cpa * Cd_ice
595
596      zztmp = 1. / ( 1. - albo )
597      !                                     ! ========================== !
598      DO jl = 1, jpl                        !  Loop over ice categories  !
599         !                                  ! ========================== !
600         DO jj = 1 , jpj
601            DO ji = 1, jpi
602               ! ----------------------------!
603               !      I   Radiative FLUXES   !
604               ! ----------------------------!
605               zst2 = ptsu(ji,jj,jl) * ptsu(ji,jj,jl)
606               zst3 = ptsu(ji,jj,jl) * zst2
607               ! Short Wave (sw)
608               qsr_ice(ji,jj,jl) = zztmp * ( 1. - palb(ji,jj,jl) ) * qsr(ji,jj)
609               ! Long  Wave (lw)
610               z_qlw(ji,jj,jl) = 0.95 * ( sf(jp_qlw)%fnow(ji,jj,1) - Stef * ptsu(ji,jj,jl) * zst3 ) * tmask(ji,jj,1)
611               ! lw sensitivity
612               z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3                                               
613
614               ! ----------------------------!
615               !     II    Turbulent FLUXES  !
616               ! ----------------------------!
617
618               ! ... turbulent heat fluxes
619               ! Sensible Heat
620               z_qsb(ji,jj,jl) = rhoa * cpa * Cd_ice * wndm_ice(ji,jj) * ( ptsu(ji,jj,jl) - sf(jp_tair)%fnow(ji,jj,1) )
621               ! Latent Heat
622               qla_ice(ji,jj,jl) = rn_efac * MAX( 0.e0, rhoa * Ls  * Cd_ice * wndm_ice(ji,jj)   &                           
623                  &                         * (  11637800. * EXP( -5897.8 / ptsu(ji,jj,jl) ) / rhoa - sf(jp_humi)%fnow(ji,jj,1)  ) )
624              ! Latent heat sensitivity for ice (Dqla/Dt)
625               IF( qla_ice(ji,jj,jl) > 0._wp ) THEN
626                  dqla_ice(ji,jj,jl) = rn_efac * zcoef_dqla * wndm_ice(ji,jj) / ( zst2 ) * EXP( -5897.8 / ptsu(ji,jj,jl) )
627               ELSE
628                  dqla_ice(ji,jj,jl) = 0._wp
629               ENDIF
630
631               ! Sensible heat sensitivity (Dqsb_ice/Dtn_ice)
632               z_dqsb(ji,jj,jl) = zcoef_dqsb * wndm_ice(ji,jj)
633
634               ! ----------------------------!
635               !     III    Total FLUXES     !
636               ! ----------------------------!
637               ! Downward Non Solar flux
638               qns_ice (ji,jj,jl) =     z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - qla_ice (ji,jj,jl)
639               ! Total non solar heat flux sensitivity for ice
640               dqns_ice(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + dqla_ice(ji,jj,jl) )
641            END DO
642            !
643         END DO
644         !
645      END DO
646      !
647      tprecip(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac      ! total precipitation [kg/m2/s]
648      sprecip(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac      ! solid precipitation [kg/m2/s]
649      CALL iom_put( 'snowpre', sprecip * 86400. )                  ! Snow precipitation
650      CALL iom_put( 'precip' , tprecip * 86400. )                  ! Total precipitation
651
652#if defined  key_lim3
653      CALL wrk_alloc( jpi,jpj, zevap, zsnw ) 
654
655      ! --- evaporation --- !
656      z1_lsub = 1._wp / Lsub
657      evap_ice (:,:,:) = rn_efac * qla_ice (:,:,:) * z1_lsub    ! sublimation
658      devap_ice(:,:,:) = rn_efac * dqla_ice(:,:,:) * z1_lsub    ! d(sublimation)/dT
659      zevap    (:,:)   = rn_efac * ( emp(:,:) + tprecip(:,:) )  ! evaporation over ocean
660
661      ! --- evaporation minus precipitation --- !
662      zsnw(:,:) = 0._wp
663      CALL lim_thd_snwblow( pfrld, zsnw )  ! snow distribution over ice after wind blowing
664      emp_oce(:,:) = pfrld(:,:) * zevap(:,:) - ( tprecip(:,:) - sprecip(:,:) ) - sprecip(:,:) * (1._wp - zsnw )
665      emp_ice(:,:) = SUM( a_i_b(:,:,:) * evap_ice(:,:,:), dim=3 ) - sprecip(:,:) * zsnw
666      emp_tot(:,:) = emp_oce(:,:) + emp_ice(:,:)
667
668      ! --- heat flux associated with emp --- !
669      qemp_oce(:,:) = - pfrld(:,:) * zevap(:,:) * sst_m(:,:) * rcp                               & ! evap at sst
670         &          + ( tprecip(:,:) - sprecip(:,:) ) * ( sf(jp_tair)%fnow(:,:,1) - rt0 ) * rcp  & ! liquid precip at Tair
671         &          +   sprecip(:,:) * ( 1._wp - zsnw ) *                                        & ! solid precip at min(Tair,Tsnow)
672         &              ( ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic * tmask(:,:,1) - lfus )
673      qemp_ice(:,:) =   sprecip(:,:) * zsnw *                                                    & ! solid precip (only)
674         &              ( ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic * tmask(:,:,1) - lfus )
675
676      ! --- total solar and non solar fluxes --- !
677      qns_tot(:,:) = pfrld(:,:) * qns_oce(:,:) + SUM( a_i_b(:,:,:) * qns_ice(:,:,:), dim=3 ) + qemp_ice(:,:) + qemp_oce(:,:)
678      qsr_tot(:,:) = pfrld(:,:) * qsr_oce(:,:) + SUM( a_i_b(:,:,:) * qsr_ice(:,:,:), dim=3 )
679
680      ! --- heat content of precip over ice in J/m3 (to be used in 1D-thermo) --- !
681      qprec_ice(:,:) = rhosn * ( ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic * tmask(:,:,1) - lfus )
682
683      ! --- heat content of evap over ice in W/m2 (to be used in 1D-thermo) --- !
684      DO jl = 1, jpl
685         qevap_ice(:,:,jl) = 0._wp ! should be -evap_ice(:,:,jl)*( ( Tice - rt0 ) * cpic * tmask(:,:,1) )
686                                   ! But we do not have Tice => consider it at 0°C => evap=0
687      END DO
688
689      CALL wrk_dealloc( jpi,jpj, zevap, zsnw ) 
690#endif
691
692      !--------------------------------------------------------------------
693      ! FRACTIONs of net shortwave radiation which is not absorbed in the
694      ! thin surface layer and penetrates inside the ice cover
695      ! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 )
696      !
697      fr1_i0(:,:) = ( 0.18 * ( 1.0 - cldf_ice ) + 0.35 * cldf_ice )
698      fr2_i0(:,:) = ( 0.82 * ( 1.0 - cldf_ice ) + 0.65 * cldf_ice )
699      !
700      !
701      IF(ln_ctl) THEN
702         CALL prt_ctl(tab3d_1=qla_ice , clinfo1=' blk_ice_core: qla_ice  : ', tab3d_2=z_qsb   , clinfo2=' z_qsb    : ', kdim=jpl)
703         CALL prt_ctl(tab3d_1=z_qlw   , clinfo1=' blk_ice_core: z_qlw    : ', tab3d_2=dqla_ice, clinfo2=' dqla_ice : ', kdim=jpl)
704         CALL prt_ctl(tab3d_1=z_dqsb  , clinfo1=' blk_ice_core: z_dqsb   : ', tab3d_2=z_dqlw  , clinfo2=' z_dqlw   : ', kdim=jpl)
705         CALL prt_ctl(tab3d_1=dqns_ice, clinfo1=' blk_ice_core: dqns_ice : ', tab3d_2=qsr_ice , clinfo2=' qsr_ice  : ', kdim=jpl)
706         CALL prt_ctl(tab3d_1=ptsu    , clinfo1=' blk_ice_core: ptsu     : ', tab3d_2=qns_ice , clinfo2=' qns_ice  : ', kdim=jpl)
707         CALL prt_ctl(tab2d_1=tprecip , clinfo1=' blk_ice_core: tprecip  : ', tab2d_2=sprecip , clinfo2=' sprecip  : ')
708      ENDIF
709
710      CALL wrk_dealloc( jpi,jpj,jpl, z_qlw, z_qsb, z_dqlw, z_dqsb )
711      !
712      IF( nn_timing == 1 )  CALL timing_stop('blk_ice_core_flx')
713     
714   END SUBROUTINE blk_ice_core_flx
715#endif
716
717   SUBROUTINE turb_core_2z( zt, zu, sst, T_zt, q_sat, q_zt, dU,    &
718      &                      Cd, Ch, Ce , T_zu, q_zu )
719      !!----------------------------------------------------------------------
720      !!                      ***  ROUTINE  turb_core  ***
721      !!
722      !! ** Purpose :   Computes turbulent transfert coefficients of surface
723      !!                fluxes according to Large & Yeager (2004) and Large & Yeager (2008)
724      !!                If relevant (zt /= zu), adjust temperature and humidity from height zt to zu
725      !!
726      !! ** Method : Monin Obukhov Similarity Theory
727      !!             + Large & Yeager (2004,2008) closure: CD_n10 = f(U_n10)
728      !!
729      !! ** References :   Large & Yeager, 2004 / Large & Yeager, 2008
730      !!
731      !! ** Last update: Laurent Brodeau, June 2014:
732      !!    - handles both cases zt=zu and zt/=zu
733      !!    - optimized: less 2D arrays allocated and less operations
734      !!    - better first guess of stability by checking air-sea difference of virtual temperature
735      !!       rather than temperature difference only...
736      !!    - added function "cd_neutral_10m" that uses the improved parametrization of
737      !!      Large & Yeager 2008. Drag-coefficient reduction for Cyclone conditions!
738      !!    - using code-wide physical constants defined into "phycst.mod" rather than redifining them
739      !!      => 'vkarmn' and 'grav'
740      !!----------------------------------------------------------------------
741      REAL(wp), INTENT(in   )                     ::   zt       ! height for T_zt and q_zt                   [m]
742      REAL(wp), INTENT(in   )                     ::   zu       ! height for dU                              [m]
743      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   sst      ! sea surface temperature              [Kelvin]
744      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   T_zt     ! potential air temperature            [Kelvin]
745      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_sat    ! sea surface specific humidity         [kg/kg]
746      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_zt     ! specific air humidity                 [kg/kg]
747      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   dU       ! relative wind module at zu            [m/s]
748      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cd       ! transfer coefficient for momentum         (tau)
749      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ch       ! transfer coefficient for sensible heat (Q_sens)
750      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ce       ! transfert coefficient for evaporation   (Q_lat)
751      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   T_zu     ! air temp. shifted at zu                     [K]
752      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   q_zu     ! spec. hum.  shifted at zu               [kg/kg]
753      !
754      INTEGER ::   j_itt
755      INTEGER , PARAMETER ::   nb_itt = 5       ! number of itterations
756      LOGICAL ::   l_zt_equal_zu = .FALSE.      ! if q and t are given at different height than U
757      !
758      REAL(wp), DIMENSION(:,:), POINTER ::   U_zu          ! relative wind at zu                            [m/s]
759      REAL(wp), DIMENSION(:,:), POINTER ::   Ce_n10        ! 10m neutral latent coefficient
760      REAL(wp), DIMENSION(:,:), POINTER ::   Ch_n10        ! 10m neutral sensible coefficient
761      REAL(wp), DIMENSION(:,:), POINTER ::   sqrt_Cd_n10   ! root square of Cd_n10
762      REAL(wp), DIMENSION(:,:), POINTER ::   sqrt_Cd       ! root square of Cd
763      REAL(wp), DIMENSION(:,:), POINTER ::   zeta_u        ! stability parameter at height zu
764      REAL(wp), DIMENSION(:,:), POINTER ::   zeta_t        ! stability parameter at height zt
765      REAL(wp), DIMENSION(:,:), POINTER ::   zpsi_h_u, zpsi_m_u
766      REAL(wp), DIMENSION(:,:), POINTER ::   ztmp0, ztmp1, ztmp2
767      REAL(wp), DIMENSION(:,:), POINTER ::   stab          ! 1st stability test integer
768      !!----------------------------------------------------------------------
769
770      IF( nn_timing == 1 )  CALL timing_start('turb_core_2z')
771   
772      CALL wrk_alloc( jpi,jpj, U_zu, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd )
773      CALL wrk_alloc( jpi,jpj, zeta_u, stab )
774      CALL wrk_alloc( jpi,jpj, zpsi_h_u, zpsi_m_u, ztmp0, ztmp1, ztmp2 )
775
776      l_zt_equal_zu = .FALSE.
777      IF( ABS(zu - zt) < 0.01 ) l_zt_equal_zu = .TRUE.    ! testing "zu == zt" is risky with double precision
778
779      IF( .NOT. l_zt_equal_zu )   CALL wrk_alloc( jpi,jpj, zeta_t )
780
781      U_zu = MAX( 0.5 , dU )   !  relative wind speed at zu (normally 10m), we don't want to fall under 0.5 m/s
782
783      !! First guess of stability:
784      ztmp0 = T_zt*(1. + 0.608*q_zt) - sst*(1. + 0.608*q_sat) ! air-sea difference of virtual pot. temp. at zt
785      stab  = 0.5 + sign(0.5,ztmp0)                           ! stab = 1 if dTv > 0  => STABLE, 0 if unstable
786
787      !! Neutral coefficients at 10m:
788      IF( ln_cdgw ) THEN      ! wave drag case
789         cdn_wave(:,:) = cdn_wave(:,:) + rsmall * ( 1._wp - tmask(:,:,1) )
790         ztmp0   (:,:) = cdn_wave(:,:)
791      ELSE
792         ztmp0 = cd_neutral_10m( U_zu )
793      ENDIF
794      sqrt_Cd_n10 = SQRT( ztmp0 )
795      Ce_n10  = 1.e-3*( 34.6 * sqrt_Cd_n10 )
796      Ch_n10  = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab))
797   
798      !! Initializing transf. coeff. with their first guess neutral equivalents :
799      Cd = ztmp0   ;   Ce = Ce_n10   ;   Ch = Ch_n10   ;   sqrt_Cd = sqrt_Cd_n10
800
801      !! Initializing values at z_u with z_t values:
802      T_zu = T_zt   ;   q_zu = q_zt
803
804      !!  * Now starting iteration loop
805      DO j_itt=1, nb_itt
806         !
807         ztmp1 = T_zu - sst   ! Updating air/sea differences
808         ztmp2 = q_zu - q_sat 
809
810         ! Updating turbulent scales :   (L&Y 2004 eq. (7))
811         ztmp1  = Ch/sqrt_Cd*ztmp1    ! theta*
812         ztmp2  = Ce/sqrt_Cd*ztmp2    ! q*
813       
814         ztmp0 = T_zu*(1. + 0.608*q_zu) ! virtual potential temperature at zu
815
816         ! Estimate the inverse of Monin-Obukov length (1/L) at height zu:
817         ztmp0 =  (vkarmn*grav/ztmp0*(ztmp1*(1.+0.608*q_zu) + 0.608*T_zu*ztmp2)) / (Cd*U_zu*U_zu) 
818         !                                                                     ( Cd*U_zu*U_zu is U*^2 at zu)
819
820         !! Stability parameters :
821         zeta_u   = zu*ztmp0   ;  zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
822         zpsi_h_u = psi_h( zeta_u )
823         zpsi_m_u = psi_m( zeta_u )
824       
825         !! Shifting temperature and humidity at zu (L&Y 2004 eq. (9b-9c))
826         IF ( .NOT. l_zt_equal_zu ) THEN
827            zeta_t = zt*ztmp0 ;  zeta_t = sign( min(abs(zeta_t),10.0), zeta_t )
828            stab = LOG(zu/zt) - zpsi_h_u + psi_h(zeta_t)  ! stab just used as temp array!!!
829            T_zu = T_zt + ztmp1/vkarmn*stab    ! ztmp1 is still theta*
830            q_zu = q_zt + ztmp2/vkarmn*stab    ! ztmp2 is still q*
831            q_zu = max(0., q_zu)
832         END IF
833       
834         IF( ln_cdgw ) THEN      ! surface wave case
835            sqrt_Cd = vkarmn / ( vkarmn / sqrt_Cd_n10 - zpsi_m_u ) 
836            Cd      = sqrt_Cd * sqrt_Cd
837         ELSE
838           ! Update neutral wind speed at 10m and neutral Cd at 10m (L&Y 2004 eq. 9a)...
839           !   In very rare low-wind conditions, the old way of estimating the
840           !   neutral wind speed at 10m leads to a negative value that causes the code
841           !   to crash. To prevent this a threshold of 0.25m/s is imposed.
842           ztmp0 = MAX( 0.25 , U_zu/(1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - zpsi_m_u)) ) !  U_n10
843           ztmp0 = cd_neutral_10m(ztmp0)                                                 ! Cd_n10
844           sqrt_Cd_n10 = sqrt(ztmp0)
845       
846           Ce_n10  = 1.e-3 * (34.6 * sqrt_Cd_n10)                     ! L&Y 2004 eq. (6b)
847           stab    = 0.5 + sign(0.5,zeta_u)                           ! update stability
848           Ch_n10  = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab))  ! L&Y 2004 eq. (6c-6d)
849
850           !! Update of transfer coefficients:
851           ztmp1 = 1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - zpsi_m_u)   ! L&Y 2004 eq. (10a)
852           Cd      = ztmp0 / ( ztmp1*ztmp1 )   
853           sqrt_Cd = SQRT( Cd )
854         ENDIF
855         !
856         ztmp0 = (LOG(zu/10.) - zpsi_h_u) / vkarmn / sqrt_Cd_n10
857         ztmp2 = sqrt_Cd / sqrt_Cd_n10
858         ztmp1 = 1. + Ch_n10*ztmp0               
859         Ch  = Ch_n10*ztmp2 / ztmp1  ! L&Y 2004 eq. (10b)
860         !
861         ztmp1 = 1. + Ce_n10*ztmp0               
862         Ce  = Ce_n10*ztmp2 / ztmp1  ! L&Y 2004 eq. (10c)
863         !
864      END DO
865     
866      CALL wrk_dealloc( jpi,jpj, U_zu, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd )
867      CALL wrk_dealloc( jpi,jpj, zeta_u, stab )
868      CALL wrk_dealloc( jpi,jpj, zpsi_h_u, zpsi_m_u, ztmp0, ztmp1, ztmp2 )
869
870      IF( .NOT. l_zt_equal_zu ) CALL wrk_dealloc( jpi,jpj, zeta_t )
871
872      IF( nn_timing == 1 )  CALL timing_stop('turb_core_2z')
873      !
874   END SUBROUTINE turb_core_2z
875
876
877   FUNCTION cd_neutral_10m( zw10 )
878      !!----------------------------------------------------------------------
879      !! Estimate of the neutral drag coefficient at 10m as a function
880      !! of neutral wind  speed at 10m
881      !!
882      !! Origin: Large & Yeager 2008 eq.(11a) and eq.(11b)
883      !!
884      !! Author: L. Brodeau, june 2014
885      !!----------------------------------------------------------------------   
886      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   zw10           ! scalar wind speed at 10m (m/s)
887      REAL(wp), DIMENSION(jpi,jpj)             ::   cd_neutral_10m
888      !
889      REAL(wp), DIMENSION(:,:), POINTER ::   rgt33
890      !!----------------------------------------------------------------------   
891      !
892      CALL wrk_alloc( jpi,jpj, rgt33 )
893      !
894      !! When wind speed > 33 m/s => Cyclone conditions => special treatment
895      rgt33 = 0.5_wp + SIGN( 0.5_wp, (zw10 - 33._wp) )   ! If zw10 < 33. => 0, else => 1 
896      cd_neutral_10m = 1.e-3 * ( &
897         &       (1._wp - rgt33)*( 2.7_wp/zw10 + 0.142_wp + zw10/13.09_wp - 3.14807E-10*zw10**6) & ! zw10< 33.
898         &      + rgt33         *      2.34   )                                                    ! zw10 >= 33.
899      !
900      CALL wrk_dealloc( jpi,jpj, rgt33)
901      !
902   END FUNCTION cd_neutral_10m
903
904
905   FUNCTION psi_m(pta)   !! Psis, L&Y 2004 eq. (8c), (8d), (8e)
906      !-------------------------------------------------------------------------------
907      ! universal profile stability function for momentum
908      !-------------------------------------------------------------------------------
909      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pta
910      !
911      REAL(wp), DIMENSION(jpi,jpj)             :: psi_m
912      REAL(wp), DIMENSION(:,:), POINTER        :: X2, X, stabit
913      !-------------------------------------------------------------------------------
914      !
915      CALL wrk_alloc( jpi,jpj, X2, X, stabit )
916      !
917      X2 = SQRT( ABS( 1. - 16.*pta ) )  ;  X2 = MAX( X2 , 1. )   ;   X = SQRT( X2 )
918      stabit = 0.5 + SIGN( 0.5 , pta )
919      psi_m = -5.*pta*stabit  &                                                          ! Stable
920         &    + (1. - stabit)*(2.*LOG((1. + X)*0.5) + LOG((1. + X2)*0.5) - 2.*ATAN(X) + rpi*0.5)  ! Unstable
921      !
922      CALL wrk_dealloc( jpi,jpj, X2, X, stabit )
923      !
924   END FUNCTION psi_m
925
926
927   FUNCTION psi_h( pta )    !! Psis, L&Y 2004 eq. (8c), (8d), (8e)
928      !-------------------------------------------------------------------------------
929      ! universal profile stability function for temperature and humidity
930      !-------------------------------------------------------------------------------
931      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pta
932      !
933      REAL(wp), DIMENSION(jpi,jpj)             ::   psi_h
934      REAL(wp), DIMENSION(:,:), POINTER        ::   X2, X, stabit
935      !-------------------------------------------------------------------------------
936      !
937      CALL wrk_alloc( jpi,jpj, X2, X, stabit )
938      !
939      X2 = SQRT( ABS( 1. - 16.*pta ) )   ;   X2 = MAX( X2 , 1. )   ;   X = SQRT( X2 )
940      stabit = 0.5 + SIGN( 0.5 , pta )
941      psi_h = -5.*pta*stabit   &                                       ! Stable
942         &    + (1. - stabit)*(2.*LOG( (1. + X2)*0.5 ))                ! Unstable
943      !
944      CALL wrk_dealloc( jpi,jpj, X2, X, stabit )
945      !
946   END FUNCTION psi_h
947
948
949   SUBROUTINE Cdn10_Lupkes2012( Cd )
950      !!----------------------------------------------------------------------
951      !!                      ***  ROUTINE  Cdn10_Lupkes2012  ***
952      !!
953      !! ** Purpose :    Recompute the ice-atm and ocean-atm drags at 10m height to make
954      !!                 them dependent on edges at leads, melt ponds and flows.
955      !!                 After some approximations, this can be resumed to a dependency
956      !!                 on ice concentration.
957      !!               
958      !! ** Method :     The parameterization is taken from Lupkes et al. (2012) eq.(50)
959      !!                 with the highest level of approximation: level4, eq.(59)
960      !!                 The drag can be re-written as follows:
961      !!
962      !!                 Cd = Cdw * (1-A) + Cdi * A + Ce * (1-A)**(nu+1/(10*beta)) * A**mu
963      !!
964      !!                    Ce = 2.23e-3       , as suggested by Lupkes (eq. 59)
965      !!                    nu = mu = beta = 1 , as suggested by Lupkes (eq. 59)
966      !!                    A is the concentration of ice minus melt ponds (if any)
967      !!
968      !!                 This new drag has a parabolic shape (as a function of A) starting at
969      !!                 Cdw(say 1.5e-3) for A=0, reaching 1.97e-3 for A~0.5
970      !!                 and going down to Cdi(say 1.4e-3) for A=1
971      !!
972      !!                 It is theoretically applicable to all ice conditions (not only MIZ)
973      !!                 => see Lupkes et al (2013)
974      !!
975      !! ** References : Lupkes et al. JGR 2012 (theory)
976      !!                 Lupkes et al. GRL 2013 (application to GCM)
977      !!
978      !!----------------------------------------------------------------------
979      REAL(wp), DIMENSION(:,:), INTENT(inout) ::   Cd
980      REAL(wp), PARAMETER ::   zCe   = 2.23e-03_wp
981      REAL(wp), PARAMETER ::   znu   = 1._wp
982      REAL(wp), PARAMETER ::   zmu   = 1._wp
983      REAL(wp), PARAMETER ::   zbeta = 1._wp
984      REAL(wp)            ::   zcoef
985      !!----------------------------------------------------------------------
986      zcoef = znu + 1._wp / ( 10._wp * zbeta )
987
988      Cd(:,:) = Cd_oce(:,:) * ( 1._wp - at_i_b(:,:) ) +  &                        ! pure ocean drag
989         &      Cd_ice      *           at_i_b(:,:)   +  &                        ! pure ice drag
990         &      zCe         * ( 1._wp - at_i_b(:,:) )**zcoef * at_i_b(:,:)**zmu   ! change due to sea-ice morphology
991     
992   END SUBROUTINE Cdn10_Lupkes2012
993     
994   !!======================================================================
995END MODULE sbcblk_core
Note: See TracBrowser for help on using the repository browser.