source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OCE_SRC/SBC/sbcblk_algo_ncar.F90 @ 9580

Last change on this file since 9580 was 9570, checked in by nicolasmartin, 3 years ago

Global renaming for core routines (./NEMO)

  • Folders
    • LIM_SRC_3 → ICE_SRC
    • OPA_SRC → OCE_SRC
  • CPP key: key_lim3 → key_si3
  • Modules, (sub)routines and variables names
    • MPI: mpi_comm_opa → mpi_comm_oce, MPI_COMM_OPA → MPI_COMM_OCE, mpi_init_opa → mpi_init_oce
    • AGRIF: agrif_opa_* → agrif_oce_*, agrif_lim3_* → agrif_si3_* and few more
    • TOP-PISCES: p.zlim → p.zice, namp.zlim → namp.zice
  • Comments
    • NEMO/OPA → NEMO/OCE
    • ESIM|LIM3 → SI3
File size: 16.2 KB
Line 
1MODULE sbcblk_algo_ncar
2   !!======================================================================
3   !!                   ***  MODULE  sbcblk_algo_ncar  ***
4   !! Computes:
5   !!   * bulk transfer coefficients C_D, C_E and C_H
6   !!   * air temp. and spec. hum. adjusted from zt (2m) to zu (10m) if needed
7   !!   * the effective bulk wind speed at 10m U_blk
8   !!   => all these are used in bulk formulas in sbcblk.F90
9   !!
10   !!    Using the bulk formulation/param. of Large & Yeager 2008
11   !!
12   !!       Routine turb_ncar maintained and developed in AeroBulk
13   !!                     (http://aerobulk.sourceforge.net/)
14   !!
15   !!                         L. Brodeau, 2015
16   !!=====================================================================
17   !! History :  3.6  !  2016-02  (L.Brodeau) successor of old turb_ncar of former sbcblk_core.F90
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   turb_ncar  : computes the bulk turbulent transfer coefficients
22   !!                   adjusts t_air and q_air from zt to zu m
23   !!                   returns the effective bulk wind speed at 10m
24   !!----------------------------------------------------------------------
25   USE oce             ! ocean dynamics and tracers
26   USE dom_oce         ! ocean space and time domain
27   USE phycst          ! physical constants
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbcwave, ONLY   :  cdn_wave ! wave module
30#if defined key_si3 || defined key_cice
31   USE sbc_ice         ! Surface boundary condition: ice fields
32#endif
33   !
34   USE iom             ! I/O manager library
35   USE lib_mpp         ! distribued memory computing library
36   USE in_out_manager  ! I/O manager
37   USE prtctl          ! Print control
38   USE lib_fortran     ! to use key_nosignedzero
39
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC ::   TURB_NCAR   ! called by sbcblk.F90
45
46   !                              ! NCAR own values for given constants:
47   REAL(wp), PARAMETER ::   rctv0 = 0.608   ! constant to obtain virtual temperature...
48   
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE turb_ncar( zt, zu, sst, t_zt, ssq, q_zt, U_zu, &
53      &                  Cd, Ch, Ce, t_zu, q_zu, U_blk,      &
54      &                  Cdn, Chn, Cen                       )
55      !!----------------------------------------------------------------------------------
56      !!                      ***  ROUTINE  turb_ncar  ***
57      !!
58      !! ** Purpose :   Computes turbulent transfert coefficients of surface
59      !!                fluxes according to Large & Yeager (2004) and Large & Yeager (2008)
60      !!                If relevant (zt /= zu), adjust temperature and humidity from height zt to zu
61      !!                Returns the effective bulk wind speed at 10m to be used in the bulk formulas
62      !!
63      !! ** Method : Monin Obukhov Similarity Theory
64      !!             + Large & Yeager (2004,2008) closure: CD_n10 = f(U_n10)
65      !!
66      !! ** References :   Large & Yeager, 2004 / Large & Yeager, 2008
67      !!
68      !! ** Last update: Laurent Brodeau, June 2014:
69      !!    - handles both cases zt=zu and zt/=zu
70      !!    - optimized: less 2D arrays allocated and less operations
71      !!    - better first guess of stability by checking air-sea difference of virtual temperature
72      !!       rather than temperature difference only...
73      !!    - added function "cd_neutral_10m" that uses the improved parametrization of
74      !!      Large & Yeager 2008. Drag-coefficient reduction for Cyclone conditions!
75      !!    - using code-wide physical constants defined into "phycst.mod" rather than redifining them
76      !!      => 'vkarmn' and 'grav'
77      !!
78      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
79      !!
80      !! INPUT :
81      !! -------
82      !!    *  zt   : height for temperature and spec. hum. of air            [m]
83      !!    *  zu   : height for wind speed (generally 10m)                   [m]
84      !!    *  U_zu : scalar wind speed at 10m                                [m/s]
85      !!    *  sst  : SST                                                     [K]
86      !!    *  t_zt : potential air temperature at zt                         [K]
87      !!    *  ssq  : specific humidity at saturation at SST                  [kg/kg]
88      !!    *  q_zt : specific humidity of air at zt                          [kg/kg]
89      !!
90      !!
91      !! OUTPUT :
92      !! --------
93      !!    *  Cd     : drag coefficient
94      !!    *  Ch     : sensible heat coefficient
95      !!    *  Ce     : evaporation coefficient
96      !!    *  t_zu   : pot. air temperature adjusted at wind height zu       [K]
97      !!    *  q_zu   : specific humidity of air        //                    [kg/kg]
98      !!    *  U_blk  : bulk wind at 10m                                      [m/s]
99      !!----------------------------------------------------------------------------------
100      REAL(wp), INTENT(in   )                     ::   zt       ! height for t_zt and q_zt                    [m]
101      REAL(wp), INTENT(in   )                     ::   zu       ! height for U_zu                             [m]
102      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   sst      ! sea surface temperature                [Kelvin]
103      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   t_zt     ! potential air temperature              [Kelvin]
104      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   ssq      ! sea surface specific humidity           [kg/kg]
105      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_zt     ! specific air humidity                   [kg/kg]
106      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   U_zu     ! relative wind module at zu                [m/s]
107      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cd       ! transfer coefficient for momentum         (tau)
108      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ch       ! transfer coefficient for sensible heat (Q_sens)
109      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ce       ! transfert coefficient for evaporation   (Q_lat)
110      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   t_zu     ! pot. air temp. adjusted at zu               [K]
111      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   q_zu     ! spec. humidity adjusted at zu           [kg/kg]
112      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   U_blk    ! bulk wind at 10m                          [m/s]
113      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cdn, Chn, Cen ! neutral transfer coefficients
114      !
115      INTEGER ::   j_itt
116      LOGICAL ::   l_zt_equal_zu = .FALSE.      ! if q and t are given at same height as U
117      INTEGER , PARAMETER ::   nb_itt = 4       ! number of itterations
118      !
119      REAL(wp), DIMENSION(jpi,jpj) ::   Cx_n10        ! 10m neutral latent/sensible coefficient
120      REAL(wp), DIMENSION(jpi,jpj) ::   sqrt_Cd_n10   ! root square of Cd_n10
121      REAL(wp), DIMENSION(jpi,jpj) ::   zeta_u        ! stability parameter at height zu
122      REAL(wp), DIMENSION(jpi,jpj) ::   zpsi_h_u
123      REAL(wp), DIMENSION(jpi,jpj) ::   ztmp0, ztmp1, ztmp2
124      REAL(wp), DIMENSION(jpi,jpj) ::   stab          ! stability test integer
125      !!----------------------------------------------------------------------------------
126      !
127      l_zt_equal_zu = .FALSE.
128      IF( ABS(zu - zt) < 0.01 ) l_zt_equal_zu = .TRUE.    ! testing "zu == zt" is risky with double precision
129
130      U_blk = MAX( 0.5 , U_zu )   !  relative wind speed at zu (normally 10m), we don't want to fall under 0.5 m/s
131
132      !! First guess of stability:
133      ztmp0 = t_zt*(1. + rctv0*q_zt) - sst*(1. + rctv0*ssq) ! air-sea difference of virtual pot. temp. at zt
134      stab  = 0.5 + sign(0.5,ztmp0)                           ! stab = 1 if dTv > 0  => STABLE, 0 if unstable
135
136      !! Neutral coefficients at 10m:
137      IF( ln_cdgw ) THEN      ! wave drag case
138         cdn_wave(:,:) = cdn_wave(:,:) + rsmall * ( 1._wp - tmask(:,:,1) )
139         ztmp0   (:,:) = cdn_wave(:,:)
140      ELSE
141         ztmp0 = cd_neutral_10m( U_blk )
142      ENDIF
143
144      sqrt_Cd_n10 = SQRT( ztmp0 )
145
146      !! Initializing transf. coeff. with their first guess neutral equivalents :
147      Cd = ztmp0
148      Ce = 1.e-3*( 34.6 * sqrt_Cd_n10 )
149      Ch = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab))
150      stab = sqrt_Cd_n10   ! Temporaty array !!! stab == SQRT(Cd)
151
152      !! Initializing values at z_u with z_t values:
153      t_zu = t_zt   ;   q_zu = q_zt
154
155      !!  * Now starting iteration loop
156      DO j_itt=1, nb_itt
157         !
158         ztmp1 = t_zu - sst   ! Updating air/sea differences
159         ztmp2 = q_zu - ssq
160
161         ! Updating turbulent scales :   (L&Y 2004 eq. (7))
162         ztmp1  = Ch/stab*ztmp1    ! theta*   (stab == SQRT(Cd))
163         ztmp2  = Ce/stab*ztmp2    ! q*       (stab == SQRT(Cd))
164
165         ztmp0 = 1. + rctv0*q_zu      ! multiply this with t and you have the virtual temperature
166
167         ! Estimate the inverse of Monin-Obukov length (1/L) at height zu:
168         ztmp0 =  (grav*vkarmn/(t_zu*ztmp0)*(ztmp1*ztmp0 + rctv0*t_zu*ztmp2)) / (Cd*U_blk*U_blk)
169         !                                                      ( Cd*U_blk*U_blk is U*^2 at zu )
170
171         !! Stability parameters :
172         zeta_u   = zu*ztmp0   ;  zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
173         zpsi_h_u = psi_h( zeta_u )
174
175         !! Shifting temperature and humidity at zu (L&Y 2004 eq. (9b-9c))
176         IF( .NOT. l_zt_equal_zu ) THEN
177            !! Array 'stab' is free for the moment so using it to store 'zeta_t'
178            stab = zt*ztmp0 ;  stab = SIGN( MIN(ABS(stab),10.0), stab )  ! Temporaty array stab == zeta_t !!!
179            stab = LOG(zt/zu) + zpsi_h_u - psi_h(stab)                   ! stab just used as temp array again!
180            t_zu = t_zt - ztmp1/vkarmn*stab    ! ztmp1 is still theta*  L&Y 2004 eq.(9b)
181            q_zu = q_zt - ztmp2/vkarmn*stab    ! ztmp2 is still q*      L&Y 2004 eq.(9c)
182            q_zu = max(0., q_zu)
183         END IF
184
185         ztmp2 = psi_m(zeta_u)
186         IF( ln_cdgw ) THEN      ! surface wave case
187            stab = vkarmn / ( vkarmn / sqrt_Cd_n10 - ztmp2 )  ! (stab == SQRT(Cd))
188            Cd      = stab * stab
189         ELSE
190            ! Update neutral wind speed at 10m and neutral Cd at 10m (L&Y 2004 eq. 9a)...
191            !   In very rare low-wind conditions, the old way of estimating the
192            !   neutral wind speed at 10m leads to a negative value that causes the code
193            !   to crash. To prevent this a threshold of 0.25m/s is imposed.
194            ztmp0 = MAX( 0.25 , U_blk/(1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - ztmp2)) ) ! U_n10 (ztmp2 == psi_m(zeta_u))
195            ztmp0 = cd_neutral_10m(ztmp0)                                               ! Cd_n10
196            Cdn(:,:) = ztmp0
197            sqrt_Cd_n10 = sqrt(ztmp0)
198
199            stab    = 0.5 + sign(0.5,zeta_u)                           ! update stability
200            Cx_n10  = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab))  ! L&Y 2004 eq. (6c-6d)    (Cx_n10 == Ch_n10)
201            Chn(:,:) = Cx_n10
202
203            !! Update of transfer coefficients:
204            ztmp1 = 1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - ztmp2)   ! L&Y 2004 eq. (10a) (ztmp2 == psi_m(zeta_u))
205            Cd      = ztmp0 / ( ztmp1*ztmp1 )
206            stab = SQRT( Cd ) ! Temporary array !!! (stab == SQRT(Cd))
207         ENDIF
208
209         ztmp0 = (LOG(zu/10.) - zpsi_h_u) / vkarmn / sqrt_Cd_n10
210         ztmp2 = stab / sqrt_Cd_n10   ! (stab == SQRT(Cd))
211         ztmp1 = 1. + Cx_n10*ztmp0    ! (Cx_n10 == Ch_n10)
212         Ch  = Cx_n10*ztmp2 / ztmp1   ! L&Y 2004 eq. (10b)
213
214         Cx_n10  = 1.e-3 * (34.6 * sqrt_Cd_n10)  ! L&Y 2004 eq. (6b)    ! Cx_n10 == Ce_n10
215         Cen(:,:) = Cx_n10
216         ztmp1 = 1. + Cx_n10*ztmp0
217         Ce  = Cx_n10*ztmp2 / ztmp1  ! L&Y 2004 eq. (10c)
218         !
219      END DO
220      !
221   END SUBROUTINE turb_ncar
222
223
224   FUNCTION cd_neutral_10m( pw10 )
225      !!----------------------------------------------------------------------------------     
226      !! Estimate of the neutral drag coefficient at 10m as a function
227      !! of neutral wind  speed at 10m
228      !!
229      !! Origin: Large & Yeager 2008 eq.(11a) and eq.(11b)
230      !!
231      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
232      !!----------------------------------------------------------------------------------
233      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pw10           ! scalar wind speed at 10m (m/s)
234      REAL(wp), DIMENSION(jpi,jpj)             :: cd_neutral_10m
235      !
236      INTEGER  ::     ji, jj     ! dummy loop indices
237      REAL(wp) :: zgt33, zw, zw6 ! local scalars
238      !!----------------------------------------------------------------------------------
239      !
240      DO jj = 1, jpj
241         DO ji = 1, jpi
242            !
243            zw  = pw10(ji,jj)
244            zw6 = zw*zw*zw
245            zw6 = zw6*zw6
246            !
247            ! When wind speed > 33 m/s => Cyclone conditions => special treatment
248            zgt33 = 0.5 + SIGN( 0.5, (zw - 33.) )   ! If pw10 < 33. => 0, else => 1
249            !
250            cd_neutral_10m(ji,jj) = 1.e-3 * ( &
251               &       (1. - zgt33)*( 2.7/zw + 0.142 + zw/13.09 - 3.14807E-10*zw6) & ! wind <  33 m/s
252               &      +    zgt33   *      2.34 )                                     ! wind >= 33 m/s
253            !
254            cd_neutral_10m(ji,jj) = MAX(cd_neutral_10m(ji,jj), 1.E-6)
255            !
256         END DO
257      END DO
258      !
259   END FUNCTION cd_neutral_10m
260
261
262   FUNCTION psi_m( pzeta )
263      !!----------------------------------------------------------------------------------
264      !! Universal profile stability function for momentum
265      !!    !! Psis, L&Y 2004 eq. (8c), (8d), (8e)
266      !!     
267      !! pzet0 : stability paramenter, z/L where z is altitude measurement                                         
268      !!         and L is M-O length
269      !!
270      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
271      !!----------------------------------------------------------------------------------
272      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pzeta
273      REAL(wp), DIMENSION(jpi,jpj)             ::   psi_m
274      !
275      INTEGER  ::   ji, jj         ! dummy loop indices
276      REAL(wp) :: zx2, zx, zstab   ! local scalars
277      !!----------------------------------------------------------------------------------
278      !
279      DO jj = 1, jpj
280         DO ji = 1, jpi
281            zx2 = SQRT( ABS( 1. - 16.*pzeta(ji,jj) ) )
282            zx2 = MAX ( zx2 , 1. )
283            zx  = SQRT( zx2 )
284            zstab = 0.5 + SIGN( 0.5 , pzeta(ji,jj) )
285            !
286            psi_m(ji,jj) =        zstab  * (-5.*pzeta(ji,jj))       &          ! Stable
287               &          + (1. - zstab) * (2.*LOG((1. + zx)*0.5)   &          ! Unstable
288               &               + LOG((1. + zx2)*0.5) - 2.*ATAN(zx) + rpi*0.5)  !    "
289            !
290         END DO
291      END DO
292      !
293   END FUNCTION psi_m
294
295
296   FUNCTION psi_h( pzeta )
297      !!----------------------------------------------------------------------------------
298      !! Universal profile stability function for temperature and humidity
299      !!    !! Psis, L&Y 2004 eq. (8c), (8d), (8e)
300      !!
301      !! pzet0 : stability paramenter, z/L where z is altitude measurement                                         
302      !!         and L is M-O length
303      !!
304      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
305      !!----------------------------------------------------------------------------------
306      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta
307      REAL(wp), DIMENSION(jpi,jpj)             :: psi_h
308      !
309      INTEGER  ::   ji, jj    ! dummy loop indices
310      REAL(wp) :: zx2, zstab  ! local scalars
311      !!----------------------------------------------------------------------------------
312      !
313      DO jj = 1, jpj
314         DO ji = 1, jpi
315            zx2 = SQRT( ABS( 1. - 16.*pzeta(ji,jj) ) )
316            zx2 = MAX ( zx2 , 1. )
317            zstab = 0.5 + SIGN( 0.5 , pzeta(ji,jj) )
318            !
319            psi_h(ji,jj) =         zstab  * (-5.*pzeta(ji,jj))        &  ! Stable
320               &           + (1. - zstab) * (2.*LOG( (1. + zx2)*0.5 ))   ! Unstable
321            !
322         END DO
323      END DO
324      !
325   END FUNCTION psi_h
326
327   !!======================================================================
328END MODULE sbcblk_algo_ncar
Note: See TracBrowser for help on using the repository browser.