New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DOM/dtatsd.F90 @ 9168

Last change on this file since 9168 was 9168, checked in by gm, 6 years ago

dev_merge_2017: OPA_SRC & CONFIG: remove useless warning when reading namelist_cfg

  • Property svn:keywords set to Id
File size: 13.2 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE phycst          ! physical constants
19   USE dom_oce         ! ocean space and time domain
20   USE fldread         ! read input fields
21   !
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! MPP library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   dta_tsd_init   ! called by opa.F90
29   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
30
31   LOGICAL , PUBLIC ::   ln_tsd_init      !: T & S data flag
32   LOGICAL , PUBLIC ::   ln_tsd_tradmp    !: internal damping toward input data flag
33
34   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
35
36   !!----------------------------------------------------------------------
37   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
38   !! $Id$
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE dta_tsd_init( ld_tradmp )
44      !!----------------------------------------------------------------------
45      !!                   ***  ROUTINE dta_tsd_init  ***
46      !!                   
47      !! ** Purpose :   initialisation of T & S input data
48      !!
49      !! ** Method  : - Read namtsd namelist
50      !!              - allocates T & S data structure
51      !!----------------------------------------------------------------------
52      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
53      !
54      INTEGER ::   ios, ierr0, ierr1, ierr2, ierr3   ! local integers
55      !!
56      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
57      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
58      TYPE(FLD_N)                   ::   sn_tem, sn_sal
59      !!
60      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal
61      !!----------------------------------------------------------------------
62      !
63      !  Initialisation
64      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
65      !
66      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
67      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
68901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtsd in reference namelist', lwp )
69      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
70      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
71902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtsd in configuration namelist', lwp )
72      IF(lwm) WRITE ( numond, namtsd )
73
74      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
75     
76      IF(lwp) THEN                  ! control print
77         WRITE(numout,*)
78         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
79         WRITE(numout,*) '~~~~~~~~~~~~ '
80         WRITE(numout,*) '   Namelist namtsd'
81         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
82         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
83         WRITE(numout,*)
84         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
85            WRITE(numout,*)
86            WRITE(numout,*) '   T & S data not used'
87         ENDIF
88      ENDIF
89      !
90      IF( ln_rstart .AND. ln_tsd_init ) THEN
91         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
92            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
93         ln_tsd_init = .FALSE.
94      ENDIF
95      !
96      !                             ! allocate the arrays (if necessary)
97      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
98         !
99         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
100         IF( ierr0 > 0 ) THEN
101            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
102         ENDIF
103         !
104                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
105         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
106                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
107         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
108         !
109         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
110            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
111         ENDIF
112         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
113         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
114         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd', no_print )
115         !
116      ENDIF
117      !
118   END SUBROUTINE dta_tsd_init
119
120
121   SUBROUTINE dta_tsd( kt, ptsd )
122      !!----------------------------------------------------------------------
123      !!                   ***  ROUTINE dta_tsd  ***
124      !!                   
125      !! ** Purpose :   provides T and S data at kt
126      !!
127      !! ** Method  : - call fldread routine
128      !!              - ORCA_R2: add some hand made alteration to read data 
129      !!              - 'key_orca_lev10' interpolates on 10 times more levels
130      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
131      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
132      !!                as T-S data are no are used
133      !!
134      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
135      !!----------------------------------------------------------------------
136      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
137      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
138      !
139      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
140      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
141      REAL(wp)::   zl, zi                             ! local scalars
142      REAL(wp), DIMENSION(jpk) ::  ztp, zsp   ! 1D workspace
143      !!----------------------------------------------------------------------
144      !
145      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
146      !
147      !
148!!gm  This should be removed from the code   ===>>>>  T & S files has to be changed
149      !
150      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
151      IF( cn_cfg == "orca" .AND. nn_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
152         !
153         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
154         ii0 = 141   ;   ii1 = 155
155         DO jj = mj0(ij0), mj1(ij1)
156            DO ji = mi0(ii0), mi1(ii1)
157               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
158               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
159               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
160               !
161               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
162               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
163               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
164               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
165            END DO
166         END DO
167         ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
168         ii0 = 148   ;   ii1 = 160
169         sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
170         sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
171         sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
172      ENDIF
173!!gm end
174      !
175      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
176      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
177      !
178      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
179         !
180         IF( kt == nit000 .AND. lwp )THEN
181            WRITE(numout,*)
182            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
183         ENDIF
184         !
185         DO jj = 1, jpj                         ! vertical interpolation of T & S
186            DO ji = 1, jpi
187               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
188                  zl = gdept_0(ji,jj,jk)
189                  IF(     zl < gdept_1d(1  ) ) THEN          ! above the first level of data
190                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
191                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
192                  ELSEIF( zl > gdept_1d(jpk) ) THEN          ! below the last level of data
193                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
194                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
195                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
196                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
197                        IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
198                           zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
199                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
200                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
201                        ENDIF
202                     END DO
203                  ENDIF
204               END DO
205               DO jk = 1, jpkm1
206                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
207                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
208               END DO
209               ptsd(ji,jj,jpk,jp_tem) = 0._wp
210               ptsd(ji,jj,jpk,jp_sal) = 0._wp
211            END DO
212         END DO
213         !
214      ELSE                                !==   z- or zps- coordinate   ==!
215         !                             
216         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
217         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
218         !
219         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
220            DO jj = 1, jpj
221               DO ji = 1, jpi
222                  ik = mbkt(ji,jj) 
223                  IF( ik > 1 ) THEN
224                     zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
225                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
226                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
227                  ENDIF
228                  ik = mikt(ji,jj)
229                  IF( ik > 1 ) THEN
230                     zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) 
231                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem)
232                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal)
233                  END IF
234               END DO
235            END DO
236         ENDIF
237         !
238      ENDIF
239      !
240      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
241         !                                              (data used only for initialisation)
242         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
243                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
244         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
245                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
246         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
247                                        DEALLOCATE( sf_tsd              )     ! the structure itself
248      ENDIF
249      !
250   END SUBROUTINE dta_tsd
251
252   !!======================================================================
253END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.