New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icerst.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/LIM_SRC_3/icerst.F90 @ 9019

Last change on this file since 9019 was 9019, checked in by timgraham, 6 years ago

Merge of dev_CNRS_2017 into branch
File size: 11.3 KB
Line 
1MODULE icerst
2   !!======================================================================
3   !!                     ***  MODULE  icerst  ***
4   !!   sea-ice :  write/read the ice restart file
5   !!======================================================================
6   !! History:   3.0  ! 2005-04 (M. Vancoppenolle) Original code
7   !!             -   ! 2008-03 (C. Ethe) restart files in using IOM interface
8   !!            3.4  ! 2011-02 (G. Madec) dynamical allocation
9   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write 3D ice fields
10   !!----------------------------------------------------------------------
11#if defined key_lim3
12   !!----------------------------------------------------------------------
13   !!   'key_lim3'                                       ESIM sea-ice model
14   !!----------------------------------------------------------------------
15   !!   ice_rst_opn   : open  restart file
16   !!   ice_rst_write : write restart file
17   !!   ice_rst_read  : read  restart file
18   !!----------------------------------------------------------------------
19   USE ice            ! sea-ice variables
20   USE dom_oce        ! ocean domain
21   USE sbc_oce , ONLY : nn_fsbc, ln_cpl
22   USE icectl
23   !
24   USE in_out_manager ! I/O manager
25   USE iom            ! I/O manager library
26   USE lib_mpp        ! MPP library
27   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   ice_rst_opn     ! called by icestp
33   PUBLIC   ice_rst_write   ! called by icestp
34   PUBLIC   ice_rst_read    ! called by ice_init
35
36   !!----------------------------------------------------------------------
37   !! NEMO/ICE 4.0 , NEMO Consortium (2017)
38   !! $Id: icerst.F90 8411 2017-08-07 16:09:12Z clem $
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE ice_rst_opn( kt )
44      !!----------------------------------------------------------------------
45      !!                    ***  ice_rst_opn  ***
46      !!
47      !! ** purpose  :   open restart file
48      !!----------------------------------------------------------------------
49      INTEGER, INTENT(in) ::   kt       ! number of iteration
50      !
51      CHARACTER(len=20)   ::   clkt     ! ocean time-step define as a character
52      CHARACTER(len=50)   ::   clname   ! ice output restart file name
53      CHARACTER(len=256)  ::   clpath   ! full path to ice output restart file
54      !!----------------------------------------------------------------------
55      !
56      IF( kt == nit000 )   lrst_ice = .FALSE.   ! default definition
57
58      ! in order to get better performances with NetCDF format, we open and define the ice restart file
59      ! one ice time step before writing the data (-> at nitrst - 2*nn_fsbc + 1), except if we write ice
60      ! restart files every ice time step or if an ice restart file was writen at nitend - 2*nn_fsbc + 1
61      IF( kt == nitrst - 2*nn_fsbc + 1 .OR. nstock == nn_fsbc    &
62         &                             .OR. ( kt == nitend - nn_fsbc + 1 .AND. .NOT. lrst_ice ) ) THEN
63         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
64            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
65            IF( nitrst > 99999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
66            ELSE                           ;   WRITE(clkt, '(i8.8)') nitrst
67            ENDIF
68            ! create the file
69            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_icerst_out)
70            clpath = TRIM(cn_icerst_outdir) 
71            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath)//'/'
72            IF(lwp) THEN
73               WRITE(numout,*)
74               SELECT CASE ( jprstlib )
75               CASE DEFAULT
76                  WRITE(numout,*) '             open ice restart NetCDF file: ',TRIM(clpath)//clname
77               END SELECT
78               IF( kt == nitrst - 2*nn_fsbc + 1 ) THEN
79                  WRITE(numout,*) '             kt = nitrst - 2*nn_fsbc + 1 = ', kt,' date= ', ndastp
80               ELSE
81                  WRITE(numout,*) '             kt = '                         , kt,' date= ', ndastp
82               ENDIF
83            ENDIF
84            !
85            CALL iom_open( TRIM(clpath)//TRIM(clname), numriw, ldwrt = .TRUE., kiolib = jprstlib, kdlev = jpl )
86            lrst_ice = .TRUE.
87         ENDIF
88      ENDIF
89      !
90      IF( ln_icectl )   CALL ice_prt( kt, iiceprt, jiceprt, 1, ' - Beginning the time step - ' )   ! control print
91      !
92   END SUBROUTINE ice_rst_opn
93
94
95   SUBROUTINE ice_rst_write( kt )
96      !!----------------------------------------------------------------------
97      !!                    ***  ice_rst_write  ***
98      !!
99      !! ** purpose  :   write restart file
100      !!----------------------------------------------------------------------
101      INTEGER, INTENT(in) ::   kt     ! number of iteration
102      !!
103      INTEGER ::   jk ,jl   ! dummy loop indices
104      INTEGER ::   iter
105      CHARACTER(len=25) ::   znam
106      CHARACTER(len=2)  ::   zchar, zchar1
107      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
108      !!----------------------------------------------------------------------
109
110      iter = kt + nn_fsbc - 1   ! ice restarts are written at kt == nitrst - nn_fsbc + 1
111
112      IF( iter == nitrst ) THEN
113         IF(lwp) WRITE(numout,*)
114         IF(lwp) WRITE(numout,*) 'ice_rst_write : write ice restart file  kt =', kt
115         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~'         
116      ENDIF
117
118      ! Write in numriw (if iter == nitrst)
119      ! ------------------
120      !                                                                        ! calendar control
121      CALL iom_rstput( iter, nitrst, numriw, 'nn_fsbc', REAL( nn_fsbc, wp ) )      ! time-step
122      CALL iom_rstput( iter, nitrst, numriw, 'kt_ice' , REAL( iter   , wp ) )      ! date
123
124      ! Prognostic variables
125      CALL iom_rstput( iter, nitrst, numriw, 'v_i' , v_i  )
126      CALL iom_rstput( iter, nitrst, numriw, 'v_s' , v_s  )
127      CALL iom_rstput( iter, nitrst, numriw, 'sv_i', sv_i )
128      CALL iom_rstput( iter, nitrst, numriw, 'oa_i', oa_i )
129      CALL iom_rstput( iter, nitrst, numriw, 'a_i' , a_i  )
130      CALL iom_rstput( iter, nitrst, numriw, 't_su', t_su )
131      ! Melt ponds
132      CALL iom_rstput( iter, nitrst, numriw, 'a_ip', a_ip )
133      CALL iom_rstput( iter, nitrst, numriw, 'v_ip', v_ip )
134!!gm dangerous !!!!!  ===>>>> better reading writing all snow layers !
135      ! Snow enthalpy (1st snow layer only)
136      z3d = e_s(:,:,1,:)
137      CALL iom_rstput( iter, nitrst, numriw, 'tempt_sl1' , z3d )
138      ! Ice enthalpy (all ice layers)
139      DO jk = 1, nlay_i 
140         WRITE(zchar1,'(I2.2)') jk
141         znam = 'tempt'//'_il'//zchar1
142         z3d(:,:,:) = e_i(:,:,jk,:)
143         CALL iom_rstput( iter, nitrst, numriw, znam , z3d )
144      END DO
145      ! ice velocity
146      CALL iom_rstput( iter, nitrst, numriw, 'u_ice', u_ice ) ! u_ice
147      CALL iom_rstput( iter, nitrst, numriw, 'v_ice', v_ice ) ! v_ice
148      ! fields needed for Met Office (Jules) coupling
149      IF( ln_cpl ) THEN
150         CALL iom_rstput( iter, nitrst, numriw, 'cnd_ice', cnd_ice )
151         CALL iom_rstput( iter, nitrst, numriw, 't1_ice' , t1_ice  )
152      ENDIF
153      !
154
155      ! close restart file
156      ! ------------------
157      IF( iter == nitrst ) THEN
158         CALL iom_close( numriw )
159         lrst_ice = .FALSE.
160      ENDIF
161      !
162   END SUBROUTINE ice_rst_write
163
164
165   SUBROUTINE ice_rst_read
166      !!----------------------------------------------------------------------
167      !!                    ***  ice_rst_read  ***
168      !!
169      !! ** purpose  :   read restart file
170      !!----------------------------------------------------------------------
171      INTEGER           ::   jk, jl
172      LOGICAL           ::   llok
173      INTEGER           ::   id1            ! local integer
174      INTEGER           ::   jlibalt = jprstlib
175      CHARACTER(len=25) ::   znam
176      CHARACTER(len=2)  ::   zchar, zchar1
177      REAL(wp)          ::   zfice, ziter
178      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
179      !!----------------------------------------------------------------------
180
181      IF(lwp) THEN
182         WRITE(numout,*)
183         WRITE(numout,*) 'ice_rst_read: read ice NetCDF restart file'
184         WRITE(numout,*) '~~~~~~~~~~~~'
185      ENDIF
186
187      CALL iom_open ( TRIM(cn_icerst_indir)//'/'//cn_icerst_in, numrir, kiolib = jprstlib, kdlev = jpl )
188
189      CALL iom_get( numrir, 'nn_fsbc', zfice )
190      CALL iom_get( numrir, 'kt_ice' , ziter )   
191      IF(lwp) WRITE(numout,*) '   read ice restart file at time step    : ', ziter
192      IF(lwp) WRITE(numout,*) '   in any case we force it to nit000 - 1 : ', nit000 - 1
193
194      ! Control of date
195      IF( ( nit000 - NINT(ziter) ) /= 1 .AND. ABS( nrstdt ) == 1 )   &
196         &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nit000 in ice restart',  &
197         &                   '   verify the file or rerun with the value 0 for the',        &
198         &                   '   control of time parameter  nrstdt' )
199      IF( NINT(zfice) /= nn_fsbc          .AND. ABS( nrstdt ) == 1 )   &
200         &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nn_fsbc in ice restart',  &
201         &                   '   verify the file or rerun with the value 0 for the',         &
202         &                   '   control of time parameter  nrstdt' )
203
204      ! Prognostic variables
205      CALL iom_get( numrir, jpdom_autoglo, 'v_i' , v_i  )
206      CALL iom_get( numrir, jpdom_autoglo, 'v_s' , v_s  )
207      CALL iom_get( numrir, jpdom_autoglo, 'sv_i', sv_i )
208      CALL iom_get( numrir, jpdom_autoglo, 'oa_i', oa_i )
209      CALL iom_get( numrir, jpdom_autoglo, 'a_i' , a_i  )
210      CALL iom_get( numrir, jpdom_autoglo, 't_su', t_su )
211      ! Melt ponds
212      id1 = iom_varid( numrir, 'a_ip_htc01' , ldstop = .FALSE. )
213      IF( id1 > 0 ) THEN                       ! fields exist (melt ponds)
214         CALL iom_get( numrir, jpdom_autoglo, 'a_ip' , a_ip )
215         CALL iom_get( numrir, jpdom_autoglo, 'v_ip' , v_ip )
216      ELSE                                     ! start from rest
217         IF(lwp) WRITE(numout,*) '   ==>>   previous run without melt ponds output then set it to zero'
218         a_ip(:,:,:) = 0._wp
219         v_ip(:,:,:) = 0._wp
220      ENDIF
221!!gm dangerous !!!!!  ===>>>> better reading writing all snow layers !
222      ! Snow enthalpy (1st snow layer only)
223      CALL iom_get( numrir, jpdom_autoglo, 'tempt_sl1' , z3d )
224      e_s(:,:,1,:) = z3d
225      ! Ice enthalpy (all ice layers)
226      DO jk = 1, nlay_i 
227         WRITE(zchar1,'(I2.2)') jk
228         znam = 'tempt'//'_il'//zchar1
229         CALL iom_get( numrir, jpdom_autoglo, znam , z3d )
230         e_i(:,:,jk,:) = z3d(:,:,:)
231      END DO
232      ! ice velocity
233      CALL iom_get( numrir, jpdom_autoglo, 'u_ice', u_ice )
234      CALL iom_get( numrir, jpdom_autoglo, 'v_ice', v_ice )
235      ! fields needed for Met Office (Jules) coupling
236      IF( ln_cpl ) THEN
237         CALL iom_get( numrir, jpdom_autoglo, 'cnd_ice', cnd_ice )
238         CALL iom_get( numrir, jpdom_autoglo, 't1_ice' , t1_ice  )
239      ENDIF
240
241   END SUBROUTINE ice_rst_read
242
243#else
244   !!----------------------------------------------------------------------
245   !!   Default option :       Empty module           NO ESIM sea-ice model
246   !!----------------------------------------------------------------------
247#endif
248
249   !!======================================================================
250END MODULE icerst
Note: See TracBrowser for help on using the repository browser.