New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2017/dev_CNRS_2017/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2017/dev_CNRS_2017/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 9012

Last change on this file since 9012 was 9012, checked in by acc, 6 years ago

Branch dev_CNRS_2017. Merge in no_ghost changes from dev_r8126_ROBUST08_no_ghost. These changes include lib_mpp refresh and rationalisation of mppini from dev_r8126_ROBUST10_MPPINI

  • Property svn:keywords set to Id
File size: 40.7 KB
RevLine 
[2496]1MODULE nemogcm
[2442]2   !!======================================================================
[2496]3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
[2442]5   !!======================================================================
[1593]6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
[3764]8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
[1593]10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
[3764]11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
[2104]13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
[1593]14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
[3764]15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
[1593]17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
[3764]27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
[2236]28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
[3294]29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
[5836]30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
[7646]35   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
[1593]36   !!----------------------------------------------------------------------
[3]37
38   !!----------------------------------------------------------------------
[6140]39   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
40   !!   nemo_init     : initialization of the NEMO system
41   !!   nemo_ctl      : initialisation of the contol print
42   !!   nemo_closefile: close remaining open files
43   !!   nemo_alloc    : dynamical allocation
44   !!   nemo_partition: calculate MPP domain decomposition
45   !!   factorise     : calculate the factors of the no. of MPI processes
[3]46   !!----------------------------------------------------------------------
[6140]47   USE step_oce       ! module used in the ocean time stepping module (step.F90)
[7646]48   USE phycst         ! physical constant                  (par_cst routine)
49   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
50   USE usrdef_nam     ! user defined configuration
[6140]51   USE tideini        ! tidal components initialization   (tide_ini routine)
[8882]52   USE bdy_oce,  ONLY : ln_bdy
[6140]53   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
54   USE istate         ! initial state setting          (istate_init routine)
55   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
56   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
57   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
58   USE asminc         ! assimilation increments     
59   USE asmbkg         ! writing out state trajectory
60   USE diaptr         ! poleward transports           (dia_ptr_init routine)
61   USE diadct         ! sections transports           (dia_dct_init routine)
62   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
63   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
64   USE step           ! NEMO time-stepping                 (stp     routine)
65   USE icbini         ! handle bergs, initialisation
66   USE icbstp         ! handle bergs, calving, themodynamics and transport
67   USE cpl_oasis3     ! OASIS3 coupling
68   USE c1d            ! 1D configuration
69   USE step_c1d       ! Time stepping loop for the 1D configuration
70   USE dyndmp         ! Momentum damping
71   USE stopar         ! Stochastic param.: ???
72   USE stopts         ! Stochastic param.: ???
[7646]73   USE diurnal_bulk   ! diurnal bulk SST
74   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
75   USE crsini         ! initialise grid coarsening utility
76   USE diatmb         ! Top,middle,bottom output
77   USE dia25h         ! 25h mean output
78   USE sbc_oce , ONLY : lk_oasis
79   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
[1594]80#if defined key_top
[6140]81   USE trcini         ! passive tracer initialisation
[1594]82#endif
[7646]83#if defined key_nemocice_decomp
84   USE ice_domain_size, only: nx_global, ny_global
85#endif
86   !
[6140]87   USE lib_mpp        ! distributed memory computing
[7646]88   USE mppini         ! shared/distributed memory setting (mpp_init routine)
89   USE lbcnfd , ONLY  : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
90   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
[1412]91#if defined key_iomput
[6140]92   USE xios           ! xIOserver
[1359]93#endif
[268]94
[2715]95   IMPLICIT NONE
[3]96   PRIVATE
97
[2496]98   PUBLIC   nemo_gcm    ! called by model.F90
99   PUBLIC   nemo_init   ! needed by AGRIF
[3764]100   PUBLIC   nemo_alloc  ! needed by TAM
[467]101
[2498]102   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
[1593]103
[3]104   !!----------------------------------------------------------------------
[7646]105   !! NEMO/OPA 3.7 , NEMO Consortium (2016)
[2392]106   !! $Id$
[2329]107   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[3]108   !!----------------------------------------------------------------------
109CONTAINS
110
[2496]111   SUBROUTINE nemo_gcm
[3]112      !!----------------------------------------------------------------------
[2496]113      !!                     ***  ROUTINE nemo_gcm  ***
[3]114      !!
[3764]115      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
[1593]116      !!              curvilinear mesh on the sphere.
[3]117      !!
118      !! ** Method  : - model general initialization
119      !!              - launch the time-stepping (stp routine)
[1593]120      !!              - finalize the run by closing files and communications
[3]121      !!
[2715]122      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
[1593]123      !!              Madec, 2008, internal report, IPSL.
[3]124      !!----------------------------------------------------------------------
[7646]125      INTEGER ::   istp   ! time step index
[389]126      !!----------------------------------------------------------------------
[2382]127      !
[392]128#if defined key_agrif
[1593]129      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
[389]130#endif
[7646]131      !
[1593]132      !                            !-----------------------!
[2496]133      CALL nemo_init               !==  Initialisations  ==!
[1593]134      !                            !-----------------------!
[2715]135#if defined key_agrif
[3680]136      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
137      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
[2715]138# if defined key_top
[3680]139      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
[2715]140# endif
[7646]141# if defined key_lim3
142      CALL Agrif_Declare_Var_lim3  !  "      "   "   "      "  LIM3
143# endif
[2715]144#endif
[682]145      ! check that all process are still there... If some process have an error,
146      ! they will never enter in step and other processes will wait until the end of the cpu time!
[900]147      IF( lk_mpp )   CALL mpp_max( nstop )
[682]148
[1593]149      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
150
151      !                            !-----------------------!
152      !                            !==   time stepping   ==!
153      !                            !-----------------------!
[900]154      istp = nit000
[2236]155#if defined key_c1d
[389]156         DO WHILE ( istp <= nitend .AND. nstop == 0 )
[900]157            CALL stp_c1d( istp )
[389]158            istp = istp + 1
159         END DO
[2236]160#else
161          IF( lk_asminc ) THEN
162             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
163             IF( ln_asmdin ) THEN                        ! Direct initialization
164                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
[3764]165                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
[2236]166                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
167             ENDIF
168          ENDIF
[3764]169
[5656]170#if defined key_agrif
171          CALL Agrif_Regrid()
172#endif
173
[389]174         DO WHILE ( istp <= nitend .AND. nstop == 0 )
[392]175#if defined key_agrif
[5656]176            CALL stp                         ! AGRIF: time stepping
[389]177#else
[6140]178            IF ( .NOT. ln_diurnal_only ) THEN
179               CALL stp( istp )                 ! standard time stepping
180            ELSE
181               CALL stp_diurnal( istp )        ! time step only the diurnal SST
182            ENDIF 
[389]183#endif
184            istp = istp + 1
[900]185            IF( lk_mpp )   CALL mpp_max( nstop )
[389]186         END DO
[2236]187#endif
188
[6140]189      IF( ln_diaobs   )   CALL dia_obs_wri
[3609]190      !
191      IF( ln_icebergs )   CALL icb_end( nitend )
[3764]192
[1593]193      !                            !------------------------!
194      !                            !==  finalize the run  ==!
195      !                            !------------------------!
[7646]196      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
[1593]197      !
[7646]198      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
[682]199         WRITE(numout,cform_err)
[3764]200         WRITE(numout,*) nstop, ' error have been found'
[389]201      ENDIF
[1593]202      !
[3294]203#if defined key_agrif
[8974]204      IF( .NOT. Agrif_Root() ) THEN
205         CALL Agrif_ParentGrid_To_ChildGrid()
206         IF( ln_diaobs )        CALL dia_obs_wri
207         IF( nn_timing == 1 )   CALL timing_finalize
208         CALL Agrif_ChildGrid_To_ParentGrid()
209      ENDIF
[3294]210#endif
[8882]211      IF( ln_timing    )   CALL timing_finalize
[3294]212      !
[2496]213      CALL nemo_closefile
[4990]214      !
[3769]215#if defined key_iomput
[7646]216      CALL xios_finalize                     ! end mpp communications with xios
217      IF( lk_oasis )   CALL cpl_finalize     ! end coupling and mpp communications with OASIS
[532]218#else
[5407]219      IF( lk_oasis ) THEN
[7646]220         CALL cpl_finalize                   ! end coupling and mpp communications with OASIS
[4990]221      ELSE
[7646]222         IF( lk_mpp )   CALL mppstop         ! end mpp communications
[4990]223      ENDIF
[532]224#endif
[900]225      !
[2496]226   END SUBROUTINE nemo_gcm
[389]227
228
[2496]229   SUBROUTINE nemo_init
[389]230      !!----------------------------------------------------------------------
[2496]231      !!                     ***  ROUTINE nemo_init  ***
[389]232      !!
[2496]233      !! ** Purpose :   initialization of the NEMO GCM
[389]234      !!----------------------------------------------------------------------
[7646]235      INTEGER  ::   ji                 ! dummy loop indices
236      INTEGER  ::   ios, ilocal_comm   ! local integer
[9012]237      INTEGER  ::   iiarea, ijarea     ! local integers
238      INTEGER  ::   iirest, ijrest     ! local integers
[7646]239      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
[4990]240      !
[7646]241      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
242         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
[8882]243         &             ln_timing, ln_diacfl
[7646]244      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
[3]245      !!----------------------------------------------------------------------
[1593]246      !
[7646]247      cltxt  = ''
248      cltxt2 = ''
249      clnam  = '' 
[5407]250      cxios_context = 'nemo'
[2496]251      !
[4147]252      !                             ! Open reference namelist and configuration namelist files
253      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
254      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
[1593]255      !
[7646]256      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints
[4147]257      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
[4289]258901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
[7646]259      !
260      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
[4147]261      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
[4289]262902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
[1593]263      !
[7646]264      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints
[4147]265      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
[4289]266903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
[4147]267
268      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
269      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
[4289]270904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
[4309]271
[7646]272      !                             !--------------------------!
273      !                             !  Set global domain size  !   (control print return in cltxt2)
274      !                             !--------------------------!
275      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
276         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
277         !
278      ELSE                                ! user-defined namelist
279         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
280      ENDIF
281      !
282      !
[1593]283      !                             !--------------------------------------------!
284      !                             !  set communicator & select the local node  !
[4624]285      !                             !  NB: mynode also opens output.namelist.dyn !
286      !                             !      on unit number numond on first proc   !
[1593]287      !                             !--------------------------------------------!
[1412]288#if defined key_iomput
[2200]289      IF( Agrif_Root() ) THEN
[5407]290         IF( lk_oasis ) THEN
[7646]291            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
292            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
[4990]293         ELSE
[7646]294            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
[4990]295         ENDIF
[2200]296      ENDIF
[5407]297      ! Nodes selection (control print return in cltxt)
298      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
[532]299#else
[5407]300      IF( lk_oasis ) THEN
[4990]301         IF( Agrif_Root() ) THEN
[7646]302            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
[4990]303         ENDIF
[5407]304         ! Nodes selection (control print return in cltxt)
305         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
[4990]306      ELSE
[7646]307         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
[5407]308         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
[2236]309      ENDIF
[532]310#endif
[7646]311
[2715]312      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
[3]313
[4624]314      lwm = (narea == 1)                                    ! control of output namelists
[2715]315      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
[1579]316
[7646]317      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
318         !                       ! now that the file has been opened in call to mynode.
319         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
[4624]320         WRITE( numond, namctl )
321         WRITE( numond, namcfg )
[7646]322         IF( .NOT.ln_read_cfg ) THEN
323            DO ji = 1, SIZE(clnam)
324               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
325            END DO
326         ENDIF
[4624]327      ENDIF
328
[3764]329      ! If dimensions of processor grid weren't specified in the namelist file
[2715]330      ! then we calculate them here now that we have our communicator size
[5836]331      IF( jpni < 1 .OR. jpnj < 1 ) THEN
[2715]332#if   defined key_mpp_mpi
[5836]333         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
[2715]334#else
335         jpni  = 1
336         jpnj  = 1
337         jpnij = jpni*jpnj
338#endif
[5836]339      ENDIF
[9012]340      !
341#if defined key_agrif
342      IF( .NOT. Agrif_Root() ) THEN       ! AGRIF children: specific setting (cf. agrif_user.F90)
343         jpiglo  = nbcellsx + 2 + 2*nbghostcells
344         jpjglo  = nbcellsy + 2 + 2*nbghostcells
345         jpi     = ( jpiglo-2*nn_hls + (jpni-1+0) ) / jpni + 2*nn_hls
346         jpj     = ( jpjglo-2*nn_hls + (jpnj-1+0) ) / jpnj + 2*nn_hls
347         jpimax  = jpi
348         jpjmax  = jpj
349         nperio  = 0
350         jperio  = 0
351         ln_use_jattr = .false.
352      ENDIF
353#endif
[2715]354
[7646]355      IF( Agrif_Root() ) THEN       ! AGRIF mother: specific setting from jpni and jpnj
[9012]356         iiarea = 1 + MOD( narea - 1 , jpni )
357         ijarea = 1 + ( narea - 1 ) / jpni
358         iirest = 1 + MOD( jpiglo - 2*nn_hls - 1 , jpni )
359         ijrest = 1 + MOD( jpjglo - 2*nn_hls - 1 , jpnj )
[3294]360#if defined key_nemocice_decomp
[9012]361         jpi = ( nx_global+2-2*nn_hls + (jpni-1) ) / jpni + 2*nn_hls    ! first  dim.
362         jpj = ( ny_global+2-2*nn_hls + (jpnj-1) ) / jpnj + 2*nn_hls    ! second dim.
363         jpimax  = jpi
364         jpjmax  = jpj
365         IF( iiarea == jpni ) jpi = jpiglo - (jpni - 1) * (jpi - 2*nn_hls)
366         IF( ijarea == jpnj ) jpj = jpjglo - (jpnj - 1) * (jpj - 2*nn_hls)
[3294]367#else
[9012]368         jpi = ( jpiglo     -2*nn_hls + (jpni-1) ) / jpni + 2*nn_hls    ! first  dim.
369         jpj = ( jpjglo     -2*nn_hls + (jpnj-1) ) / jpnj + 2*nn_hls    ! second dim.
370         jpimax  = jpi
371         jpjmax  = jpj
372         IF( iiarea > iirest ) jpi = jpi - 1
373         IF( ijarea > ijrest ) jpj = jpj - 1
[3294]374#endif
[7646]375      ENDIF
376
377      jpk = jpkglo                                             ! third dim
378
[5656]379#if defined key_agrif
[7646]380      ! simple trick to use same vertical grid as parent but different number of levels:
381      ! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
382      ! Suppress once vertical online interpolation is ok
383      IF(.NOT.Agrif_Root())   jpkglo = Agrif_Parent( jpkglo )
[5656]384#endif
[7646]385      jpim1 = jpi-1                                            ! inner domain indices
386      jpjm1 = jpj-1                                            !   "           "
[7761]387      jpkm1 = MAX( 1, jpk-1 )                                  !   "           "
[7646]388      jpij  = jpi*jpj                                          !  jpi x j
[2715]389
[1593]390      IF(lwp) THEN                            ! open listing units
391         !
[1581]392         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
[1593]393         !
[1579]394         WRITE(numout,*)
[3294]395         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
[1593]396         WRITE(numout,*) '                       NEMO team'
[1579]397         WRITE(numout,*) '            Ocean General Circulation Model'
[7646]398         WRITE(numout,*) '                NEMO version 3.7  (2016) '
[1579]399         WRITE(numout,*)
400         WRITE(numout,*)
[3764]401         DO ji = 1, SIZE(cltxt)
[7646]402            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
[1579]403         END DO
[7646]404         WRITE(numout,*)
405         WRITE(numout,*)
406         DO ji = 1, SIZE(cltxt2)
407            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
408         END DO
[1593]409         !
[7646]410         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
411         !
[473]412      ENDIF
[2715]413
[7646]414      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
[2715]415      CALL nemo_alloc()
416
[2496]417      !                             !-------------------------------!
418      !                             !  NEMO general initialization  !
419      !                             !-------------------------------!
[473]420
[7646]421      CALL nemo_ctl                          ! Control prints
[531]422
[2082]423      !                                      ! Domain decomposition
[9012]424      CALL mpp_init
425      IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
[2382]426      !
[8882]427      IF( ln_timing    )   CALL timing_init
[3294]428      !
[2082]429      !                                      ! General initialization
[8882]430                           CALL     phy_cst    ! Physical constants
431                           CALL     eos_init   ! Equation of state
432      IF( lk_c1d       )   CALL     c1d_init   ! 1D column configuration
433                           CALL     wad_init   ! Wetting and drying options
434                           CALL     dom_init   ! Domain
435      IF( ln_crs       )   CALL     crs_init   ! coarsened grid: domain initialization
[9012]436      !IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
[8882]437      IF( ln_ctl       )   CALL prt_ctl_init   ! Print control
[6140]438     
[8882]439      CALL diurnal_sst_bulk_init             ! diurnal sst
[6140]440      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
441     
442      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
[8882]443      IF( ln_diurnal_only ) THEN
[6140]444         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
445         CALL     sbc_init   ! Forcings : surface module
446         CALL tra_qsr_init   ! penetrative solar radiation qsr
[8882]447         IF( ln_diaobs ) THEN                   ! Observation & model comparison
448            CALL dia_obs_init                      ! Initialize observational data
449            CALL dia_obs( nit000 - 1 )             ! Observation operator for restart
[6140]450         ENDIF     
451         !                                     ! Assimilation increments
[8882]452         IF( lk_asminc )   CALL asm_inc_init   ! Initialize assimilation increments
[6140]453                 
454         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
455         RETURN
456      ENDIF
457     
[8882]458                           CALL  istate_init   ! ocean initial state (Dynamics and tracers)
[3651]459
[5836]460      !                                      ! external forcing
[8882]461                           CALL    tide_init   ! tidal harmonics
462                           CALL     sbc_init   ! surface boundary conditions (including sea-ice)
463                           CALL     bdy_init   ! Open boundaries initialisation
464
[5836]465      !                                      ! Ocean physics
[8882]466                           CALL zdf_phy_init    ! Vertical physics
467                                     
[2082]468      !                                         ! Lateral physics
[8882]469                           CALL ldf_tra_init      ! Lateral ocean tracer physics
470                           CALL ldf_eiv_init      ! eddy induced velocity param.
471                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
[2082]472
[8882]473      !                                      ! Active tracers
[8970]474      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
[8882]475                           CALL tra_bbc_init      ! bottom heat flux
476      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
477                           CALL tra_dmp_init      ! internal tracer damping
478                           CALL tra_adv_init      ! horizontal & vertical advection
479                           CALL tra_ldf_init      ! lateral mixing
[2027]480
[8882]481      !                                      ! Dynamics
482      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
483                           CALL dyn_adv_init      ! advection (vector or flux form)
484                           CALL dyn_vor_init      ! vorticity term including Coriolis
485                           CALL dyn_ldf_init      ! lateral mixing
486                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
487                           CALL dyn_spg_init      ! surface pressure gradient
[3764]488
[5836]489#if defined key_top
490      !                                      ! Passive tracers
[8882]491                           CALL     trc_init
[5836]492#endif
[8882]493      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
[5836]494
495      !                                      ! Icebergs
[8882]496                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
[5836]497
498      !                                      ! Misc. options
[8882]499                           CALL sto_par_init    ! Stochastic parametrization
500      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
[4147]501     
[5836]502      !                                      ! Diagnostics
[8882]503      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
504      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
505                           CALL dia_ptr_init    ! Poleward TRansports initialization
506      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
507                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
508                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
509                           CALL dia_obs_init    ! Initialize observational data
510      IF( ln_diaobs    )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
[6140]511
[8882]512      !                                      ! Assimilation increments
513      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
[2382]514      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
[8882]515                           CALL dia_tmb_init    ! TMB outputs
516                           CALL dia_25h_init    ! 25h mean  outputs
[1593]517      !
[2496]518   END SUBROUTINE nemo_init
[467]519
520
[2496]521   SUBROUTINE nemo_ctl
[467]522      !!----------------------------------------------------------------------
[2496]523      !!                     ***  ROUTINE nemo_ctl  ***
[467]524      !!
[3764]525      !! ** Purpose :   control print setting
[467]526      !!
[2442]527      !! ** Method  : - print namctl information and check some consistencies
[467]528      !!----------------------------------------------------------------------
[2442]529      !
[2496]530      IF(lwp) THEN                  ! control print
[531]531         WRITE(numout,*)
[7646]532         WRITE(numout,*) 'nemo_ctl: Control prints'
[531]533         WRITE(numout,*) '~~~~~~~ '
[1593]534         WRITE(numout,*) '   Namelist namctl'
[1601]535         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
536         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
537         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
538         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
539         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
540         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
541         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
542         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
[8882]543         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
544         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
[531]545      ENDIF
[2442]546      !
[1601]547      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
548      nictls    = nn_ictls
549      nictle    = nn_ictle
550      njctls    = nn_jctls
551      njctle    = nn_jctle
552      isplt     = nn_isplt
553      jsplt     = nn_jsplt
[8882]554!!gm to be remove at the end of the 2017 merge party
555      if( ln_timing ) then  ;  nn_timing = 1
556      else                  ;  nn_timing = 0
557      endif
558!!gm end
559     
[4147]560
561      IF(lwp) THEN                  ! control print
562         WRITE(numout,*)
[7646]563         WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
564         WRITE(numout,*) '~~~~~~ '
[4147]565         WRITE(numout,*) '   Namelist namcfg'
[7646]566         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
567         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
568         WRITE(numout,*) '      write configuration definition file           ln_write_cfg     = ', ln_write_cfg
569         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
570         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
[4147]571      ENDIF
[2442]572      !                             ! Parameter control
[1593]573      !
574      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
[3294]575         IF( lk_mpp .AND. jpnij > 1 ) THEN
[2496]576            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
[531]577         ELSE
578            IF( isplt == 1 .AND. jsplt == 1  ) THEN
[1593]579               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
580                  &           ' - the print control will be done over the whole domain' )
[531]581            ENDIF
[1593]582            ijsplt = isplt * jsplt            ! total number of processors ijsplt
[531]583         ENDIF
584         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
585         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
[1593]586         !
587         !                              ! indices used for the SUM control
588         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
[3764]589            lsp_area = .FALSE.
[1593]590         ELSE                                             ! print control done over a specific  area
[531]591            lsp_area = .TRUE.
592            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
593               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
594               nictls = 1
595            ENDIF
596            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
597               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
598               nictle = jpiglo
599            ENDIF
600            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
601               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
602               njctls = 1
603            ENDIF
604            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
605               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
606               njctle = jpjglo
607            ENDIF
[1593]608         ENDIF
609      ENDIF
[2442]610      !
[3764]611      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
612         &                                               'f2003 standard. '                              ,  &
613         &                                               'Compile with key_nosignedzero enabled' )
614      !
[2496]615   END SUBROUTINE nemo_ctl
[467]616
617
[2496]618   SUBROUTINE nemo_closefile
[467]619      !!----------------------------------------------------------------------
[2496]620      !!                     ***  ROUTINE nemo_closefile  ***
[467]621      !!
622      !! ** Purpose :   Close the files
623      !!----------------------------------------------------------------------
[1593]624      !
625      IF( lk_mpp )   CALL mppsync
626      !
[1685]627      CALL iom_close                                 ! close all input/output files managed by iom_*
[1593]628      !
[4147]629      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
[8882]630      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
[4147]631      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
632      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
[4624]633      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
[4147]634      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
635      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
[4624]636      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
[4147]637      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
638      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
639      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
640      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
641      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
[1593]642      !
[2442]643      numout = 6                                     ! redefine numout in case it is used after this point...
644      !
[2496]645   END SUBROUTINE nemo_closefile
[467]646
[2715]647
648   SUBROUTINE nemo_alloc
649      !!----------------------------------------------------------------------
650      !!                     ***  ROUTINE nemo_alloc  ***
651      !!
652      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
653      !!
654      !! ** Method  :
655      !!----------------------------------------------------------------------
656      USE diawri    , ONLY: dia_wri_alloc
657      USE dom_oce   , ONLY: dom_oce_alloc
658      USE trc_oce   , ONLY: trc_oce_alloc
[3680]659#if defined key_diadct 
660      USE diadct    , ONLY: diadct_alloc 
661#endif
[4354]662      USE bdy_oce   , ONLY: bdy_oce_alloc
[2715]663      !
664      INTEGER :: ierr
665      !!----------------------------------------------------------------------
666      !
[7646]667      ierr =        oce_alloc       ()          ! ocean
[2715]668      ierr = ierr + dia_wri_alloc   ()
669      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
670      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
671      !
672      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
673      !
[3680]674#if defined key_diadct 
675      ierr = ierr + diadct_alloc    ()          !
676#endif
[4354]677      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
[3680]678      !
[2715]679      IF( lk_mpp    )   CALL mpp_sum( ierr )
680      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
681      !
682   END SUBROUTINE nemo_alloc
683
684
685   SUBROUTINE nemo_partition( num_pes )
686      !!----------------------------------------------------------------------
687      !!                 ***  ROUTINE nemo_partition  ***
688      !!
[3764]689      !! ** Purpose :
[2715]690      !!
691      !! ** Method  :
692      !!----------------------------------------------------------------------
[4990]693      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
[2715]694      !
695      INTEGER, PARAMETER :: nfactmax = 20
696      INTEGER :: nfact ! The no. of factors returned
697      INTEGER :: ierr  ! Error flag
698      INTEGER :: ji
699      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
700      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
701      !!----------------------------------------------------------------------
[4990]702      !
[2715]703      ierr = 0
[4990]704      !
[2715]705      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
[4990]706      !
[2715]707      IF( nfact <= 1 ) THEN
708         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
709         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
710         jpnj = 1
711         jpni = num_pes
712      ELSE
713         ! Search through factors for the pair that are closest in value
714         mindiff = 1000000
715         imin    = 1
716         DO ji = 1, nfact-1, 2
717            idiff = ABS( ifact(ji) - ifact(ji+1) )
718            IF( idiff < mindiff ) THEN
719               mindiff = idiff
720               imin = ji
721            ENDIF
722         END DO
723         jpnj = ifact(imin)
724         jpni = ifact(imin + 1)
725      ENDIF
726      !
727      jpnij = jpni*jpnj
728      !
729   END SUBROUTINE nemo_partition
730
731
732   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
733      !!----------------------------------------------------------------------
734      !!                     ***  ROUTINE factorise  ***
735      !!
736      !! ** Purpose :   return the prime factors of n.
[3764]737      !!                knfax factors are returned in array kfax which is of
[2715]738      !!                maximum dimension kmaxfax.
739      !! ** Method  :
740      !!----------------------------------------------------------------------
741      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
742      INTEGER                    , INTENT(  out) ::   kerr, knfax
743      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
744      !
745      INTEGER :: ifac, jl, inu
746      INTEGER, PARAMETER :: ntest = 14
[5836]747      INTEGER, DIMENSION(ntest) ::   ilfax
[5656]748      !!----------------------------------------------------------------------
[5836]749      !
[2715]750      ! lfax contains the set of allowed factors.
[5656]751      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
[5836]752      !
[2715]753      ! Clear the error flag and initialise output vars
[5836]754      kerr  = 0
755      kfax  = 1
[2715]756      knfax = 0
[5836]757      !
[2715]758      ! Find the factors of n.
[8528]759      IF( kn .NE. 1 ) THEN
[2715]760
[8528]761         ! nu holds the unfactorised part of the number.
762         ! knfax holds the number of factors found.
763         ! l points to the allowed factor list.
764         ! ifac holds the current factor.
[2715]765         !
[8528]766         inu   = kn
767         knfax = 0
768         !
769         DO jl = ntest, 1, -1
[2715]770            !
[8528]771            ifac = ilfax(jl)
772            IF( ifac > inu )   CYCLE
773   
774            ! Test whether the factor will divide.
775   
776            IF( MOD(inu,ifac) == 0 ) THEN
777               !
778               knfax = knfax + 1            ! Add the factor to the list
779               IF( knfax > kmaxfax ) THEN
780                  kerr = 6
781                  write (*,*) 'FACTOR: insufficient space in factor array ', knfax
782                  return
783               ENDIF
784               kfax(knfax) = ifac
785               ! Store the other factor that goes with this one
786               knfax = knfax + 1
787               kfax(knfax) = inu / ifac
788               !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
[2715]789            ENDIF
[8528]790            !
791         END DO
[2715]792         !
[8528]793      ENDIF
[5836]794      !
[2715]795   END SUBROUTINE factorise
796
[3294]797#if defined key_mpp_mpi
[4990]798
[3294]799   SUBROUTINE nemo_northcomms
[5836]800      !!----------------------------------------------------------------------
[3294]801      !!                     ***  ROUTINE  nemo_northcomms  ***
[5836]802      !! ** Purpose :   Setup for north fold exchanges with explicit
803      !!                point-to-point messaging
[3764]804      !!
[5836]805      !! ** Method :   Initialization of the northern neighbours lists.
[3294]806      !!----------------------------------------------------------------------
[3764]807      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
[4230]808      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
[3294]809      !!----------------------------------------------------------------------
[4230]810      INTEGER  ::   sxM, dxM, sxT, dxT, jn
811      INTEGER  ::   njmppmax
[5836]812      !!----------------------------------------------------------------------
813      !
[4230]814      njmppmax = MAXVAL( njmppt )
[5836]815      !
[4230]816      !initializes the north-fold communication variables
817      isendto(:) = 0
[5836]818      nsndto     = 0
819      !
[4230]820      !if I am a process in the north
821      IF ( njmpp == njmppmax ) THEN
822          !sxM is the first point (in the global domain) needed to compute the
823          !north-fold for the current process
824          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
825          !dxM is the last point (in the global domain) needed to compute the
826          !north-fold for the current process
827          dxM = jpiglo - nimppt(narea) + 2
[3294]828
[4230]829          !loop over the other north-fold processes to find the processes
830          !managing the points belonging to the sxT-dxT range
[4671]831 
832          DO jn = 1, jpni
[4230]833                !sxT is the first point (in the global domain) of the jn
834                !process
[4671]835                sxT = nfiimpp(jn, jpnj)
[4230]836                !dxT is the last point (in the global domain) of the jn
837                !process
[4671]838                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
[4230]839                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
840                   nsndto = nsndto + 1
[7646]841                   isendto(nsndto) = jn
[4645]842                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
[4230]843                   nsndto = nsndto + 1
[7646]844                   isendto(nsndto) = jn
[4230]845                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
846                   nsndto = nsndto + 1
[7646]847                   isendto(nsndto) = jn
848                ENDIF
[4230]849          END DO
[4671]850          nfsloop = 1
851          nfeloop = nlci
852          DO jn = 2,jpni-1
853           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
854              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
855                 nfsloop = nldi
856              ENDIF
857              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
858                 nfeloop = nlei
859              ENDIF
860           ENDIF
861        END DO
862
[3294]863      ENDIF
[4230]864      l_north_nogather = .TRUE.
[3294]865   END SUBROUTINE nemo_northcomms
[5836]866
[3294]867#else
868   SUBROUTINE nemo_northcomms      ! Dummy routine
869      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
870   END SUBROUTINE nemo_northcomms
871#endif
[4990]872
[3]873   !!======================================================================
[2496]874END MODULE nemogcm
[4354]875
Note: See TracBrowser for help on using the repository browser.