New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OCE_SRC/IOM – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OCE_SRC/IOM/restart.F90 @ 9570

Last change on this file since 9570 was 9570, checked in by nicolasmartin, 6 years ago

Global renaming for core routines (./NEMO)

  • Folders
    • LIM_SRC_3 -> ICE_SRC
    • OPA_SRC -> OCE_SRC
  • CPP key: key_lim3 -> key_si3
  • Modules, (sub)routines and variables names
    • MPI: mpi_comm_opa -> mpi_comm_oce, MPI_COMM_OPA -> MPI_COMM_OCE, mpi_init_opa -> mpi_init_oce
    • AGRIF: agrif_opa_* -> agrif_oce_*, agrif_lim3_* -> agrif_si3_* and few more
    • TOP-PISCES: p.zlim -> p.zice, namp.zlim -> namp.zice
  • Comments
    • NEMO/OPA -> NEMO/OCE
    • ESIM|LIM3 -> SI3
  • Property svn:keywords set to Id
File size: 15.9 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diurnal_bulk
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   rst_opn         ! routine called by step module
35   PUBLIC   rst_write       ! routine called by step module
36   PUBLIC   rst_read        ! routine called by istate module
37   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!                     
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      !!
60      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
61      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
62      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
63      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
64      CHARACTER(LEN=256)  ::   clinfo    ! info character
65      !!----------------------------------------------------------------------
66      !
67      IF( kt == nit000 ) THEN   ! default definitions
68         lrst_oce = .FALSE.   
69         IF( ln_rst_list ) THEN
70            nrst_lst = 1
71            nitrst = nstocklist( nrst_lst )
72         ELSE
73            nitrst = nitend
74         ENDIF
75      ENDIF
76
77      ! frequency-based restart dumping (nn_stock)
78      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
79         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
80         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
81         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
82      ENDIF
83      ! to get better performances with NetCDF format:
84      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
85      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
86      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
87         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
88            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
89            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
90            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
91            ENDIF
92            ! create the file
93            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
94            clpath = TRIM(cn_ocerst_outdir)
95            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
96            IF(lwp) THEN
97               WRITE(numout,*)
98               IF(.NOT.lwxios) THEN
99                  SELECT CASE ( jprstlib )
100                  CASE DEFAULT         ;   WRITE(numout,*)                            &
101                      '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
102                  END SELECT
103                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
104                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
105                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
106                  ENDIF
107               ENDIF
108            ENDIF
109            !
110            IF(.NOT.lwxios) THEN
111               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
112            ELSE
113#if defined key_iomput
114               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
115               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
116                  clpname = clname
117               ELSE
118                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
119               ENDIF
120               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname))
121               CALL xios_update_calendar(nitrst)
122               CALL iom_swap(      cxios_context          )
123#else
124               clinfo = 'Can not use XIOS in rst_opn'
125               CALL ctl_stop(TRIM(clinfo))
126#endif
127            ENDIF
128            lrst_oce = .TRUE.
129         ENDIF
130      ENDIF
131      !
132   END SUBROUTINE rst_opn
133
134
135   SUBROUTINE rst_write( kt )
136      !!---------------------------------------------------------------------
137      !!                   ***  ROUTINE rstwrite  ***
138      !!                     
139      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
140      !!
141      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
142      !!              file, save fields which are necessary for restart
143      !!----------------------------------------------------------------------
144      INTEGER, INTENT(in) ::   kt   ! ocean time-step
145      !!----------------------------------------------------------------------
146                     IF(lwxios) CALL iom_swap(      cwxios_context          )
147                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       , ldxios = lwxios)   ! dynamics time step
148
149      IF ( .NOT. ln_diurnal_only ) THEN
150                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub, ldxios = lwxios        )     ! before fields
151                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb, ldxios = lwxios        )
152                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lwxios )
153                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lwxios )
154                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb, ldxios = lwxios      )
155                     !
156                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un, ldxios = lwxios        )     ! now fields
157                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn, ldxios = lwxios        )
158                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lwxios )
159                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lwxios )
160                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn, ldxios = lwxios      )
161                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, ldxios = lwxios      )
162                  ! extra variable needed for the ice sheet coupling
163                  IF ( ln_iscpl ) THEN
164                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask, ldxios = lwxios ) ! need to extrapolate T/S
165                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask, ldxios = lwxios ) ! need to correct barotropic velocity
166                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
167                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
168                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:), ldxios = lwxios )   ! need to compute temperature correction
169                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
170                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
171                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:), ldxios = lwxios ) ! need to compute extrapolation if vvl
172                  END IF
173      ENDIF
174     
175      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
176      IF(lwxios) CALL iom_swap(      cxios_context          )
177      IF( kt == nitrst ) THEN
178         IF(.NOT.lwxios) THEN
179            CALL iom_close( numrow )     ! close the restart file (only at last time step)
180         ELSE
181            CALL iom_context_finalize(      cwxios_context          )
182         ENDIF
183!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
184!!gm  not sure what to do here   ===>>>  ask to Sebastian
185         lrst_oce = .FALSE.
186            IF( ln_rst_list ) THEN
187               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
188               nitrst = nstocklist( nrst_lst )
189            ENDIF
190      ENDIF
191      !
192   END SUBROUTINE rst_write
193
194
195   SUBROUTINE rst_read_open
196      !!----------------------------------------------------------------------
197      !!                   ***  ROUTINE rst_read_open  ***
198      !!
199      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
200      !!
201      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
202      !!                the file has already been opened
203      !!----------------------------------------------------------------------
204      INTEGER        ::   jlibalt = jprstlib
205      LOGICAL        ::   llok
206      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
207      !!----------------------------------------------------------------------
208      !
209      IF( numror <= 0 ) THEN
210         IF(lwp) THEN                                             ! Contol prints
211            WRITE(numout,*)
212            SELECT CASE ( jprstlib )
213            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
214            END SELECT
215            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
216            WRITE(numout,*) '~~~~~~~~'
217         ENDIF
218         lxios_sini = .FALSE.
219         clpath = TRIM(cn_ocerst_indir)
220         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
221         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
222! are we using XIOS to read the data? Part above will have to modified once XIOS
223! can handle checking if variable is in the restart file (there will be no need to open
224! restart)
225         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
226         IF( lrxios) THEN
227             crxios_context = 'nemo_rst'
228             IF( .NOT.lxios_set ) THEN
229                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
230                 CALL iom_init( crxios_context )
231                 lxios_set = .TRUE.
232             ENDIF
233         ENDIF
234         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
235             CALL iom_init( crxios_context )
236             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
237             lxios_set = .TRUE.
238         ENDIF
239      ENDIF
240
241   END SUBROUTINE rst_read_open
242
243
244   SUBROUTINE rst_read
245      !!----------------------------------------------------------------------
246      !!                   ***  ROUTINE rst_read  ***
247      !!
248      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
249      !!
250      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
251      !!----------------------------------------------------------------------
252      REAL(wp) ::   zrdt
253      INTEGER  ::   jk
254      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
255      !!----------------------------------------------------------------------
256
257      CALL rst_read_open           ! open restart for reading (if not already opened)
258
259      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
260      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
261         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
262         IF( zrdt /= rdt )   neuler = 0
263      ENDIF
264
265      ! Diurnal DSST
266      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios ) 
267      IF ( ln_diurnal_only ) THEN
268         IF(lwp) WRITE( numout, * ) &
269         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
270         rhop = rau0
271         CALL iom_get( numror, jpdom_autoglo, 'tn'     , w3d, ldxios = lrxios ) 
272         tsn(:,:,1,jp_tem) = w3d(:,:,1)
273         RETURN
274      ENDIF 
275     
276      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
277         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub, ldxios = lrxios                )   ! before fields
278         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb, ldxios = lrxios                )
279         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lrxios )
280         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lrxios )
281         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb, ldxios = lrxios              )
282      ELSE
283         neuler = 0
284      ENDIF
285      !
286      CALL iom_get( numror, jpdom_autoglo, 'un'     , un, ldxios = lrxios )   ! now    fields
287      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn, ldxios = lrxios )
288      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lrxios )
289      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lrxios )
290      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn, ldxios = lrxios )
291      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
292         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, ldxios = lrxios )   ! now    potential density
293      ELSE
294         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
295      ENDIF
296      !
297      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
298         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
299         ub   (:,:,:)   = un   (:,:,:)
300         vb   (:,:,:)   = vn   (:,:,:)
301         sshb (:,:)     = sshn (:,:)
302         !
303         IF( .NOT.ln_linssh ) THEN
304            DO jk = 1, jpk
305               e3t_b(:,:,jk) = e3t_n(:,:,jk)
306            END DO
307         ENDIF
308         !
309      ENDIF
310      !
311   END SUBROUTINE rst_read
312
313   !!=====================================================================
314END MODULE restart
Note: See TracBrowser for help on using the repository browser.