New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/IOM/iom_nf90.F90 @ 9367

Last change on this file since 9367 was 9367, checked in by mathiot, 6 years ago

Add restart read/write via XIOS capability (#1953 and #1962 and twiki: 2017WP/Met_Office-1_Mirek_XIOSread). WARNING: need to upgrade XIOS to r1296 to compile
  • Property svn:keywords set to Id
File size: 48.6 KB
Line 
1MODULE iom_nf90
2   !!======================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!======================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write any 3D fields
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_gettime    : read the time axis kvid in the file
18   !!   iom_varid      : get the id of a variable in a file
19   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
20   !!----------------------------------------------------------------------
21   USE dom_oce         ! ocean space and time domain
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25   USE in_out_manager  ! I/O manager
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC iom_nf90_open  , iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
32   PUBLIC iom_nf90_getatt, iom_nf90_putatt
33
34   INTERFACE iom_nf90_get
35      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
36   END INTERFACE
37   INTERFACE iom_nf90_getatt
38      MODULE PROCEDURE iom_nf90_giatt, iom_nf90_gratt, iom_nf90_gcatt
39   END INTERFACE
40   INTERFACE iom_nf90_putatt
41      MODULE PROCEDURE iom_nf90_piatt, iom_nf90_pratt, iom_nf90_pcatt
42   END INTERFACE
43   INTERFACE iom_nf90_rstput
44      MODULE PROCEDURE iom_nf90_rp0123d
45   END INTERFACE
46
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 4.0 , NEMO Consortium (2017)
49   !! $Id$
50   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar, kdlev )
55      !!---------------------------------------------------------------------
56      !!                   ***  SUBROUTINE  iom_open  ***
57      !!
58      !! ** Purpose : open an input file with NF90
59      !!---------------------------------------------------------------------
60      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
61      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
62      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
63      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
64      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
65      INTEGER                , INTENT(in   ), OPTIONAL ::   kdlev       ! size of the third dimension
66
67      CHARACTER(LEN=256) ::   clinfo           ! info character
68      CHARACTER(LEN=256) ::   cltmp            ! temporary character
69      INTEGER            ::   iln              ! lengths of character
70      INTEGER            ::   istop            ! temporary storage of nstop
71      INTEGER            ::   if90id           ! nf90 identifier of the opened file
72      INTEGER            ::   idmy             ! dummy variable
73      INTEGER            ::   jl               ! loop variable
74      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
75      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
76      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
77      LOGICAL            ::   llclobber        ! local definition of ln_clobber
78      INTEGER            ::   ilevels           ! vertical levels
79      !---------------------------------------------------------------------
80      !
81      clinfo = '                    iom_nf90_open ~~~  '
82      istop = nstop     ! store the actual value of nstop
83      !
84      !                 !number of vertical levels
85      IF( PRESENT(kdlev) ) THEN   ;   ilevels = kdlev    ! use input value (useful for sea-ice)
86      ELSE                        ;   ilevels = jpk      ! by default jpk
87      ENDIF
88      !
89      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
90      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
91      ENDIF
92      !
93      llclobber = ldwrt .AND. ln_clobber
94      IF( ldok .AND. .NOT. llclobber ) THEN      !==  Open existing file ==!
95         !                                       !=========================!
96         IF( ldwrt ) THEN  ! ... in write mode
97            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
98            IF( snc4set%luse ) THEN
99               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
100            ELSE
101               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
102            ENDIF
103            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
104         ELSE              ! ... in read mode
105            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
106            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
107         ENDIF
108      ELSE                                       !== the file doesn't exist ==!   (or we overwrite it)
109         !                                       !============================!
110         iln = INDEX( cdname, '.nc' )
111         IF( ldwrt ) THEN              !* the file should be open in write mode so we create it...
112            IF( jpnij > 1 ) THEN
113               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
114               cdname = TRIM(cltmp)
115            ENDIF
116            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
117
118            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
119            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
120            ENDIF
121            IF( snc4set%luse ) THEN
122               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
123               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
124               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
125               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
126               ENDIF
127               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
128            ELSE
129               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
130            ENDIF
131            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                     ), clinfo)
132            ! define dimensions
133            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'x'      , kdompar(1,1)  , idmy ), clinfo)
134            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'y'      , kdompar(2,1)  , idmy ), clinfo)
135            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'nav_lev', jpk           , idmy ), clinfo)
136            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
137            ! global attributes
138            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
139            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
140            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
141            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
142            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
143            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
144            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
145            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
146            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
147            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
148         ELSE                          !* the file should be open for read mode so it must exist...
149            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
150         ENDIF
151      ENDIF
152      !
153      ! start to fill file informations
154      ! =============
155      IF( istop == nstop ) THEN   ! no error within this routine
156!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
157         kiomid = 0
158         DO jl = jpmax_files, 1, -1
159            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
160         ENDDO
161         iom_file(kiomid)%name   = TRIM(cdname)
162         iom_file(kiomid)%nfid   = if90id
163         iom_file(kiomid)%iolib  = jpnf90
164         iom_file(kiomid)%nvars  = 0
165         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
166         iom_file(kiomid)%nlev   = ilevels
167         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
168         IF( iom_file(kiomid)%iduld .GE. 0 ) THEN
169            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,    & 
170               &                                       name = iom_file(kiomid)%uldname,   &
171               &                                       len  = iom_file(kiomid)%lenuld ), clinfo )
172         ENDIF
173         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
174      ELSE
175         kiomid = 0               ! return error flag
176      ENDIF
177      !
178   END SUBROUTINE iom_nf90_open
179
180
181   SUBROUTINE iom_nf90_close( kiomid )
182      !!--------------------------------------------------------------------
183      !!                   ***  SUBROUTINE  iom_nf90_close  ***
184      !!
185      !! ** Purpose : close an input file with NF90
186      !!--------------------------------------------------------------------
187      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
188      CHARACTER(LEN=100)  ::   clinfo   ! info character
189      !---------------------------------------------------------------------
190      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
191      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
192   END SUBROUTINE iom_nf90_close
193
194
195   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims ) 
196      !!-----------------------------------------------------------------------
197      !!                  ***  FUNCTION  iom_varid  ***
198      !!
199      !! ** Purpose : get the id of a variable in a file with NF90
200      !!-----------------------------------------------------------------------
201      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
202      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
203      INTEGER              , INTENT(in   )           ::   kiv   !
204      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
205      INTEGER,               INTENT(  out), OPTIONAL ::   kndims   ! size of the dimensions
206      !
207      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
208      INTEGER                        ::   if90id           ! nf90 file identifier
209      INTEGER                        ::   ji               ! dummy loop index
210      INTEGER                        ::   ivarid           ! NetCDF  variable Id
211      INTEGER                        ::   i_nvd            ! number of dimension of the variable
212      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
213      LOGICAL                        ::   llok             ! ok  test
214      CHARACTER(LEN=100)             ::   clinfo           ! info character
215      !!-----------------------------------------------------------------------
216      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
217      iom_nf90_varid = 0                    ! default definition
218      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
219      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
220      !
221      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
222      IF( llok ) THEN
223         iom_nf90_varid = kiv
224         iom_file(kiomid)%nvars       = kiv
225         iom_file(kiomid)%nvid(kiv)   = ivarid
226         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
227         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
228         iom_file(kiomid)%ndims(kiv)  = i_nvd
229         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
230         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
231         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
232         DO ji = 1, i_nvd                       ! dimensions size
233            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
234            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
235         END DO
236         !---------- Deal with scale_factor and add_offset
237         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
238         IF( llok) THEN
239            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
240         ELSE
241            iom_file(kiomid)%scf(kiv) = 1.
242         END IF
243         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
244         IF( llok ) THEN
245            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
246         ELSE
247            iom_file(kiomid)%ofs(kiv) = 0.
248         END IF
249         ! return the simension size
250         IF( PRESENT(kdimsz) ) THEN
251            IF( i_nvd == SIZE(kdimsz) ) THEN
252               kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
253            ELSE
254               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
255               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
256            ENDIF
257         ENDIF
258         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
259      ELSE 
260         iom_nf90_varid = -1   !   variable not found, return error code: -1
261      ENDIF
262      !
263   END FUNCTION iom_nf90_varid
264
265   !!----------------------------------------------------------------------
266   !!                   INTERFACE iom_nf90_get
267   !!----------------------------------------------------------------------
268
269   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar, kstart )
270      !!-----------------------------------------------------------------------
271      !!                  ***  ROUTINE  iom_nf90_g0d  ***
272      !!
273      !! ** Purpose : read a scalar with NF90
274      !!-----------------------------------------------------------------------
275      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
276      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
277      REAL(wp),               INTENT(  out)            ::   pvar     ! read field
278      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
279      !
280      CHARACTER(LEN=100)      ::   clinfo   ! info character
281      !---------------------------------------------------------------------
282      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
283      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
284   END SUBROUTINE iom_nf90_g0d
285
286
287   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
288         &                    pv_r1d, pv_r2d, pv_r3d )
289      !!-----------------------------------------------------------------------
290      !!                  ***  ROUTINE  iom_nf90_g123d  ***
291      !!
292      !! ** Purpose : read a 1D/2D/3D variable with NF90
293      !!
294      !! ** Method : read ONE record at each CALL
295      !!-----------------------------------------------------------------------
296      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
297      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
298      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
299      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
300      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
301      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
302      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
303      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
304      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
305      !
306      CHARACTER(LEN=100) ::   clinfo               ! info character
307      INTEGER            ::   if90id               ! nf90 identifier of the opened file
308      INTEGER            ::   ivid                 ! nf90 variable id
309      !---------------------------------------------------------------------
310      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
311      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
312      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
313      !
314      IF(     PRESENT(pv_r1d) ) THEN
315         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
316            &                                                                       count = kcount(1:knbdim)), clinfo )
317      ELSEIF( PRESENT(pv_r2d) ) THEN
318         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
319            &                                                                       count = kcount(1:knbdim)), clinfo )
320      ELSEIF( PRESENT(pv_r3d) ) THEN
321         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
322            &                                                                       count = kcount(1:knbdim)), clinfo )
323      ENDIF
324      !
325   END SUBROUTINE iom_nf90_g123d
326
327   !!----------------------------------------------------------------------
328   !!                   INTERFACE iom_nf90_getatt
329   !!----------------------------------------------------------------------
330
331   SUBROUTINE iom_nf90_giatt( kiomid, cdatt, pv_i0d, cdvar)
332      !!-----------------------------------------------------------------------
333      !!                  ***  ROUTINE  iom_nf90_giatt  ***
334      !!
335      !! ** Purpose : read an integer attribute with NF90
336      !!              (either a global attribute (default) or a variable
337      !!               attribute if optional variable name is supplied (cdvar))
338      !!-----------------------------------------------------------------------
339      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
340      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
341      INTEGER         , INTENT(  out) ::   pv_i0d   ! read field
342      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
343                      &               ::   cdvar    ! name of the variable
344      !
345      INTEGER                         ::   if90id   ! temporary integer
346      INTEGER                         ::   ivarid   ! NetCDF variable Id
347      LOGICAL                         ::   llok     ! temporary logical
348      CHARACTER(LEN=100)              ::   clinfo   ! info character
349      !---------------------------------------------------------------------
350      !
351      if90id = iom_file(kiomid)%nfid
352      IF( PRESENT(cdvar) ) THEN
353         ! check the variable exists in the file
354         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
355         IF( llok ) THEN
356            ! check the variable has the attribute required
357            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
358         ELSE
359            CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found')
360         ENDIF
361      ELSE
362         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
363         ivarid = NF90_GLOBAL
364      ENDIF
365      !
366      IF( llok) THEN
367         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', giatt: '//TRIM(cdatt)
368         CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_i0d), clinfo)
369      ELSE
370         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
371         pv_i0d = -999
372      ENDIF
373      !
374   END SUBROUTINE iom_nf90_giatt
375
376
377   SUBROUTINE iom_nf90_gratt( kiomid, cdatt, pv_r0d, cdvar )
378      !!-----------------------------------------------------------------------
379      !!                  ***  ROUTINE  iom_nf90_gratt  ***
380      !!
381      !! ** Purpose : read a real attribute with NF90
382      !!              (either a global attribute (default) or a variable
383      !!               attribute if optional variable name is supplied (cdvar))
384      !!-----------------------------------------------------------------------
385      INTEGER                   , INTENT(in   ) ::   kiomid   ! Identifier of the file
386      CHARACTER(len=*)          , INTENT(in   ) ::   cdatt    ! attribute name
387      REAL(wp)                  , INTENT(  out) ::   pv_r0d   ! read field
388      CHARACTER(len=*), OPTIONAL, INTENT(in   ) ::   cdvar    ! name of the variable
389      !
390      INTEGER            ::   if90id   ! temporary integer
391      INTEGER            ::   ivarid   ! NetCDF variable Id
392      LOGICAL            ::   llok     ! temporary logical
393      CHARACTER(LEN=100) ::   clinfo   ! info character
394      !---------------------------------------------------------------------
395      !
396      if90id = iom_file(kiomid)%nfid
397      IF( PRESENT(cdvar) ) THEN
398         ! check the variable exists in the file
399         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
400         IF( llok ) THEN
401            ! check the variable has the attribute required
402            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
403         ELSE
404            CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found')
405         ENDIF
406      ELSE
407         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
408         ivarid = NF90_GLOBAL
409      ENDIF
410      !
411      IF( llok) THEN
412         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', gratt: '//TRIM(cdatt)
413         CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_r0d), clinfo)
414      ELSE
415         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
416         pv_r0d = -999._wp
417      ENDIF
418      !
419   END SUBROUTINE iom_nf90_gratt
420
421
422   SUBROUTINE iom_nf90_gcatt( kiomid, cdatt, pv_c0d, cdvar )
423      !!-----------------------------------------------------------------------
424      !!                  ***  ROUTINE  iom_nf90_gcatt  ***
425      !!
426      !! ** Purpose : read a character attribute with NF90
427      !!              (either a global attribute (default) or a variable
428      !!               attribute if optional variable name is supplied (cdvar))
429      !!-----------------------------------------------------------------------
430      INTEGER                   , INTENT(in   ) ::   kiomid   ! Identifier of the file
431      CHARACTER(len=*)          , INTENT(in   ) ::   cdatt    ! attribute name
432      CHARACTER(len=*)          , INTENT(  out) ::   pv_c0d   ! read field
433      CHARACTER(len=*), OPTIONAL, INTENT(in   ) ::   cdvar    ! name of the variable
434      !
435      INTEGER            ::   if90id   ! temporary integer
436      INTEGER            ::   ivarid   ! NetCDF variable Id
437      LOGICAL            ::   llok     ! temporary logical
438      CHARACTER(LEN=100) ::   clinfo   ! info character
439      !---------------------------------------------------------------------
440      !
441      if90id = iom_file(kiomid)%nfid
442      IF( PRESENT(cdvar) ) THEN
443         ! check the variable exists in the file
444         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
445         IF( llok ) THEN
446            ! check the variable has the attribute required
447            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
448         ELSE
449            CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found')
450         ENDIF
451      ELSE
452         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
453         ivarid = NF90_GLOBAL
454      ENDIF
455!
456      IF( llok) THEN
457         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', gcatt: '//TRIM(cdatt)
458         CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_c0d), clinfo)
459      ELSE
460         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
461         pv_c0d = '!'
462      ENDIF
463      !
464   END SUBROUTINE iom_nf90_gcatt
465
466
467   !!----------------------------------------------------------------------
468   !!                   INTERFACE iom_nf90_putatt
469   !!----------------------------------------------------------------------
470
471   SUBROUTINE iom_nf90_piatt( kiomid, cdatt, pv_i0d, cdvar)
472      !!-----------------------------------------------------------------------
473      !!                  ***  ROUTINE  iom_nf90_piatt  ***
474      !!
475      !! ** Purpose : write an integer attribute with NF90
476      !!              (either a global attribute (default) or a variable
477      !!               attribute if optional variable name is supplied (cdvar))
478      !!-----------------------------------------------------------------------
479      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
480      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
481      INTEGER         , INTENT(in   ) ::   pv_i0d   ! write field
482      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
483                      &               ::   cdvar    ! name of the variable
484      !
485      INTEGER                         ::   if90id   ! temporary integer
486      INTEGER                         ::   ivarid   ! NetCDF variable Id
487      LOGICAL                         ::   llok     ! temporary logical
488      LOGICAL                         ::   lenddef  ! temporary logical
489      CHARACTER(LEN=100)              ::   clinfo   ! info character
490      !---------------------------------------------------------------------
491      !
492      if90id = iom_file(kiomid)%nfid
493      lenddef = .false.
494      IF( PRESENT(cdvar) ) THEN
495         ! check the variable exists in the file
496         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
497         IF( .NOT. llok ) THEN
498            CALL ctl_warn('iom_nf90_putatt: no variable '//cdvar//' found')
499         ENDIF
500      ELSE
501         llok = .true.
502         ivarid = NF90_GLOBAL
503      ENDIF
504      !
505      IF( llok) THEN
506         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', piatt: '//TRIM(cdatt)
507         IF( iom_file(kiomid)%irec /= -1 ) THEN   
508            ! trick: irec used to know if the file is in define mode or not
509            ! if it is not then temporarily put it into define mode
510            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
511            lenddef = .true.
512         ENDIF
513         !
514         CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values=pv_i0d), clinfo)
515         !
516         IF( lenddef ) THEN   
517            ! file was in data mode on entry; put it back in that mode
518            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
519         ENDIF
520      ELSE
521         CALL ctl_warn('iom_nf90_putatt: no attribute '//cdatt//' written')
522      ENDIF
523      !
524   END SUBROUTINE iom_nf90_piatt
525
526
527   SUBROUTINE iom_nf90_pratt( kiomid, cdatt, pv_r0d, cdvar )
528      !!-----------------------------------------------------------------------
529      !!                  ***  ROUTINE  iom_nf90_pratt  ***
530      !!
531      !! ** Purpose : write a real attribute with NF90
532      !!              (either a global attribute (default) or a variable
533      !!               attribute if optional variable name is supplied (cdvar))
534      !!-----------------------------------------------------------------------
535      INTEGER                   , INTENT(in   ) ::   kiomid   ! Identifier of the file
536      CHARACTER(len=*)          , INTENT(in   ) ::   cdatt    ! attribute name
537      REAL(wp)                  , INTENT(in   ) ::   pv_r0d   ! write field
538      CHARACTER(len=*), OPTIONAL, INTENT(in   ) ::   cdvar    ! name of the variable
539      !
540      INTEGER            ::   if90id   ! temporary integer
541      INTEGER            ::   ivarid   ! NetCDF variable Id
542      LOGICAL            ::   llok     ! temporary logical
543      LOGICAL            ::   lenddef  ! temporary logical
544      CHARACTER(LEN=100) ::   clinfo   ! info character
545      !---------------------------------------------------------------------
546      !
547      if90id = iom_file(kiomid)%nfid
548      lenddef = .false.
549      IF( PRESENT(cdvar) ) THEN
550         ! check the variable exists in the file
551         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
552         IF( .NOT. llok ) THEN
553            CALL ctl_warn('iom_nf90_putatt: no variable '//cdvar//' found')
554         ENDIF
555      ELSE
556         llok = .true.
557         ivarid = NF90_GLOBAL
558      ENDIF
559      !
560      IF( llok) THEN
561         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', pratt: '//TRIM(cdatt)
562         IF( iom_file(kiomid)%irec /= -1 ) THEN   
563            ! trick: irec used to know if the file is in define mode or not
564            ! if it is not then temporarily put it into define mode
565            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
566            lenddef = .true.
567         ENDIF
568         !
569         CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values=pv_r0d), clinfo)
570         !
571         IF( lenddef ) THEN   
572            ! file was in data mode on entry; put it back in that mode
573            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
574         ENDIF
575      ELSE
576         CALL ctl_warn('iom_nf90_putatt: no attribute '//cdatt//' written')
577      ENDIF
578      !
579   END SUBROUTINE iom_nf90_pratt
580
581
582   SUBROUTINE iom_nf90_pcatt( kiomid, cdatt, pv_c0d, cdvar )
583      !!-----------------------------------------------------------------------
584      !!                  ***  ROUTINE  iom_nf90_pcatt  ***
585      !!
586      !! ** Purpose : write a character attribute with NF90
587      !!              (either a global attribute (default) or a variable
588      !!               attribute if optional variable name is supplied (cdvar))
589      !!-----------------------------------------------------------------------
590      INTEGER                   , INTENT(in   ) ::   kiomid   ! Identifier of the file
591      CHARACTER(len=*)          , INTENT(in   ) ::   cdatt    ! attribute name
592      CHARACTER(len=*)          , INTENT(in   ) ::   pv_c0d   ! write field
593      CHARACTER(len=*), OPTIONAL, INTENT(in   ) ::   cdvar    ! name of the variable
594      !
595      INTEGER            ::   if90id   ! temporary integer
596      INTEGER            ::   ivarid   ! NetCDF variable Id
597      LOGICAL            ::   llok     ! temporary logical
598      LOGICAL            ::   lenddef  ! temporary logical
599      CHARACTER(LEN=100) ::   clinfo   ! info character
600      !---------------------------------------------------------------------
601      !
602      if90id = iom_file(kiomid)%nfid
603      lenddef = .false.
604      IF( PRESENT(cdvar) ) THEN
605         ! check the variable exists in the file
606         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
607         IF( .NOT. llok ) THEN
608            CALL ctl_warn('iom_nf90_putatt: no variable '//cdvar//' found')
609         ENDIF
610      ELSE
611         llok = .true.
612         ivarid = NF90_GLOBAL
613      ENDIF
614      !
615      IF( llok) THEN
616         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', pcatt: '//TRIM(cdatt)
617         IF( iom_file(kiomid)%irec /= -1 ) THEN   
618            ! trick: irec used to know if the file is in define mode or not
619            ! if it is not then temporarily put it into define mode
620            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
621            lenddef = .true.
622         ENDIF
623         !
624         CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values=pv_c0d), clinfo)
625         !
626         IF( lenddef ) THEN   
627            ! file was in data mode on entry; put it back in that mode
628            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
629         ENDIF
630      ELSE
631         CALL ctl_warn('iom_nf90_putatt: no attribute '//cdatt//' written')
632      ENDIF
633      !
634   END SUBROUTINE iom_nf90_pcatt
635
636
637   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
638      !!--------------------------------------------------------------------
639      !!                   ***  SUBROUTINE iom_gettime  ***
640      !!
641      !! ** Purpose : read the time axis kvid in the file with NF90
642      !!--------------------------------------------------------------------
643      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
644      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
645      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
646      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
647      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
648      !
649      CHARACTER(LEN=100) ::   clinfo     ! info character
650      !---------------------------------------------------------------------
651      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
652      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
653            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
654      IF ( PRESENT(cdunits) ) THEN
655         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", &
656            &                           values=cdunits), clinfo)
657      ENDIF
658      IF ( PRESENT(cdcalendar) ) THEN
659         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", &
660            &                           values=cdcalendar), clinfo)
661      ENDIF
662      !
663   END SUBROUTINE iom_nf90_gettime
664
665
666   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
667         &                                  pv_r0d, pv_r1d, pv_r2d, pv_r3d )
668      !!--------------------------------------------------------------------
669      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
670      !!
671      !! ** Purpose : read the time axis cdvar in the file
672      !!--------------------------------------------------------------------
673      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
674      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
675      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
676      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
677      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
678      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
679      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
680      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
681      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
682      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
683      !
684      INTEGER               :: idims                ! number of dimension
685      INTEGER               :: idvar                ! variable id
686      INTEGER               :: jd                   ! dimension loop counter   
687      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
688      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
689      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
690      CHARACTER(LEN=256)    :: clinfo               ! info character
691      CHARACTER(LEN= 12), DIMENSION(4) :: cltmp     ! temporary character
692      INTEGER               :: if90id               ! nf90 file identifier
693      INTEGER               :: idmy                 ! dummy variable
694      INTEGER               :: itype                ! variable type
695      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
696      !                                             ! nn_nchunks_[i,j,k,t] namelist parameters
697      INTEGER               :: ichunkalg, ishuffle, ideflate, ideflate_level
698      !                                             ! NetCDF4 internally fixed parameters
699      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
700      !                                             ! when appropriate (currently chunking is applied to 4d fields only)
701      INTEGER               :: idlv                 ! local variable
702      !---------------------------------------------------------------------
703      !
704      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
705      if90id = iom_file(kiomid)%nfid
706      !
707      ! define dimension variables if it is not already done
708      ! ==========================
709      IF( iom_file(kiomid)%nvars == 0 ) THEN
710         ! are we in define mode?
711         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
712            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
713         ENDIF
714         ! define the dimension variables if it is not already done
715         IF(iom_file(kiomid)%nlev == jpk ) THEN
716          cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter' /)
717         ELSE
718          cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'numcat      ', 'time_counter' /)
719         ENDIF
720         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
721         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
722         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
723         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
724         ! update informations structure related the dimension variable we just added...
725         iom_file(kiomid)%nvars       = 4
726         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
727         iom_file(kiomid)%cn_var(1:4) = cltmp
728         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /) 
729         ! trick: defined to 0 to say that dimension variables are defined but not yet written
730         iom_file(kiomid)%dimsz(1, 1)  = 0   
731         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
732      ENDIF
733      ! define the data if it is not already done
734      ! ===============
735      IF( kvid <= 0 ) THEN
736         !
737         ! NetCDF4 chunking and compression fixed settings
738         ichunkalg = 0
739         ishuffle = 1
740         ideflate = 1
741         ideflate_level = 1
742         !
743         idvar = iom_file(kiomid)%nvars + 1
744         ! are we in define mode?
745         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
746            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
747         ENDIF
748         ! variable definition
749         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
750         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
751         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
752         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
753         ENDIF
754         IF( PRESENT(ktype) ) THEN   ! variable external type
755            SELECT CASE (ktype)
756            CASE (jp_r8)  ;   itype = NF90_DOUBLE
757            CASE (jp_r4)  ;   itype = NF90_FLOAT
758            CASE (jp_i4)  ;   itype = NF90_INT
759            CASE (jp_i2)  ;   itype = NF90_SHORT
760            CASE (jp_i1)  ;   itype = NF90_BYTE
761            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
762            END SELECT
763         ELSE
764            itype = NF90_DOUBLE
765         ENDIF
766         IF( PRESENT(pv_r0d) ) THEN
767            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
768               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
769         ELSE
770            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
771               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
772         ENDIF
773         lchunk = .false.
774         IF( snc4set%luse .AND. idims == 4 )   lchunk = .true.
775         ! update informations structure related the new variable we want to add...
776         iom_file(kiomid)%nvars         = idvar
777         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
778         iom_file(kiomid)%scf(idvar)    = 1.
779         iom_file(kiomid)%ofs(idvar)    = 0.
780         iom_file(kiomid)%ndims(idvar)  = idims
781         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
782         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
783         ENDIF
784         DO jd = 1, idims
785            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
786            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
787         END DO
788         IF ( lchunk ) THEN
789            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
790            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
791            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
792            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
793            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
794            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
795            !                                                                          ! unlimited dimension
796            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
797            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
798            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
799         ENDIF
800         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
801      ELSE
802         idvar = kvid
803      ENDIF
804      !
805      ! time step kwrite : write the variable
806      IF( kt == kwrite ) THEN
807         ! are we in write mode?
808         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
809            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
810         ENDIF
811         ! on what kind of domain must the data be written?
812         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
813            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
814            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
815               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
816            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
817               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
818            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
819               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
820            ELSE
821               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
822            ENDIF
823
824            ! write dimension variables if it is not already done
825            ! =============
826            ! trick: is defined to 0 => dimension variable are defined but not yet written
827            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
828               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lon'     , idmy )         , clinfo )
829               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo )
830               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lat'     , idmy )         , clinfo )
831               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo )
832               IF(iom_file(kiomid)%nlev == jpk ) THEN 
833                  !NEMO
834                  CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo )
835                  CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gdept_1d       ), clinfo )
836               ELSE
837                  CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'numcat'     , idmy ), clinfo)
838                  CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, (/ (idlv, idlv = 1,iom_file(kiomid)%nlev) /)), clinfo )
839               ENDIF
840               ! +++ WRONG VALUE: to be improved but not really useful...
841               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo )
842               CALL iom_nf90_check( NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo )   
843               ! update the values of the variables dimensions size
844               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo )
845               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo )
846               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
847               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo )
848               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
849               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
850            ENDIF
851         ENDIF
852
853         ! write the data
854         ! =============
855         IF(     PRESENT(pv_r0d) ) THEN
856            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r0d                    ), clinfo )
857         ELSEIF( PRESENT(pv_r1d) ) THEN
858            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r1d(:)                 ), clinfo )
859         ELSEIF( PRESENT(pv_r2d) ) THEN
860            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2,iy1:iy2)   ), clinfo )
861         ELSEIF( PRESENT(pv_r3d) ) THEN
862            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2,iy1:iy2,:) ), clinfo )
863         ENDIF
864         ! add 1 to the size of the temporal dimension (not really useful...)
865         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
866               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
867         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
868      ENDIF
869      !     
870   END SUBROUTINE iom_nf90_rp0123d
871
872
873   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
874      !!--------------------------------------------------------------------
875      !!                   ***  SUBROUTINE iom_nf90_check  ***
876      !!
877      !! ** Purpose :   check nf90 errors
878      !!--------------------------------------------------------------------
879      INTEGER,          INTENT(in) :: kstatus
880      CHARACTER(LEN=*), INTENT(in) :: cdinfo
881      !---------------------------------------------------------------------
882      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
883   END SUBROUTINE iom_nf90_check
884
885   !!======================================================================
886END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.