New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in branches/2017/dev_CNRS_2017/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2017/dev_CNRS_2017/NEMOGCM/NEMO/OPA_SRC/TRA/trasbc.F90 @ 8882

Last change on this file since 8882 was 8882, checked in by flavoni, 6 years ago

dev_CNRS_2017 branch: merged dev_r7881_ENHANCE09_RK3 with trunk r8864

  • Property svn:keywords set to Id
File size: 12.0 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_sbc       : update the tracer trend at ocean surface
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and active tracers
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE dom_oce        ! ocean space domain variables
20   USE phycst         ! physical constant
21   USE eosbn2         ! Equation Of State
22   USE sbcmod         ! ln_rnf 
23   USE sbcrnf         ! River runoff 
24   USE sbcisf         ! Ice shelf   
25   USE iscplini       ! Ice sheet coupling
26   USE traqsr         ! solar radiation penetration
27   USE trd_oce        ! trends: ocean variables
28   USE trdtra         ! trends manager: tracers
29   !
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE iom            ! xIOS server
33   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
34   USE timing         ! Timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_sbc   ! routine called by step.F90
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE tra_sbc ( kt )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_sbc  ***
53      !!                   
54      !! ** Purpose :   Compute the tracer surface boundary condition trend of
55      !!      (flux through the interface, concentration/dilution effect)
56      !!      and add it to the general trend of tracer equations.
57      !!
58      !! ** Method :   The (air+ice)-sea flux has two components:
59      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
60      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
61      !!               The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe,
62      !!             they are simply added to the tracer trend (tsa).
63      !!               In linear free surface case (ln_linssh=T), the volume of the
64      !!             ocean does not change with the water exchanges at the (air+ice)-sea
65      !!             interface. Therefore another term has to be added, to mimic the
66      !!             concentration/dilution effect associated with water exchanges.
67      !!
68      !! ** Action  : - Update tsa with the surface boundary condition trend
69      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
70      !!----------------------------------------------------------------------
71      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
72      !
73      INTEGER  ::   ji, jj, jk, jn        ! dummy loop indices 
74      INTEGER  ::   ikt, ikb              ! local integers
75      REAL(wp) ::   zfact, z1_e3t, zdep   ! local scalar
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  ztrdt, ztrds
77      !!----------------------------------------------------------------------
78      !
79      IF( ln_timing )   CALL timing_start('tra_sbc')
80      !
81      IF( kt == nit000 ) THEN
82         IF(lwp) WRITE(numout,*)
83         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
84         IF(lwp) WRITE(numout,*) '~~~~~~~ '
85      ENDIF
86      !
87      IF( l_trdtra ) THEN                    !* Save ta and sa trends
88         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) ) 
89         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
90         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
91      ENDIF
92      !
93!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
94      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
95         qns(:,:) = qns(:,:) + qsr(:,:)      ! total heat flux in qns
96         qsr(:,:) = 0._wp                     ! qsr set to zero
97      ENDIF
98
99      !----------------------------------------
100      !        EMP, SFX and QNS effects
101      !----------------------------------------
102      !                             !==  Set before sbc tracer content fields  ==!
103      IF( kt == nit000 ) THEN             !* 1st time-step
104         IF( ln_rstart .AND.    &               ! Restart: read in restart file
105              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
106            IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
107            zfact = 0.5_wp
108            sbc_tsc(:,:,:) = 0._wp
109            CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
110            CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
111         ELSE                                   ! No restart or restart not found: Euler forward time stepping
112            zfact = 1._wp
113            sbc_tsc(:,:,:) = 0._wp
114            sbc_tsc_b(:,:,:) = 0._wp
115         ENDIF
116      ELSE                                !* other time-steps: swap of forcing fields
117         zfact = 0.5_wp
118         sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:)
119      ENDIF
120      !                             !==  Now sbc tracer content fields  ==!
121      DO jj = 2, jpj
122         DO ji = fs_2, fs_jpim1   ! vector opt.
123            sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)   ! non solar heat flux
124            sbc_tsc(ji,jj,jp_sal) = r1_rau0     * sfx(ji,jj)   ! salt flux due to freezing/melting
125         END DO
126      END DO
127      IF( ln_linssh ) THEN                !* linear free surface 
128         DO jj = 2, jpj                         !==>> add concentration/dilution effect due to constant volume cell
129            DO ji = fs_2, fs_jpim1   ! vector opt.
130               sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem)
131               sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal)
132            END DO
133         END DO                                 !==>> output c./d. term
134         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) )
135         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) )
136      ENDIF
137      !
138      DO jn = 1, jpts               !==  update tracer trend  ==!
139         DO jj = 2, jpj
140            DO ji = fs_2, fs_jpim1   ! vector opt. 
141               tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1)
142            END DO
143         END DO
144      END DO
145      !                 
146      IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
147         CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
148         CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
149      ENDIF
150      !
151      !----------------------------------------
152      !       Ice Shelf effects (ISF)
153      !     tbl treated as in Losh (2008) JGR
154      !----------------------------------------
155      !
156!!gm BUG ?   Why no differences between non-linear and linear free surface ?
157!!gm         probably taken into account in r1_hisf_tbl : to be verified
158      IF( ln_isf ) THEN
159         zfact = 0.5_wp
160         DO jj = 2, jpj
161            DO ji = fs_2, fs_jpim1
162               !
163               ikt = misfkt(ji,jj)
164               ikb = misfkb(ji,jj)
165               !
166               ! level fully include in the ice shelf boundary layer
167               ! sign - because fwf sign of evapo (rnf sign of precip)
168               DO jk = ikt, ikb - 1
169               ! compute trend
170                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                                &
171                     &           + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
172                     &           * r1_hisf_tbl(ji,jj)
173               END DO
174   
175               ! level partially include in ice shelf boundary layer
176               ! compute trend
177               tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem)                                                 &
178                  &              + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
179                  &              * r1_hisf_tbl(ji,jj) * ralpha(ji,jj)
180
181            END DO
182         END DO
183      END IF
184      !
185      !----------------------------------------
186      !        River Runoff effects
187      !----------------------------------------
188      !
189      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
190         zfact = 0.5_wp
191         DO jj = 2, jpj 
192            DO ji = fs_2, fs_jpim1
193               IF( rnf(ji,jj) /= 0._wp ) THEN
194                  zdep = zfact / h_rnf(ji,jj)
195                  DO jk = 1, nk_rnf(ji,jj)
196                                        tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                 &
197                                           &                 +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
198                     IF( ln_rnf_sal )   tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)                                 &
199                                           &                 +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
200                  END DO
201               ENDIF
202            END DO 
203         END DO 
204      ENDIF
205
206      IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) )   ! runoff term on sst
207      IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) )   ! runoff term on sss
208
209      !
210      !----------------------------------------
211      !        Ice Sheet coupling imbalance correction to have conservation
212      !----------------------------------------
213      !
214      IF( ln_iscpl .AND. ln_hsb) THEN         ! input of heat and salt due to river runoff
215         DO jk = 1,jpk
216            DO jj = 2, jpj 
217               DO ji = fs_2, fs_jpim1
218                  zdep = 1._wp / e3t_n(ji,jj,jk) 
219                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem)                       &
220                      &                                         * zdep
221                  tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal)                       &
222                      &                                         * zdep 
223               END DO 
224            END DO 
225         END DO
226      ENDIF
227
228      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
229         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
230         ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:)
231         CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt )
232         CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds )
233         DEALLOCATE( ztrdt , ztrds ) 
234      ENDIF
235      !
236      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
237         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
238      !
239      IF( ln_timing )   CALL timing_stop('tra_sbc')
240      !
241   END SUBROUTINE tra_sbc
242
243   !!======================================================================
244END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.