| 1 | MODULE traldf_triad |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traldf_triad *** |
|---|
| 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) Griffies operator (original code) |
|---|
| 7 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) triad operator (Griffies) + Method of Stabilizing Correction |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and active tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | USE phycst ! physical constants |
|---|
| 16 | USE trc_oce ! share passive tracers/Ocean variables |
|---|
| 17 | USE zdf_oce ! ocean vertical physics |
|---|
| 18 | USE ldftra ! lateral physics: eddy diffusivity |
|---|
| 19 | USE ldfslp ! lateral physics: iso-neutral slopes |
|---|
| 20 | USE traldf_iso ! lateral diffusion (Madec operator) (tra_ldf_iso routine) |
|---|
| 21 | USE diaptr ! poleward transport diagnostics |
|---|
| 22 | USE diaar5 ! AR5 diagnostics |
|---|
| 23 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 24 | ! |
|---|
| 25 | USE in_out_manager ! I/O manager |
|---|
| 26 | USE iom ! I/O library |
|---|
| 27 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 28 | USE lib_mpp ! MPP library |
|---|
| 29 | USE timing ! Timing |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC tra_ldf_triad ! routine called by traldf.F90 |
|---|
| 35 | |
|---|
| 36 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zdkt3d !: vertical tracer gradient at 2 levels |
|---|
| 37 | |
|---|
| 38 | LOGICAL :: l_ptr ! flag to compute poleward transport |
|---|
| 39 | LOGICAL :: l_hst ! flag to compute heat transport |
|---|
| 40 | |
|---|
| 41 | |
|---|
| 42 | !! * Substitutions |
|---|
| 43 | # include "vectopt_loop_substitute.h90" |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! NEMO/OPA 3.7 , NEMO Consortium (2015) |
|---|
| 46 | !! $Id$ |
|---|
| 47 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | CONTAINS |
|---|
| 50 | |
|---|
| 51 | SUBROUTINE tra_ldf_triad( kt, kit000, cdtype, pahu, pahv, pgu , pgv , & |
|---|
| 52 | & pgui, pgvi, & |
|---|
| 53 | & ptb , ptbb, pta , kjpt, kpass ) |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! *** ROUTINE tra_ldf_triad *** |
|---|
| 56 | !! |
|---|
| 57 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
|---|
| 58 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
|---|
| 59 | !! add it to the general trend of tracer equation. |
|---|
| 60 | !! |
|---|
| 61 | !! ** Method : The horizontal component of the lateral diffusive trends |
|---|
| 62 | !! is provided by a 2nd order operator rotated along neural or geopo- |
|---|
| 63 | !! tential surfaces to which an eddy induced advection can be added |
|---|
| 64 | !! It is computed using before fields (forward in time) and isopyc- |
|---|
| 65 | !! nal or geopotential slopes computed in routine ldfslp. |
|---|
| 66 | !! |
|---|
| 67 | !! see documentation for the desciption |
|---|
| 68 | !! |
|---|
| 69 | !! ** Action : pta updated with the before rotated diffusion |
|---|
| 70 | !! ah_wslp2 .... |
|---|
| 71 | !! akz stabilizing vertical diffusivity coefficient (used in trazdf_imp) |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 74 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 75 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 76 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 77 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 78 | REAL(wp), DIMENSION(jpi,jpj,jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 79 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 80 | REAL(wp), DIMENSION(jpi,jpj, kjpt), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 81 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 82 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptbb ! tracer (only used in kpass=2) |
|---|
| 83 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
|---|
| 84 | ! |
|---|
| 85 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 86 | INTEGER :: ip,jp,kp ! dummy loop indices |
|---|
| 87 | INTEGER :: ierr ! local integer |
|---|
| 88 | REAL(wp) :: zmsku, zabe1, zcof1, zcoef3 ! local scalars |
|---|
| 89 | REAL(wp) :: zmskv, zabe2, zcof2, zcoef4 ! - - |
|---|
| 90 | REAL(wp) :: zcoef0, ze3w_2, zsign, z2dt, z1_2dt ! - - |
|---|
| 91 | ! |
|---|
| 92 | REAL(wp) :: zslope_skew, zslope_iso, zslope2, zbu, zbv |
|---|
| 93 | REAL(wp) :: ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt |
|---|
| 94 | REAL(wp) :: zah, zah_slp, zaei_slp |
|---|
| 95 | REAL(wp), DIMENSION(jpi,jpj ) :: z2d ! 2D workspace |
|---|
| 96 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ! 3D - |
|---|
| 97 | !!---------------------------------------------------------------------- |
|---|
| 98 | ! |
|---|
| 99 | IF( ln_timing ) CALL timing_start('tra_ldf_triad') |
|---|
| 100 | ! |
|---|
| 101 | IF( .NOT.ALLOCATED(zdkt3d) ) THEN |
|---|
| 102 | ALLOCATE( zdkt3d(jpi,jpj,0:1) , STAT=ierr ) |
|---|
| 103 | IF( lk_mpp ) CALL mpp_sum ( ierr ) |
|---|
| 104 | IF( ierr > 0 ) CALL ctl_stop('STOP', 'tra_ldf_triad: unable to allocate arrays') |
|---|
| 105 | ENDIF |
|---|
| 106 | ! |
|---|
| 107 | IF( kpass == 1 .AND. kt == kit000 ) THEN |
|---|
| 108 | IF(lwp) WRITE(numout,*) |
|---|
| 109 | IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype |
|---|
| 110 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~' |
|---|
| 111 | ENDIF |
|---|
| 112 | ! |
|---|
| 113 | l_hst = .FALSE. |
|---|
| 114 | l_ptr = .FALSE. |
|---|
| 115 | IF( cdtype == 'TRA' .AND. ln_diaptr ) l_ptr = .TRUE. |
|---|
| 116 | IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. & |
|---|
| 117 | & iom_use("uadv_salttr") .OR. iom_use("vadv_salttr") ) ) l_hst = .TRUE. |
|---|
| 118 | ! |
|---|
| 119 | ! ! set time step size (Euler/Leapfrog) |
|---|
| 120 | IF( neuler == 0 .AND. kt == kit000 ) THEN ; z2dt = rdt ! at nit000 (Euler) |
|---|
| 121 | ELSE ; z2dt = 2.* rdt ! (Leapfrog) |
|---|
| 122 | ENDIF |
|---|
| 123 | z1_2dt = 1._wp / z2dt |
|---|
| 124 | ! |
|---|
| 125 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
|---|
| 126 | ELSE ; zsign = -1._wp |
|---|
| 127 | ENDIF |
|---|
| 128 | ! |
|---|
| 129 | !!---------------------------------------------------------------------- |
|---|
| 130 | !! 0 - calculate ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw |
|---|
| 131 | !!---------------------------------------------------------------------- |
|---|
| 132 | ! |
|---|
| 133 | IF( kpass == 1 ) THEN !== first pass only and whatever the tracer is ==! |
|---|
| 134 | ! |
|---|
| 135 | akz (:,:,:) = 0._wp |
|---|
| 136 | ah_wslp2(:,:,:) = 0._wp |
|---|
| 137 | IF( ln_ldfeiv_dia ) THEN |
|---|
| 138 | zpsi_uw(:,:,:) = 0._wp |
|---|
| 139 | zpsi_vw(:,:,:) = 0._wp |
|---|
| 140 | ENDIF |
|---|
| 141 | ! |
|---|
| 142 | DO ip = 0, 1 ! i-k triads |
|---|
| 143 | DO kp = 0, 1 |
|---|
| 144 | DO jk = 1, jpkm1 |
|---|
| 145 | DO jj = 1, jpjm1 |
|---|
| 146 | DO ji = 1, fs_jpim1 |
|---|
| 147 | ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp) |
|---|
| 148 | zbu = e1e2u(ji,jj) * e3u_n(ji,jj,jk) |
|---|
| 149 | zah = 0.25_wp * pahu(ji,jj,jk) |
|---|
| 150 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 151 | ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth) |
|---|
| 152 | zslope2 = zslope_skew + ( gdept_n(ji+1,jj,jk) - gdept_n(ji,jj,jk) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 153 | zslope2 = zslope2 *zslope2 |
|---|
| 154 | ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji+ip,jj) * zslope2 |
|---|
| 155 | akz (ji+ip,jj,jk+kp) = akz (ji+ip,jj,jk+kp) + zah * r1_e1u(ji,jj) & |
|---|
| 156 | & * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 157 | ! |
|---|
| 158 | IF( ln_ldfeiv_dia ) zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) & |
|---|
| 159 | & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * zslope_skew |
|---|
| 160 | END DO |
|---|
| 161 | END DO |
|---|
| 162 | END DO |
|---|
| 163 | END DO |
|---|
| 164 | END DO |
|---|
| 165 | ! |
|---|
| 166 | DO jp = 0, 1 ! j-k triads |
|---|
| 167 | DO kp = 0, 1 |
|---|
| 168 | DO jk = 1, jpkm1 |
|---|
| 169 | DO jj = 1, jpjm1 |
|---|
| 170 | DO ji = 1, fs_jpim1 |
|---|
| 171 | ze3wr = 1.0_wp / e3w_n(ji,jj+jp,jk+kp) |
|---|
| 172 | zbv = e1e2v(ji,jj) * e3v_n(ji,jj,jk) |
|---|
| 173 | zah = 0.25_wp * pahv(ji,jj,jk) |
|---|
| 174 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 175 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
|---|
| 176 | ! (do this by *adding* gradient of depth) |
|---|
| 177 | zslope2 = zslope_skew + ( gdept_n(ji,jj+1,jk) - gdept_n(ji,jj,jk) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 178 | zslope2 = zslope2 * zslope2 |
|---|
| 179 | ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj+jp) * zslope2 |
|---|
| 180 | akz (ji,jj+jp,jk+kp) = akz (ji,jj+jp,jk+kp) + zah * r1_e2v(ji,jj) & |
|---|
| 181 | & * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 182 | ! |
|---|
| 183 | IF( ln_ldfeiv_dia ) zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) & |
|---|
| 184 | & + 0.25 * aeiv(ji,jj,jk) * e1v(ji,jj) * zslope_skew |
|---|
| 185 | END DO |
|---|
| 186 | END DO |
|---|
| 187 | END DO |
|---|
| 188 | END DO |
|---|
| 189 | END DO |
|---|
| 190 | ! |
|---|
| 191 | IF( ln_traldf_msc ) THEN ! stabilizing vertical diffusivity coefficient |
|---|
| 192 | ! |
|---|
| 193 | IF( ln_traldf_blp ) THEN ! bilaplacian operator |
|---|
| 194 | DO jk = 2, jpkm1 |
|---|
| 195 | DO jj = 1, jpjm1 |
|---|
| 196 | DO ji = 1, fs_jpim1 |
|---|
| 197 | akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk) & |
|---|
| 198 | & * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) ) ) |
|---|
| 199 | END DO |
|---|
| 200 | END DO |
|---|
| 201 | END DO |
|---|
| 202 | ELSEIF( ln_traldf_lap ) THEN ! laplacian operator |
|---|
| 203 | DO jk = 2, jpkm1 |
|---|
| 204 | DO jj = 1, jpjm1 |
|---|
| 205 | DO ji = 1, fs_jpim1 |
|---|
| 206 | ze3w_2 = e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) |
|---|
| 207 | zcoef0 = z2dt * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2 ) |
|---|
| 208 | akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt |
|---|
| 209 | END DO |
|---|
| 210 | END DO |
|---|
| 211 | END DO |
|---|
| 212 | ENDIF |
|---|
| 213 | ! |
|---|
| 214 | ELSE ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit |
|---|
| 215 | akz(:,:,:) = ah_wslp2(:,:,:) |
|---|
| 216 | ENDIF |
|---|
| 217 | ! |
|---|
| 218 | IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) CALL ldf_eiv_dia( zpsi_uw, zpsi_vw ) |
|---|
| 219 | ! |
|---|
| 220 | ENDIF !== end 1st pass only ==! |
|---|
| 221 | ! |
|---|
| 222 | ! ! =========== |
|---|
| 223 | DO jn = 1, kjpt ! tracer loop |
|---|
| 224 | ! ! =========== |
|---|
| 225 | ! Zero fluxes for each tracer |
|---|
| 226 | !!gm this should probably be done outside the jn loop |
|---|
| 227 | ztfw(:,:,:) = 0._wp |
|---|
| 228 | zftu(:,:,:) = 0._wp |
|---|
| 229 | zftv(:,:,:) = 0._wp |
|---|
| 230 | ! |
|---|
| 231 | DO jk = 1, jpkm1 !== before lateral T & S gradients at T-level jk ==! |
|---|
| 232 | DO jj = 1, jpjm1 |
|---|
| 233 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 234 | zdit(ji,jj,jk) = ( ptb(ji+1,jj ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
|---|
| 235 | zdjt(ji,jj,jk) = ( ptb(ji ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
|---|
| 236 | END DO |
|---|
| 237 | END DO |
|---|
| 238 | END DO |
|---|
| 239 | IF( ln_zps .AND. l_grad_zps ) THEN ! partial steps: correction at top/bottom ocean level |
|---|
| 240 | DO jj = 1, jpjm1 ! bottom level |
|---|
| 241 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 242 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
|---|
| 243 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
|---|
| 244 | END DO |
|---|
| 245 | END DO |
|---|
| 246 | IF( ln_isfcav ) THEN ! top level (ocean cavities only) |
|---|
| 247 | DO jj = 1, jpjm1 |
|---|
| 248 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 249 | IF( miku(ji,jj) > 1 ) zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) |
|---|
| 250 | IF( mikv(ji,jj) > 1 ) zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) |
|---|
| 251 | END DO |
|---|
| 252 | END DO |
|---|
| 253 | ENDIF |
|---|
| 254 | ENDIF |
|---|
| 255 | ! |
|---|
| 256 | !!---------------------------------------------------------------------- |
|---|
| 257 | !! II - horizontal trend (full) |
|---|
| 258 | !!---------------------------------------------------------------------- |
|---|
| 259 | ! |
|---|
| 260 | DO jk = 1, jpkm1 |
|---|
| 261 | ! !== Vertical tracer gradient at level jk and jk+1 |
|---|
| 262 | zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1) |
|---|
| 263 | ! |
|---|
| 264 | ! ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1) |
|---|
| 265 | IF( jk == 1 ) THEN ; zdkt3d(:,:,0) = zdkt3d(:,:,1) |
|---|
| 266 | ELSE ; zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk) |
|---|
| 267 | ENDIF |
|---|
| 268 | ! |
|---|
| 269 | zaei_slp = 0._wp |
|---|
| 270 | ! |
|---|
| 271 | IF( ln_botmix_triad ) THEN |
|---|
| 272 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 273 | DO kp = 0, 1 |
|---|
| 274 | DO jj = 1, jpjm1 |
|---|
| 275 | DO ji = 1, fs_jpim1 |
|---|
| 276 | ze1ur = r1_e1u(ji,jj) |
|---|
| 277 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 278 | ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp) |
|---|
| 279 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 280 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 281 | zslope_iso = triadi (ji+ip,jj,jk,1-ip,kp) |
|---|
| 282 | ! |
|---|
| 283 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk) |
|---|
| 284 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 285 | zah = pahu(ji,jj,jk) |
|---|
| 286 | zah_slp = zah * zslope_iso |
|---|
| 287 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew |
|---|
| 288 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 289 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 290 | END DO |
|---|
| 291 | END DO |
|---|
| 292 | END DO |
|---|
| 293 | END DO |
|---|
| 294 | ! |
|---|
| 295 | DO jp = 0, 1 |
|---|
| 296 | DO kp = 0, 1 |
|---|
| 297 | DO jj = 1, jpjm1 |
|---|
| 298 | DO ji = 1, fs_jpim1 |
|---|
| 299 | ze2vr = r1_e2v(ji,jj) |
|---|
| 300 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 301 | ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp) |
|---|
| 302 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 303 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 304 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 305 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk) |
|---|
| 306 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahv is masked... |
|---|
| 307 | zah = pahv(ji,jj,jk) |
|---|
| 308 | zah_slp = zah * zslope_iso |
|---|
| 309 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew |
|---|
| 310 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 311 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt * zbv * ze3wr |
|---|
| 312 | END DO |
|---|
| 313 | END DO |
|---|
| 314 | END DO |
|---|
| 315 | END DO |
|---|
| 316 | ! |
|---|
| 317 | ELSE |
|---|
| 318 | ! |
|---|
| 319 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 320 | DO kp = 0, 1 |
|---|
| 321 | DO jj = 1, jpjm1 |
|---|
| 322 | DO ji = 1, fs_jpim1 |
|---|
| 323 | ze1ur = r1_e1u(ji,jj) |
|---|
| 324 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 325 | ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp) |
|---|
| 326 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 327 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 328 | zslope_iso = triadi(ji+ip,jj,jk,1-ip,kp) |
|---|
| 329 | ! |
|---|
| 330 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk) |
|---|
| 331 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 332 | zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp) ! pahu(ji+ip,jj,jk) ===>> ???? |
|---|
| 333 | zah_slp = zah * zslope_iso |
|---|
| 334 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew ! aeit(ji+ip,jj,jk)*zslope_skew |
|---|
| 335 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 336 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 337 | END DO |
|---|
| 338 | END DO |
|---|
| 339 | END DO |
|---|
| 340 | END DO |
|---|
| 341 | ! |
|---|
| 342 | DO jp = 0, 1 |
|---|
| 343 | DO kp = 0, 1 |
|---|
| 344 | DO jj = 1, jpjm1 |
|---|
| 345 | DO ji = 1, fs_jpim1 |
|---|
| 346 | ze2vr = r1_e2v(ji,jj) |
|---|
| 347 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 348 | ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp) |
|---|
| 349 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 350 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 351 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 352 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk) |
|---|
| 353 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 354 | zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 355 | zah_slp = zah * zslope_iso |
|---|
| 356 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew ! aeit(ji,jj+jp,jk)*zslope_skew |
|---|
| 357 | zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 358 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr |
|---|
| 359 | END DO |
|---|
| 360 | END DO |
|---|
| 361 | END DO |
|---|
| 362 | END DO |
|---|
| 363 | ENDIF |
|---|
| 364 | ! !== horizontal divergence and add to the general trend ==! |
|---|
| 365 | DO jj = 2 , jpjm1 |
|---|
| 366 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 367 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( zftu(ji-1,jj,jk) - zftu(ji,jj,jk) & |
|---|
| 368 | & + zftv(ji,jj-1,jk) - zftv(ji,jj,jk) ) & |
|---|
| 369 | & / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) ) |
|---|
| 370 | END DO |
|---|
| 371 | END DO |
|---|
| 372 | ! |
|---|
| 373 | END DO |
|---|
| 374 | ! |
|---|
| 375 | ! !== add the vertical 33 flux ==! |
|---|
| 376 | IF( ln_traldf_lap ) THEN ! laplacian case: eddy coef = ah_wslp2 - akz |
|---|
| 377 | DO jk = 2, jpkm1 |
|---|
| 378 | DO jj = 1, jpjm1 |
|---|
| 379 | DO ji = fs_2, fs_jpim1 |
|---|
| 380 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 381 | & * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) ) & |
|---|
| 382 | & * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) |
|---|
| 383 | END DO |
|---|
| 384 | END DO |
|---|
| 385 | END DO |
|---|
| 386 | ELSE ! bilaplacian |
|---|
| 387 | SELECT CASE( kpass ) |
|---|
| 388 | CASE( 1 ) ! 1st pass : eddy coef = ah_wslp2 |
|---|
| 389 | DO jk = 2, jpkm1 |
|---|
| 390 | DO jj = 1, jpjm1 |
|---|
| 391 | DO ji = fs_2, fs_jpim1 |
|---|
| 392 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 393 | & * ah_wslp2(ji,jj,jk) * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) |
|---|
| 394 | END DO |
|---|
| 395 | END DO |
|---|
| 396 | END DO |
|---|
| 397 | CASE( 2 ) ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb and ptbb gradients, resp. |
|---|
| 398 | DO jk = 2, jpkm1 |
|---|
| 399 | DO jj = 1, jpjm1 |
|---|
| 400 | DO ji = fs_2, fs_jpim1 |
|---|
| 401 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 402 | & * ( ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) ) & |
|---|
| 403 | & + akz (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) ) ) |
|---|
| 404 | END DO |
|---|
| 405 | END DO |
|---|
| 406 | END DO |
|---|
| 407 | END SELECT |
|---|
| 408 | ENDIF |
|---|
| 409 | ! |
|---|
| 410 | DO jk = 1, jpkm1 !== Divergence of vertical fluxes added to pta ==! |
|---|
| 411 | DO jj = 2, jpjm1 |
|---|
| 412 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 413 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk) ) & |
|---|
| 414 | & / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) ) |
|---|
| 415 | END DO |
|---|
| 416 | END DO |
|---|
| 417 | END DO |
|---|
| 418 | ! |
|---|
| 419 | IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR. & !== first pass only ( laplacian) ==! |
|---|
| 420 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass (bilaplacian) ==! |
|---|
| 421 | ! |
|---|
| 422 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
|---|
| 423 | IF( l_ptr ) CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:) ) |
|---|
| 424 | ! ! Diffusive heat transports |
|---|
| 425 | IF( l_hst ) CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) ) |
|---|
| 426 | ! |
|---|
| 427 | ENDIF !== end pass selection ==! |
|---|
| 428 | ! |
|---|
| 429 | ! ! =============== |
|---|
| 430 | END DO ! end tracer loop |
|---|
| 431 | ! ! =============== |
|---|
| 432 | IF( ln_timing ) CALL timing_stop('tra_ldf_triad') |
|---|
| 433 | ! |
|---|
| 434 | END SUBROUTINE tra_ldf_triad |
|---|
| 435 | |
|---|
| 436 | !!============================================================================== |
|---|
| 437 | END MODULE traldf_triad |
|---|
