New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_lap_blp.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/DYN/dynldf_lap_blp.F90 @ 9090

Last change on this file since 9090 was 9090, checked in by flavoni, 6 years ago

change lbc_lnk in lbc_lnk_multi
  • Property svn:keywords set to Id
File size: 8.1 KB
Line 
1MODULE dynldf_lap_blp
2   !!======================================================================
3   !!                   ***  MODULE  dynldf_lap_blp  ***
4   !! Ocean dynamics:  lateral viscosity trend (laplacian and bilaplacian)
5   !!======================================================================
6   !! History : 3.7  ! 2014-01  (G. Madec, S. Masson)  Original code, re-entrant laplacian
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dyn_ldf_lap   : update the momentum trend with the lateral viscosity using an iso-level   laplacian operator
11   !!   dyn_ldf_blp   : update the momentum trend with the lateral viscosity using an iso-level bilaplacian operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ldfdyn         ! lateral diffusion: eddy viscosity coef.
16   USE ldfslp         ! iso-neutral slopes
17   USE zdf_oce        ! ocean vertical physics
18   !
19   USE in_out_manager ! I/O manager
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE timing         ! Timing
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC dyn_ldf_lap  ! called by dynldf.F90
27   PUBLIC dyn_ldf_blp  ! called by dynldf.F90
28
29   !! * Substitutions
30#  include "vectopt_loop_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 4.0 , NEMO Consortium (2017)
33   !! $Id$
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE dyn_ldf_lap( kt, pub, pvb, pua, pva, kpass )
39      !!----------------------------------------------------------------------
40      !!                     ***  ROUTINE dyn_ldf_lap  ***
41      !!                       
42      !! ** Purpose :   Compute the before horizontal momentum diffusive
43      !!      trend and add it to the general trend of momentum equation.
44      !!
45      !! ** Method  :   The Laplacian operator apply on horizontal velocity is
46      !!      writen as :   grad_h( ahmt div_h(U )) - curl_h( ahmf curl_z(U) )
47      !!
48      !! ** Action : - pua, pva increased by the harmonic operator applied on pub, pvb.
49      !!----------------------------------------------------------------------
50      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
51      INTEGER                         , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
52      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pub, pvb   ! before velocity  [m/s]
53      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! velocity trend   [m/s2]
54      !
55      INTEGER  ::   ji, jj, jk   ! dummy loop indices
56      REAL(wp) ::   zsign        ! local scalars
57      REAL(wp) ::   zua, zva     ! local scalars
58      REAL(wp), DIMENSION(jpi,jpj) ::   zcur, zdiv
59      !!----------------------------------------------------------------------
60      !
61      IF( kt == nit000 .AND. lwp ) THEN
62         WRITE(numout,*)
63         WRITE(numout,*) 'dyn_ldf : iso-level harmonic (laplacian) operator, pass=', kpass
64         WRITE(numout,*) '~~~~~~~ '
65      ENDIF
66      !
67      IF( ln_timing )   CALL timing_start('dyn_ldf_lap')
68      !
69      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign
70      ELSE                    ;   zsign = -1._wp      !  (eddy viscosity coef. >0)
71      ENDIF
72      !
73      !                                                ! ===============
74      DO jk = 1, jpkm1                                 ! Horizontal slab
75         !                                             ! ===============
76         DO jj = 2, jpj
77            DO ji = fs_2, jpi   ! vector opt.
78               !                                      ! ahm * e3 * curl  (computed from 1 to jpim1/jpjm1)
79!!gm open question here : e3f  at before or now ?    probably now...
80!!gm note that ahmf has already been multiplied by fmask
81               zcur(ji-1,jj-1) = ahmf(ji-1,jj-1,jk) * e3f_n(ji-1,jj-1,jk) * r1_e1e2f(ji-1,jj-1)       &
82                  &     * (  e2v(ji  ,jj-1) * pvb(ji  ,jj-1,jk) - e2v(ji-1,jj-1) * pvb(ji-1,jj-1,jk)  &
83                  &        - e1u(ji-1,jj  ) * pub(ji-1,jj  ,jk) + e1u(ji-1,jj-1) * pub(ji-1,jj-1,jk)  )
84               !                                      ! ahm * div        (computed from 2 to jpi/jpj)
85!!gm note that ahmt has already been multiplied by tmask
86               zdiv(ji,jj)     = ahmt(ji,jj,jk) * r1_e1e2t(ji,jj) / e3t_b(ji,jj,jk)                                         &
87                  &     * (  e2u(ji,jj)*e3u_b(ji,jj,jk) * pub(ji,jj,jk) - e2u(ji-1,jj)*e3u_b(ji-1,jj,jk) * pub(ji-1,jj,jk)  &
88                  &        + e1v(ji,jj)*e3v_b(ji,jj,jk) * pvb(ji,jj,jk) - e1v(ji,jj-1)*e3v_b(ji,jj-1,jk) * pvb(ji,jj-1,jk)  )
89            END DO 
90         END DO 
91         !
92         DO jj = 2, jpjm1                             ! - curl( curl) + grad( div )
93            DO ji = fs_2, fs_jpim1   ! vector opt.
94               pua(ji,jj,jk) = pua(ji,jj,jk) + zsign * (                                                 &
95                  &              - ( zcur(ji  ,jj) - zcur(ji,jj-1) ) * r1_e2u(ji,jj) / e3u_n(ji,jj,jk)   &
96                  &              + ( zdiv(ji+1,jj) - zdiv(ji,jj  ) ) * r1_e1u(ji,jj)                     )
97                  !
98               pva(ji,jj,jk) = pva(ji,jj,jk) + zsign * (                                                 &
99                  &                ( zcur(ji,jj  ) - zcur(ji-1,jj) ) * r1_e1v(ji,jj) / e3v_n(ji,jj,jk)   &
100                  &              + ( zdiv(ji,jj+1) - zdiv(ji  ,jj) ) * r1_e2v(ji,jj)                     )
101            END DO
102         END DO
103         !                                             ! ===============
104      END DO                                           !   End of slab
105      !                                                ! ===============
106      !
107      IF( ln_timing )   CALL timing_stop('dyn_ldf_lap')
108      !
109   END SUBROUTINE dyn_ldf_lap
110
111
112   SUBROUTINE dyn_ldf_blp( kt, pub, pvb, pua, pva )
113      !!----------------------------------------------------------------------
114      !!                 ***  ROUTINE dyn_ldf_blp  ***
115      !!                   
116      !! ** Purpose :   Compute the before lateral momentum viscous trend
117      !!              and add it to the general trend of momentum equation.
118      !!
119      !! ** Method  :   The lateral viscous trends is provided by a bilaplacian
120      !!      operator applied to before field (forward in time).
121      !!      It is computed by two successive calls to dyn_ldf_lap routine
122      !!
123      !! ** Action :   pta   updated with the before rotated bilaplacian diffusion
124      !!----------------------------------------------------------------------
125      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
126      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pub, pvb   ! before velocity fields
127      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! momentum trend
128      !
129      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zulap, zvlap   ! laplacian at u- and v-point
130      !!----------------------------------------------------------------------
131      !
132      IF( ln_timing )   CALL timing_start('dyn_ldf_blp')
133      !
134      IF( kt == nit000 )  THEN
135         IF(lwp) WRITE(numout,*)
136         IF(lwp) WRITE(numout,*) 'dyn_ldf_blp : bilaplacian operator momentum '
137         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
138      ENDIF
139      !
140      zulap(:,:,:) = 0._wp
141      zvlap(:,:,:) = 0._wp
142      !
143      CALL dyn_ldf_lap( kt, pub, pvb, zulap, zvlap, 1 )   ! rotated laplacian applied to ptb (output in zlap)
144      !
145      CALL lbc_lnk_multi( zulap, 'U', -1., zvlap, 'V', -1. )             ! Lateral boundary conditions
146      !
147      CALL dyn_ldf_lap( kt, zulap, zvlap, pua, pva, 2 )   ! rotated laplacian applied to zlap (output in pta)
148      !
149      IF( ln_timing )   CALL timing_stop('dyn_ldf_blp')
150      !
151   END SUBROUTINE dyn_ldf_blp
152
153   !!======================================================================
154END MODULE dynldf_lap_blp
Note: See TracBrowser for help on using the repository browser.