New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in branches/2017/dev_CNRS_2017/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2017/dev_CNRS_2017/NEMOGCM/NEMO/OPA_SRC/stpctl.F90 @ 9012

Last change on this file since 9012 was 8882, checked in by flavoni, 6 years ago

dev_CNRS_2017 branch: merged dev_r7881_ENHANCE09_RK3 with trunk r8864
  • Property svn:keywords set to Id
File size: 6.8 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!            3.7  ! 2016-09  (G. Madec)  Remove solver
12   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   stp_ctl      : Control the run
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE c1d             ! 1D vertical configuration
21   !
22   USE in_out_manager  ! I/O manager
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE lib_mpp         ! distributed memory computing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC stp_ctl           ! routine called by step.F90
30   !!----------------------------------------------------------------------
31   !! NEMO/OPA 4.0 , NEMO Consortium (2017)
32   !! $Id$
33   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
34   !!----------------------------------------------------------------------
35CONTAINS
36
37   SUBROUTINE stp_ctl( kt, kindic )
38      !!----------------------------------------------------------------------
39      !!                    ***  ROUTINE stp_ctl  ***
40      !!                     
41      !! ** Purpose :   Control the run
42      !!
43      !! ** Method  : - Save the time step in numstp
44      !!              - Print it each 50 time steps
45      !!              - Stop the run IF problem encountered by setting indic=-3
46      !!                Problems checked: |ssh| maximum larger than 10 m
47      !!                                  |U|   maximum larger than 10 m/s
48      !!                                  negative sea surface salinity
49      !!
50      !! ** Actions :   "time.step" file = last ocean time-step
51      !!                "run.stat"  file = run statistics
52      !!----------------------------------------------------------------------
53      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
54      INTEGER, INTENT(inout) ::   kindic   ! error indicator
55      !!
56      INTEGER  ::   ji, jj, jk             ! dummy loop indices
57      INTEGER  ::   iih, ijh               ! local integers
58      INTEGER  ::   iiu, iju, iku          !   -       -
59      INTEGER  ::   iis, ijs, iks          !   -       -
60      REAL(wp) ::   zzz                    ! local real
61      INTEGER , DIMENSION(3) ::   ilocu, ilocs
62      INTEGER , DIMENSION(2) ::   iloch
63      REAL(wp), DIMENSION(3) ::   zmax
64      !!----------------------------------------------------------------------
65      !
66      IF( kt == nit000 .AND. lwp ) THEN
67         WRITE(numout,*)
68         WRITE(numout,*) 'stp_ctl : time-stepping control'
69         WRITE(numout,*) '~~~~~~~'
70         !                                ! open time.step file
71         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
72         !                                ! open run.stat file
73         CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
74      ENDIF
75      !
76      IF(lwp) THEN                        !==  current time step  ==!   ("time.step" file)
77         WRITE ( numstp, '(1x, i8)' )   kt
78         REWIND( numstp )
79      ENDIF
80      !
81      !                                   !==  test of extrema  ==!
82      zmax(1) = MAXVAL(  ABS( sshn(:,:) )  )                                  ! ssh max
83      zmax(2) = MAXVAL(  ABS( un(:,:,:) )  )                                  ! velocity max (zonal only)
84      zmax(3) = MAXVAL( -tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )   ! minus salinity max
85      !
86      IF( lk_mpp )   CALL mpp_max_multiple( zmax(:), 3 ) ! max over the global domain
87      !
88      IF( MOD( kt, nwrite ) == 1 .AND. lwp ) THEN
89         WRITE(numout,*) ' ==>> time-step= ', kt, ' |ssh| max: ',   zmax(1), ' |U| max: ', zmax(2),   &
90            &                                     ' S min: '    , - zmax(3)
91      ENDIF
92      !
93      IF (  zmax(1) >  10._wp .OR.   &                     ! too large sea surface height ( > 10 m)
94         &  zmax(2) >  10._wp .OR.   &                     ! too large velocity ( > 10 m/s)
95         &  zmax(3) >=  0._wp .OR.   &                     ! negative or zero sea surface salinity
96         &  ISNAN( zmax(1) + zmax(2) + zmax(3) )  ) THEN   ! NaN encounter in the tests
97         IF( lk_mpp ) THEN
98            CALL mpp_maxloc( ABS(sshn)        , ssmask(:,:)  , zzz, iih, ijh )
99            CALL mpp_maxloc( ABS(un)          , umask (:,:,:), zzz, iiu, iju, iku )
100            CALL mpp_minloc( tsn(:,:,:,jp_sal), tmask (:,:,:), zzz, iis, ijs, iks )
101         ELSE
102            iloch = MINLOC( ABS( sshn(:,:)   )                               )
103            ilocu = MAXLOC( ABS( un  (:,:,:) )                               )
104            ilocs = MINLOC( tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )
105            iih = iloch(1) + nimpp - 1   ;   ijh = iloch(2) + njmpp - 1
106            iiu = ilocu(1) + nimpp - 1   ;   iju = ilocu(2) + njmpp - 1   ;   iku = ilocu(3)
107            iis = ilocs(1) + nimpp - 1   ;   ijs = ilocs(2) + njmpp - 1   ;   iks = ilocu(3)
108         ENDIF
109         IF(lwp) THEN
110            WRITE(numout,cform_err)
111            WRITE(numout,*) ' stpctl: |ssh| > 10 m   or   |U| > 10 m/s   or   S < 0   or   NaN encounter in the tests'
112            WRITE(numout,*) ' ====== '
113            WRITE(numout,9100) kt,   zmax(1), iih, ijh
114            WRITE(numout,9200) kt,   zmax(2), iiu, iju, iku
115            WRITE(numout,9300) kt, - zmax(3), iis, ijs, iks
116            WRITE(numout,*)
117            WRITE(numout,*) '          output of last computed fields in output.abort.nc file'
118         ENDIF
119         kindic = -3
120      ENDIF
1219100  FORMAT (' kt=',i8,'   |ssh| max: ',1pg11.4,', at  i j  : ',2i5)
1229200  FORMAT (' kt=',i8,'   |U|   max: ',1pg11.4,', at  i j k: ',3i5)
1239300  FORMAT (' kt=',i8,'   S     min: ',1pg11.4,', at  i j  : ',2i5)
124      !
125      !                                            !==  run statistics  ==!   ("run.stat" file)
126      IF(lwp) WRITE(numrun,9400) kt, zmax(1), zmax(2), - zmax(3)
127      !
1289400  FORMAT(' it :', i8, '    |ssh|_max: ', e16.10, ' |U|_max: ',e16.10,' S_min: ',e16.10)
129      !
130   END SUBROUTINE stp_ctl
131
132   !!======================================================================
133END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.