New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domzgr.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DOM/domzgr.F90 @ 9124

Last change on this file since 9124 was 9124, checked in by gm, 6 years ago

dev_merge_2017: ln_timing instead of nn_timing + restricted timing to nemo_init and routine called by step in OPA_SRC

  • Property svn:keywords set to Id
File size: 18.0 KB
Line 
1MODULE domzgr
2   !!==============================================================================
3   !!                       ***  MODULE domzgr   ***
4   !! Ocean domain : definition of the vertical coordinate system
5   !!==============================================================================
6   !! History :  OPA  ! 1995-12  (G. Madec)  Original code : s vertical coordinate
7   !!                 ! 1997-07  (G. Madec)  lbc_lnk call
8   !!                 ! 1997-04  (J.-O. Beismann)
9   !!            8.5  ! 2002-09  (A. Bozec, G. Madec)  F90: Free form and module
10   !!             -   ! 2002-09  (A. de Miranda)  rigid-lid + islands
11   !!  NEMO      1.0  ! 2003-08  (G. Madec)  F90: Free form and module
12   !!             -   ! 2005-10  (A. Beckmann)  modifications for hybrid s-ccordinates & new stretching function
13   !!            2.0  ! 2006-04  (R. Benshila, G. Madec)  add zgr_zco
14   !!            3.0  ! 2008-06  (G. Madec)  insertion of domzgr_zps.h90 & conding style
15   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
16   !!            3.3  ! 2010-11  (G. Madec) add mbk. arrays associated to the deepest ocean level
17   !!            3.4  ! 2012-08  (J. Siddorn) added Siddorn and Furner stretching function
18   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  modify C1D case 
19   !!            3.6  ! 2014-11  (P. Mathiot and C. Harris) add ice shelf capabilitye 
20   !!            3.?  ! 2015-11  (H. Liu) Modifications for Wetting/Drying
21   !!----------------------------------------------------------------------
22
23   !!----------------------------------------------------------------------
24   !!   dom_zgr       : read or set the ocean vertical coordinate system
25   !!   zgr_read      : read the vertical information in the domain configuration file
26   !!   zgr_top_bot   : ocean top and bottom level for t-, u, and v-points with 1 as minimum value
27   !!---------------------------------------------------------------------
28   USE oce            ! ocean variables
29   USE dom_oce        ! ocean domain
30   USE usrdef_zgr     ! user defined vertical coordinate system
31   USE depth_e3       ! depth <=> e3
32   USE wet_dry,   ONLY: ll_wd, ssh_ref  ! Wetting and drying
33   !
34   USE in_out_manager ! I/O manager
35   USE iom            ! I/O library
36   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
37   USE lib_mpp        ! distributed memory computing library
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   dom_zgr        ! called by dom_init.F90
43
44  !! * Substitutions
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3.1 , NEMO Consortium (2011)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS       
52
53   SUBROUTINE dom_zgr( k_top, k_bot )
54      !!----------------------------------------------------------------------
55      !!                ***  ROUTINE dom_zgr  ***
56      !!                   
57      !! ** Purpose :   set the depth of model levels and the resulting
58      !!              vertical scale factors.
59      !!
60      !! ** Method  : - reference 1D vertical coordinate (gdep._1d, e3._1d)
61      !!              - read/set ocean depth and ocean levels (bathy, mbathy)
62      !!              - vertical coordinate (gdep., e3.) depending on the
63      !!                coordinate chosen :
64      !!                   ln_zco=T   z-coordinate   
65      !!                   ln_zps=T   z-coordinate with partial steps
66      !!                   ln_zco=T   s-coordinate
67      !!
68      !! ** Action  :   define gdep., e3., mbathy and bathy
69      !!----------------------------------------------------------------------
70      INTEGER, DIMENSION(:,:), INTENT(out) ::   k_top, k_bot   ! ocean first and last level indices
71      !
72      INTEGER  ::   jk                  ! dummy loop index
73      INTEGER  ::   ioptio, ibat, ios   ! local integer
74      REAL(wp) ::   zrefdep             ! depth of the reference level (~10m)
75      !!----------------------------------------------------------------------
76      !
77      IF(lwp) THEN                     ! Control print
78         WRITE(numout,*)
79         WRITE(numout,*) 'dom_zgr : vertical coordinate'
80         WRITE(numout,*) '~~~~~~~'
81      ENDIF
82
83      IF( ln_linssh .AND. lwp) WRITE(numout,*) '   linear free surface: the vertical mesh does not change in time'
84
85
86      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
87         IF(lwp) WRITE(numout,*)
88         IF(lwp) WRITE(numout,*) '          Read vertical mesh in ', TRIM( cn_domcfg ), ' file'
89         !
90         CALL zgr_read   ( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
91            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
92            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
93            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
94            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
95            &              k_top   , k_bot            )                  ! 1st & last ocean level
96         !
97      ELSE                          !==  User defined configuration  ==!
98         IF(lwp) WRITE(numout,*)
99         IF(lwp) WRITE(numout,*) '          User defined vertical mesh (usr_def_zgr)'
100         !
101         CALL usr_def_zgr( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
102            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
103            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
104            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
105            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
106            &              k_top   , k_bot            )                  ! 1st & last ocean level
107         !
108      ENDIF
109      !
110!!gm to be remove when removing the OLD definition of e3 scale factors so that gde3w disappears
111      ! Compute gde3w_0 (vertical sum of e3w)
112      gde3w_0(:,:,1) = 0.5_wp * e3w_0(:,:,1)
113      DO jk = 2, jpk
114         gde3w_0(:,:,jk) = gde3w_0(:,:,jk-1) + e3w_0(:,:,jk)
115      END DO
116      !
117      IF(lwp) THEN                     ! Control print
118         WRITE(numout,*)
119         WRITE(numout,*) '   Type of vertical coordinate (read in ', TRIM( cn_domcfg ), ' file or set in userdef_nam) :'
120         WRITE(numout,*) '      z-coordinate - full steps      ln_zco    = ', ln_zco
121         WRITE(numout,*) '      z-coordinate - partial steps   ln_zps    = ', ln_zps
122         WRITE(numout,*) '      s- or hybrid z-s-coordinate    ln_sco    = ', ln_sco
123         WRITE(numout,*) '      ice shelf cavities             ln_isfcav = ', ln_isfcav
124      ENDIF
125
126      ioptio = 0                       ! Check Vertical coordinate options
127      IF( ln_zco      )   ioptio = ioptio + 1
128      IF( ln_zps      )   ioptio = ioptio + 1
129      IF( ln_sco      )   ioptio = ioptio + 1
130      IF( ioptio /= 1 )   CALL ctl_stop( ' none or several vertical coordinate options used' )
131
132
133      !                                ! top/bottom ocean level indices for t-, u- and v-points (f-point also for top)
134      CALL zgr_top_bot( k_top, k_bot )      ! with a minimum value set to 1
135     
136
137      !                                ! deepest/shallowest W level Above/Below ~10m
138!!gm BUG in s-coordinate this does not work!
139      zrefdep = 10._wp - 0.1_wp * MINVAL( e3w_1d )                   ! ref. depth with tolerance (10% of minimum layer thickness)
140      nlb10 = MINLOC( gdepw_1d, mask = gdepw_1d > zrefdep, dim = 1 ) ! shallowest W level Below ~10m
141      nla10 = nlb10 - 1                                              ! deepest    W level Above ~10m
142!!gm end bug
143      !
144      IF( nprint == 1 .AND. lwp )   THEN
145         WRITE(numout,*) ' MIN val k_top   ', MINVAL(   k_top(:,:) ), ' MAX ', MAXVAL( k_top(:,:) )
146         WRITE(numout,*) ' MIN val k_bot   ', MINVAL(   k_bot(:,:) ), ' MAX ', MAXVAL( k_bot(:,:) )
147         WRITE(numout,*) ' MIN val depth t ', MINVAL( gdept_0(:,:,:) ),   &
148            &                          ' w ', MINVAL( gdepw_0(:,:,:) ), '3w ', MINVAL( gde3w_0(:,:,:) )
149         WRITE(numout,*) ' MIN val e3    t ', MINVAL(   e3t_0(:,:,:) ), ' f ', MINVAL(   e3f_0(:,:,:) ),  &
150            &                          ' u ', MINVAL(   e3u_0(:,:,:) ), ' u ', MINVAL(   e3v_0(:,:,:) ),  &
151            &                          ' uw', MINVAL(  e3uw_0(:,:,:) ), ' vw', MINVAL(  e3vw_0(:,:,:)),   &
152            &                          ' w ', MINVAL(   e3w_0(:,:,:) )
153
154         WRITE(numout,*) ' MAX val depth t ', MAXVAL( gdept_0(:,:,:) ),   &
155            &                          ' w ', MAXVAL( gdepw_0(:,:,:) ), '3w ', MAXVAL( gde3w_0(:,:,:) )
156         WRITE(numout,*) ' MAX val e3    t ', MAXVAL(   e3t_0(:,:,:) ), ' f ', MAXVAL(   e3f_0(:,:,:) ),  &
157            &                          ' u ', MAXVAL(   e3u_0(:,:,:) ), ' u ', MAXVAL(   e3v_0(:,:,:) ),  &
158            &                          ' uw', MAXVAL(  e3uw_0(:,:,:) ), ' vw', MAXVAL(  e3vw_0(:,:,:) ),  &
159            &                          ' w ', MAXVAL(   e3w_0(:,:,:) )
160      ENDIF
161      !
162   END SUBROUTINE dom_zgr
163
164
165   SUBROUTINE zgr_read( ld_zco  , ld_zps  , ld_sco  , ld_isfcav,   &   ! type of vertical coordinate
166      &                 pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d  ,   &   ! 1D reference vertical coordinate
167      &                 pdept , pdepw ,                            &   ! 3D t & w-points depth
168      &                 pe3t  , pe3u  , pe3v   , pe3f ,            &   ! vertical scale factors
169      &                 pe3w  , pe3uw , pe3vw         ,            &   !     -      -      -
170      &                 k_top  , k_bot    )                            ! top & bottom ocean level
171      !!---------------------------------------------------------------------
172      !!              ***  ROUTINE zgr_read  ***
173      !!
174      !! ** Purpose :   Read the vertical information in the domain configuration file
175      !!
176      !!----------------------------------------------------------------------
177      LOGICAL                   , INTENT(out) ::   ld_zco, ld_zps, ld_sco      ! vertical coordinate flags
178      LOGICAL                   , INTENT(out) ::   ld_isfcav                   ! under iceshelf cavity flag
179      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pdept_1d, pdepw_1d          ! 1D grid-point depth       [m]
180      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pe3t_1d , pe3w_1d           ! 1D vertical scale factors [m]
181      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pdept, pdepw                ! grid-point depth          [m]
182      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3t , pe3u , pe3v , pe3f   ! vertical scale factors    [m]
183      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3w , pe3uw, pe3vw         !    -       -      -
184      INTEGER , DIMENSION(:,:)  , INTENT(out) ::   k_top , k_bot               ! first & last ocean level
185      !
186      INTEGER  ::   jk     ! dummy loop index
187      INTEGER  ::   inum   ! local logical unit
188      REAL(WP) ::   z_zco, z_zps, z_sco, z_cav
189      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
190      !!----------------------------------------------------------------------
191      !
192      IF(lwp) THEN
193         WRITE(numout,*)
194         WRITE(numout,*) '   zgr_read : read the vertical coordinates in ', TRIM( cn_domcfg ), ' file'
195         WRITE(numout,*) '   ~~~~~~~~'
196      ENDIF
197      !
198      CALL iom_open( cn_domcfg, inum )
199      !
200      !                          !* type of vertical coordinate
201      CALL iom_get( inum, 'ln_zco'   , z_zco )
202      CALL iom_get( inum, 'ln_zps'   , z_zps )
203      CALL iom_get( inum, 'ln_sco'   , z_sco )
204      IF( z_zco == 0._wp ) THEN   ;   ld_zco = .false.   ;   ELSE   ;   ld_zco = .true.   ;   ENDIF
205      IF( z_zps == 0._wp ) THEN   ;   ld_zps = .false.   ;   ELSE   ;   ld_zps = .true.   ;   ENDIF
206      IF( z_sco == 0._wp ) THEN   ;   ld_sco = .false.   ;   ELSE   ;   ld_sco = .true.   ;   ENDIF
207      !
208      !                          !* ocean cavities under iceshelves
209      CALL iom_get( inum, 'ln_isfcav', z_cav )
210      IF( z_cav == 0._wp ) THEN   ;   ld_isfcav = .false.   ;   ELSE   ;   ld_isfcav = .true.   ;   ENDIF
211      !
212      !                          !* vertical scale factors
213      CALL iom_get( inum, jpdom_unknown, 'e3t_1d'  , pe3t_1d  )                     ! 1D reference coordinate
214      CALL iom_get( inum, jpdom_unknown, 'e3w_1d'  , pe3w_1d  )
215      !
216      CALL iom_get( inum, jpdom_data, 'e3t_0'  , pe3t  , lrowattr=ln_use_jattr )    ! 3D coordinate
217      CALL iom_get( inum, jpdom_data, 'e3u_0'  , pe3u  , lrowattr=ln_use_jattr )
218      CALL iom_get( inum, jpdom_data, 'e3v_0'  , pe3v  , lrowattr=ln_use_jattr )
219      CALL iom_get( inum, jpdom_data, 'e3f_0'  , pe3f  , lrowattr=ln_use_jattr )
220      CALL iom_get( inum, jpdom_data, 'e3w_0'  , pe3w  , lrowattr=ln_use_jattr )
221      CALL iom_get( inum, jpdom_data, 'e3uw_0' , pe3uw , lrowattr=ln_use_jattr )
222      CALL iom_get( inum, jpdom_data, 'e3vw_0' , pe3vw , lrowattr=ln_use_jattr )
223      !
224      !                          !* depths
225      !                                   !- old depth definition (obsolescent feature)
226      IF(  iom_varid( inum, 'gdept_1d', ldstop = .FALSE. ) > 0  .AND.  &
227         & iom_varid( inum, 'gdepw_1d', ldstop = .FALSE. ) > 0  .AND.  &
228         & iom_varid( inum, 'gdept_0' , ldstop = .FALSE. ) > 0  .AND.  &
229         & iom_varid( inum, 'gdepw_0' , ldstop = .FALSE. ) > 0    ) THEN
230         CALL ctl_warn( 'zgr_read : old definition of depths and scale factors used ', & 
231            &           '           depths at t- and w-points read in the domain configuration file')
232         CALL iom_get( inum, jpdom_unknown, 'gdept_1d', pdept_1d )   
233         CALL iom_get( inum, jpdom_unknown, 'gdepw_1d', pdepw_1d )
234         CALL iom_get( inum, jpdom_data   , 'gdept_0' , pdept , lrowattr=ln_use_jattr )
235         CALL iom_get( inum, jpdom_data   , 'gdepw_0' , pdepw , lrowattr=ln_use_jattr )
236         !
237      ELSE                                !- depths computed from e3. scale factors
238         CALL e3_to_depth( pe3t_1d, pe3w_1d, pdept_1d, pdepw_1d )    ! 1D reference depth
239         CALL e3_to_depth( pe3t   , pe3w   , pdept   , pdepw    )    ! 3D depths
240         IF(lwp) THEN
241            WRITE(numout,*)
242            WRITE(numout,*) '              Reference 1D z-coordinate depth and scale factors:'
243            WRITE(numout, "(9x,' level  gdept_1d  gdepw_1d  e3t_1d   e3w_1d  ')" )
244            WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, pdept_1d(jk), pdepw_1d(jk), pe3t_1d(jk), pe3w_1d(jk), jk = 1, jpk )
245         ENDIF
246      ENDIF
247      !
248      !                          !* ocean top and bottom level
249      CALL iom_get( inum, jpdom_data, 'top_level'    , z2d  , lrowattr=ln_use_jattr )   ! 1st wet T-points (ISF)
250      k_top(:,:) = INT( z2d(:,:) )
251      CALL iom_get( inum, jpdom_data, 'bottom_level' , z2d  , lrowattr=ln_use_jattr )   ! last wet T-points
252      k_bot(:,:) = INT( z2d(:,:) )
253      !
254      ! reference depth for negative bathy (wetting and drying only)
255      IF( ll_wd )  CALL iom_get( inum,  'rn_wd_ref_depth' , ssh_ref   )
256      !
257      CALL iom_close( inum )
258      !
259   END SUBROUTINE zgr_read
260
261
262   SUBROUTINE zgr_top_bot( k_top, k_bot )
263      !!----------------------------------------------------------------------
264      !!                    ***  ROUTINE zgr_top_bot  ***
265      !!
266      !! ** Purpose :   defines the vertical index of ocean bottom (mbk. arrays)
267      !!
268      !! ** Method  :   computes from k_top and k_bot with a minimum value of 1 over land
269      !!
270      !! ** Action  :   mikt, miku, mikv :   vertical indices of the shallowest
271      !!                                     ocean level at t-, u- & v-points
272      !!                                     (min value = 1)
273      !! ** Action  :   mbkt, mbku, mbkv :   vertical indices of the deeptest
274      !!                                     ocean level at t-, u- & v-points
275      !!                                     (min value = 1 over land)
276      !!----------------------------------------------------------------------
277      INTEGER , DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! top & bottom ocean level indices
278      !
279      INTEGER ::   ji, jj   ! dummy loop indices
280      REAL(wp), DIMENSION(jpi,jpj) ::   zk   ! workspace
281      !!----------------------------------------------------------------------
282      !
283      IF(lwp) WRITE(numout,*)
284      IF(lwp) WRITE(numout,*) '    zgr_top_bot : ocean top and bottom k-index of T-, U-, V- and W-levels '
285      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~'
286      !
287      mikt(:,:) = MAX( k_top(:,:) , 1 )    ! top    ocean k-index of T-level (=1 over land)
288      !
289      mbkt(:,:) = MAX( k_bot(:,:) , 1 )    ! bottom ocean k-index of T-level (=1 over land)
290 
291      !                                    ! N.B.  top     k-index of W-level = mikt
292      !                                    !       bottom  k-index of W-level = mbkt+1
293      DO jj = 1, jpjm1
294         DO ji = 1, jpim1
295            miku(ji,jj) = MAX(  mikt(ji+1,jj  ) , mikt(ji,jj)  )
296            mikv(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj)  )
297            mikf(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj), mikt(ji+1,jj  ), mikt(ji+1,jj+1)  )
298            !
299            mbku(ji,jj) = MIN(  mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
300            mbkv(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
301         END DO
302      END DO
303      ! converte into REAL to use lbc_lnk ; impose a min value of 1 as a zero can be set in lbclnk
304      zk(:,:) = REAL( miku(:,:), wp )   ;   CALL lbc_lnk( zk, 'U', 1. )   ;   miku(:,:) = MAX( INT( zk(:,:) ), 1 )
305      zk(:,:) = REAL( mikv(:,:), wp )   ;   CALL lbc_lnk( zk, 'V', 1. )   ;   mikv(:,:) = MAX( INT( zk(:,:) ), 1 )
306      zk(:,:) = REAL( mikf(:,:), wp )   ;   CALL lbc_lnk( zk, 'F', 1. )   ;   mikf(:,:) = MAX( INT( zk(:,:) ), 1 )
307      !
308      zk(:,:) = REAL( mbku(:,:), wp )   ;   CALL lbc_lnk( zk, 'U', 1. )   ;   mbku(:,:) = MAX( INT( zk(:,:) ), 1 )
309      zk(:,:) = REAL( mbkv(:,:), wp )   ;   CALL lbc_lnk( zk, 'V', 1. )   ;   mbkv(:,:) = MAX( INT( zk(:,:) ), 1 )
310      !
311   END SUBROUTINE zgr_top_bot
312
313   !!======================================================================
314END MODULE domzgr
Note: See TracBrowser for help on using the repository browser.