New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 9019

Last change on this file since 9019 was 9019, checked in by timgraham, 6 years ago

Merge of dev_CNRS_2017 into branch
  • Property svn:keywords set to Id
File size: 15.2 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26
27   !
28   USE iom            ! XIOS library
29   USE timing         ! Timing
30   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
31   USE in_out_manager ! I/O manager
32   USE lib_mpp        ! distribued memory computing
33   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
39   
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
41   !                                                           !  and in closed seas (orca 2 and 1 configurations)
42   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
43   
44   LOGICAL  ::   l_trd   ! flag to compute trends
45   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
46   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
47
48   !! * Substitutions
49#  include "vectopt_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
52   !! $Id$
53   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
58      &                                              ptb, pta, kjpt, ld_msc_ups )
59      !!----------------------------------------------------------------------
60      !!                    ***  ROUTINE tra_adv_mus  ***
61      !!
62      !! ** Purpose :   Compute the now trend due to total advection of tracers
63      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
64      !!              Conservation Laws) and add it to the general tracer trend.
65      !!
66      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
67      !!              ld_msc_ups=T :
68      !!
69      !! ** Action : - update pta  with the now advective tracer trends
70      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
71      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
72      !!
73      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
74      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
75      !!----------------------------------------------------------------------
76      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
77      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
78      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
79      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
80      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
81      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
82      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
83      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
85      !
86      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
87      INTEGER  ::   ierr             ! local integer
88      REAL(wp) ::   zu, z0u, zzwx, zw , zalpha   ! local scalars
89      REAL(wp) ::   zv, z0v, zzwy, z0w           !   -      -
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwx, zslpx   ! 3D workspace
91      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwy, zslpy   ! -      -
92      !!----------------------------------------------------------------------
93      !
94      IF( ln_timing )   CALL timing_start('tra_adv_mus')
95      !
96      IF( kt == kit000 )  THEN
97         IF(lwp) WRITE(numout,*)
98         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
99         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
100         IF(lwp) WRITE(numout,*) '~~~~~~~'
101         IF(lwp) WRITE(numout,*)
102         !
103         ! Upstream / MUSCL scheme indicator
104         !
105         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
106         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
107         !
108         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
109            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
110            upsmsk(:,:) = 0._wp                             ! not upstream by default
111            !
112            DO jk = 1, jpkm1
113               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
114                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
115                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
116            END DO
117         ENDIF 
118         !
119      ENDIF 
120      !     
121      l_trd = .FALSE.
122      l_hst = .FALSE.
123      l_ptr = .FALSE.
124      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
125      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                               l_ptr = .TRUE. 
126      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
127         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
128      !
129      DO jn = 1, kjpt            !==  loop over the tracers  ==!
130         !
131         !                          !* Horizontal advective fluxes
132         !
133         !                                !-- first guess of the slopes
134         zwx(:,:,jpk) = 0._wp                   ! bottom values
135         zwy(:,:,jpk) = 0._wp 
136         DO jk = 1, jpkm1                       ! interior values
137            DO jj = 1, jpjm1     
138               DO ji = 1, fs_jpim1   ! vector opt.
139                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
140                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
141               END DO
142           END DO
143         END DO
144         CALL lbc_lnk( zwx, 'U', -1. )          ! lateral boundary conditions   (changed sign)
145         CALL lbc_lnk( zwy, 'V', -1. )
146         !                                !-- Slopes of tracer
147         zslpx(:,:,jpk) = 0._wp                 ! bottom values
148         zslpy(:,:,jpk) = 0._wp
149         DO jk = 1, jpkm1                       ! interior values
150            DO jj = 2, jpj
151               DO ji = fs_2, jpi   ! vector opt.
152                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
153                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
154                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
155                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
156               END DO
157            END DO
158         END DO
159         !
160         DO jk = 1, jpkm1                 !-- Slopes limitation
161            DO jj = 2, jpj
162               DO ji = fs_2, jpi   ! vector opt.
163                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
164                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
165                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
166                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
167                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
168                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
169               END DO
170           END DO
171         END DO
172         !
173         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
174            DO jj = 2, jpjm1
175               DO ji = fs_2, fs_jpim1   ! vector opt.
176                  ! MUSCL fluxes
177                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
178                  zalpha = 0.5 - z0u
179                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
180                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
181                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
182                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
183                  !
184                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
185                  zalpha = 0.5 - z0v
186                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
187                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
188                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
189                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
190               END DO
191            END DO
192         END DO
193         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
194         !
195         DO jk = 1, jpkm1                 !-- Tracer advective trend
196            DO jj = 2, jpjm1     
197               DO ji = fs_2, fs_jpim1   ! vector opt.
198                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
199                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
200                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
201               END DO
202           END DO
203         END DO       
204         !                                ! trend diagnostics
205         IF( l_trd )  THEN
206            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
207            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
208         END IF
209         !                                 ! "Poleward" heat and salt transports
210         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
211         !                                 !  heat transport
212         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
213         !
214         !                          !* Vertical advective fluxes
215         !
216         !                                !-- first guess of the slopes
217         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
218         zwx(:,:,jpk) = 0._wp
219         DO jk = 2, jpkm1                       ! interior values
220            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
221         END DO
222         !                                !-- Slopes of tracer
223         zslpx(:,:,1) = 0._wp                   ! surface values
224         DO jk = 2, jpkm1                       ! interior value
225            DO jj = 1, jpj
226               DO ji = 1, jpi
227                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
228                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
229               END DO
230            END DO
231         END DO
232         DO jk = 2, jpkm1                 !-- Slopes limitation
233            DO jj = 1, jpj                      ! interior values
234               DO ji = 1, jpi
235                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
236                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
237                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
238               END DO
239            END DO
240         END DO
241         DO jk = 1, jpk-2                 !-- vertical advective flux
242            DO jj = 2, jpjm1     
243               DO ji = fs_2, fs_jpim1   ! vector opt.
244                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
245                  zalpha = 0.5 + z0w
246                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
247                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
248                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
249                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
250               END DO
251            END DO
252         END DO
253         IF( ln_linssh ) THEN                   ! top values, linear free surface only
254            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
255               DO jj = 1, jpj
256                  DO ji = 1, jpi
257                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
258                  END DO
259               END DO   
260            ELSE                                      ! no cavities: only at the ocean surface
261               zwx(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
262            ENDIF
263         ENDIF
264         !
265         DO jk = 1, jpkm1                 !-- vertical advective trend
266            DO jj = 2, jpjm1     
267               DO ji = fs_2, fs_jpim1   ! vector opt.
268                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
269               END DO
270            END DO
271         END DO
272         !                                ! send trends for diagnostic
273         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
274         !
275      END DO                     ! end of tracer loop
276      !
277      IF( ln_timing )   CALL timing_stop('tra_adv_mus')
278      !
279   END SUBROUTINE tra_adv_mus
280
281   !!======================================================================
282END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.