New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2017/dev_CNRS_2017/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2017/dev_CNRS_2017/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 8882

Last change on this file since 8882 was 8882, checked in by flavoni, 6 years ago
dev_CNRS_2017 branch: merged dev_r7881_ENHANCE09_RK3 with trunk r8864
Property svn:keywords set to `Id`
File size: 40.1 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31	!! - ! 2011-11 (C. Harris) decomposition changes for running with CICE
32	!! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33	!! - ! 2013-06 (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34	!! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla)
35	!! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface
36	!!----------------------------------------------------------------------
37
38	!!----------------------------------------------------------------------
39	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
40	!! nemo_init : initialization of the NEMO system
41	!! nemo_ctl : initialisation of the contol print
42	!! nemo_closefile: close remaining open files
43	!! nemo_alloc : dynamical allocation
44	!! nemo_partition: calculate MPP domain decomposition
45	!! factorise : calculate the factors of the no. of MPI processes
46	!!----------------------------------------------------------------------
47	USE step_oce ! module used in the ocean time stepping module (step.F90)
48	USE phycst ! physical constant (par_cst routine)
49	USE domain ! domain initialization (dom_init & dom_cfg routines)
50	USE usrdef_nam ! user defined configuration
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE bdy_oce, ONLY : ln_bdy
53	USE bdyini ! open boundary cond. setting (bdy_init routine)
54	USE istate ! initial state setting (istate_init routine)
55	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
56	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
57	USE trdini ! dyn/tra trends initialization (trd_init routine)
58	USE asminc ! assimilation increments
59	USE asmbkg ! writing out state trajectory
60	USE diaptr ! poleward transports (dia_ptr_init routine)
61	USE diadct ! sections transports (dia_dct_init routine)
62	USE diaobs ! Observation diagnostics (dia_obs_init routine)
63	USE diacfl ! CFL diagnostics (dia_cfl_init routine)
64	USE step ! NEMO time-stepping (stp routine)
65	USE icbini ! handle bergs, initialisation
66	USE icbstp ! handle bergs, calving, themodynamics and transport
67	USE cpl_oasis3 ! OASIS3 coupling
68	USE c1d ! 1D configuration
69	USE step_c1d ! Time stepping loop for the 1D configuration
70	USE dyndmp ! Momentum damping
71	USE stopar ! Stochastic param.: ???
72	USE stopts ! Stochastic param.: ???
73	USE diurnal_bulk ! diurnal bulk SST
74	USE step_diu ! diurnal bulk SST timestepping (called from here if run offline)
75	USE crsini ! initialise grid coarsening utility
76	USE diatmb ! Top,middle,bottom output
77	USE dia25h ! 25h mean output
78	USE sbc_oce , ONLY : lk_oasis
79	USE wet_dry ! Wetting and drying setting (wad_init routine)
80	#if defined key_top
81	USE trcini ! passive tracer initialisation
82	#endif
83	#if defined key_nemocice_decomp
84	USE ice_domain_size, only: nx_global, ny_global
85	#endif
86	!
87	USE lib_mpp ! distributed memory computing
88	USE mppini ! shared/distributed memory setting (mpp_init routine)
89	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
90	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
91	#if defined key_iomput
92	USE xios ! xIOserver
93	#endif
94
95	IMPLICIT NONE
96	PRIVATE
97
98	PUBLIC nemo_gcm ! called by model.F90
99	PUBLIC nemo_init ! needed by AGRIF
100	PUBLIC nemo_alloc ! needed by TAM
101
102	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
103
104	!!----------------------------------------------------------------------
105	!! NEMO/OPA 3.7 , NEMO Consortium (2016)
106	!! $Id$
107	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
108	!!----------------------------------------------------------------------
109	CONTAINS
110
111	SUBROUTINE nemo_gcm
112	!!----------------------------------------------------------------------
113	!! * ROUTINE nemo_gcm *
114	!!
115	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
116	!! curvilinear mesh on the sphere.
117	!!
118	!! ** Method : - model general initialization
119	!! - launch the time-stepping (stp routine)
120	!! - finalize the run by closing files and communications
121	!!
122	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
123	!! Madec, 2008, internal report, IPSL.
124	!!----------------------------------------------------------------------
125	INTEGER :: istp ! time step index
126	!!----------------------------------------------------------------------
127	!
128	#if defined key_agrif
129	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
130	#endif
131	!
132	! !-----------------------!
133	CALL nemo_init !== Initialisations ==!
134	! !-----------------------!
135	#if defined key_agrif
136	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
137	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
138	# if defined key_top
139	CALL Agrif_Declare_Var_top ! " " " " " TOP
140	# endif
141	# if defined key_lim3
142	CALL Agrif_Declare_Var_lim3 ! " " " " " LIM3
143	# endif
144	#endif
145	! check that all process are still there... If some process have an error,
146	! they will never enter in step and other processes will wait until the end of the cpu time!
147	IF( lk_mpp ) CALL mpp_max( nstop )
148
149	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
150
151	! !-----------------------!
152	! !== time stepping ==!
153	! !-----------------------!
154	istp = nit000
155	#if defined key_c1d
156	DO WHILE ( istp <= nitend .AND. nstop == 0 )
157	CALL stp_c1d( istp )
158	istp = istp + 1
159	END DO
160	#else
161	IF( lk_asminc ) THEN
162	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
163	IF( ln_asmdin ) THEN ! Direct initialization
164	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
165	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
166	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
167	ENDIF
168	ENDIF
169
170	#if defined key_agrif
171	CALL Agrif_Regrid()
172	#endif
173
174	DO WHILE ( istp <= nitend .AND. nstop == 0 )
175	#if defined key_agrif
176	CALL stp ! AGRIF: time stepping
177	#else
178	IF ( .NOT. ln_diurnal_only ) THEN
179	CALL stp( istp ) ! standard time stepping
180	ELSE
181	CALL stp_diurnal( istp ) ! time step only the diurnal SST
182	ENDIF
183	#endif
184	istp = istp + 1
185	IF( lk_mpp ) CALL mpp_max( nstop )
186	END DO
187	#endif
188
189	IF( ln_diaobs ) CALL dia_obs_wri
190	!
191	IF( ln_icebergs ) CALL icb_end( nitend )
192
193	! !------------------------!
194	! !== finalize the run ==!
195	! !------------------------!
196	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
197	!
198	IF( nstop /= 0 .AND. lwp ) THEN ! error print
199	WRITE(numout,cform_err)
200	WRITE(numout,*) nstop, ' error have been found'
201	ENDIF
202	!
203	#if defined key_agrif
204	CALL Agrif_ParentGrid_To_ChildGrid()
205	IF( ln_diaobs ) CALL dia_obs_wri
206	IF( nn_timing == 1 ) CALL timing_finalize
207	CALL Agrif_ChildGrid_To_ParentGrid()
208	#endif
209	IF( ln_timing ) CALL timing_finalize
210	!
211	CALL nemo_closefile
212	!
213	#if defined key_iomput
214	CALL xios_finalize ! end mpp communications with xios
215	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
216	#else
217	IF( lk_oasis ) THEN
218	CALL cpl_finalize ! end coupling and mpp communications with OASIS
219	ELSE
220	IF( lk_mpp ) CALL mppstop ! end mpp communications
221	ENDIF
222	#endif
223	!
224	END SUBROUTINE nemo_gcm
225
226
227	SUBROUTINE nemo_init
228	!!----------------------------------------------------------------------
229	!! * ROUTINE nemo_init *
230	!!
231	!! ** Purpose : initialization of the NEMO GCM
232	!!----------------------------------------------------------------------
233	INTEGER :: ji ! dummy loop indices
234	INTEGER :: ios, ilocal_comm ! local integer
235	CHARACTER(len=120), DIMENSION(30) :: cltxt, cltxt2, clnam
236	!
237	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
238	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
239	& ln_timing, ln_diacfl
240	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
241	!!----------------------------------------------------------------------
242	!
243	cltxt = ''
244	cltxt2 = ''
245	clnam = ''
246	cxios_context = 'nemo'
247	!
248	! ! Open reference namelist and configuration namelist files
249	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
250	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
251	!
252	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints
253	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
254	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
255	!
256	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
257	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
258	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
259	!
260	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints
261	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
262	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
263
264	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
265	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
266	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
267
268	! !--------------------------!
269	! ! Set global domain size ! (control print return in cltxt2)
270	! !--------------------------!
271	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
272	CALL domain_cfg ( cltxt2, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
273	!
274	ELSE ! user-defined namelist
275	CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
276	ENDIF
277	!
278	jpk = jpkglo
279	!
280	#if defined key_agrif
281	IF( .NOT. Agrif_Root() ) THEN ! AGRIF children: specific setting (cf. agrif_user.F90)
282	jpiglo = nbcellsx + 2 + 2*nbghostcells
283	jpjglo = nbcellsy + 2 + 2*nbghostcells
284	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
285	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
286	nperio = 0
287	jperio = 0
288	ln_use_jattr = .false.
289	ENDIF
290	#endif
291	!
292	! !--------------------------------------------!
293	! ! set communicator & select the local node !
294	! ! NB: mynode also opens output.namelist.dyn !
295	! ! on unit number numond on first proc !
296	! !--------------------------------------------!
297	#if defined key_iomput
298	IF( Agrif_Root() ) THEN
299	IF( lk_oasis ) THEN
300	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
301	CALL xios_initialize( "not used" ,local_comm= ilocal_comm ) ! send nemo communicator to xios
302	ELSE
303	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
304	ENDIF
305	ENDIF
306	! Nodes selection (control print return in cltxt)
307	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
308	#else
309	IF( lk_oasis ) THEN
310	IF( Agrif_Root() ) THEN
311	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
312	ENDIF
313	! Nodes selection (control print return in cltxt)
314	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
315	ELSE
316	ilocal_comm = 0 ! Nodes selection (control print return in cltxt)
317	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
318	ENDIF
319	#endif
320
321	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
322
323	lwm = (narea == 1) ! control of output namelists
324	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
325
326	IF(lwm) THEN ! write merged namelists from earlier to output namelist
327	! ! now that the file has been opened in call to mynode.
328	! ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
329	WRITE( numond, namctl )
330	WRITE( numond, namcfg )
331	IF( .NOT.ln_read_cfg ) THEN
332	DO ji = 1, SIZE(clnam)
333	IF( TRIM(clnam(ji)) /= '' ) WRITE(numond, * ) clnam(ji) ! namusr_def print
334	END DO
335	ENDIF
336	ENDIF
337
338	! If dimensions of processor grid weren't specified in the namelist file
339	! then we calculate them here now that we have our communicator size
340	IF( jpni < 1 .OR. jpnj < 1 ) THEN
341	#if defined key_mpp_mpi
342	IF( Agrif_Root() ) CALL nemo_partition( mppsize )
343	#else
344	jpni = 1
345	jpnj = 1
346	jpnij = jpni*jpnj
347	#endif
348	ENDIF
349
350	IF( Agrif_Root() ) THEN ! AGRIF mother: specific setting from jpni and jpnj
351	#if defined key_nemocice_decomp
352	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
353	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
354	#else
355	jpi = ( jpiglo -2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
356	jpj = ( jpjglo -2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
357	#endif
358	ENDIF
359
360	!!gm ??? why here it has already been done in line 301 !
361	jpk = jpkglo ! third dim
362	!!gm end
363
364	#if defined key_agrif
365	! simple trick to use same vertical grid as parent but different number of levels:
366	! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
367	! Suppress once vertical online interpolation is ok
368	IF(.NOT.Agrif_Root()) jpkglo = Agrif_Parent( jpkglo )
369	#endif
370	jpim1 = jpi-1 ! inner domain indices
371	jpjm1 = jpj-1 ! " "
372	jpkm1 = MAX( 1, jpk-1 ) ! " "
373	jpij = jpi*jpj ! jpi x j
374
375	IF(lwp) THEN ! open listing units
376	!
377	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
378	!
379	WRITE(numout,*)
380	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
381	WRITE(numout,*) ' NEMO team'
382	WRITE(numout,*) ' Ocean General Circulation Model'
383	WRITE(numout,*) ' NEMO version 3.7 (2016) '
384	WRITE(numout,*)
385	WRITE(numout,*)
386	DO ji = 1, SIZE(cltxt)
387	IF( TRIM(cltxt (ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
388	END DO
389	WRITE(numout,*)
390	WRITE(numout,*)
391	DO ji = 1, SIZE(cltxt2)
392	IF( TRIM(cltxt2(ji)) /= '' ) WRITE(numout,*) cltxt2(ji) ! control print of domain size
393	END DO
394	!
395	WRITE(numout,cform_aaa) ! Flag AAAAAAA
396	!
397	ENDIF
398
399	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
400	CALL nemo_alloc()
401
402	! !-------------------------------!
403	! ! NEMO general initialization !
404	! !-------------------------------!
405
406	CALL nemo_ctl ! Control prints
407
408	! ! Domain decomposition
409	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
410	ELSE ; CALL mpp_init2 ! eliminate land processors
411	ENDIF
412	!
413	IF( ln_timing ) CALL timing_init
414	!
415	! ! General initialization
416	CALL phy_cst ! Physical constants
417	CALL eos_init ! Equation of state
418	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
419	CALL wad_init ! Wetting and drying options
420	CALL dom_init ! Domain
421	IF( ln_crs ) CALL crs_init ! coarsened grid: domain initialization
422	IF( ln_nnogather ) CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
423	IF( ln_ctl ) CALL prt_ctl_init ! Print control
424
425	CALL diurnal_sst_bulk_init ! diurnal sst
426	IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin
427
428	! IF ln_diurnal_only, then we only want a subset of the initialisation routines
429	IF( ln_diurnal_only ) THEN
430	CALL istate_init ! ocean initial state (Dynamics and tracers)
431	CALL sbc_init ! Forcings : surface module
432	CALL tra_qsr_init ! penetrative solar radiation qsr
433	IF( ln_diaobs ) THEN ! Observation & model comparison
434	CALL dia_obs_init ! Initialize observational data
435	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
436	ENDIF
437	! ! Assimilation increments
438	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
439
440	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
441	RETURN
442	ENDIF
443
444	CALL istate_init ! ocean initial state (Dynamics and tracers)
445
446	! ! external forcing
447	CALL tide_init ! tidal harmonics
448	CALL sbc_init ! surface boundary conditions (including sea-ice)
449	CALL bdy_init ! Open boundaries initialisation
450
451	! ! Ocean physics
452	CALL zdf_phy_init ! Vertical physics
453
454	! ! Lateral physics
455	CALL ldf_tra_init ! Lateral ocean tracer physics
456	CALL ldf_eiv_init ! eddy induced velocity param.
457	CALL ldf_dyn_init ! Lateral ocean momentum physics
458
459	! ! Active tracers
460	CALL tra_qsr_init ! penetrative solar radiation qsr
461	CALL tra_bbc_init ! bottom heat flux
462	IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
463	CALL tra_dmp_init ! internal tracer damping
464	CALL tra_adv_init ! horizontal & vertical advection
465	CALL tra_ldf_init ! lateral mixing
466
467	! ! Dynamics
468	IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping
469	CALL dyn_adv_init ! advection (vector or flux form)
470	CALL dyn_vor_init ! vorticity term including Coriolis
471	CALL dyn_ldf_init ! lateral mixing
472	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
473	CALL dyn_spg_init ! surface pressure gradient
474
475	#if defined key_top
476	! ! Passive tracers
477	CALL trc_init
478	#endif
479	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
480
481	! ! Icebergs
482	CALL icb_init( rdt, nit000) ! initialise icebergs instance
483
484	! ! Misc. options
485	CALL sto_par_init ! Stochastic parametrization
486	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
487
488	! ! Diagnostics
489	IF( lk_floats ) CALL flo_init ! drifting Floats
490	IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics
491	CALL dia_ptr_init ! Poleward TRansports initialization
492	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
493	CALL dia_hsb_init ! heat content, salt content and volume budgets
494	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
495	CALL dia_obs_init ! Initialize observational data
496	IF( ln_diaobs ) CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
497
498	! ! Assimilation increments
499	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
500	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
501	CALL dia_tmb_init ! TMB outputs
502	CALL dia_25h_init ! 25h mean outputs
503	!
504	END SUBROUTINE nemo_init
505
506
507	SUBROUTINE nemo_ctl
508	!!----------------------------------------------------------------------
509	!! * ROUTINE nemo_ctl *
510	!!
511	!! ** Purpose : control print setting
512	!!
513	!! ** Method : - print namctl information and check some consistencies
514	!!----------------------------------------------------------------------
515	!
516	IF(lwp) THEN ! control print
517	WRITE(numout,*)
518	WRITE(numout,*) 'nemo_ctl: Control prints'
519	WRITE(numout,*) '~~~~~~~ '
520	WRITE(numout,*) ' Namelist namctl'
521	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
522	WRITE(numout,*) ' level of print nn_print = ', nn_print
523	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
524	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
525	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
526	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
527	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
528	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
529	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
530	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
531	ENDIF
532	!
533	nprint = nn_print ! convert DOCTOR namelist names into OLD names
534	nictls = nn_ictls
535	nictle = nn_ictle
536	njctls = nn_jctls
537	njctle = nn_jctle
538	isplt = nn_isplt
539	jsplt = nn_jsplt
540	!!gm to be remove at the end of the 2017 merge party
541	if( ln_timing ) then ; nn_timing = 1
542	else ; nn_timing = 0
543	endif
544	!!gm end
545
546
547	IF(lwp) THEN ! control print
548	WRITE(numout,*)
549	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
550	WRITE(numout,*) '~~~~~~ '
551	WRITE(numout,*) ' Namelist namcfg'
552	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
553	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
554	WRITE(numout,*) ' write configuration definition file ln_write_cfg = ', ln_write_cfg
555	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
556	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
557	ENDIF
558	! ! Parameter control
559	!
560	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
561	IF( lk_mpp .AND. jpnij > 1 ) THEN
562	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
563	ELSE
564	IF( isplt == 1 .AND. jsplt == 1 ) THEN
565	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
566	& ' - the print control will be done over the whole domain' )
567	ENDIF
568	ijsplt = isplt * jsplt ! total number of processors ijsplt
569	ENDIF
570	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
571	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
572	!
573	! ! indices used for the SUM control
574	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
575	lsp_area = .FALSE.
576	ELSE ! print control done over a specific area
577	lsp_area = .TRUE.
578	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
579	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
580	nictls = 1
581	ENDIF
582	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
583	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
584	nictle = jpiglo
585	ENDIF
586	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
587	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
588	njctls = 1
589	ENDIF
590	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
591	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
592	njctle = jpjglo
593	ENDIF
594	ENDIF
595	ENDIF
596	!
597	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
598	& 'f2003 standard. ' , &
599	& 'Compile with key_nosignedzero enabled' )
600	!
601	END SUBROUTINE nemo_ctl
602
603
604	SUBROUTINE nemo_closefile
605	!!----------------------------------------------------------------------
606	!! * ROUTINE nemo_closefile *
607	!!
608	!! ** Purpose : Close the files
609	!!----------------------------------------------------------------------
610	!
611	IF( lk_mpp ) CALL mppsync
612	!
613	CALL iom_close ! close all input/output files managed by iom_*
614	!
615	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
616	IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file
617	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
618	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
619	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
620	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
621	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
622	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
623	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
624	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
625	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
626	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
627	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
628	!
629	numout = 6 ! redefine numout in case it is used after this point...
630	!
631	END SUBROUTINE nemo_closefile
632
633
634	SUBROUTINE nemo_alloc
635	!!----------------------------------------------------------------------
636	!! * ROUTINE nemo_alloc *
637	!!
638	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
639	!!
640	!! ** Method :
641	!!----------------------------------------------------------------------
642	USE diawri , ONLY: dia_wri_alloc
643	USE dom_oce , ONLY: dom_oce_alloc
644	USE trc_oce , ONLY: trc_oce_alloc
645	#if defined key_diadct
646	USE diadct , ONLY: diadct_alloc
647	#endif
648	USE bdy_oce , ONLY: bdy_oce_alloc
649	!
650	INTEGER :: ierr
651	!!----------------------------------------------------------------------
652	!
653	ierr = oce_alloc () ! ocean
654	ierr = ierr + dia_wri_alloc ()
655	ierr = ierr + dom_oce_alloc () ! ocean domain
656	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
657	!
658	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
659	!
660	#if defined key_diadct
661	ierr = ierr + diadct_alloc () !
662	#endif
663	ierr = ierr + bdy_oce_alloc () ! bdy masks (incl. initialization)
664	!
665	IF( lk_mpp ) CALL mpp_sum( ierr )
666	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
667	!
668	END SUBROUTINE nemo_alloc
669
670
671	SUBROUTINE nemo_partition( num_pes )
672	!!----------------------------------------------------------------------
673	!! * ROUTINE nemo_partition *
674	!!
675	!! ** Purpose :
676	!!
677	!! ** Method :
678	!!----------------------------------------------------------------------
679	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
680	!
681	INTEGER, PARAMETER :: nfactmax = 20
682	INTEGER :: nfact ! The no. of factors returned
683	INTEGER :: ierr ! Error flag
684	INTEGER :: ji
685	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
686	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
687	!!----------------------------------------------------------------------
688	!
689	ierr = 0
690	!
691	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
692	!
693	IF( nfact <= 1 ) THEN
694	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
695	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
696	jpnj = 1
697	jpni = num_pes
698	ELSE
699	! Search through factors for the pair that are closest in value
700	mindiff = 1000000
701	imin = 1
702	DO ji = 1, nfact-1, 2
703	idiff = ABS( ifact(ji) - ifact(ji+1) )
704	IF( idiff < mindiff ) THEN
705	mindiff = idiff
706	imin = ji
707	ENDIF
708	END DO
709	jpnj = ifact(imin)
710	jpni = ifact(imin + 1)
711	ENDIF
712	!
713	jpnij = jpni*jpnj
714	!
715	END SUBROUTINE nemo_partition
716
717
718	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
719	!!----------------------------------------------------------------------
720	!! * ROUTINE factorise *
721	!!
722	!! ** Purpose : return the prime factors of n.
723	!! knfax factors are returned in array kfax which is of
724	!! maximum dimension kmaxfax.
725	!! ** Method :
726	!!----------------------------------------------------------------------
727	INTEGER , INTENT(in ) :: kn, kmaxfax
728	INTEGER , INTENT( out) :: kerr, knfax
729	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
730	!
731	INTEGER :: ifac, jl, inu
732	INTEGER, PARAMETER :: ntest = 14
733	INTEGER, DIMENSION(ntest) :: ilfax
734	!!----------------------------------------------------------------------
735	!
736	! lfax contains the set of allowed factors.
737	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
738	!
739	! Clear the error flag and initialise output vars
740	kerr = 0
741	kfax = 1
742	knfax = 0
743	!
744	! Find the factors of n.
745	IF( kn .NE. 1 ) THEN
746
747	! nu holds the unfactorised part of the number.
748	! knfax holds the number of factors found.
749	! l points to the allowed factor list.
750	! ifac holds the current factor.
751	!
752	inu = kn
753	knfax = 0
754	!
755	DO jl = ntest, 1, -1
756	!
757	ifac = ilfax(jl)
758	IF( ifac > inu ) CYCLE
759
760	! Test whether the factor will divide.
761
762	IF( MOD(inu,ifac) == 0 ) THEN
763	!
764	knfax = knfax + 1 ! Add the factor to the list
765	IF( knfax > kmaxfax ) THEN
766	kerr = 6
767	write (,) 'FACTOR: insufficient space in factor array ', knfax
768	return
769	ENDIF
770	kfax(knfax) = ifac
771	! Store the other factor that goes with this one
772	knfax = knfax + 1
773	kfax(knfax) = inu / ifac
774	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
775	ENDIF
776	!
777	END DO
778	!
779	ENDIF
780	!
781	END SUBROUTINE factorise
782
783	#if defined key_mpp_mpi
784
785	SUBROUTINE nemo_northcomms
786	!!----------------------------------------------------------------------
787	!! * ROUTINE nemo_northcomms *
788	!! ** Purpose : Setup for north fold exchanges with explicit
789	!! point-to-point messaging
790	!!
791	!! ** Method : Initialization of the northern neighbours lists.
792	!!----------------------------------------------------------------------
793	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
794	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
795	!!----------------------------------------------------------------------
796	INTEGER :: sxM, dxM, sxT, dxT, jn
797	INTEGER :: njmppmax
798	!!----------------------------------------------------------------------
799	!
800	njmppmax = MAXVAL( njmppt )
801	!
802	!initializes the north-fold communication variables
803	isendto(:) = 0
804	nsndto = 0
805	!
806	!if I am a process in the north
807	IF ( njmpp == njmppmax ) THEN
808	!sxM is the first point (in the global domain) needed to compute the
809	!north-fold for the current process
810	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
811	!dxM is the last point (in the global domain) needed to compute the
812	!north-fold for the current process
813	dxM = jpiglo - nimppt(narea) + 2
814
815	!loop over the other north-fold processes to find the processes
816	!managing the points belonging to the sxT-dxT range
817
818	DO jn = 1, jpni
819	!sxT is the first point (in the global domain) of the jn
820	!process
821	sxT = nfiimpp(jn, jpnj)
822	!dxT is the last point (in the global domain) of the jn
823	!process
824	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
825	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
826	nsndto = nsndto + 1
827	isendto(nsndto) = jn
828	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
829	nsndto = nsndto + 1
830	isendto(nsndto) = jn
831	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
832	nsndto = nsndto + 1
833	isendto(nsndto) = jn
834	ENDIF
835	END DO
836	nfsloop = 1
837	nfeloop = nlci
838	DO jn = 2,jpni-1
839	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
840	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
841	nfsloop = nldi
842	ENDIF
843	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
844	nfeloop = nlei
845	ENDIF
846	ENDIF
847	END DO
848
849	ENDIF
850	l_north_nogather = .TRUE.
851	END SUBROUTINE nemo_northcomms
852
853	#else
854	SUBROUTINE nemo_northcomms ! Dummy routine
855	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
856	END SUBROUTINE nemo_northcomms
857	#endif
858
859	!!======================================================================
860	END MODULE nemogcm
861

Note: See TracBrowser for help on using the repository browser.

Download in other formats: