New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 9168

Last change on this file since 9168 was 9168, checked in by gm, 6 years ago

dev_merge_2017: OPA_SRC & CONFIG: remove useless warning when reading namelist_cfg

  • Property svn:keywords set to Id
File size: 70.9 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE wet_dry         ! wetting and drying
36   USE phycst          ! physical constants
37   USE trd_oce         ! trends: ocean variables
38   USE trddyn          ! trend manager: dynamics
39!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
40   !
41   USE in_out_manager  ! I/O manager
42   USE prtctl          ! Print control
43   USE lbclnk          ! lateral boundary condition
44   USE lib_mpp         ! MPP library
45   USE eosbn2          ! compute density
46   USE timing          ! Timing
47   USE iom
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   dyn_hpg        ! routine called by step module
53   PUBLIC   dyn_hpg_init   ! routine called by opa module
54
55   !                                 !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56   LOGICAL , PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
57   LOGICAL , PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
58   LOGICAL , PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
59   LOGICAL , PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
60   LOGICAL , PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
61   LOGICAL , PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "vectopt_loop_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE dyn_hpg( kt )
75      !!---------------------------------------------------------------------
76      !!                  ***  ROUTINE dyn_hpg  ***
77      !!
78      !! ** Method  :   Call the hydrostatic pressure gradient routine
79      !!              using the scheme defined in the namelist
80      !!
81      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
82      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
83      !!----------------------------------------------------------------------
84      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
85      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
86      !!----------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('dyn_hpg')
89      !
90      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
91         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
92         ztrdu(:,:,:) = ua(:,:,:)
93         ztrdv(:,:,:) = va(:,:,:)
94      ENDIF
95      !
96      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
97      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
98      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
99      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
100      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
101      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
102      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
103      END SELECT
104      !
105      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
106         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
107         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
108         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
109         DEALLOCATE( ztrdu , ztrdv )
110      ENDIF
111      !
112      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
113         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
114      !
115      IF( ln_timing )   CALL timing_stop('dyn_hpg')
116      !
117   END SUBROUTINE dyn_hpg
118
119
120   SUBROUTINE dyn_hpg_init
121      !!----------------------------------------------------------------------
122      !!                 ***  ROUTINE dyn_hpg_init  ***
123      !!
124      !! ** Purpose :   initializations for the hydrostatic pressure gradient
125      !!              computation and consistency control
126      !!
127      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
128      !!      with the type of vertical coordinate used (zco, zps, sco)
129      !!----------------------------------------------------------------------
130      INTEGER ::   ioptio = 0      ! temporary integer
131      INTEGER ::   ios             ! Local integer output status for namelist read
132      !!
133      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
134      REAL(wp) ::   znad
135      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
136      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
137      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
138      !!
139      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
140         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
141      !!----------------------------------------------------------------------
142      !
143      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
144      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
145901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
146      !
147      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
148      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
149902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
150      IF(lwm) WRITE ( numond, namdyn_hpg )
151      !
152      IF(lwp) THEN                   ! Control print
153         WRITE(numout,*)
154         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
155         WRITE(numout,*) '~~~~~~~~~~~~'
156         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
157         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
158         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
159         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
160         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
161         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
162         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
163      ENDIF
164      !
165      IF( ln_hpg_djc )   &
166         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
167         &                 '   currently disabled (bugs under investigation).'        ,   &
168         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
169         !
170      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
171         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
172         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
173         &                 '   the pressure jacobian formulation hpg_prj'             )
174         !
175      IF( ln_hpg_isf ) THEN
176         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
177       ELSE
178         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
179      ENDIF
180      !
181      !                               ! Set nhpg from ln_hpg_... flags
182      IF( ln_hpg_zco )   nhpg = 0
183      IF( ln_hpg_zps )   nhpg = 1
184      IF( ln_hpg_sco )   nhpg = 2
185      IF( ln_hpg_djc )   nhpg = 3
186      IF( ln_hpg_prj )   nhpg = 4
187      IF( ln_hpg_isf )   nhpg = 5
188      !
189      !                               ! Consistency check
190      ioptio = 0
191      IF( ln_hpg_zco )   ioptio = ioptio + 1
192      IF( ln_hpg_zps )   ioptio = ioptio + 1
193      IF( ln_hpg_sco )   ioptio = ioptio + 1
194      IF( ln_hpg_djc )   ioptio = ioptio + 1
195      IF( ln_hpg_prj )   ioptio = ioptio + 1
196      IF( ln_hpg_isf )   ioptio = ioptio + 1
197      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
198      !
199      !                         
200      IF ( .NOT. ln_isfcav ) THEN     !--- no ice shelf load
201         riceload(:,:) = 0._wp
202         !
203      ELSE                            !--- set an ice shelf load
204         !
205         IF(lwp) WRITE(numout,*)
206         IF(lwp) WRITE(numout,*) '   ice shelf case: set the ice-shelf load'
207         ALLOCATE( zts_top(jpi,jpj,jpts) , zrhd(jpi,jpj,jpk) , zrhdtop_isf(jpi,jpj) , ziceload(jpi,jpj) ) 
208         !
209         znad = 1._wp                     !- To use density and not density anomaly
210         !
211         !                                !- assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
212         zts_top(:,:,jp_tem) = -1.9_wp   ;   zts_top(:,:,jp_sal) = 34.4_wp
213         !
214         DO jk = 1, jpk                   !- compute density of the water displaced by the ice shelf
215            CALL eos( zts_top(:,:,:), gdept_n(:,:,jk), zrhd(:,:,jk) )
216         END DO
217         !
218         !                                !- compute rhd at the ice/oce interface (ice shelf side)
219         CALL eos( zts_top , risfdep, zrhdtop_isf )
220         !
221         !                                !- Surface value + ice shelf gradient
222         ziceload = 0._wp                       ! compute pressure due to ice shelf load
223         DO jj = 1, jpj                         ! (used to compute hpgi/j for all the level from 1 to miku/v)
224            DO ji = 1, jpi                      ! divided by 2 later
225               ikt = mikt(ji,jj)
226               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * e3w_n(ji,jj,1) * (1._wp - tmask(ji,jj,1))
227               DO jk = 2, ikt-1
228                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * e3w_n(ji,jj,jk) &
229                     &                              * (1._wp - tmask(ji,jj,jk))
230               END DO
231               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
232                  &                                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
233            END DO
234         END DO
235         riceload(:,:) = ziceload(:,:)  ! need to be saved for diaar5
236         !
237         DEALLOCATE( zts_top , zrhd , zrhdtop_isf , ziceload ) 
238      ENDIF
239      !
240   END SUBROUTINE dyn_hpg_init
241
242
243   SUBROUTINE hpg_zco( kt )
244      !!---------------------------------------------------------------------
245      !!                  ***  ROUTINE hpg_zco  ***
246      !!
247      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
248      !!      The now hydrostatic pressure gradient at a given level, jk,
249      !!      is computed by taking the vertical integral of the in-situ
250      !!      density gradient along the model level from the suface to that
251      !!      level:    zhpi = grav .....
252      !!                zhpj = grav .....
253      !!      add it to the general momentum trend (ua,va).
254      !!            ua = ua - 1/e1u * zhpi
255      !!            va = va - 1/e2v * zhpj
256      !!
257      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
258      !!----------------------------------------------------------------------
259      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
260      !
261      INTEGER  ::   ji, jj, jk       ! dummy loop indices
262      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
263      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
264      !!----------------------------------------------------------------------
265      !
266      IF( kt == nit000 ) THEN
267         IF(lwp) WRITE(numout,*)
268         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
269         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
270      ENDIF
271
272      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
273
274      ! Surface value
275      DO jj = 2, jpjm1
276         DO ji = fs_2, fs_jpim1   ! vector opt.
277            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
278            ! hydrostatic pressure gradient
279            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
280            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
281            ! add to the general momentum trend
282            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
283            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
284         END DO
285      END DO
286
287      !
288      ! interior value (2=<jk=<jpkm1)
289      DO jk = 2, jpkm1
290         DO jj = 2, jpjm1
291            DO ji = fs_2, fs_jpim1   ! vector opt.
292               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
293               ! hydrostatic pressure gradient
294               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
295                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
296                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
297
298               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
299                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
300                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
301               ! add to the general momentum trend
302               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
303               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
304            END DO
305         END DO
306      END DO
307      !
308   END SUBROUTINE hpg_zco
309
310
311   SUBROUTINE hpg_zps( kt )
312      !!---------------------------------------------------------------------
313      !!                 ***  ROUTINE hpg_zps  ***
314      !!
315      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
316      !!
317      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
318      !!----------------------------------------------------------------------
319      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
320      !!
321      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
322      INTEGER  ::   iku, ikv                         ! temporary integers
323      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
324      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
325      !!----------------------------------------------------------------------
326      !
327      IF( kt == nit000 ) THEN
328         IF(lwp) WRITE(numout,*)
329         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
330         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
331      ENDIF
332
333      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
334!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
335
336      ! Local constant initialization
337      zcoef0 = - grav * 0.5_wp
338
339      !  Surface value (also valid in partial step case)
340      DO jj = 2, jpjm1
341         DO ji = fs_2, fs_jpim1   ! vector opt.
342            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
343            ! hydrostatic pressure gradient
344            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
345            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
346            ! add to the general momentum trend
347            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
348            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
349         END DO
350      END DO
351
352      ! interior value (2=<jk=<jpkm1)
353      DO jk = 2, jpkm1
354         DO jj = 2, jpjm1
355            DO ji = fs_2, fs_jpim1   ! vector opt.
356               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
357               ! hydrostatic pressure gradient
358               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
359                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
360                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
361
362               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
363                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
364                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
365               ! add to the general momentum trend
366               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
367               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
368            END DO
369         END DO
370      END DO
371
372      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
373      DO jj = 2, jpjm1
374         DO ji = 2, jpim1
375            iku = mbku(ji,jj)
376            ikv = mbkv(ji,jj)
377            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
378            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
379            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
380               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
381               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
382                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
383               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
384            ENDIF
385            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
386               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
387               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
388                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
389               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
390            ENDIF
391         END DO
392      END DO
393      !
394   END SUBROUTINE hpg_zps
395
396
397   SUBROUTINE hpg_sco( kt )
398      !!---------------------------------------------------------------------
399      !!                  ***  ROUTINE hpg_sco  ***
400      !!
401      !! ** Method  :   s-coordinate case. Jacobian scheme.
402      !!      The now hydrostatic pressure gradient at a given level, jk,
403      !!      is computed by taking the vertical integral of the in-situ
404      !!      density gradient along the model level from the suface to that
405      !!      level. s-coordinates (ln_sco): a corrective term is added
406      !!      to the horizontal pressure gradient :
407      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
408      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
409      !!      add it to the general momentum trend (ua,va).
410      !!         ua = ua - 1/e1u * zhpi
411      !!         va = va - 1/e2v * zhpj
412      !!
413      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
414      !!----------------------------------------------------------------------
415      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
416      !!
417      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
418      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
419      LOGICAL  ::   ll_tmp1, ll_tmp2                     ! local logical variables
420      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
421      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
422      !!----------------------------------------------------------------------
423      !
424      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
425      !
426      IF( kt == nit000 ) THEN
427         IF(lwp) WRITE(numout,*)
428         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
429         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
430      ENDIF
431      !
432      zcoef0 = - grav * 0.5_wp
433      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
434      ELSE                    ;   znad = 1._wp         ! Variable volume: density
435      ENDIF
436      !
437      IF( ln_wd_il ) THEN
438        DO jj = 2, jpjm1
439           DO ji = 2, jpim1 
440             ll_tmp1 = MIN(  sshn(ji,jj)               ,  sshn(ji+1,jj) ) >                &
441                  &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
442                  &    MAX(  sshn(ji,jj) +  ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
443                  &                                                       > rn_wdmin1 + rn_wdmin2
444             ll_tmp2 = ( ABS( sshn(ji,jj)              -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (       &
445                  &    MAX(   sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
446                  &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
447
448             IF(ll_tmp1) THEN
449               zcpx(ji,jj) = 1.0_wp
450             ELSE IF(ll_tmp2) THEN
451               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
452               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
453                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
454             ELSE
455               zcpx(ji,jj) = 0._wp
456             END IF
457     
458             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
459                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
460                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
461                  &                                                      > rn_wdmin1 + rn_wdmin2
462             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
463                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
464                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
465
466             IF(ll_tmp1) THEN
467               zcpy(ji,jj) = 1.0_wp
468             ELSE IF(ll_tmp2) THEN
469               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
470               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
471                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
472             ELSE
473               zcpy(ji,jj) = 0._wp
474             END IF
475           END DO
476        END DO
477        CALL lbc_lnk_multi( zcpx, 'U', 1., zcpy, 'V', 1. )
478      END IF
479
480      ! Surface value
481      DO jj = 2, jpjm1
482         DO ji = fs_2, fs_jpim1   ! vector opt.
483            ! hydrostatic pressure gradient along s-surfaces
484            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
485               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
486            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
487               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
488            ! s-coordinate pressure gradient correction
489            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
490               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
491            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
492               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
493            !
494            IF( ln_wd_il ) THEN
495               zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
496               zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
497               zuap = zuap * zcpx(ji,jj)
498               zvap = zvap * zcpy(ji,jj)
499            ENDIF
500            !
501            ! add to the general momentum trend
502            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
503            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
504         END DO
505      END DO
506
507      ! interior value (2=<jk=<jpkm1)
508      DO jk = 2, jpkm1
509         DO jj = 2, jpjm1
510            DO ji = fs_2, fs_jpim1   ! vector opt.
511               ! hydrostatic pressure gradient along s-surfaces
512               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
513                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
514                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
515               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
516                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
517                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
518               ! s-coordinate pressure gradient correction
519               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
520                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
521               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
522                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
523               !
524               IF( ln_wd_il ) THEN
525                  zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
526                  zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
527                  zuap = zuap * zcpx(ji,jj)
528                  zvap = zvap * zcpy(ji,jj)
529               ENDIF
530               !
531               ! add to the general momentum trend
532               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
533               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
534            END DO
535         END DO
536      END DO
537      !
538      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
539      !
540   END SUBROUTINE hpg_sco
541
542
543   SUBROUTINE hpg_isf( kt )
544      !!---------------------------------------------------------------------
545      !!                  ***  ROUTINE hpg_isf  ***
546      !!
547      !! ** Method  :   s-coordinate case. Jacobian scheme.
548      !!      The now hydrostatic pressure gradient at a given level, jk,
549      !!      is computed by taking the vertical integral of the in-situ
550      !!      density gradient along the model level from the suface to that
551      !!      level. s-coordinates (ln_sco): a corrective term is added
552      !!      to the horizontal pressure gradient :
553      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
554      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
555      !!      add it to the general momentum trend (ua,va).
556      !!         ua = ua - 1/e1u * zhpi
557      !!         va = va - 1/e2v * zhpj
558      !!      iceload is added and partial cell case are added to the top and bottom
559      !!     
560      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
561      !!----------------------------------------------------------------------
562      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
563      !!
564      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
565      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
566      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
567      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
568      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
569      !!----------------------------------------------------------------------
570      !
571      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
572      !
573      znad=1._wp                 ! To use density and not density anomaly
574      !
575      !                          ! iniitialised to 0. zhpi zhpi
576      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
577
578      ! compute rhd at the ice/oce interface (ocean side)
579      ! usefull to reduce residual current in the test case ISOMIP with no melting
580      DO ji = 1, jpi
581        DO jj = 1, jpj
582          ikt = mikt(ji,jj)
583          zts_top(ji,jj,1) = tsn(ji,jj,ikt,1)
584          zts_top(ji,jj,2) = tsn(ji,jj,ikt,2)
585        END DO
586      END DO
587      CALL eos( zts_top, risfdep, zrhdtop_oce )
588
589!==================================================================================     
590!===== Compute surface value =====================================================
591!==================================================================================
592      DO jj = 2, jpjm1
593         DO ji = fs_2, fs_jpim1   ! vector opt.
594            ikt    = mikt(ji,jj)
595            iktp1i = mikt(ji+1,jj)
596            iktp1j = mikt(ji,jj+1)
597            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
598            ! we assume ISF is in isostatic equilibrium
599            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
600               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
601               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
602               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
603               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
604            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
605               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
606               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
607               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
608               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
609            ! s-coordinate pressure gradient correction (=0 if z coordinate)
610            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
611               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
612            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
613               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
614            ! add to the general momentum trend
615            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
616            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
617         END DO
618      END DO
619!==================================================================================     
620!===== Compute interior value =====================================================
621!==================================================================================
622      ! interior value (2=<jk=<jpkm1)
623      DO jk = 2, jpkm1
624         DO jj = 2, jpjm1
625            DO ji = fs_2, fs_jpim1   ! vector opt.
626               ! hydrostatic pressure gradient along s-surfaces
627               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
628                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
629                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
630               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
631                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
632                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
633               ! s-coordinate pressure gradient correction
634               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
635                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
636               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
637                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
638               ! add to the general momentum trend
639               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
640               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
641            END DO
642         END DO
643      END DO
644      !
645   END SUBROUTINE hpg_isf
646
647
648   SUBROUTINE hpg_djc( kt )
649      !!---------------------------------------------------------------------
650      !!                  ***  ROUTINE hpg_djc  ***
651      !!
652      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
653      !!
654      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
655      !!----------------------------------------------------------------------
656      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
657      !!
658      INTEGER  ::   ji, jj, jk          ! dummy loop indices
659      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
660      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
661      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
662      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
663      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
664      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
665      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
666      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
667      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
668      !!----------------------------------------------------------------------
669      !
670      IF( ln_wd_il ) THEN
671         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
672        DO jj = 2, jpjm1
673           DO ji = 2, jpim1 
674             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
675                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
676                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
677                  &                                                      > rn_wdmin1 + rn_wdmin2
678             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (        &
679                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
680                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
681             IF(ll_tmp1) THEN
682               zcpx(ji,jj) = 1.0_wp
683             ELSE IF(ll_tmp2) THEN
684               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
685               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
686                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
687             ELSE
688               zcpx(ji,jj) = 0._wp
689             END IF
690     
691             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
692                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
693                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
694                  &                                                      > rn_wdmin1 + rn_wdmin2
695             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
696                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
697                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
698
699             IF(ll_tmp1) THEN
700               zcpy(ji,jj) = 1.0_wp
701             ELSE IF(ll_tmp2) THEN
702               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
703               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
704                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
705             ELSE
706               zcpy(ji,jj) = 0._wp
707             END IF
708           END DO
709        END DO
710        CALL lbc_lnk_multi( zcpx, 'U', 1., zcpy, 'V', 1. )
711      END IF
712
713      IF( kt == nit000 ) THEN
714         IF(lwp) WRITE(numout,*)
715         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
716         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
717      ENDIF
718
719      ! Local constant initialization
720      zcoef0 = - grav * 0.5_wp
721      z1_10  = 1._wp / 10._wp
722      z1_12  = 1._wp / 12._wp
723
724      !----------------------------------------------------------------------------------------
725      !  compute and store in provisional arrays elementary vertical and horizontal differences
726      !----------------------------------------------------------------------------------------
727
728!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
729
730      DO jk = 2, jpkm1
731         DO jj = 2, jpjm1
732            DO ji = fs_2, fs_jpim1   ! vector opt.
733               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
734               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
735               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
736               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
737               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
738               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
739            END DO
740         END DO
741      END DO
742
743      !-------------------------------------------------------------------------
744      ! compute harmonic averages using eq. 5.18
745      !-------------------------------------------------------------------------
746      zep = 1.e-15
747
748!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
749!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
750
751      DO jk = 2, jpkm1
752         DO jj = 2, jpjm1
753            DO ji = fs_2, fs_jpim1   ! vector opt.
754               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
755
756               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
757               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
758
759               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
760               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
761
762               IF( cffw > zep) THEN
763                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
764                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
765               ELSE
766                  drhow(ji,jj,jk) = 0._wp
767               ENDIF
768
769               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
770                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
771
772               IF( cffu > zep ) THEN
773                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
774                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
775               ELSE
776                  drhou(ji,jj,jk ) = 0._wp
777               ENDIF
778
779               IF( cffx > zep ) THEN
780                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
781                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
782               ELSE
783                  dzu(ji,jj,jk) = 0._wp
784               ENDIF
785
786               IF( cffv > zep ) THEN
787                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
788                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
789               ELSE
790                  drhov(ji,jj,jk) = 0._wp
791               ENDIF
792
793               IF( cffy > zep ) THEN
794                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
795                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
796               ELSE
797                  dzv(ji,jj,jk) = 0._wp
798               ENDIF
799
800            END DO
801         END DO
802      END DO
803
804      !----------------------------------------------------------------------------------
805      ! apply boundary conditions at top and bottom using 5.36-5.37
806      !----------------------------------------------------------------------------------
807      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
808      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
809      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
810
811      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
812      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
813      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
814
815
816      !--------------------------------------------------------------
817      ! Upper half of top-most grid box, compute and store
818      !-------------------------------------------------------------
819
820!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
821!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
822
823      DO jj = 2, jpjm1
824         DO ji = fs_2, fs_jpim1   ! vector opt.
825            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
826               &                   * (  rhd(ji,jj,1)                                     &
827               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
828               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
829               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
830         END DO
831      END DO
832
833!!bug gm    : here also, simplification is possible
834!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
835
836      DO jk = 2, jpkm1
837         DO jj = 2, jpjm1
838            DO ji = fs_2, fs_jpim1   ! vector opt.
839
840               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
841                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
842                  &            - grav * z1_10 * (                                                                   &
843                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
844                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
845                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
846                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
847                  &                             )
848
849               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
850                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
851                  &            - grav* z1_10 * (                                                                    &
852                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
853                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
854                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
855                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
856                  &                            )
857
858               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
859                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
860                  &            - grav* z1_10 * (                                                                    &
861                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
862                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
863                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
864                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
865                  &                            )
866
867            END DO
868         END DO
869      END DO
870      CALL lbc_lnk_multi( rho_k, 'W', 1., rho_i, 'U', 1., rho_j, 'V', 1. )
871
872      ! ---------------
873      !  Surface value
874      ! ---------------
875      DO jj = 2, jpjm1
876         DO ji = fs_2, fs_jpim1   ! vector opt.
877            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
878            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
879            IF( ln_wd_il ) THEN
880              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
881              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
882            ENDIF
883            ! add to the general momentum trend
884            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
885            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
886         END DO
887      END DO
888
889      ! ----------------
890      !  interior value   (2=<jk=<jpkm1)
891      ! ----------------
892      DO jk = 2, jpkm1
893         DO jj = 2, jpjm1
894            DO ji = fs_2, fs_jpim1   ! vector opt.
895               ! hydrostatic pressure gradient along s-surfaces
896               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
897                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
898                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
899               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
900                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
901                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
902               IF( ln_wd_il ) THEN
903                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
904                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
905               ENDIF
906               ! add to the general momentum trend
907               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
908               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
909            END DO
910         END DO
911      END DO
912      !
913      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
914      !
915   END SUBROUTINE hpg_djc
916
917
918   SUBROUTINE hpg_prj( kt )
919      !!---------------------------------------------------------------------
920      !!                  ***  ROUTINE hpg_prj  ***
921      !!
922      !! ** Method  :   s-coordinate case.
923      !!      A Pressure-Jacobian horizontal pressure gradient method
924      !!      based on the constrained cubic-spline interpolation for
925      !!      all vertical coordinate systems
926      !!
927      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
928      !!----------------------------------------------------------------------
929      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
930      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
931      !!
932      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
933      REAL(wp) ::   zcoef0, znad                    ! local scalars
934      !
935      !! The local variables for the correction term
936      INTEGER  :: jk1, jis, jid, jjs, jjd
937      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
938      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
939      REAL(wp) :: zrhdt1
940      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
941      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
942      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
943      REAL(wp), DIMENSION(jpi,jpj)   ::   zsshu_n, zsshv_n
944      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
945      !!----------------------------------------------------------------------
946      !
947      IF( kt == nit000 ) THEN
948         IF(lwp) WRITE(numout,*)
949         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
950         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
951      ENDIF
952
953      ! Local constant initialization
954      zcoef0 = - grav
955      znad = 1._wp
956      IF( ln_linssh )   znad = 0._wp
957
958      IF( ln_wd_il ) THEN
959         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
960         DO jj = 2, jpjm1
961           DO ji = 2, jpim1 
962             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
963                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
964                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
965                  &                                                      > rn_wdmin1 + rn_wdmin2
966             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (         &
967                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
968                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
969
970             IF(ll_tmp1) THEN
971               zcpx(ji,jj) = 1.0_wp
972             ELSE IF(ll_tmp2) THEN
973               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
974               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
975                           &    / (sshn(ji+1,jj) -  sshn(ji  ,jj)) )
976             
977                zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
978             ELSE
979               zcpx(ji,jj) = 0._wp
980             END IF
981     
982             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
983                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
984                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
985                  &                                                      > rn_wdmin1 + rn_wdmin2
986             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (      &
987                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
988                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
989
990             IF(ll_tmp1) THEN
991               zcpy(ji,jj) = 1.0_wp
992             ELSE IF(ll_tmp2) THEN
993               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
994               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
995                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
996                zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
997
998               ELSE
999                  zcpy(ji,jj) = 0._wp
1000               ENDIF
1001            END DO
1002         END DO
1003         CALL lbc_lnk_multi( zcpx, 'U', 1., zcpy, 'V', 1. )
1004      ENDIF
1005
1006      ! Clean 3-D work arrays
1007      zhpi(:,:,:) = 0._wp
1008      zrhh(:,:,:) = rhd(:,:,:)
1009
1010      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1011      DO jj = 1, jpj
1012        DO ji = 1, jpi
1013          jk = mbkt(ji,jj)+1
1014          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1015          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1016          ELSEIF( jk < jpkm1 ) THEN
1017             DO jkk = jk+1, jpk
1018                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
1019                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1020             END DO
1021          ENDIF
1022        END DO
1023      END DO
1024
1025      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1026      DO jj = 1, jpj
1027         DO ji = 1, jpi
1028            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1029         END DO
1030      END DO
1031
1032      DO jk = 2, jpk
1033         DO jj = 1, jpj
1034            DO ji = 1, jpi
1035               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1036            END DO
1037         END DO
1038      END DO
1039
1040      fsp(:,:,:) = zrhh (:,:,:)
1041      xsp(:,:,:) = zdept(:,:,:)
1042
1043      ! Construct the vertical density profile with the
1044      ! constrained cubic spline interpolation
1045      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1046      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1047
1048      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1049      DO jj = 2, jpj
1050        DO ji = 2, jpi
1051          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1052             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1053
1054          ! assuming linear profile across the top half surface layer
1055          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1056        END DO
1057      END DO
1058
1059      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1060      DO jk = 2, jpkm1
1061        DO jj = 2, jpj
1062          DO ji = 2, jpi
1063            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1064               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1065               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1066               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1067          END DO
1068        END DO
1069      END DO
1070
1071      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1072
1073      ! Prepare zsshu_n and zsshv_n
1074      DO jj = 2, jpjm1
1075        DO ji = 2, jpim1
1076!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1077!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1078!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1079!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1080!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1081!!gm not this:
1082          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1083                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1084          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1085                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1086        END DO
1087      END DO
1088
1089      CALL lbc_lnk_multi (zsshu_n, 'U', 1., zsshv_n, 'V', 1. )
1090
1091      DO jj = 2, jpjm1
1092        DO ji = 2, jpim1
1093          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1094          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1095        END DO
1096      END DO
1097
1098      DO jk = 2, jpkm1
1099        DO jj = 2, jpjm1
1100          DO ji = 2, jpim1
1101            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1102            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1103          END DO
1104        END DO
1105      END DO
1106
1107      DO jk = 1, jpkm1
1108        DO jj = 2, jpjm1
1109          DO ji = 2, jpim1
1110            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1111            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1112          END DO
1113        END DO
1114      END DO
1115
1116      DO jk = 1, jpkm1
1117        DO jj = 2, jpjm1
1118          DO ji = 2, jpim1
1119            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1120            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1121            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1122            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1123          END DO
1124        END DO
1125      END DO
1126
1127
1128      DO jk = 1, jpkm1
1129        DO jj = 2, jpjm1
1130          DO ji = 2, jpim1
1131            zpwes = 0._wp; zpwed = 0._wp
1132            zpnss = 0._wp; zpnsd = 0._wp
1133            zuijk = zu(ji,jj,jk)
1134            zvijk = zv(ji,jj,jk)
1135
1136            !!!!!     for u equation
1137            IF( jk <= mbku(ji,jj) ) THEN
1138               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1139                 jis = ji + 1; jid = ji
1140               ELSE
1141                 jis = ji;     jid = ji +1
1142               ENDIF
1143
1144               ! integrate the pressure on the shallow side
1145               jk1 = jk
1146               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1147                 IF( jk1 == mbku(ji,jj) ) THEN
1148                   zuijk = -zdept(jis,jj,jk1)
1149                   EXIT
1150                 ENDIF
1151                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1152                 zpwes = zpwes +                                    &
1153                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1154                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1155                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1156                 jk1 = jk1 + 1
1157               END DO
1158
1159               ! integrate the pressure on the deep side
1160               jk1 = jk
1161               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1162                 IF( jk1 == 1 ) THEN
1163                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1164                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1165                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1166                                                     dsp(jid,jj,1)) * zdeps
1167                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1168                   EXIT
1169                 ENDIF
1170                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1171                 zpwed = zpwed +                                        &
1172                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1173                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1174                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1175                 jk1 = jk1 - 1
1176               END DO
1177
1178               ! update the momentum trends in u direction
1179
1180               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1181               IF( .NOT.ln_linssh ) THEN
1182                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1183                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1184                ELSE
1185                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1186               ENDIF
1187               IF( ln_wd_il ) THEN
1188                  zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1189                  zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1190               ENDIF
1191               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1192            ENDIF
1193
1194            !!!!!     for v equation
1195            IF( jk <= mbkv(ji,jj) ) THEN
1196               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1197                 jjs = jj + 1; jjd = jj
1198               ELSE
1199                 jjs = jj    ; jjd = jj + 1
1200               ENDIF
1201
1202               ! integrate the pressure on the shallow side
1203               jk1 = jk
1204               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1205                 IF( jk1 == mbkv(ji,jj) ) THEN
1206                   zvijk = -zdept(ji,jjs,jk1)
1207                   EXIT
1208                 ENDIF
1209                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1210                 zpnss = zpnss +                                      &
1211                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1212                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1213                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1214                 jk1 = jk1 + 1
1215               END DO
1216
1217               ! integrate the pressure on the deep side
1218               jk1 = jk
1219               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1220                 IF( jk1 == 1 ) THEN
1221                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1222                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1223                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1224                                                     dsp(ji,jjd,1) ) * zdeps
1225                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1226                   EXIT
1227                 ENDIF
1228                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1229                 zpnsd = zpnsd +                                        &
1230                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1231                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1232                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1233                 jk1 = jk1 - 1
1234               END DO
1235
1236
1237               ! update the momentum trends in v direction
1238
1239               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1240               IF( .NOT.ln_linssh ) THEN
1241                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1242                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1243               ELSE
1244                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1245               ENDIF
1246               IF( ln_wd_il ) THEN
1247                  zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1248                  zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1249               ENDIF
1250
1251               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1252            ENDIF
1253               !
1254            END DO
1255         END DO
1256      END DO
1257      !
1258      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1259      !
1260   END SUBROUTINE hpg_prj
1261
1262
1263   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1264      !!----------------------------------------------------------------------
1265      !!                 ***  ROUTINE cspline  ***
1266      !!
1267      !! ** Purpose :   constrained cubic spline interpolation
1268      !!
1269      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1270      !!
1271      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1272      !!----------------------------------------------------------------------
1273      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1274      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1275      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1276      !
1277      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1278      INTEGER  ::   jpi, jpj, jpkm1
1279      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1280      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1281      REAL(wp) ::   zdf(size(fsp,3))
1282      !!----------------------------------------------------------------------
1283      !
1284!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1285      jpi   = size(fsp,1)
1286      jpj   = size(fsp,2)
1287      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1288      !
1289      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1290         DO ji = 1, jpi
1291            DO jj = 1, jpj
1292           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1293           !    DO jk = 2, jpkm1-1
1294           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1295           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1296           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1297           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1298           !
1299           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1300           !
1301           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1302           !           zdf(jk) = 0._wp
1303           !       ELSE
1304           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1305           !       ENDIF
1306           !    END DO
1307
1308           !!Simply geometric average
1309               DO jk = 2, jpkm1-1
1310                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1311                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1312
1313                  IF(zdf1 * zdf2 <= 0._wp) THEN
1314                     zdf(jk) = 0._wp
1315                  ELSE
1316                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1317                  ENDIF
1318               END DO
1319
1320               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1321                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1322               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1323                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1324
1325               DO jk = 1, jpkm1 - 1
1326                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1327                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1328                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1329                 zddf1  = -2._wp * ztmp1 + ztmp2
1330                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1331                 zddf2  =  2._wp * ztmp1 - ztmp2
1332
1333                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1334                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1335                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1336                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1337                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1338                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1339                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1340                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1341                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1342               END DO
1343            END DO
1344         END DO
1345
1346      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1347         DO ji = 1, jpi
1348            DO jj = 1, jpj
1349               DO jk = 1, jpkm1-1
1350                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1351                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1352
1353                  dsp(ji,jj,jk) = 0._wp
1354                  csp(ji,jj,jk) = 0._wp
1355                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1356                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1357               END DO
1358            END DO
1359         END DO
1360         !
1361      ELSE
1362         CALL ctl_stop( 'invalid polynomial type in cspline' )
1363      ENDIF
1364      !
1365   END SUBROUTINE cspline
1366
1367
1368   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1369      !!----------------------------------------------------------------------
1370      !!                 ***  ROUTINE interp1  ***
1371      !!
1372      !! ** Purpose :   1-d linear interpolation
1373      !!
1374      !! ** Method  :   interpolation is straight forward
1375      !!                extrapolation is also permitted (no value limit)
1376      !!----------------------------------------------------------------------
1377      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1378      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1379      REAL(wp)             ::  zdeltx
1380      !!----------------------------------------------------------------------
1381      !
1382      zdeltx = xr - xl
1383      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1384         f = 0.5_wp * (fl + fr)
1385      ELSE
1386         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1387      ENDIF
1388      !
1389   END FUNCTION interp1
1390
1391
1392   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1393      !!----------------------------------------------------------------------
1394      !!                 ***  ROUTINE interp1  ***
1395      !!
1396      !! ** Purpose :   1-d constrained cubic spline interpolation
1397      !!
1398      !! ** Method  :  cubic spline interpolation
1399      !!
1400      !!----------------------------------------------------------------------
1401      REAL(wp), INTENT(in) ::  x, a, b, c, d
1402      REAL(wp)             ::  f ! value from the interpolation
1403      !!----------------------------------------------------------------------
1404      !
1405      f = a + x* ( b + x * ( c + d * x ) )
1406      !
1407   END FUNCTION interp2
1408
1409
1410   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1411      !!----------------------------------------------------------------------
1412      !!                 ***  ROUTINE interp1  ***
1413      !!
1414      !! ** Purpose :   Calculate the first order of derivative of
1415      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1416      !!
1417      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1418      !!
1419      !!----------------------------------------------------------------------
1420      REAL(wp), INTENT(in) ::  x, a, b, c, d
1421      REAL(wp)             ::  f ! value from the interpolation
1422      !!----------------------------------------------------------------------
1423      !
1424      f = b + x * ( 2._wp * c + 3._wp * d * x)
1425      !
1426   END FUNCTION interp3
1427
1428
1429   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1430      !!----------------------------------------------------------------------
1431      !!                 ***  ROUTINE interp1  ***
1432      !!
1433      !! ** Purpose :   1-d constrained cubic spline integration
1434      !!
1435      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1436      !!
1437      !!----------------------------------------------------------------------
1438      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1439      REAL(wp)             ::  za1, za2, za3
1440      REAL(wp)             ::  f                   ! integration result
1441      !!----------------------------------------------------------------------
1442      !
1443      za1 = 0.5_wp * b
1444      za2 = c / 3.0_wp
1445      za3 = 0.25_wp * d
1446      !
1447      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1448         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1449      !
1450   END FUNCTION integ_spline
1451
1452   !!======================================================================
1453END MODULE dynhpg
1454
Note: See TracBrowser for help on using the repository browser.