source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/NST_SRC/agrif_lim3_update.F90 @ 9160

Last change on this file since 9160 was 9160, checked in by clem, 3 years ago

make ice with agrif restartable. Reproducibility still needs to be checked out

File size: 9.9 KB
Line 
1#define TWO_WAY
2
3MODULE agrif_lim3_update
4   !!=====================================================================================
5   !!                       ***  MODULE agrif_lim3_update ***
6   !! Nesting module :  update surface ocean boundary condition over ice from a child grid
7   !! Sea-Ice model  :  LIM 3.6 Sea ice model time-stepping
8   !!=====================================================================================
9   !! History :  2.0   !  04-2008  (F. Dupont)  initial version
10   !!            3.4   !  08-2012  (R. Benshila, C. Herbaut) update and EVP
11   !!            3.6   !  05-2016  (C. Rousset)  Add LIM3 compatibility
12   !!----------------------------------------------------------------------
13#if defined key_agrif && defined key_lim3
14   !!----------------------------------------------------------------------
15   !!   'key_lim3'  :                                 LIM 3.6 sea-ice model
16   !!   'key_agrif' :                                 AGRIF library
17   !!----------------------------------------------------------------------
18   !!   agrif_update_lim3  : update sea-ice on boundaries or total
19   !!                        child domain for velocities and ice properties
20   !!   update_tra_ice     : sea-ice properties
21   !!   update_u_ice       : zonal      ice velocity
22   !!   update_v_ice       : meridional ice velocity
23   !!----------------------------------------------------------------------
24   USE dom_oce
25   USE sbc_oce
26   USE agrif_oce
27   USE ice
28   USE agrif_ice 
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   agrif_update_lim3   ! called by agrif_user.F90
34
35   !!----------------------------------------------------------------------
36   !! NEMO/NST 4.0 , LOCEAN-IPSL (2017)
37   !! $Id: agrif_lim3_update.F90 6204 2016-01-04 13:47:06Z cetlod $
38   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE agrif_update_lim3( kt )
43      !!----------------------------------------------------------------------
44      !!                     *** ROUTINE agrif_update_lim3 ***
45      !! ** Method  :   Call the hydrostaticupdate pressure at the boundary or the entire domain
46      !!
47      !! ** Action : - Update (u_ice,v_ice) and ice tracers
48      !!----------------------------------------------------------------------
49      INTEGER, INTENT(in) :: kt
50      !!----------------------------------------------------------------------
51      !
52      !! clem: I think the update should take place each time the ocean sees the surface forcings
53      !!       (but maybe I am wrong and we should update every rhot time steps)
54      IF( ( MOD( (kt-nit000)/nn_fsbc + 1, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) /=0 ) .AND. (kt /= 0) ) RETURN ! do not update if nb of child time steps differ from time refinement
55                                                                                                                           ! i.e. update only at the parent time step
56      IF( nn_ice == 0 ) RETURN   ! do not update if child domain does not have ice
57      !
58      Agrif_SpecialValueFineGrid    = -9999.
59      Agrif_UseSpecialValueInUpdate = .TRUE.
60# if defined TWO_WAY
61      CALL Agrif_Update_Variable( tra_ice_id , procname = update_tra_ice  )
62      CALL Agrif_Update_Variable( u_ice_id   , procname = update_u_ice    )
63      CALL Agrif_Update_Variable( v_ice_id   , procname = update_v_ice    )
64
65!      CALL Agrif_Update_Variable( tra_ice_id , locupdate=(/0,2/), procname = update_tra_ice  )
66!      CALL Agrif_Update_Variable( u_ice_id   , locupdate=(/0,1/), procname = update_u_ice    )
67!      CALL Agrif_Update_Variable( v_ice_id   , locupdate=(/0,1/), procname = update_v_ice    )
68# endif
69      Agrif_SpecialValueFineGrid    = 0.
70      Agrif_UseSpecialValueInUpdate = .FALSE.
71      !
72   END SUBROUTINE agrif_update_lim3
73
74
75   SUBROUTINE update_tra_ice( ptab, i1, i2, j1, j2, k1, k2, before )
76      !!-----------------------------------------------------------------------
77      !!                        *** ROUTINE update_tra_ice ***
78      !! ** Method  : Compute the mass properties on the fine grid and recover
79      !!              the properties per mass on the coarse grid
80      !!-----------------------------------------------------------------------
81      INTEGER                               , INTENT(in   ) ::   i1, i2, j1, j2, k1, k2
82      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2), INTENT(inout) ::   ptab
83      LOGICAL                               , INTENT(in   ) ::   before
84      !!
85      INTEGER  :: ji, jj, jk, jl, jm
86      !!-----------------------------------------------------------------------
87      ! it is ok not to multiply by e1*e2 since we conserve tracers here (same as in the ocean).
88      IF( before ) THEN
89         jm = 1
90         DO jl = 1, jpl
91            ptab(i1:i2,j1:j2,jm  ) = a_i (i1:i2,j1:j2,jl)
92            ptab(i1:i2,j1:j2,jm+1) = v_i (i1:i2,j1:j2,jl)
93            ptab(i1:i2,j1:j2,jm+2) = v_s (i1:i2,j1:j2,jl)
94            ptab(i1:i2,j1:j2,jm+3) = sv_i(i1:i2,j1:j2,jl)
95            ptab(i1:i2,j1:j2,jm+4) = oa_i (i1:i2,j1:j2,jl)
96            jm = jm + 5
97            DO jk = 1, nlay_s
98               ptab(i1:i2,j1:j2,jm) = e_s(i1:i2,j1:j2,jk,jl)   ;   jm = jm + 1
99            END DO
100            DO jk = 1, nlay_i
101               ptab(i1:i2,j1:j2,jm) = e_i(i1:i2,j1:j2,jk,jl)   ;   jm = jm + 1
102            END DO
103         END DO
104         !
105         DO jk = k1, k2
106            WHERE( tmask(i1:i2,j1:j2,1) == 0. )   ptab(i1:i2,j1:j2,jk) = Agrif_SpecialValueFineGrid 
107         END DO
108         !
109      ELSE
110         !
111         jm = 1
112         DO jl = 1, jpl
113            !
114            DO jj = j1, j2
115               DO ji = i1, i2
116                  IF( ptab(ji,jj,jm) /= Agrif_SpecialValueFineGrid ) THEN
117                     a_i (ji,jj,jl) = ptab(ji,jj,jm  ) * tmask(ji,jj,1)
118                     v_i (ji,jj,jl) = ptab(ji,jj,jm+1) * tmask(ji,jj,1)
119                     v_s (ji,jj,jl) = ptab(ji,jj,jm+2) * tmask(ji,jj,1)
120                     sv_i(ji,jj,jl) = ptab(ji,jj,jm+3) * tmask(ji,jj,1)
121                     oa_i(ji,jj,jl) = ptab(ji,jj,jm+4) * tmask(ji,jj,1)
122                  ENDIF
123               END DO
124            END DO
125            jm = jm + 5
126            !
127            DO jk = 1, nlay_s
128               WHERE( ptab(i1:i2,j1:j2,jm) /= Agrif_SpecialValueFineGrid )
129                  e_s(i1:i2,j1:j2,jk,jl) = ptab(i1:i2,j1:j2,jm) * tmask(i1:i2,j1:j2,1)
130               ENDWHERE
131               jm = jm + 1
132            END DO
133            !
134            DO jk = 1, nlay_i
135               WHERE( ptab(i1:i2,j1:j2,jm) /= Agrif_SpecialValueFineGrid )
136                  e_i(i1:i2,j1:j2,jk,jl) = ptab(i1:i2,j1:j2,jm) * tmask(i1:i2,j1:j2,1)
137               ENDWHERE
138               jm = jm + 1
139            END DO
140            !
141         END DO
142         !
143         ! integrated values
144         vt_i(i1:i2,j1:j2) = SUM(      v_i(i1:i2,j1:j2,:)           , dim=3 )
145         vt_s(i1:i2,j1:j2) = SUM(      v_s(i1:i2,j1:j2,:)           , dim=3 )
146         at_i(i1:i2,j1:j2) = SUM(      a_i(i1:i2,j1:j2,:)           , dim=3 )
147         et_s(i1:i2,j1:j2) = SUM( SUM( e_s(i1:i2,j1:j2,:,:), dim=4 ), dim=3 )
148         et_i(i1:i2,j1:j2) = SUM( SUM( e_i(i1:i2,j1:j2,:,:), dim=4 ), dim=3 )
149         
150      ENDIF
151      !
152   END SUBROUTINE update_tra_ice
153
154
155   SUBROUTINE update_u_ice( ptab, i1, i2, j1, j2, before )
156      !!-----------------------------------------------------------------------
157      !!                        *** ROUTINE update_u_ice ***
158      !! ** Method  : Update the fluxes and recover the properties (C-grid)
159      !!-----------------------------------------------------------------------
160      INTEGER                         , INTENT(in   ) ::   i1, i2, j1, j2
161      REAL(wp), DIMENSION(i1:i2,j1:j2), INTENT(inout) ::   ptab
162      LOGICAL                         , INTENT(in   ) ::   before
163      !!
164      REAL(wp) ::   zrhoy   ! local scalar
165      !!-----------------------------------------------------------------------
166      !
167      IF( before ) THEN
168         zrhoy = Agrif_Rhoy()
169         ptab(:,:) = e2u(i1:i2,j1:j2) * u_ice(i1:i2,j1:j2) * zrhoy
170         WHERE( umask(i1:i2,j1:j2,1) == 0._wp )   ptab(:,:) = Agrif_SpecialValueFineGrid
171      ELSE
172         WHERE( ptab(i1:i2,j1:j2) /= Agrif_SpecialValueFineGrid )
173            u_ice(i1:i2,j1:j2) = ptab(i1:i2,j1:j2) / e2u(i1:i2,j1:j2) * umask(i1:i2,j1:j2,1)
174         ENDWHERE
175      ENDIF
176      !
177   END SUBROUTINE update_u_ice
178
179
180   SUBROUTINE update_v_ice( ptab, i1, i2, j1, j2, before )
181      !!-----------------------------------------------------------------------
182      !!                    *** ROUTINE update_v_ice ***
183      !! ** Method  : Update the fluxes and recover the properties (C-grid)
184      !!-----------------------------------------------------------------------
185      INTEGER                         , INTENT(in   ) ::   i1, i2, j1, j2
186      REAL(wp), DIMENSION(i1:i2,j1:j2), INTENT(inout) ::   ptab
187      LOGICAL                         , INTENT(in   ) ::   before
188      !!
189      REAL(wp) ::   zrhox   ! local scalar
190      !!-----------------------------------------------------------------------
191      !
192      IF( before ) THEN
193         zrhox = Agrif_Rhox()
194         ptab(:,:) = e1v(i1:i2,j1:j2) * v_ice(i1:i2,j1:j2) * zrhox
195         WHERE( vmask(i1:i2,j1:j2,1) == 0._wp )   ptab(:,:) = Agrif_SpecialValueFineGrid
196      ELSE
197         WHERE( ptab(i1:i2,j1:j2) /= Agrif_SpecialValueFineGrid )
198            v_ice(i1:i2,j1:j2) = ptab(i1:i2,j1:j2) / e1v(i1:i2,j1:j2) * vmask(i1:i2,j1:j2,1)
199         ENDWHERE
200      ENDIF
201      !
202   END SUBROUTINE update_v_ice
203
204#else
205   !!----------------------------------------------------------------------
206   !!   Empty module                                             no sea-ice
207   !!----------------------------------------------------------------------
208CONTAINS
209   SUBROUTINE agrif_lim3_update_empty
210      WRITE(*,*)  'agrif_lim3_update : You should not have seen this print! error?'
211   END SUBROUTINE agrif_lim3_update_empty
212#endif
213
214   !!======================================================================
215END MODULE agrif_lim3_update
Note: See TracBrowser for help on using the repository browser.