Context Navigation

nemogcm.F90 @ 9012

Last change on this file since 9012 was 9012, checked in by acc, 6 years ago
Branch dev_CNRS_2017. Merge in no_ghost changes from dev_r8126_ROBUST08_no_ghost. These changes include lib_mpp refresh and rationalisation of mppini from dev_r8126_ROBUST10_MPPINI
Property svn:keywords set to `Id`
File size: 28.6 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : 3.6 ! 2015-12 (A. Ryan) Original code (from OPA_SRC/)
7	!! 4.0 ! 2016-11 (G. Madec, S. Flavoni) domain configuration / user defined interface
8	!!----------------------------------------------------------------------
9
10	!!----------------------------------------------------------------------
11	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
12	!! nemo_init : initialization of the NEMO system
13	!! nemo_ctl : initialisation of the contol print
14	!! nemo_closefile: close remaining open files
15	!! nemo_alloc : dynamical allocation
16	!! nemo_partition: calculate MPP domain decomposition
17	!! factorise : calculate the factors of the no. of MPI processes
18	!!----------------------------------------------------------------------
19	USE step_oce ! module used in the ocean time stepping module (step.F90)
20	USE domain ! domain initialization (dom_init & dom_cfg routines)
21	USE istate ! initial state setting (istate_init routine)
22	USE phycst ! physical constant (par_cst routine)
23	USE step ! NEMO time-stepping (stp routine)
24	USE cpl_oasis3 ! OASIS3 coupling
25	USE diaobs ! Observation diagnostics (dia_obs_init routine)
26	#if defined key_nemocice_decomp
27	USE ice_domain_size, only: nx_global, ny_global
28	#endif
29	! ! Stand Alone Observation operator modules
30	USE sao_data
31	USE sao_intp
32	!
33	USE lib_mpp ! distributed memory computing
34	USE mppini ! shared/distributed memory setting (mpp_init routine)
35	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
36	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
37	#if defined key_iomput
38	USE xios ! xIOserver
39	#endif
40
41	IMPLICIT NONE
42	PRIVATE
43
44	PUBLIC nemo_gcm ! called by model.F90
45	PUBLIC nemo_init ! needed by AGRIF
46	PUBLIC nemo_alloc ! needed by TAM
47
48	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
49
50	!!----------------------------------------------------------------------
51	!! NEMO/OPA 4.0 , NEMO Consortium (2016)
52	!! $Id$
53	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
54	!!----------------------------------------------------------------------
55	CONTAINS
56
57	SUBROUTINE nemo_gcm
58	!!----------------------------------------------------------------------
59	!! * SUBROUTINE offline_obs_oper *
60	!!
61	!! ** Purpose : To use NEMO components to interpolate model fields
62	!! to observation space.
63	!!
64	!! ** Method : 1. Initialise NEMO
65	!! 2. Initialise offline obs_oper
66	!! 3. Cycle through match ups
67	!! 4. Write results to file
68	!!----------------------------------------------------------------------
69	!
70	CALL nemo_init ! Initialise NEMO
71	!
72	CALL sao_data_init ! Initialise Stand Alone Observation operator data
73	!
74	CALL dia_obs_init ! Initialise obs_operator
75	!
76	CALL sao_interp ! Interpolate to observation space
77	!
78	CALL dia_obs_wri ! Pipe to output files
79	!
80	CALL dia_obs_dealloc ! Reset the obs_oper between
81	!
82	IF(lk_mpp) CALL mppstop ! Safely stop MPI (end mpp communications)
83	!
84	END SUBROUTINE nemo_gcm
85
86
87	SUBROUTINE nemo_init
88	!!----------------------------------------------------------------------
89	!! * ROUTINE nemo_init *
90	!!
91	!! ** Purpose : initialization of the NEMO GCM
92	!!----------------------------------------------------------------------
93	INTEGER :: ji ! dummy loop indices
94	INTEGER :: ios, ilocal_comm ! local integer
95	INTEGER :: iiarea, ijarea ! local integers
96	INTEGER :: iirest, ijrest ! local integers
97	CHARACTER(len=120), DIMENSION(30) :: cltxt, cltxt2, clnam
98	!
99	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
100	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
101	& ln_timing, ln_diacfl
102	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
103	!!----------------------------------------------------------------------
104	!
105	cltxt = ''
106	cltxt2 = ''
107	clnam = ''
108	cxios_context = 'nemo'
109	!
110	! ! Open reference namelist and configuration namelist files
111	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
112	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
113	!
114	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints
115	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
116	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
117	!
118	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
119	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
120	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
121	!
122	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints
123	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
124	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
125
126	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
127	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
128	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
129
130	! !--------------------------!
131	! ! Set global domain size ! (control print return in cltxt2)
132	! !--------------------------!
133	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
134	CALL domain_cfg ( cltxt2, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
135	!
136	ELSE ! user-defined namelist
137	CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
138	ENDIF
139	!
140	jpk = jpkglo
141	!
142	#if defined key_agrif
143	IF( .NOT. Agrif_Root() ) THEN ! AGRIF children: specific setting (cf. agrif_user.F90)
144	jpiglo = nbcellsx + 2 + 2*nbghostcells
145	jpjglo = nbcellsy + 2 + 2*nbghostcells
146	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
147	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
148	nperio = 0
149	jperio = 0
150	ln_use_jattr = .false.
151	ENDIF
152	#endif
153	!
154	! !--------------------------------------------!
155	! ! set communicator & select the local node !
156	! ! NB: mynode also opens output.namelist.dyn !
157	! ! on unit number numond on first proc !
158	! !--------------------------------------------!
159	#if defined key_iomput
160	IF( Agrif_Root() ) THEN
161	IF( lk_oasis ) THEN
162	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
163	CALL xios_initialize( "not used",local_comm=ilocal_comm ) ! send nemo communicator to xios
164	ELSE
165	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
166	ENDIF
167	ENDIF
168	! Nodes selection (control print return in cltxt)
169	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
170	#else
171	IF( lk_oasis ) THEN
172	IF( Agrif_Root() ) THEN
173	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
174	ENDIF
175	! Nodes selection (control print return in cltxt)
176	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
177	ELSE
178	ilocal_comm = 0
179	! Nodes selection (control print return in cltxt)
180	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
181	ENDIF
182	#endif
183
184	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
185
186	lwm = (narea == 1) ! control of output namelists
187	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
188
189	IF(lwm) THEN
190	! write merged namelists from earlier to output namelist now that the
191	! file has been opened in call to mynode. nammpp has already been
192	! written in mynode (if lk_mpp_mpi)
193	WRITE( numond, namctl )
194	WRITE( numond, namcfg )
195	IF( .NOT.ln_read_cfg ) THEN
196	DO ji = 1, SIZE(clnam)
197	IF( TRIM(clnam(ji)) /= '' ) WRITE(numond, * ) clnam(ji) ! namusr_def print
198	END DO
199	ENDIF
200	ENDIF
201
202	! If dimensions of processor grid weren't specified in the namelist file
203	! then we calculate them here now that we have our communicator size
204	IF( jpni < 1 .OR. jpnj < 1 ) THEN
205	#if defined key_mpp_mpi
206	IF( Agrif_Root() ) CALL nemo_partition( mppsize )
207	#else
208	jpni = 1
209	jpnj = 1
210	jpnij = jpni*jpnj
211	#endif
212	ENDIF
213	!
214	#if defined key_agrif
215	IF( .NOT. Agrif_Root() ) THEN ! AGRIF children: specific setting (cf. agrif_user.F90)
216	jpiglo = nbcellsx + 2 + 2*nbghostcells
217	jpjglo = nbcellsy + 2 + 2*nbghostcells
218	jpi = ( jpiglo-2nn_hls + (jpni-1+0) ) / jpni + 2nn_hls
219	jpj = ( jpjglo-2nn_hls + (jpnj-1+0) ) / jpnj + 2nn_hls
220	jpimax = jpi
221	jpjmax = jpj
222	nperio = 0
223	jperio = 0
224	ln_use_jattr = .false.
225	ENDIF
226	#endif
227
228	IF( Agrif_Root() ) THEN ! AGRIF mother: specific setting from jpni and jpnj
229	iiarea = 1 + MOD( narea - 1 , jpni )
230	ijarea = 1 + ( narea - 1 ) / jpni
231	iirest = 1 + MOD( jpiglo - 2*nn_hls - 1 , jpni )
232	ijrest = 1 + MOD( jpjglo - 2*nn_hls - 1 , jpnj )
233	#if defined key_nemocice_decomp
234	jpi = ( nx_global+2-2nn_hls + (jpni-1) ) / jpni + 2nn_hls ! first dim.
235	jpj = ( ny_global+2-2nn_hls + (jpnj-1) ) / jpnj + 2nn_hls ! second dim.
236	jpimax = jpi
237	jpjmax = jpj
238	IF( iiarea == jpni ) jpi = jpiglo - (jpni - 1) * (jpi - 2*nn_hls)
239	IF( ijarea == jpnj ) jpj = jpjglo - (jpnj - 1) * (jpj - 2*nn_hls)
240	#else
241	jpi = ( jpiglo -2nn_hls + (jpni-1) ) / jpni + 2nn_hls ! first dim.
242	jpj = ( jpjglo -2nn_hls + (jpnj-1) ) / jpnj + 2nn_hls ! second dim.
243	jpimax = jpi
244	jpjmax = jpj
245	IF( iiarea > iirest ) jpi = jpi - 1
246	IF( ijarea > ijrest ) jpj = jpj - 1
247	#endif
248	ENDIF
249
250	jpk = jpkglo ! third dim
251
252	#if defined key_agrif
253	! simple trick to use same vertical grid as parent but different number of levels:
254	! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
255	! Suppress once vertical online interpolation is ok
256	IF(.NOT.Agrif_Root()) jpkglo = Agrif_Parent( jpkglo )
257	#endif
258	jpim1 = jpi-1 ! inner domain indices
259	jpjm1 = jpj-1 ! " "
260	jpkm1 = MAX( 1, jpk-1 ) ! " "
261	jpij = jpi*jpj ! jpi x j
262
263	IF(lwp) THEN ! open listing units
264	!
265	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
266	!
267	WRITE(numout,*)
268	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
269	WRITE(numout,*) ' NEMO team'
270	WRITE(numout,*) ' Stand Alone Observation operator'
271	WRITE(numout,*) ' NEMO version 3.7 (2015) '
272	WRITE(numout,*)
273	WRITE(numout,*)
274	DO ji = 1, SIZE(cltxt)
275	IF( TRIM(cltxt (ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
276	END DO
277	WRITE(numout,*)
278	WRITE(numout,*)
279	DO ji = 1, SIZE(cltxt2)
280	IF( TRIM(cltxt2(ji)) /= '' ) WRITE(numout,*) cltxt2(ji) ! control print of domain size
281	END DO
282	!
283	WRITE(numout,cform_aaa) ! Flag AAAAAAA
284	!
285	ENDIF
286
287	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
288	CALL nemo_alloc()
289
290	! !-------------------------------!
291	! ! NEMO general initialization !
292	! !-------------------------------!
293
294	CALL nemo_ctl ! Control prints & Benchmark
295
296	! ! Domain decomposition
297	CALL mpp_init
298	!
299	IF( ln_timing ) CALL timing_init ! timing by routine
300	!
301	! ! General initialization
302	CALL phy_cst ! Physical constants
303	CALL eos_init ! Equation of state
304	CALL dom_init ! Domain
305
306	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
307
308	IF( ln_ctl ) CALL prt_ctl_init ! Print control
309
310	CALL istate_init ! ocean initial state (Dynamics and tracers)
311	END SUBROUTINE nemo_init
312
313
314	SUBROUTINE nemo_ctl
315	!!----------------------------------------------------------------------
316	!! * ROUTINE nemo_ctl *
317	!!
318	!! ** Purpose : control print setting
319	!!
320	!! ** Method : - print namctl information and check some consistencies
321	!!----------------------------------------------------------------------
322	!
323	IF(lwp) THEN ! control print
324	WRITE(numout,*)
325	WRITE(numout,*) 'nemo_ctl: Control prints'
326	WRITE(numout,*) '~~~~~~~ '
327	WRITE(numout,*) ' Namelist namctl'
328	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
329	WRITE(numout,*) ' level of print nn_print = ', nn_print
330	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
331	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
332	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
333	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
334	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
335	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
336	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
337	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
338	ENDIF
339	!
340	nprint = nn_print ! convert DOCTOR namelist names into OLD names
341	nictls = nn_ictls
342	nictle = nn_ictle
343	njctls = nn_jctls
344	njctle = nn_jctle
345	isplt = nn_isplt
346	jsplt = nn_jsplt
347
348	IF(lwp) THEN ! control print
349	WRITE(numout,*)
350	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
351	WRITE(numout,*) '~~~~~~~ '
352	WRITE(numout,*) ' Namelist namcfg'
353	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
354	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
355	WRITE(numout,*) ' write configuration definition file ln_write_cfg = ', ln_write_cfg
356	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
357	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
358	ENDIF
359	! ! Parameter control
360	!
361	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
362	IF( lk_mpp .AND. jpnij > 1 ) THEN
363	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
364	ELSE
365	IF( isplt == 1 .AND. jsplt == 1 ) THEN
366	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
367	& ' - the print control will be done over the whole domain' )
368	ENDIF
369	ijsplt = isplt * jsplt ! total number of processors ijsplt
370	ENDIF
371	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
372	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
373	!
374	! ! indices used for the SUM control
375	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
376	lsp_area = .FALSE.
377	ELSE ! print control done over a specific area
378	lsp_area = .TRUE.
379	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
380	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
381	nictls = 1
382	ENDIF
383	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
384	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
385	nictle = jpiglo
386	ENDIF
387	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
388	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
389	njctls = 1
390	ENDIF
391	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
392	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
393	njctle = jpjglo
394	ENDIF
395	ENDIF
396	ENDIF
397	!
398	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
399	& 'f2003 standard. ' , &
400	& 'Compile with key_nosignedzero enabled' )
401	!
402	END SUBROUTINE nemo_ctl
403
404
405	SUBROUTINE nemo_closefile
406	!!----------------------------------------------------------------------
407	!! * ROUTINE nemo_closefile *
408	!!
409	!! ** Purpose : Close the files
410	!!----------------------------------------------------------------------
411	!
412	IF( lk_mpp ) CALL mppsync
413	!
414	CALL iom_close ! close all input/output files managed by iom_*
415	!
416	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
417	IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file
418	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
419	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
420	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
421	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
422	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
423	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
424	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
425	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
426	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
427	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
428	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
429	!
430	numout = 6 ! redefine numout in case it is used after this point...
431	!
432	END SUBROUTINE nemo_closefile
433
434
435	SUBROUTINE nemo_alloc
436	!!----------------------------------------------------------------------
437	!! * ROUTINE nemo_alloc *
438	!!
439	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
440	!!
441	!! ** Method :
442	!!----------------------------------------------------------------------
443	USE diawri , ONLY: dia_wri_alloc
444	USE dom_oce , ONLY: dom_oce_alloc
445	!
446	INTEGER :: ierr
447	!!----------------------------------------------------------------------
448	!
449	ierr = oce_alloc () ! ocean
450	ierr = ierr + dia_wri_alloc ()
451	ierr = ierr + dom_oce_alloc () ! ocean domain
452	!
453	IF( lk_mpp ) CALL mpp_sum( ierr )
454	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
455	!
456	END SUBROUTINE nemo_alloc
457
458
459	SUBROUTINE nemo_partition( num_pes )
460	!!----------------------------------------------------------------------
461	!! * ROUTINE nemo_partition *
462	!!
463	!! ** Purpose :
464	!!
465	!! ** Method :
466	!!----------------------------------------------------------------------
467	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
468	!
469	INTEGER, PARAMETER :: nfactmax = 20
470	INTEGER :: nfact ! The no. of factors returned
471	INTEGER :: ierr ! Error flag
472	INTEGER :: ji
473	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
474	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
475	!!----------------------------------------------------------------------
476	!
477	ierr = 0
478	!
479	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
480	!
481	IF( nfact <= 1 ) THEN
482	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
483	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
484	jpnj = 1
485	jpni = num_pes
486	ELSE
487	! Search through factors for the pair that are closest in value
488	mindiff = 1000000
489	imin = 1
490	DO ji = 1, nfact-1, 2
491	idiff = ABS( ifact(ji) - ifact(ji+1) )
492	IF( idiff < mindiff ) THEN
493	mindiff = idiff
494	imin = ji
495	ENDIF
496	END DO
497	jpnj = ifact(imin)
498	jpni = ifact(imin + 1)
499	ENDIF
500	!
501	jpnij = jpni*jpnj
502	!
503	END SUBROUTINE nemo_partition
504
505
506	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
507	!!----------------------------------------------------------------------
508	!! * ROUTINE factorise *
509	!!
510	!! ** Purpose : return the prime factors of n.
511	!! knfax factors are returned in array kfax which is of
512	!! maximum dimension kmaxfax.
513	!! ** Method :
514	!!----------------------------------------------------------------------
515	INTEGER , INTENT(in ) :: kn, kmaxfax
516	INTEGER , INTENT( out) :: kerr, knfax
517	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
518	!
519	INTEGER :: ifac, jl, inu
520	INTEGER, PARAMETER :: ntest = 14
521	INTEGER, DIMENSION(ntest) :: ilfax
522	!!----------------------------------------------------------------------
523	!
524	! lfax contains the set of allowed factors.
525	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
526	!
527	! Clear the error flag and initialise output vars
528	kerr = 0
529	kfax = 1
530	knfax = 0
531	!
532	! Find the factors of n.
533	IF( kn .NE. 1 ) THEN
534
535	! nu holds the unfactorised part of the number.
536	! knfax holds the number of factors found.
537	! l points to the allowed factor list.
538	! ifac holds the current factor.
539	!
540	inu = kn
541	knfax = 0
542	!
543	DO jl = ntest, 1, -1
544	!
545	ifac = ilfax(jl)
546	IF( ifac > inu ) CYCLE
547
548	! Test whether the factor will divide.
549
550	IF( MOD(inu,ifac) == 0 ) THEN
551	!
552	knfax = knfax + 1 ! Add the factor to the list
553	IF( knfax > kmaxfax ) THEN
554	kerr = 6
555	write (,) 'FACTOR: insufficient space in factor array ', knfax
556	return
557	ENDIF
558	kfax(knfax) = ifac
559	! Store the other factor that goes with this one
560	knfax = knfax + 1
561	kfax(knfax) = inu / ifac
562	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
563	ENDIF
564	!
565	END DO
566	!
567	ENDIF
568	!
569	END SUBROUTINE factorise
570
571	#if defined key_mpp_mpi
572
573	SUBROUTINE nemo_northcomms
574	!!----------------------------------------------------------------------
575	!! * ROUTINE nemo_northcomms *
576	!! ** Purpose : Setup for north fold exchanges with explicit
577	!! point-to-point messaging
578	!!
579	!! ** Method : Initialization of the northern neighbours lists.
580	!!----------------------------------------------------------------------
581	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
582	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
583	!!----------------------------------------------------------------------
584	INTEGER :: sxM, dxM, sxT, dxT, jn
585	INTEGER :: njmppmax
586	!!----------------------------------------------------------------------
587	!
588	njmppmax = MAXVAL( njmppt )
589	!
590	!initializes the north-fold communication variables
591	isendto(:) = 0
592	nsndto = 0
593	!
594	!if I am a process in the north
595	IF ( njmpp == njmppmax ) THEN
596	!sxM is the first point (in the global domain) needed to compute the
597	!north-fold for the current process
598	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
599	!dxM is the last point (in the global domain) needed to compute the
600	!north-fold for the current process
601	dxM = jpiglo - nimppt(narea) + 2
602
603	!loop over the other north-fold processes to find the processes
604	!managing the points belonging to the sxT-dxT range
605
606	DO jn = 1, jpni
607	!sxT is the first point (in the global domain) of the jn
608	!process
609	sxT = nfiimpp(jn, jpnj)
610	!dxT is the last point (in the global domain) of the jn
611	!process
612	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
613	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
614	nsndto = nsndto + 1
615	isendto(nsndto) = jn
616	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
617	nsndto = nsndto + 1
618	isendto(nsndto) = jn
619	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
620	nsndto = nsndto + 1
621	isendto(nsndto) = jn
622	ENDIF
623	END DO
624	nfsloop = 1
625	nfeloop = nlci
626	DO jn = 2,jpni-1
627	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
628	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
629	nfsloop = nldi
630	ENDIF
631	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
632	nfeloop = nlei
633	ENDIF
634	ENDIF
635	END DO
636
637	ENDIF
638	l_north_nogather = .TRUE.
639	END SUBROUTINE nemo_northcomms
640
641	#else
642	SUBROUTINE nemo_northcomms ! Dummy routine
643	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
644	END SUBROUTINE nemo_northcomms
645	#endif
646
647	!!======================================================================
648	END MODULE nemogcm
649

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/2017/dev_CNRS_2017/NEMOGCM/NEMO/SAO_SRC/nemogcm.F90 @ 9012

Download in other formats: