New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcice_lim.F90 in branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2016/dev_v3_6_STABLE_r6506_AGRIF_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 6584

Last change on this file since 6584 was 6584, checked in by clem, 8 years ago
LIM3 and Agrif compatibility
Property svn:keywords set to `Id`
File size: 35.1 KB

Line
1	MODULE sbcice_lim
2	!!======================================================================
3	!! * MODULE sbcice_lim *
4	!! Surface module : update the ocean surface boundary condition over ice
5	!! & covered area using LIM sea-ice model
6	!! Sea-Ice model : LIM-3 Sea ice model time-stepping
7	!!=====================================================================
8	!! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code
9	!! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90
10	!! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine
11	!! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! 3.4 ! 2011-01 (A Porter) dynamical allocation
13	!! - ! 2012-10 (C. Rousset) add lim_diahsb
14	!! 3.6 ! 2014-07 (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15	!!----------------------------------------------------------------------
16	#if defined key_lim3
17	!!----------------------------------------------------------------------
18	!! 'key_lim3' : LIM 3.0 sea-ice model
19	!!----------------------------------------------------------------------
20	!! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area
21	!!----------------------------------------------------------------------
22	USE oce ! ocean dynamics and tracers
23	USE dom_oce ! ocean space and time domain
24	USE ice ! LIM-3: ice variables
25	USE thd_ice ! LIM-3: thermodynamical variables
26	USE dom_ice ! LIM-3: ice domain
27
28	USE sbc_oce ! Surface boundary condition: ocean fields
29	USE sbc_ice ! Surface boundary condition: ice fields
30	USE sbcblk_core ! Surface boundary condition: CORE bulk
31	USE sbcblk_clio ! Surface boundary condition: CLIO bulk
32	USE sbccpl ! Surface boundary condition: coupled interface
33	USE albedo ! ocean & ice albedo
34
35	USE phycst ! Define parameters for the routines
36	USE eosbn2 ! equation of state
37	USE limdyn ! Ice dynamics
38	USE limtrp ! Ice transport
39	USE limhdf ! Ice horizontal diffusion
40	USE limthd ! Ice thermodynamics
41	USE limitd_me ! Mechanics on ice thickness distribution
42	USE limsbc ! sea surface boundary condition
43	USE limdiahsb ! Ice budget diagnostics
44	USE limwri ! Ice outputs
45	USE limrst ! Ice restarts
46	USE limupdate1 ! update of global variables
47	USE limupdate2 ! update of global variables
48	USE limvar ! Ice variables switch
49
50	USE limmsh ! LIM mesh
51	USE limistate ! LIM initial state
52	USE limthd_sal ! LIM ice thermodynamics: salinity
53
54	USE c1d ! 1D vertical configuration
55	USE lbclnk ! lateral boundary condition - MPP link
56	USE lib_mpp ! MPP library
57	USE wrk_nemo ! work arrays
58	USE timing ! Timing
59	USE iom ! I/O manager library
60	USE in_out_manager ! I/O manager
61	USE prtctl ! Print control
62	USE lib_fortran !
63	USE limctl
64
65	#if defined key_bdy
66	USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine)
67	#endif
68	# if defined key_agrif
69	USE agrif_ice
70	USE agrif_lim3_update
71	USE agrif_lim3_interp
72	# endif
73
74	IMPLICIT NONE
75	PRIVATE
76
77	PUBLIC sbc_ice_lim ! routine called by sbcmod.F90
78	PUBLIC sbc_lim_init ! routine called by sbcmod.F90
79
80	!! * Substitutions
81	# include "domzgr_substitute.h90"
82	# include "vectopt_loop_substitute.h90"
83	!!----------------------------------------------------------------------
84	!! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
85	!! $Id$
86	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
87	!!----------------------------------------------------------------------
88	CONTAINS
89
90	!!======================================================================
91
92	SUBROUTINE sbc_ice_lim( kt, kblk )
93	!!---------------------------------------------------------------------
94	!! * ROUTINE sbc_ice_lim *
95	!!
96	!! ** Purpose : update the ocean surface boundary condition via the
97	!! Louvain la Neuve Sea Ice Model time stepping
98	!!
99	!! ** Method : ice model time stepping
100	!! - call the ice dynamics routine
101	!! - call the ice advection/diffusion routine
102	!! - call the ice thermodynamics routine
103	!! - call the routine that computes mass and
104	!! heat fluxes at the ice/ocean interface
105	!! - save the outputs
106	!! - save the outputs for restart when necessary
107	!!
108	!! ** Action : - time evolution of the LIM sea-ice model
109	!! - update all sbc variables below sea-ice:
110	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
111	!!---------------------------------------------------------------------
112	INTEGER, INTENT(in) :: kt ! ocean time step
113	INTEGER, INTENT(in) :: kblk ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
114	!!
115	INTEGER :: jl ! dummy loop index
116	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_os, zalb_cs ! ice albedo under overcast/clear sky
117	REAL(wp), POINTER, DIMENSION(:,: ) :: zutau_ice, zvtau_ice
118	!!----------------------------------------------------------------------
119
120	IF( nn_timing == 1 ) CALL timing_start('sbc_ice_lim')
121
122	!-----------------------!
123	! --- Ice time step --- !
124	!-----------------------!
125	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
126
127	# if defined key_agrif
128	IF( .NOT. Agrif_Root() ) THEN
129	lim_nbstep = MOD( lim_nbstep, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) + 1
130	ENDIF
131	# endif
132
133	! mean surface ocean current at ice velocity point (C-grid dynamics : U- & V-points as the ocean)
134	u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
135	v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
136
137	! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
138	CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
139	t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
140
141	! Mask sea ice surface temperature (set to rt0 over land)
142	DO jl = 1, jpl
143	t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
144	END DO
145	!
146	!------------------------------------------------!
147	! --- Dynamical coupling with the atmosphere --- !
148	!------------------------------------------------!
149	! It provides the following fields:
150	! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
151	!-----------------------------------------------------------------
152	SELECT CASE( kblk )
153	CASE( jp_clio ) ; CALL blk_ice_clio_tau ! CLIO bulk formulation
154	CASE( jp_core ) ; CALL blk_ice_core_tau ! CORE bulk formulation
155	CASE( jp_purecpl ) ; CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) ! Coupled formulation
156	END SELECT
157
158	IF( ln_mixcpl) THEN ! Case of a mixed Bulk/Coupled formulation
159	CALL wrk_alloc( jpi,jpj , zutau_ice, zvtau_ice)
160	CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
161	utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
162	vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
163	CALL wrk_dealloc( jpi,jpj , zutau_ice, zvtau_ice)
164	ENDIF
165
166	!-------------------------------------------------------!
167	! --- ice dynamics and transport (except in 1D case) ---!
168	!-------------------------------------------------------!
169	numit = numit + nn_fsbc ! Ice model time step
170	!
171	CALL sbc_lim_bef ! Store previous ice values
172	CALL sbc_lim_diag0 ! set diag of mass, heat and salt fluxes to 0
173	CALL lim_rst_opn( kt ) ! Open Ice restart file
174	!
175	#if defined key_agrif
176	IF( .NOT. Agrif_Root() ) CALL agrif_interp_lim3('T')
177	#endif
178	! --- zap this if no ice dynamics --- !
179	IF( .NOT. lk_c1d .AND. ln_limdyn ) THEN
180	!
181	IF( nn_limdyn /= 0 ) THEN ! -- Ice dynamics
182	CALL lim_dyn( kt ) ! rheology
183	ELSE
184	u_ice(:,:) = rn_uice * umask(:,:,1) ! or prescribed velocity
185	v_ice(:,:) = rn_vice * vmask(:,:,1)
186	ENDIF
187	CALL lim_trp( kt ) ! -- Ice transport (Advection/diffusion)
188	IF( nn_limdyn == 2 .AND. nn_monocat /= 2 ) & ! -- Mechanical redistribution (ridging/rafting)
189	& CALL lim_itd_me
190	IF( nn_limdyn == 2 ) CALL lim_update1( kt ) ! -- Corrections
191	!
192	ENDIF
193	! ---
194	#if defined key_agrif
195	IF( .NOT. Agrif_Root() ) CALL agrif_interp_lim3('T')
196	#endif
197	#if defined key_bdy
198	IF( ln_limthd ) CALL bdy_ice_lim( kt ) ! -- bdy ice thermo
199	IF( ln_icectl ) CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
200	#endif
201
202	! previous lead fraction and ice volume for flux calculations
203	CALL sbc_lim_bef
204	CALL lim_var_glo2eqv ! ht_i and ht_s for ice albedo calculation
205	CALL lim_var_agg(1) ! at_i for coupling (via pfrld)
206	!
207	pfrld(:,:) = 1._wp - at_i(:,:)
208	phicif(:,:) = vt_i(:,:)
209
210	!------------------------------------------------------!
211	! --- Thermodynamical coupling with the atmosphere --- !
212	!------------------------------------------------------!
213	! It provides the following fields:
214	! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2]
215	! qla_ice : latent heat flux over ice (T-point) [W/m2]
216	! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2]
217	! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s]
218	! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%]
219	!----------------------------------------------------------------------------------------
220	CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs )
221
222	CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
223	SELECT CASE( kblk )
224
225	CASE( jp_clio ) ! CLIO bulk formulation
226	! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
227	! (alb_ice) is computed within the bulk routine
228	CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, alb_ice )
229	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
230	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
231
232	CASE( jp_core ) ! CORE bulk formulation
233	! albedo depends on cloud fraction because of non-linear spectral effects
234	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
235	CALL blk_ice_core_flx( t_su, alb_ice )
236	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
237	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
238
239	CASE ( jp_purecpl ) ! Coupled formulation
240	! albedo depends on cloud fraction because of non-linear spectral effects
241	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
242	CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
243	IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
244
245	END SELECT
246
247	CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs )
248
249	!----------------------------!
250	! --- ice thermodynamics --- !
251	!----------------------------!
252	! --- zap this if no ice thermo --- !
253	IF( ln_limthd ) CALL lim_thd( kt ) ! -- Ice thermodynamics
254	IF( ln_limthd ) CALL lim_update2( kt ) ! -- Corrections
255	! ---
256	# if defined key_agrif
257	IF( .NOT. Agrif_Root() ) CALL agrif_update_lim3( kt )
258	# endif
259	CALL lim_var_glo2eqv ! necessary calls (at least for coupling)
260	CALL lim_var_agg( 2 ) ! necessary calls (at least for coupling)
261	!
262	CALL lim_sbc_flx( kt ) ! -- Update surface ocean mass, heat and salt fluxes
263	!
264	IF(ln_limdiaout) CALL lim_diahsb ! -- Diagnostics and outputs
265	!
266	CALL lim_wri( 1 ) ! -- Ice outputs
267	!
268	IF( kt == nit000 .AND. ln_rstart ) &
269	& CALL iom_close( numrir ) ! close input ice restart file
270	!
271	IF( lrst_ice ) CALL lim_rst_write( kt ) ! -- Ice restart file
272	!
273	IF( ln_icectl ) CALL lim_ctl( kt ) ! alerts in case of model crash
274	!
275	ENDIF ! End sea-ice time step only
276
277	!-------------------------!
278	! --- Ocean time step --- !
279	!-------------------------!
280	! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
281	! using before instantaneous surf. currents
282	IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )
283	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
284	!
285	IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
286	!
287	END SUBROUTINE sbc_ice_lim
288
289
290	SUBROUTINE sbc_lim_init
291	!!----------------------------------------------------------------------
292	!! * ROUTINE sbc_lim_init *
293	!!
294	!! ** purpose : Allocate all the dynamic arrays of the LIM-3 modules
295	!!----------------------------------------------------------------------
296	INTEGER :: ierr
297	INTEGER :: ji, jj
298	!!----------------------------------------------------------------------
299	IF(lwp) WRITE(numout,*)
300	IF(lwp) WRITE(numout,*) 'sbc_lim_init : update ocean surface boudary condition'
301	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping'
302	!
303	! Open the reference and configuration namelist files and namelist output file
304	CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
305	CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
306	IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
307
308	CALL ice_run ! set some ice run parameters
309	!
310	! ! Allocate the ice arrays
311	ierr = ice_alloc () ! ice variables
312	ierr = ierr + dom_ice_alloc () ! domain
313	ierr = ierr + sbc_ice_alloc () ! surface forcing
314	ierr = ierr + thd_ice_alloc () ! thermodynamics
315	IF( ln_limdyn ) ierr = ierr + lim_itd_me_alloc () ! ice thickness distribution - mechanics
316	!
317	IF( lk_mpp ) CALL mpp_sum( ierr )
318	IF( ierr /= 0 ) CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
319	!
320	! ! adequation jpk versus ice/snow layers/categories
321	IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk ) &
322	& CALL ctl_stop( 'STOP', &
323	& 'sbc_lim_init: the 3rd dimension of workspace arrays is too small.', &
324	& 'use more ocean levels or less ice/snow layers/categories.' )
325	!
326	CALL lim_itd_init ! ice thickness distribution initialization
327	!
328	CALL lim_hdf_init ! set ice horizontal diffusion computation parameters
329	!
330	CALL lim_thd_init ! set ice thermodynics parameters
331	!
332	CALL lim_thd_sal_init ! set ice salinity parameters
333	!
334	CALL lim_msh ! ice mesh initialization
335	!
336	IF( ln_limdyn ) CALL lim_itd_me_init ! ice thickness distribution initialization for mecanical deformation
337	! ! Initial sea-ice state
338	IF( .NOT. ln_rstart ) THEN ! start from rest: sea-ice deduced from sst
339	numit = 0
340	numit = nit000 - 1
341	CALL lim_istate
342	ELSE ! start from a restart file
343	CALL lim_rst_read
344	numit = nit000 - 1
345	ENDIF
346	CALL lim_var_agg(1)
347	CALL lim_var_glo2eqv
348	!
349	CALL lim_sbc_init ! ice surface boundary condition
350	!
351	fr_i(:,:) = at_i(:,:) ! initialisation of sea-ice fraction
352	tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu
353	!
354	DO jj = 1, jpj
355	DO ji = 1, jpi
356	IF( gphit(ji,jj) > 0._wp ) THEN ; rn_amax_2d(ji,jj) = rn_amax_n ! NH
357	ELSE ; rn_amax_2d(ji,jj) = rn_amax_s ! SH
358	ENDIF
359	ENDDO
360	ENDDO
361	!
362	nstart = numit + nn_fsbc
363	nitrun = nitend - nit000 + 1
364	nlast = numit + nitrun
365	!
366	IF( nstock == 0 ) nstock = nlast + 1
367	!
368	# if defined key_agrif
369	IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim3
370	# endif
371	!
372	END SUBROUTINE sbc_lim_init
373
374
375	SUBROUTINE ice_run
376	!!-------------------------------------------------------------------
377	!! * ROUTINE ice_run *
378	!!
379	!! ** Purpose : Definition some run parameter for ice model
380	!!
381	!! ** Method : Read the namicerun namelist and check the parameter
382	!! values called at the first timestep (nit000)
383	!!
384	!! ** input : Namelist namicerun
385	!!-------------------------------------------------------------------
386	INTEGER :: ios ! Local integer output status for namelist read
387	NAMELIST/namicerun/ jpl, nlay_i, nlay_s, rn_amax_n, rn_amax_s, cn_icerst_in, cn_icerst_indir, &
388	& cn_icerst_out, cn_icerst_outdir, ln_limthd, ln_limdyn, nn_limdyn, rn_uice, rn_vice
389	NAMELIST/namicediag/ ln_limdiahsb, ln_limdiaout, ln_icectl, iiceprt, jiceprt
390	!!-------------------------------------------------------------------
391	!
392	REWIND( numnam_ice_ref ) ! Namelist namicerun in reference namelist : Parameters for ice
393	READ ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
394	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
395
396	REWIND( numnam_ice_cfg ) ! Namelist namicerun in configuration namelist : Parameters for ice
397	READ ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
398	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
399	IF(lwm) WRITE ( numoni, namicerun )
400	!
401	REWIND( numnam_ice_ref ) ! Namelist namicediag in reference namelist : Parameters for ice
402	READ ( numnam_ice_ref, namicediag, IOSTAT = ios, ERR = 903)
403	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in reference namelist', lwp )
404
405	REWIND( numnam_ice_cfg ) ! Namelist namicediag in configuration namelist : Parameters for ice
406	READ ( numnam_ice_cfg, namicediag, IOSTAT = ios, ERR = 904 )
407	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in configuration namelist', lwp )
408	IF(lwm) WRITE ( numoni, namicediag )
409	!
410	IF(lwp) THEN ! control print
411	WRITE(numout,*)
412	WRITE(numout,*) 'ice_run : ice share~d parameters for dynamics/advection/thermo of sea-ice'
413	WRITE(numout,*) ' ~~~~~~'
414	WRITE(numout,*) ' number of ice categories = ', jpl
415	WRITE(numout,*) ' number of ice layers = ', nlay_i
416	WRITE(numout,*) ' number of snow layers = ', nlay_s
417	WRITE(numout,*) ' maximum ice concentration for NH = ', rn_amax_n
418	WRITE(numout,*) ' maximum ice concentration for SH = ', rn_amax_s
419	WRITE(numout,*) ' Ice thermodynamics (T) or not (F) ln_limthd = ', ln_limthd
420	WRITE(numout,*) ' Ice dynamics (T) or not (F) ln_limdyn = ', ln_limdyn
421	WRITE(numout,*) ' (ln_limdyn=T) Ice dynamics switch nn_limdyn = ', nn_limdyn
422	WRITE(numout,*) ' 2: total'
423	WRITE(numout,*) ' 1: advection only (no diffusion, no ridging/rafting)'
424	WRITE(numout,*) ' 0: advection only (as 1 + prescribed velocity, bypass rheology)'
425	WRITE(numout,*) ' (ln_limdyn=T) prescribed u-vel (case nn_limdyn=0) = ', rn_uice
426	WRITE(numout,*) ' (ln_limdyn=T) prescribed v-vel (case nn_limdyn=0) = ', rn_vice
427	WRITE(numout,*)
428	WRITE(numout,*) '...and ice diagnostics'
429	WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~'
430	WRITE(numout,*) ' Diagnose heat/mass/salt budget or not ln_limdiahsb = ', ln_limdiahsb
431	WRITE(numout,*) ' Output heat/mass/salt budget or not ln_limdiaout = ', ln_limdiaout
432	WRITE(numout,*) ' control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_icectl
433	WRITE(numout,*) ' i-index for control prints (ln_icectl=true) = ', iiceprt
434	WRITE(numout,*) ' j-index for control prints (ln_icectl=true) = ', jiceprt
435	ENDIF
436	!
437	! sea-ice timestep and inverse
438	rdt_ice = nn_fsbc * rdttra(1)
439	r1_rdtice = 1._wp / rdt_ice
440
441	! inverse of nlay_i and nlay_s
442	r1_nlay_i = 1._wp / REAL( nlay_i, wp )
443	r1_nlay_s = 1._wp / REAL( nlay_s, wp )
444	!
445	#if defined key_bdy
446	IF( lwp .AND. ln_limdiahsb ) CALL ctl_warn('online conservation check activated but it does not work with BDY')
447	#endif
448	!
449	END SUBROUTINE ice_run
450
451
452	SUBROUTINE lim_itd_init
453	!!------------------------------------------------------------------
454	!! * ROUTINE lim_itd_init *
455	!!
456	!! ** Purpose : Initializes the ice thickness distribution
457	!! ** Method : ...
458	!! ** input : Namelist namiceitd
459	!!-------------------------------------------------------------------
460	INTEGER :: ios ! Local integer output status for namelist read
461	NAMELIST/namiceitd/ nn_catbnd, rn_himean
462	!
463	INTEGER :: jl ! dummy loop index
464	REAL(wp) :: zc1, zc2, zc3, zx1 ! local scalars
465	REAL(wp) :: zhmax, znum, zden, zalpha !
466	!!------------------------------------------------------------------
467	!
468	REWIND( numnam_ice_ref ) ! Namelist namiceitd in reference namelist : Parameters for ice
469	READ ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 905)
470	905 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
471
472	REWIND( numnam_ice_cfg ) ! Namelist namiceitd in configuration namelist : Parameters for ice
473	READ ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 906 )
474	906 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
475	IF(lwm) WRITE ( numoni, namiceitd )
476	!
477	IF(lwp) THEN ! control print
478	WRITE(numout,*)
479	WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
480	WRITE(numout,*) '~~~~~~~~~~~~'
481	WRITE(numout,*) ' shape of ice categories distribution nn_catbnd = ', nn_catbnd
482	WRITE(numout,*) ' mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
483	ENDIF
484
485	!----------------------------------
486	!- Thickness categories boundaries
487	!----------------------------------
488	hi_max(:) = 0._wp
489
490	SELECT CASE ( nn_catbnd )
491	!----------------------
492	CASE (1) ! tanh function (CICE)
493	!----------------------
494	zc1 = 3._wp / REAL( jpl, wp )
495	zc2 = 10._wp * zc1
496	zc3 = 3._wp
497
498	DO jl = 1, jpl
499	zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
500	hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
501	END DO
502
503	!----------------------
504	CASE (2) ! h^(-alpha) function
505	!----------------------
506	zalpha = 0.05 ! exponent of the transform function
507
508	zhmax = 3.*rn_himean
509
510	DO jl = 1, jpl
511	znum = jpl * ( zhmax+1 )**zalpha
512	zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
513	hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
514	END DO
515
516	END SELECT
517
518	DO jl = 1, jpl
519	hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
520	END DO
521
522	! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
523	hi_max(jpl) = 99._wp
524
525	IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
526	IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
527	!
528	END SUBROUTINE lim_itd_init
529
530
531	SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
532	!!---------------------------------------------------------------------
533	!! * ROUTINE ice_lim_flx *
534	!!
535	!! ** Purpose : update the ice surface boundary condition by averaging and / or
536	!! redistributing fluxes on ice categories
537	!!
538	!! ** Method : average then redistribute
539	!!
540	!! ** Action :
541	!!---------------------------------------------------------------------
542	INTEGER , INTENT(in ) :: k_limflx ! =-1 do nothing; =0 average ;
543	! =1 average and redistribute ; =2 redistribute
544	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: ptn_ice ! ice surface temperature
545	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb_ice ! ice albedo
546	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqns_ice ! non solar flux
547	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqsr_ice ! net solar flux
548	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdqn_ice ! non solar flux sensitivity
549	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pevap_ice ! sublimation
550	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdevap_ice ! sublimation sensitivity
551	!
552	INTEGER :: jl ! dummy loop index
553	!
554	REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m ! Mean albedo over all categories
555	REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m ! Mean temperature over all categories
556	!
557	REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m ! Mean solar heat flux over all categories
558	REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m ! Mean non solar heat flux over all categories
559	REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m ! Mean sublimation over all categories
560	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m ! Mean d(qns)/dT over all categories
561	REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
562	!!----------------------------------------------------------------------
563
564	IF( nn_timing == 1 ) CALL timing_start('ice_lim_flx')
565	!
566	!
567	SELECT CASE( k_limflx ) !== averaged on all ice categories ==!
568	CASE( 0 , 1 )
569	CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
570	!
571	z_qns_m (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
572	z_qsr_m (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
573	z_dqn_m (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
574	z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
575	z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
576	DO jl = 1, jpl
577	pdqn_ice (:,:,jl) = z_dqn_m(:,:)
578	pdevap_ice(:,:,jl) = z_devap_m(:,:)
579	END DO
580	!
581	DO jl = 1, jpl
582	pqns_ice (:,:,jl) = z_qns_m(:,:)
583	pqsr_ice (:,:,jl) = z_qsr_m(:,:)
584	pevap_ice(:,:,jl) = z_evap_m(:,:)
585	END DO
586	!
587	CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
588	END SELECT
589
590	SELECT CASE( k_limflx ) !== redistribution on all ice categories ==!
591	CASE( 1 , 2 )
592	CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
593	!
594	zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) )
595	ztem_m(:,:) = fice_ice_ave ( ptn_ice (:,:,:) )
596	DO jl = 1, jpl
597	pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
598	pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
599	pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
600	END DO
601	!
602	CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
603	END SELECT
604	!
605	IF( nn_timing == 1 ) CALL timing_stop('ice_lim_flx')
606	!
607	END SUBROUTINE ice_lim_flx
608
609	SUBROUTINE sbc_lim_bef
610	!!----------------------------------------------------------------------
611	!! * ROUTINE sbc_lim_bef *
612	!!
613	!! ** purpose : store ice variables at "before" time step
614	!!----------------------------------------------------------------------
615	a_i_b (:,:,:) = a_i (:,:,:) ! ice area
616	e_i_b (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
617	v_i_b (:,:,:) = v_i (:,:,:) ! ice volume
618	v_s_b (:,:,:) = v_s (:,:,:) ! snow volume
619	e_s_b (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
620	smv_i_b(:,:,:) = smv_i(:,:,:) ! salt content
621	oa_i_b (:,:,:) = oa_i (:,:,:) ! areal age content
622	u_ice_b(:,:) = u_ice(:,:)
623	v_ice_b(:,:) = v_ice(:,:)
624
625	END SUBROUTINE sbc_lim_bef
626
627	SUBROUTINE sbc_lim_diag0
628	!!----------------------------------------------------------------------
629	!! * ROUTINE sbc_lim_diag0 *
630	!!
631	!! ** purpose : set ice-ocean and ice-atm. fluxes to zeros at the beggining
632	!! of the time step
633	!!----------------------------------------------------------------------
634	sfx (:,:) = 0._wp ;
635	sfx_bri(:,:) = 0._wp ; sfx_lam(:,:) = 0._wp
636	sfx_sni(:,:) = 0._wp ; sfx_opw(:,:) = 0._wp
637	sfx_bog(:,:) = 0._wp ; sfx_dyn(:,:) = 0._wp
638	sfx_bom(:,:) = 0._wp ; sfx_sum(:,:) = 0._wp
639	sfx_res(:,:) = 0._wp ; sfx_sub(:,:) = 0._wp
640
641	wfx_snw(:,:) = 0._wp ; wfx_ice(:,:) = 0._wp
642	wfx_sni(:,:) = 0._wp ; wfx_opw(:,:) = 0._wp
643	wfx_bog(:,:) = 0._wp ; wfx_dyn(:,:) = 0._wp
644	wfx_bom(:,:) = 0._wp ; wfx_sum(:,:) = 0._wp
645	wfx_res(:,:) = 0._wp ; wfx_sub(:,:) = 0._wp
646	wfx_spr(:,:) = 0._wp ; wfx_lam(:,:) = 0._wp
647
648	hfx_thd(:,:) = 0._wp ;
649	hfx_snw(:,:) = 0._wp ; hfx_opw(:,:) = 0._wp
650	hfx_bog(:,:) = 0._wp ; hfx_dyn(:,:) = 0._wp
651	hfx_bom(:,:) = 0._wp ; hfx_sum(:,:) = 0._wp
652	hfx_res(:,:) = 0._wp ; hfx_sub(:,:) = 0._wp
653	hfx_spr(:,:) = 0._wp ; hfx_dif(:,:) = 0._wp
654	hfx_err(:,:) = 0._wp ; hfx_err_rem(:,:) = 0._wp
655	hfx_err_dif(:,:) = 0._wp
656	wfx_err_sub(:,:) = 0._wp
657
658	afx_tot(:,:) = 0._wp ;
659	afx_dyn(:,:) = 0._wp ; afx_thd(:,:) = 0._wp
660
661	diag_heat(:,:) = 0._wp ; diag_smvi(:,:) = 0._wp ;
662	diag_vice(:,:) = 0._wp ; diag_vsnw(:,:) = 0._wp ;
663
664	END SUBROUTINE sbc_lim_diag0
665
666
667	FUNCTION fice_cell_ave ( ptab )
668	!!--------------------------------------------------------------------------
669	!! * Compute average over categories, for grid cell (ice covered and free ocean)
670	!!--------------------------------------------------------------------------
671	REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
672	REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
673	INTEGER :: jl ! Dummy loop index
674
675	fice_cell_ave (:,:) = 0.0_wp
676	DO jl = 1, jpl
677	fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
678	END DO
679
680	END FUNCTION fice_cell_ave
681
682
683	FUNCTION fice_ice_ave ( ptab )
684	!!--------------------------------------------------------------------------
685	!! * Compute average over categories, for ice covered part of grid cell
686	!!--------------------------------------------------------------------------
687	REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
688	REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
689
690	fice_ice_ave (:,:) = 0.0_wp
691	WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
692
693	END FUNCTION fice_ice_ave
694
695
696	#else
697	!!----------------------------------------------------------------------
698	!! Default option Dummy module NO LIM 3.0 sea-ice model
699	!!----------------------------------------------------------------------
700	CONTAINS
701	SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine
702	WRITE(,) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
703	END SUBROUTINE sbc_ice_lim
704	SUBROUTINE sbc_lim_init ! Dummy routine
705	END SUBROUTINE sbc_lim_init
706	#endif
707
708	!!======================================================================
709	END MODULE sbcice_lim

Note: See TracBrowser for help on using the repository browser.

Download in other formats: