New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
usrdef_sbc.F90 in branches/2017/dev_merge_2017/NEMOGCM/CONFIG/TEST_CASES/SAS_BIPER/MY_SRC – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/CONFIG/TEST_CASES/SAS_BIPER/MY_SRC/usrdef_sbc.F90 @ 9019

Last change on this file since 9019 was 9019, checked in by timgraham, 6 years ago

Merge of dev_CNRS_2017 into branch
File size: 7.3 KB
Line 
1MODULE usrdef_sbc
2   !!======================================================================
3   !!                       ***  MODULE  usrdef_sbc  ***
4   !!
5   !!                     ===  SAS_BIPER configuration  ===
6   !!
7   !! User defined :   surface forcing of a user configuration
8   !!======================================================================
9   !! History :  4.0   ! 2016-03  (S. Flavoni, G. Madec)  user defined interface
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   usr_def_sbc    : user defined surface bounday conditions in SAS_BIPER case
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE sbc_oce         ! Surface boundary condition: ocean fields
18   USE sbc_ice         ! Surface boundary condition: ice fields
19   USE phycst          ! physical constants
20   USE ice, ONLY       : at_i_b, a_i_b
21   USE icethd_dh       ! for CALL ice_thd_snwblow
22   !
23   USE in_out_manager  ! I/O manager
24   USE lib_mpp         ! distribued memory computing library
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   usrdef_sbc_oce      ! routine called by sbcmod.F90 for sbc ocean
32   PUBLIC   usrdef_sbc_ice_tau  ! routine called by sbcice_lim.F90 for ice dynamics
33   PUBLIC   usrdef_sbc_ice_flx  ! routine called by sbcice_lim.F90 for ice thermo
34
35   !! * Substitutions
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 4.0 , NEMO Consortium (2016)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE usrdef_sbc_oce( kt )
45      !!---------------------------------------------------------------------
46      !!                    ***  ROUTINE usr_def_sbc  ***
47      !!             
48      !! ** Purpose :   provide at each time-step the surface boundary
49      !!              condition, i.e. the momentum, heat and freshwater fluxes.
50      !!
51      !! ** Method  :   all 0 fields, for SAS_BIPER case
52      !!                CAUTION : never mask the surface stress field !
53      !!
54      !! ** Action  : - set to ZERO all the ocean surface boundary condition, i.e.   
55      !!                   utau, vtau, taum, wndm, qns, qsr, emp, sfx
56      !!
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt   ! ocean time step
59      !!---------------------------------------------------------------------
60      !
61      IF( kt == nit000 ) THEN
62         !
63         IF(lwp)   WRITE(numout,*)' usrdef_sbc_oce : SAS_BIPER case: NO surface forcing'
64         ! --- oce variables --- !
65         utau(:,:) = 0._wp
66         vtau(:,:) = 0._wp
67         taum(:,:) = 0._wp
68         wndm(:,:) = 0._wp
69         !
70         emp (:,:) = 0._wp
71         sfx (:,:) = 0._wp
72         qns (:,:) = 0._wp
73         qsr (:,:) = 0._wp
74         !
75      ENDIF
76      !
77   END SUBROUTINE usrdef_sbc_oce
78
79   SUBROUTINE usrdef_sbc_ice_tau( kt )
80      !!---------------------------------------------------------------------
81      !!                     ***  ROUTINE usrdef_sbc_ice_tau  ***
82      !!
83      !! ** Purpose :   provide the surface boundary (momentum) condition over sea-ice
84      !!---------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time step
86      !!---------------------------------------------------------------------
87      IF( kt==nit000 .AND. lwp)   WRITE(numout,*)' usrdef_sbc_ice : SAS_BIPER case: constant stress forcing'
88      !
89      utau_ice(:,:) = 1.3_wp   ! <=> 0.5 m/s
90      vtau_ice(:,:) = 0._wp
91      !
92   END SUBROUTINE usrdef_sbc_ice_tau
93
94   SUBROUTINE usrdef_sbc_ice_flx( kt, phs, phi )
95      !!---------------------------------------------------------------------
96      !!                     ***  ROUTINE usrdef_sbc_ice_flx  ***
97      !!
98      !! ** Purpose :   provide the surface boundary (flux) condition over sea-ice
99      !!---------------------------------------------------------------------
100      INTEGER, INTENT(in) ::   kt   ! ocean time step
101      REAL(wp), DIMENSION(:,:,:), INTENT(in)  ::   phs    ! snow thickness
102      REAL(wp), DIMENSION(:,:,:), INTENT(in)  ::   phi    ! ice thickness
103      !!
104      REAL(wp) ::   zfr1, zfr2                 ! local variables
105      REAL(wp), DIMENSION(jpi,jpj) ::   zsnw   ! snw distribution after wind blowing
106      !!---------------------------------------------------------------------
107      !
108      IF( kt==nit000 .AND. lwp)   WRITE(numout,*)' usrdef_sbc_ice : SAS_BIPER case: NO flux forcing'
109      !
110      ! ocean variables (renaming)
111      emp_oce (:,:)   = 0._wp   ! uniform value for freshwater budget (E-P)
112      qsr_oce (:,:)   = 0._wp   ! uniform value for     solar radiation
113      qns_oce (:,:)   = 0._wp   ! uniform value for non-solar radiation
114
115      ! ice variables
116      alb_ice (:,:,:) = 0.7_wp  ! useless
117      qsr_ice (:,:,:) = 0._wp   ! uniform value for     solar radiation
118      qns_ice (:,:,:) = 0._wp   ! uniform value for non-solar radiation
119      sprecip (:,:)   = 0._wp   ! uniform value for snow precip
120      evap_ice(:,:,:) = 0._wp   ! uniform value for sublimation
121
122      ! ice fields deduced from above
123      zsnw(:,:) = 1._wp
124      !!CALL lim_thd_snwblow( at_i_b, zsnw )  ! snow distribution over ice after wind blowing
125      emp_ice  (:,:)   = SUM( a_i_b(:,:,:) * evap_ice(:,:,:), dim=3 ) - sprecip(:,:) * zsnw(:,:)
126      emp_oce  (:,:)   = emp_oce(:,:) - sprecip(:,:) * (1._wp - zsnw(:,:) )
127      qevap_ice(:,:,:) =   0._wp
128      qprec_ice(:,:)   =   rhosn * ( sst_m(:,:) * cpic - lfus ) * tmask(:,:,1) !  in J/m3
129      qemp_oce (:,:)   = - emp_oce(:,:) * sst_m(:,:) * rcp
130      qemp_ice (:,:)   =   sprecip(:,:) * zsnw * ( sst_m(:,:) * cpic - lfus ) * tmask(:,:,1) ! solid precip (only)
131
132      ! total fluxes
133      emp_tot (:,:) = emp_ice  + emp_oce
134      qns_tot (:,:) = at_i_b(:,:) * qns_oce(:,:) + SUM( a_i_b(:,:,:) * qns_ice(:,:,:), dim=3 ) + qemp_ice(:,:) + qemp_oce(:,:)
135      qsr_tot (:,:) = at_i_b(:,:) * qsr_oce(:,:) + SUM( a_i_b(:,:,:) * qsr_ice(:,:,:), dim=3 )
136
137      ! --- shortwave radiation transmitted below the surface (W/m2, see Grenfell Maykut 77) --- !
138      zfr1 = ( 0.18 * ( 1.0 - cldf_ice ) + 0.35 * cldf_ice )            ! transmission when hi>10cm
139      zfr2 = ( 0.82 * ( 1.0 - cldf_ice ) + 0.65 * cldf_ice )            ! zfr2 such that zfr1 + zfr2 to equal 1
140      !
141      WHERE    ( phs(:,:,:) <= 0._wp .AND. phi(:,:,:) <  0.1_wp )       ! linear decrease from hi=0 to 10cm 
142         qsr_ice_tr(:,:,:) = qsr_ice(:,:,:) * ( zfr1 + zfr2 * ( 1._wp - phi(:,:,:) * 10._wp ) )
143      ELSEWHERE( phs(:,:,:) <= 0._wp .AND. phi(:,:,:) >= 0.1_wp )       ! constant (zfr1) when hi>10cm
144         qsr_ice_tr(:,:,:) = qsr_ice(:,:,:) * zfr1
145      ELSEWHERE                                                         ! zero when hs>0
146         qsr_ice_tr(:,:,:) = 0._wp 
147      END WHERE
148         
149   END SUBROUTINE usrdef_sbc_ice_flx
150
151
152   !!======================================================================
153END MODULE usrdef_sbc
Note: See TracBrowser for help on using the repository browser.