| 1 | MODULE zdfphy |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE zdfphy *** |
|---|
| 4 | !! Vertical ocean physics : manager of all vertical physics packages |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 4.0 ! 2017-04 (G. Madec) original code |
|---|
| 7 | !!---------------------------------------------------------------------- |
|---|
| 8 | |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | !! zdf_phy_init : initialization of all vertical physics packages |
|---|
| 11 | !! zdf_phy : upadate at each time-step the vertical mixing coeff. |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and tracers variables |
|---|
| 14 | USE zdf_oce ! vertical physics: shared variables |
|---|
| 15 | USE zdfdrg ! vertical physics: top/bottom drag coef. |
|---|
| 16 | USE zdfsh2 ! vertical physics: shear production term of TKE |
|---|
| 17 | USE zdfric ! vertical physics: RIChardson dependent vertical mixing |
|---|
| 18 | USE zdftke ! vertical physics: TKE vertical mixing |
|---|
| 19 | USE zdfgls ! vertical physics: GLS vertical mixing |
|---|
| 20 | USE zdfddm ! vertical physics: double diffusion mixing |
|---|
| 21 | USE zdfevd ! vertical physics: convection via enhanced vertical diffusion |
|---|
| 22 | USE zdfiwm ! vertical physics: internal wave-induced mixing |
|---|
| 23 | USE zdfswm ! vertical physics: surface wave-induced mixing |
|---|
| 24 | USE zdfmxl ! vertical physics: mixed layer |
|---|
| 25 | USE tranpc ! convection: non penetrative adjustment |
|---|
| 26 | USE trc_oce ! variables shared between passive tracer & ocean |
|---|
| 27 | USE sbc_oce ! surface module (only for nn_isf in the option compatibility test) |
|---|
| 28 | USE sbcrnf ! surface boundary condition: runoff variables |
|---|
| 29 | #if defined key_agrif |
|---|
| 30 | USE agrif_opa_interp ! interpavm |
|---|
| 31 | #endif |
|---|
| 32 | ! |
|---|
| 33 | USE in_out_manager ! I/O manager |
|---|
| 34 | USE iom ! IOM library |
|---|
| 35 | USE lbclnk ! lateral boundary conditions |
|---|
| 36 | USE lib_mpp ! distribued memory computing |
|---|
| 37 | USE timing ! Timing |
|---|
| 38 | |
|---|
| 39 | IMPLICIT NONE |
|---|
| 40 | PRIVATE |
|---|
| 41 | |
|---|
| 42 | PUBLIC zdf_phy_init ! called by nemogcm.F90 |
|---|
| 43 | PUBLIC zdf_phy ! called by step.F90 |
|---|
| 44 | |
|---|
| 45 | INTEGER :: nzdf_phy ! type of vertical closure used |
|---|
| 46 | ! ! associated indicators |
|---|
| 47 | INTEGER, PARAMETER :: np_CST = 1 ! Constant Kz |
|---|
| 48 | INTEGER, PARAMETER :: np_RIC = 2 ! Richardson number dependent Kz |
|---|
| 49 | INTEGER, PARAMETER :: np_TKE = 3 ! Turbulente Kinetic Eenergy closure scheme for Kz |
|---|
| 50 | INTEGER, PARAMETER :: np_GLS = 4 ! Generic Length Scale closure scheme for Kz |
|---|
| 51 | |
|---|
| 52 | LOGICAL :: l_zdfsh2 ! shear production term flag (=F for CST, =T otherwise (i.e. TKE, GLS, RIC)) |
|---|
| 53 | |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! NEMO/OPA 4.0 , NEMO Consortium (2017) |
|---|
| 56 | !! $Id: zdfphy.F90 8160 2017-06-10 07:31:34Z gm $ |
|---|
| 57 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | CONTAINS |
|---|
| 60 | |
|---|
| 61 | SUBROUTINE zdf_phy_init |
|---|
| 62 | !!---------------------------------------------------------------------- |
|---|
| 63 | !! *** ROUTINE zdf_phy_init *** |
|---|
| 64 | !! |
|---|
| 65 | !! ** Purpose : initializations of the vertical ocean physics |
|---|
| 66 | !! |
|---|
| 67 | !! ** Method : Read namelist namzdf, control logicals |
|---|
| 68 | !! set horizontal shape and vertical profile of background mixing coef. |
|---|
| 69 | !!---------------------------------------------------------------------- |
|---|
| 70 | INTEGER :: jk ! dummy loop indices |
|---|
| 71 | INTEGER :: ioptio, ios ! local integers |
|---|
| 72 | !! |
|---|
| 73 | NAMELIST/namzdf/ ln_zdfcst, ln_zdfric, ln_zdftke, ln_zdfgls, & ! type of closure scheme |
|---|
| 74 | & ln_zdfevd, nn_evdm, rn_evd , & ! convection : evd |
|---|
| 75 | & ln_zdfnpc, nn_npc , nn_npcp, & ! convection : npc |
|---|
| 76 | & ln_zdfddm, rn_avts, rn_hsbfr, & ! double diffusion |
|---|
| 77 | & ln_zdfswm, & ! surface wave-induced mixing |
|---|
| 78 | & ln_zdfiwm, & ! internal - - - |
|---|
| 79 | & rn_avm0, rn_avt0, nn_avb, nn_havtb ! coefficients |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | ! |
|---|
| 82 | IF( ln_timing ) CALL timing_start('zdf_phy_init') |
|---|
| 83 | ! |
|---|
| 84 | ! !== Namelist ==! |
|---|
| 85 | REWIND( numnam_ref ) ! Namelist namzdf in reference namelist : Vertical mixing parameters |
|---|
| 86 | READ ( numnam_ref, namzdf, IOSTAT = ios, ERR = 901) |
|---|
| 87 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf in reference namelist', lwp ) |
|---|
| 88 | ! |
|---|
| 89 | REWIND( numnam_cfg ) ! Namelist namzdf in reference namelist : Vertical mixing parameters |
|---|
| 90 | READ ( numnam_cfg, namzdf, IOSTAT = ios, ERR = 902 ) |
|---|
| 91 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf in configuration namelist', lwp ) |
|---|
| 92 | IF(lwm) WRITE ( numond, namzdf ) |
|---|
| 93 | ! |
|---|
| 94 | IF(lwp) THEN ! Parameter print |
|---|
| 95 | WRITE(numout,*) |
|---|
| 96 | WRITE(numout,*) 'zdf_phy_init: vertical physics' |
|---|
| 97 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 98 | WRITE(numout,*) ' Namelist namzdf : set vertical mixing mixing parameters' |
|---|
| 99 | WRITE(numout,*) ' vertical closure scheme' |
|---|
| 100 | WRITE(numout,*) ' constant vertical mixing coefficient ln_zdfcst = ', ln_zdfcst |
|---|
| 101 | WRITE(numout,*) ' Richardson number dependent closure ln_zdfric = ', ln_zdfric |
|---|
| 102 | WRITE(numout,*) ' Turbulent Kinetic Energy closure (TKE) ln_zdftke = ', ln_zdftke |
|---|
| 103 | WRITE(numout,*) ' Generic Length Scale closure (GLS) ln_zdfgls = ', ln_zdfgls |
|---|
| 104 | WRITE(numout,*) ' convection: ' |
|---|
| 105 | WRITE(numout,*) ' enhanced vertical diffusion ln_zdfevd = ', ln_zdfevd |
|---|
| 106 | WRITE(numout,*) ' applied on momentum (=1/0) nn_evdm = ', nn_evdm |
|---|
| 107 | WRITE(numout,*) ' vertical coefficient for evd rn_evd = ', rn_evd |
|---|
| 108 | WRITE(numout,*) ' non-penetrative convection (npc) ln_zdfnpc = ', ln_zdfnpc |
|---|
| 109 | WRITE(numout,*) ' npc call frequency nn_npc = ', nn_npc |
|---|
| 110 | WRITE(numout,*) ' npc print frequency nn_npcp = ', nn_npcp |
|---|
| 111 | WRITE(numout,*) ' double diffusive mixing ln_zdfddm = ', ln_zdfddm |
|---|
| 112 | WRITE(numout,*) ' maximum avs for dd mixing rn_avts = ', rn_avts |
|---|
| 113 | WRITE(numout,*) ' heat/salt buoyancy flux ratio rn_hsbfr= ', rn_hsbfr |
|---|
| 114 | WRITE(numout,*) ' gravity wave-induced mixing' |
|---|
| 115 | WRITE(numout,*) ' surface wave (Qiao et al 2010) ln_zdfswm = ', ln_zdfswm ! surface wave induced mixing |
|---|
| 116 | WRITE(numout,*) ' internal wave (de Lavergne et al 2017) ln_zdfiwm = ', ln_zdfiwm |
|---|
| 117 | WRITE(numout,*) ' coefficients : ' |
|---|
| 118 | WRITE(numout,*) ' vertical eddy viscosity rn_avm0 = ', rn_avm0 |
|---|
| 119 | WRITE(numout,*) ' vertical eddy diffusivity rn_avt0 = ', rn_avt0 |
|---|
| 120 | WRITE(numout,*) ' constant background or profile nn_avb = ', nn_avb |
|---|
| 121 | WRITE(numout,*) ' horizontal variation for avtb nn_havtb = ', nn_havtb |
|---|
| 122 | ENDIF |
|---|
| 123 | |
|---|
| 124 | ! !== Background eddy viscosity and diffusivity ==! |
|---|
| 125 | IF( nn_avb == 0 ) THEN ! Define avmb, avtb from namelist parameter |
|---|
| 126 | avmb(:) = rn_avm0 |
|---|
| 127 | avtb(:) = rn_avt0 |
|---|
| 128 | ELSE ! Background profile of avt (fit a theoretical/observational profile (Krauss 1990) |
|---|
| 129 | avmb(:) = rn_avm0 |
|---|
| 130 | avtb(:) = rn_avt0 + ( 3.e-4_wp - 2._wp * rn_avt0 ) * 1.e-4_wp * gdepw_1d(:) ! m2/s |
|---|
| 131 | IF(ln_sco .AND. lwp) CALL ctl_warn( 'avtb profile not valid in sco' ) |
|---|
| 132 | ENDIF |
|---|
| 133 | ! ! 2D shape of the avtb |
|---|
| 134 | avtb_2d(:,:) = 1._wp ! uniform |
|---|
| 135 | ! |
|---|
| 136 | IF( nn_havtb == 1 ) THEN ! decrease avtb by a factor of ten in the equatorial band |
|---|
| 137 | ! ! -15S -5S : linear decrease from avt0 to avt0/10. |
|---|
| 138 | ! ! -5S +5N : cst value avt0/10. |
|---|
| 139 | ! ! 5N 15N : linear increase from avt0/10, to avt0 |
|---|
| 140 | WHERE(-15. <= gphit .AND. gphit < -5 ) avtb_2d = (1. - 0.09 * (gphit + 15.)) |
|---|
| 141 | WHERE( -5. <= gphit .AND. gphit < 5 ) avtb_2d = 0.1 |
|---|
| 142 | WHERE( 5. <= gphit .AND. gphit < 15 ) avtb_2d = (0.1 + 0.09 * (gphit - 5.)) |
|---|
| 143 | ENDIF |
|---|
| 144 | ! |
|---|
| 145 | DO jk = 1, jpk ! set turbulent closure Kz to the background value (avt_k, avm_k) |
|---|
| 146 | avt_k(:,:,jk) = avtb_2d(:,:) * avtb(jk) * wmask (:,:,jk) |
|---|
| 147 | avm_k(:,:,jk) = avmb(jk) * wmask (:,:,jk) |
|---|
| 148 | END DO |
|---|
| 149 | !!gm to be tested only the 1st & last levels |
|---|
| 150 | ! avt (:,:, 1 ) = 0._wp ; avs(:,:, 1 ) = 0._wp ; avm (:,:, 1 ) = 0._wp |
|---|
| 151 | ! avt (:,:,jpk) = 0._wp ; avs(:,:,jpk) = 0._wp ; avm (:,:,jpk) = 0._wp |
|---|
| 152 | !!gm |
|---|
| 153 | avt (:,:,:) = 0._wp ; avs(:,:,:) = 0._wp ; avm (:,:,:) = 0._wp |
|---|
| 154 | |
|---|
| 155 | ! !== Convection ==! |
|---|
| 156 | ! |
|---|
| 157 | IF( ln_zdfnpc .AND. ln_zdfevd ) CALL ctl_stop( 'zdf_phy_init: chose between ln_zdfnpc and ln_zdfevd' ) |
|---|
| 158 | IF( lk_top .AND. ln_zdfnpc ) CALL ctl_stop( 'zdf_phy_init: npc scheme is not working with key_top' ) |
|---|
| 159 | IF(lwp) THEN |
|---|
| 160 | WRITE(numout,*) |
|---|
| 161 | IF ( ln_zdfnpc ) THEN ; WRITE(numout,*) ' convection: use non penetrative convective scheme' |
|---|
| 162 | ELSEIF( ln_zdfevd ) THEN ; WRITE(numout,*) ' convection: use enhanced vertical diffusion scheme' |
|---|
| 163 | ELSE ; WRITE(numout,*) ' convection: no specific scheme used' |
|---|
| 164 | ENDIF |
|---|
| 165 | ENDIF |
|---|
| 166 | |
|---|
| 167 | IF(lwp) THEN !== Double Diffusion Mixing parameterization ==! (ddm) |
|---|
| 168 | WRITE(numout,*) |
|---|
| 169 | IF( ln_zdfddm ) THEN ; WRITE(numout,*) ' use double diffusive mixing: avs /= avt' |
|---|
| 170 | ELSE ; WRITE(numout,*) ' No double diffusive mixing: avs = avt' |
|---|
| 171 | ENDIF |
|---|
| 172 | ENDIF |
|---|
| 173 | |
|---|
| 174 | ! !== type of vertical turbulent closure ==! (set nzdf_phy) |
|---|
| 175 | ioptio = 0 |
|---|
| 176 | IF( ln_zdfcst ) THEN ; ioptio = ioptio + 1 ; nzdf_phy = np_CST ; ENDIF |
|---|
| 177 | IF( ln_zdfric ) THEN ; ioptio = ioptio + 1 ; nzdf_phy = np_RIC ; CALL zdf_ric_init ; ENDIF |
|---|
| 178 | IF( ln_zdftke ) THEN ; ioptio = ioptio + 1 ; nzdf_phy = np_TKE ; CALL zdf_tke_init ; ENDIF |
|---|
| 179 | IF( ln_zdfgls ) THEN ; ioptio = ioptio + 1 ; nzdf_phy = np_GLS ; CALL zdf_gls_init ; ENDIF |
|---|
| 180 | ! |
|---|
| 181 | IF( ioptio /= 1 ) CALL ctl_stop( 'zdf_phy_init: one and only one vertical diffusion option has to be defined ' ) |
|---|
| 182 | IF( ln_isfcav ) THEN |
|---|
| 183 | IF( ln_zdfric .OR. ln_zdfgls ) CALL ctl_stop( 'zdf_phy_init: zdfric and zdfgls never tested with ice shelves cavities ' ) |
|---|
| 184 | ENDIF |
|---|
| 185 | ! ! shear production term flag |
|---|
| 186 | IF( ln_zdfcst ) THEN ; l_zdfsh2 = .FALSE. |
|---|
| 187 | ELSE ; l_zdfsh2 = .TRUE. |
|---|
| 188 | ENDIF |
|---|
| 189 | |
|---|
| 190 | ! !== gravity wave-driven mixing ==! |
|---|
| 191 | IF( ln_zdfiwm ) CALL zdf_iwm_init ! internal wave-driven mixing |
|---|
| 192 | IF( ln_zdfswm ) CALL zdf_swm_init ! surface wave-driven mixing |
|---|
| 193 | |
|---|
| 194 | ! !== top/bottom friction ==! |
|---|
| 195 | CALL zdf_drg_init |
|---|
| 196 | ! |
|---|
| 197 | ! !== time-stepping ==! |
|---|
| 198 | ! Check/update of time stepping done in dynzdf_init/trazdf_init |
|---|
| 199 | !!gm move it here ? |
|---|
| 200 | ! |
|---|
| 201 | IF( ln_timing ) CALL timing_stop('zdf_phy_init') |
|---|
| 202 | ! |
|---|
| 203 | END SUBROUTINE zdf_phy_init |
|---|
| 204 | |
|---|
| 205 | |
|---|
| 206 | SUBROUTINE zdf_phy( kt ) |
|---|
| 207 | !!---------------------------------------------------------------------- |
|---|
| 208 | !! *** ROUTINE zdf_phy *** |
|---|
| 209 | !! |
|---|
| 210 | !! ** Purpose : Update ocean physics at each time-step |
|---|
| 211 | !! |
|---|
| 212 | !! ** Method : |
|---|
| 213 | !! |
|---|
| 214 | !! ** Action : avm, avt vertical eddy viscosity and diffusivity at w-points |
|---|
| 215 | !! nmld ??? mixed layer depth in level and meters <<<<====verifier ! |
|---|
| 216 | !! bottom stress..... <<<<====verifier ! |
|---|
| 217 | !!---------------------------------------------------------------------- |
|---|
| 218 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 219 | ! |
|---|
| 220 | INTEGER :: ji, jj, jk ! dummy loop indice |
|---|
| 221 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zsh2 ! shear production |
|---|
| 222 | !! --------------------------------------------------------------------- |
|---|
| 223 | ! |
|---|
| 224 | IF( ln_timing ) CALL timing_start('zdf_phy') |
|---|
| 225 | ! |
|---|
| 226 | IF( l_zdfdrg ) THEN !== update top/bottom drag ==! (non-linear cases) |
|---|
| 227 | ! |
|---|
| 228 | ! !* bottom drag |
|---|
| 229 | CALL zdf_drg( kt, mbkt , r_Cdmin_bot, r_Cdmax_bot, & ! <<== in |
|---|
| 230 | & r_z0_bot, r_ke0_bot, rCd0_bot, & |
|---|
| 231 | & rCdU_bot ) ! ==>> out : bottom drag [m/s] |
|---|
| 232 | IF( ln_isfcav ) THEN !* top drag (ocean cavities) |
|---|
| 233 | CALL zdf_drg( kt, mikt , r_Cdmin_top, r_Cdmax_top, & ! <<== in |
|---|
| 234 | & r_z0_top, r_ke0_top, rCd0_top, & |
|---|
| 235 | & rCdU_top ) ! ==>> out : bottom drag [m/s] |
|---|
| 236 | ENDIF |
|---|
| 237 | ENDIF |
|---|
| 238 | ! |
|---|
| 239 | ! !== Kz from chosen turbulent closure ==! (avm_k, avt_k) |
|---|
| 240 | ! |
|---|
| 241 | IF( l_zdfsh2 ) & !* shear production at w-points (energy conserving form) |
|---|
| 242 | CALL zdf_sh2( ub, vb, un, vn, avm_k, & ! <<== in |
|---|
| 243 | & zsh2 ) ! ==>> out : shear production |
|---|
| 244 | ! |
|---|
| 245 | SELECT CASE ( nzdf_phy ) !* Vertical eddy viscosity and diffusivity coefficients at w-points |
|---|
| 246 | CASE( np_RIC ) ; CALL zdf_ric( kt, gdept_n, zsh2, avm_k, avt_k ) ! Richardson number dependent Kz |
|---|
| 247 | CASE( np_TKE ) ; CALL zdf_tke( kt , zsh2, avm_k, avt_k ) ! TKE closure scheme for Kz |
|---|
| 248 | CASE( np_GLS ) ; CALL zdf_gls( kt , zsh2, avm_k, avt_k ) ! GLS closure scheme for Kz |
|---|
| 249 | ! CASE( np_CST ) ! Constant Kz (reset avt, avm to the background value) |
|---|
| 250 | ! ! avt_k and avm_k set one for all at initialisation phase |
|---|
| 251 | !!gm avt(2:jpim1,2:jpjm1,1:jpkm1) = rn_avt0 * wmask(2:jpim1,2:jpjm1,1:jpkm1) |
|---|
| 252 | !!gm avm(2:jpim1,2:jpjm1,1:jpkm1) = rn_avm0 * wmask(2:jpim1,2:jpjm1,1:jpkm1) |
|---|
| 253 | END SELECT |
|---|
| 254 | ! |
|---|
| 255 | ! !== ocean Kz ==! (avt, avs, avm) |
|---|
| 256 | ! |
|---|
| 257 | ! !* start from turbulent closure values |
|---|
| 258 | avt(:,:,2:jpkm1) = avt_k(:,:,2:jpkm1) |
|---|
| 259 | avm(:,:,2:jpkm1) = avm_k(:,:,2:jpkm1) |
|---|
| 260 | ! |
|---|
| 261 | IF( ln_rnf_mouth ) THEN !* increase diffusivity at rivers mouths |
|---|
| 262 | DO jk = 2, nkrnf |
|---|
| 263 | avt(:,:,jk) = avt(:,:,jk) + 2._wp * rn_avt_rnf * rnfmsk(:,:) * wmask(:,:,jk) |
|---|
| 264 | END DO |
|---|
| 265 | ENDIF |
|---|
| 266 | ! |
|---|
| 267 | IF( ln_zdfevd ) CALL zdf_evd( kt, avm, avt ) !* convection: enhanced vertical eddy diffusivity |
|---|
| 268 | ! |
|---|
| 269 | ! !* double diffusive mixing |
|---|
| 270 | IF( ln_zdfddm ) THEN ! update avt and compute avs |
|---|
| 271 | CALL zdf_ddm( kt, avm, avt, avs ) |
|---|
| 272 | ELSE ! same mixing on all tracers |
|---|
| 273 | avs(2:jpim1,2:jpjm1,1:jpkm1) = avt(2:jpim1,2:jpjm1,1:jpkm1) |
|---|
| 274 | ENDIF |
|---|
| 275 | ! |
|---|
| 276 | ! !* wave-induced mixing |
|---|
| 277 | IF( ln_zdfswm ) CALL zdf_swm( kt, avm, avt, avs ) ! surface wave (Qiao et al. 2004) |
|---|
| 278 | IF( ln_zdfiwm ) CALL zdf_iwm( kt, avm, avt, avs ) ! internal wave (de Lavergne et al 2017) |
|---|
| 279 | |
|---|
| 280 | #if defined key_agrif |
|---|
| 281 | ! interpolation parent grid => child grid for avm_k ( ex : at west border: update column 1 and 2) |
|---|
| 282 | IF( l_zdfsh2 ) CALL Agrif_avm |
|---|
| 283 | #endif |
|---|
| 284 | |
|---|
| 285 | ! !* Lateral boundary conditions (sign unchanged) |
|---|
| 286 | IF( l_zdfsh2 ) THEN |
|---|
| 287 | CALL lbc_lnk( avm_k, 'W', 1. ) ! needed to compute the shear production term |
|---|
| 288 | CALL lbc_lnk( avt_k, 'W', 1. ) !!gm a priori useless ==>> to be tested |
|---|
| 289 | ENDIF |
|---|
| 290 | CALL lbc_lnk( avm , 'W', 1. ) ! needed to compute avm at u- and v-points |
|---|
| 291 | CALL lbc_lnk( avt , 'W', 1. ) !!gm a priori only avm_k and avm are required |
|---|
| 292 | CALL lbc_lnk( avs , 'W', 1. ) !!gm for calculation, keeped here for output only |
|---|
| 293 | ! |
|---|
| 294 | IF( l_zdfdrg ) THEN ! drag have been updated (non-linear cases) |
|---|
| 295 | IF( ln_isfcav ) CALL lbc_lnk( rCdU_top, 'T', 1. ) ! top drag |
|---|
| 296 | CALL lbc_lnk( rCdU_bot, 'T', 1. ) ! bottom drag |
|---|
| 297 | ENDIF |
|---|
| 298 | ! |
|---|
| 299 | CALL zdf_mxl( kt ) !* mixed layer depth, and level |
|---|
| 300 | ! |
|---|
| 301 | IF( lrst_oce ) THEN !* write TKE, GLS or RIC fields in the restart file |
|---|
| 302 | IF( ln_zdftke ) CALL tke_rst( kt, 'WRITE' ) |
|---|
| 303 | IF( ln_zdfgls ) CALL gls_rst( kt, 'WRITE' ) |
|---|
| 304 | IF( ln_zdfric ) CALL ric_rst( kt, 'WRITE' ) |
|---|
| 305 | ENDIF |
|---|
| 306 | ! |
|---|
| 307 | IF( ln_timing ) CALL timing_stop('zdf_phy') |
|---|
| 308 | ! |
|---|
| 309 | END SUBROUTINE zdf_phy |
|---|
| 310 | |
|---|
| 311 | !!====================================================================== |
|---|
| 312 | END MODULE zdfphy |
|---|
