New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

zdfiwm.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

Context Navigation

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfiwm.F90 @ 9019

Last change on this file since 9019 was 9019, checked in by timgraham, 6 years ago
Merge of dev_CNRS_2017 into branch
File size: 25.5 KB

Line
1	MODULE zdfiwm
2	!!========================================================================
3	!! * MODULE zdfiwm *
4	!! Ocean physics: Internal gravity wave-driven vertical mixing
5	!!========================================================================
6	!! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code
7	!! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait
8	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
9	!! 3.6 ! 2016-03 (C. de Lavergne) New param: internal wave-driven mixing
10	!! 4.0 ! 2017-04 (G. Madec) renamed module, remove the old param. and the CPP keys
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! zdf_iwm : global momentum & tracer Kz with wave induced Kz
15	!! zdf_iwm_init : global momentum & tracer Kz with wave induced Kz
16	!!----------------------------------------------------------------------
17	USE oce ! ocean dynamics and tracers variables
18	USE dom_oce ! ocean space and time domain variables
19	USE zdf_oce ! ocean vertical physics variables
20	USE zdfddm ! ocean vertical physics: double diffusive mixing
21	USE lbclnk ! ocean lateral boundary conditions (or mpp link)
22	USE eosbn2 ! ocean equation of state
23	USE phycst ! physical constants
24	USE prtctl ! Print control
25	USE in_out_manager ! I/O manager
26	USE iom ! I/O Manager
27	USE lib_mpp ! MPP library
28	USE wrk_nemo ! work arrays
29	USE timing ! Timing
30	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
31
32	IMPLICIT NONE
33	PRIVATE
34
35	PUBLIC zdf_iwm ! called in step module
36	PUBLIC zdf_iwm_init ! called in nemogcm module
37
38	! !!* Namelist namzdf_iwm : internal wave-driven mixing *
39	INTEGER :: nn_zpyc ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2)
40	LOGICAL :: ln_mevar ! variable (=T) or constant (=F) mixing efficiency
41	LOGICAL :: ln_tsdiff ! account for differential T/S wave-driven mixing (=T) or not (=F)
42
43	REAL(wp):: r1_6 = 1._wp / 6._wp
44
45	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ebot_iwm ! power available from high-mode wave breaking (W/m2)
46	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: epyc_iwm ! power available from low-mode, pycnocline-intensified wave breaking (W/m2)
47	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ecri_iwm ! power available from low-mode, critical slope wave breaking (W/m2)
48	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hbot_iwm ! WKB decay scale for high-mode energy dissipation (m)
49	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hcri_iwm ! decay scale for low-mode critical slope dissipation (m)
50
51	!! * Substitutions
52	# include "vectopt_loop_substitute.h90"
53	!!----------------------------------------------------------------------
54	!! NEMO/OPA 4.0 , NEMO Consortium (2016)
55	!! $Id: zdfiwm.F90 8093 2017-05-30 08:13:14Z gm $
56	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
57	!!----------------------------------------------------------------------
58	CONTAINS
59
60	INTEGER FUNCTION zdf_iwm_alloc()
61	!!----------------------------------------------------------------------
62	!! * FUNCTION zdf_iwm_alloc *
63	!!----------------------------------------------------------------------
64	ALLOCATE( ebot_iwm(jpi,jpj), epyc_iwm(jpi,jpj), ecri_iwm(jpi,jpj) , &
65	& hbot_iwm(jpi,jpj), hcri_iwm(jpi,jpj) , STAT=zdf_iwm_alloc )
66	!
67	IF( lk_mpp ) CALL mpp_sum ( zdf_iwm_alloc )
68	IF( zdf_iwm_alloc /= 0 ) CALL ctl_warn('zdf_iwm_alloc: failed to allocate arrays')
69	END FUNCTION zdf_iwm_alloc
70
71
72	SUBROUTINE zdf_iwm( kt, p_avm, p_avt, p_avs )
73	!!----------------------------------------------------------------------
74	!! * ROUTINE zdf_iwm *
75	!!
76	!! ** Purpose : add to the vertical mixing coefficients the effect of
77	!! breaking internal waves.
78	!!
79	!! ** Method : - internal wave-driven vertical mixing is given by:
80	!! Kz_wave = min( 100 cm2/s, f( Reb = zemx_iwm /( Nu * N^2 ) )
81	!! where zemx_iwm is the 3D space distribution of the wave-breaking
82	!! energy and Nu the molecular kinematic viscosity.
83	!! The function f(Reb) is linear (constant mixing efficiency)
84	!! if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T.
85	!!
86	!! - Compute zemx_iwm, the 3D power density that allows to compute
87	!! Reb and therefrom the wave-induced vertical diffusivity.
88	!! This is divided into three components:
89	!! 1. Bottom-intensified low-mode dissipation at critical slopes
90	!! zemx_iwm(z) = ( ecri_iwm / rau0 ) * EXP( -(H-z)/hcri_iwm )
91	!! / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm
92	!! where hcri_iwm is the characteristic length scale of the bottom
93	!! intensification, ecri_iwm a map of available power, and H the ocean depth.
94	!! 2. Pycnocline-intensified low-mode dissipation
95	!! zemx_iwm(z) = ( epyc_iwm / rau0 ) * ( sqrt(rn2(z))^nn_zpyc )
96	!! / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) )
97	!! where epyc_iwm is a map of available power, and nn_zpyc
98	!! is the chosen stratification-dependence of the internal wave
99	!! energy dissipation.
100	!! 3. WKB-height dependent high mode dissipation
101	!! zemx_iwm(z) = ( ebot_iwm / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm)
102	!! / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w(z) )
103	!! where hbot_iwm is the characteristic length scale of the WKB bottom
104	!! intensification, ebot_iwm is a map of available power, and z_wkb is the
105	!! WKB-stretched height above bottom defined as
106	!! z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) )
107	!! / SUM( sqrt(rn2(z')) * e3w(z') )
108	!!
109	!! - update the model vertical eddy viscosity and diffusivity:
110	!! avt = avt + av_wave
111	!! avm = avm + av_wave
112	!!
113	!! - if namelist parameter ln_tsdiff = T, account for differential mixing:
114	!! avs = avt + av_wave * diffusivity_ratio(Reb)
115	!!
116	!! ** Action : - avt, avs, avm, increased by tide internal wave-driven mixing
117	!!
118	!! References : de Lavergne et al. 2015, JPO; 2016, in prep.
119	!!----------------------------------------------------------------------
120	INTEGER , INTENT(in ) :: kt ! ocean time step
121	REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: p_avm ! momentum Kz (w-points)
122	REAL(wp), DIMENSION(:,:,:) , INTENT(inout) :: p_avt, p_avs ! tracer Kz (w-points)
123	!
124	INTEGER :: ji, jj, jk ! dummy loop indices
125	REAL(wp) :: zztmp ! scalar workspace
126	REAL(wp), DIMENSION(jpi,jpj) :: zfact ! Used for vertical structure
127	REAL(wp), DIMENSION(jpi,jpj) :: zhdep ! Ocean depth
128	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwkb ! WKB-stretched height above bottom
129	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zweight ! Weight for high mode vertical distribution
130	REAL(wp), DIMENSION(jpi,jpj,jpk) :: znu_t ! Molecular kinematic viscosity (T grid)
131	REAL(wp), DIMENSION(jpi,jpj,jpk) :: znu_w ! Molecular kinematic viscosity (W grid)
132	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zReb ! Turbulence intensity parameter
133	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zemx_iwm ! local energy density available for mixing (W/kg)
134	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zav_ratio ! S/T diffusivity ratio (only for ln_tsdiff=T)
135	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zav_wave ! Internal wave-induced diffusivity
136	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: z3d ! 3D workspace used for iom_put
137	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z2d ! 2D - - - -
138	!!----------------------------------------------------------------------
139	!
140	IF( ln_timing ) CALL timing_start('zdf_iwm')
141	!
142	! !* Set to zero the 1st and last vertical levels of appropriate variables
143	zemx_iwm (:,:,1) = 0._wp ; zemx_iwm (:,:,jpk) = 0._wp
144	zav_ratio(:,:,1) = 0._wp ; zav_ratio(:,:,jpk) = 0._wp
145	zav_wave (:,:,1) = 0._wp ; zav_wave (:,:,jpk) = 0._wp
146	!
147	! ! ----------------------------- !
148	! ! Internal wave-driven mixing ! (compute zav_wave)
149	! ! ----------------------------- !
150	!
151	! !* Critical slope mixing: distribute energy over the time-varying ocean depth,
152	! using an exponential decay from the seafloor.
153	DO jj = 1, jpj ! part independent of the level
154	DO ji = 1, jpi
155	zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean
156	zfact(ji,jj) = rau0 * ( 1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) ) )
157	IF( zfact(ji,jj) /= 0._wp ) zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj)
158	END DO
159	END DO
160	!!gm gde3w ==>>> check for ssh taken into account.... seem OK gde3w_n=gdept_n - sshn
161	DO jk = 2, jpkm1 ! complete with the level-dependent part
162	zemx_iwm(:,:,jk) = zfact(:,:) * ( EXP( ( gde3w_n(:,:,jk ) - zhdep(:,:) ) / hcri_iwm(:,:) ) &
163	& - EXP( ( gde3w_n(:,:,jk-1) - zhdep(:,:) ) / hcri_iwm(:,:) ) ) * wmask(:,:,jk) &
164	& / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) )
165
166	!!gm delta(gde3w_n) = e3t_n !! Please verify the grid-point position w versus t-point
167	!!gm it seems to me that only 1/hcri_iwm is used ==> compute it one for all
168
169	END DO
170
171	! !* Pycnocline-intensified mixing: distribute energy over the time-varying
172	! !* ocean depth as proportional to sqrt(rn2)^nn_zpyc
173	! ! (NB: N2 is masked, so no use of wmask here)
174	SELECT CASE ( nn_zpyc )
175	!
176	CASE ( 1 ) ! Dissipation scales as N (recommended)
177	!
178	zfact(:,:) = 0._wp
179	DO jk = 2, jpkm1 ! part independent of the level
180	zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk)
181	END DO
182	!
183	DO jj = 1, jpj
184	DO ji = 1, jpi
185	IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
186	END DO
187	END DO
188	!
189	DO jk = 2, jpkm1 ! complete with the level-dependent part
190	zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk)
191	END DO
192	!
193	CASE ( 2 ) ! Dissipation scales as N^2
194	!
195	zfact(:,:) = 0._wp
196	DO jk = 2, jpkm1 ! part independent of the level
197	zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
198	END DO
199	!
200	DO jj= 1, jpj
201	DO ji = 1, jpi
202	IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
203	END DO
204	END DO
205	!
206	DO jk = 2, jpkm1 ! complete with the level-dependent part
207	zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
208	END DO
209	!
210	END SELECT
211
212	! !* WKB-height dependent mixing: distribute energy over the time-varying
213	! !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot)
214	!
215	zwkb (:,:,:) = 0._wp
216	zfact(:,:) = 0._wp
217	DO jk = 2, jpkm1
218	zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk)
219	zwkb(:,:,jk) = zfact(:,:)
220	END DO
221	!!gm even better:
222	! DO jk = 2, jpkm1
223	! zwkb(:,:) = zwkb(:,:) + e3w_n(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) )
224	! END DO
225	! zfact(:,:) = zwkb(:,:,jpkm1)
226	!!gm or just use zwkb(k=jpk-1) instead of zfact...
227	!!gm
228	!
229	DO jk = 2, jpkm1
230	DO jj = 1, jpj
231	DO ji = 1, jpi
232	IF( zfact(ji,jj) /= 0 ) zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) ) &
233	& * wmask(ji,jj,jk) / zfact(ji,jj)
234	END DO
235	END DO
236	END DO
237	zwkb(:,:,1) = zhdep(:,:) * wmask(:,:,1)
238	!
239	zweight(:,:,:) = 0._wp
240	DO jk = 2, jpkm1
241	zweight(:,:,jk) = MAX( 0._wp, rn2(:,:,jk) ) * hbot_iwm(:,:) * wmask(:,:,jk) &
242	& * ( EXP( -zwkb(:,:,jk) / hbot_iwm(:,:) ) - EXP( -zwkb(:,:,jk-1) / hbot_iwm(:,:) ) )
243	END DO
244	!
245	zfact(:,:) = 0._wp
246	DO jk = 2, jpkm1 ! part independent of the level
247	zfact(:,:) = zfact(:,:) + zweight(:,:,jk)
248	END DO
249	!
250	DO jj = 1, jpj
251	DO ji = 1, jpi
252	IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ebot_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
253	END DO
254	END DO
255	!
256	DO jk = 2, jpkm1 ! complete with the level-dependent part
257	zemx_iwm(:,:,jk) = zemx_iwm(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk) &
258	& / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) )
259	!!gm use of e3t_n just above?
260	END DO
261	!
262	!!gm this is to be replaced by just a constant value znu=1.e-6 m2/s
263	! Calculate molecular kinematic viscosity
264	znu_t(:,:,:) = 1.e-4_wp * ( 17.91_wp - 0.53810_wp * tsn(:,:,:,jp_tem) + 0.00694_wp * tsn(:,:,:,jp_tem) * tsn(:,:,:,jp_tem) &
265	& + 0.02305_wp * tsn(:,:,:,jp_sal) ) * tmask(:,:,:) * r1_rau0
266	DO jk = 2, jpkm1
267	znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk)
268	END DO
269	!!gm end
270	!
271	! Calculate turbulence intensity parameter Reb
272	DO jk = 2, jpkm1
273	zReb(:,:,jk) = zemx_iwm(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) )
274	END DO
275	!
276	! Define internal wave-induced diffusivity
277	DO jk = 2, jpkm1
278	zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6 ! This corresponds to a constant mixing efficiency of 1/6
279	END DO
280	!
281	IF( ln_mevar ) THEN ! Variable mixing efficiency case : modify zav_wave in the
282	DO jk = 2, jpkm1 ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes
283	DO jj = 1, jpj
284	DO ji = 1, jpi
285	IF( zReb(ji,jj,jk) > 480.00_wp ) THEN
286	zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
287	ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN
288	zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
289	ENDIF
290	END DO
291	END DO
292	END DO
293	ENDIF
294	!
295	DO jk = 2, jpkm1 ! Bound diffusivity by molecular value and 100 cm2/s
296	zav_wave(:,:,jk) = MIN( MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp ) * wmask(:,:,jk)
297	END DO
298	!
299	IF( kt == nit000 ) THEN !* Control print at first time-step: diagnose the energy consumed by zav_wave
300	zztmp = 0._wp
301	!!gm used of glosum 3D....
302	DO jk = 2, jpkm1
303	DO jj = 1, jpj
304	DO ji = 1, jpi
305	zztmp = zztmp + e3w_n(ji,jj,jk) * e1e2t(ji,jj) &
306	& * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
307	END DO
308	END DO
309	END DO
310	IF( lk_mpp ) CALL mpp_sum( zztmp )
311	zztmp = rau0 * zztmp ! Global integral of rauo * Kz * N^2 = power contributing to mixing
312	!
313	IF(lwp) THEN
314	WRITE(numout,*)
315	WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)'
316	WRITE(numout,*) '~~~~~~~ '
317	WRITE(numout,*)
318	WRITE(numout,) ' Total power consumption by av_wave = ', zztmp 1.e-12_wp, 'TW'
319	ENDIF
320	ENDIF
321
322	! ! ----------------------- !
323	! ! Update mixing coefs !
324	! ! ----------------------- !
325	!
326	IF( ln_tsdiff ) THEN !* Option for differential mixing of salinity and temperature
327	DO jk = 2, jpkm1 ! Calculate S/T diffusivity ratio as a function of Reb
328	DO jj = 1, jpj
329	DO ji = 1, jpi
330	zav_ratio(ji,jj,jk) = ( 0.505_wp + 0.495_wp * &
331	& TANH( 0.92_wp * ( LOG10( MAX( 1.e-20_wp, zReb(ji,jj,jk) * 5._wp * r1_6 ) ) - 0.60_wp ) ) &
332	& ) * wmask(ji,jj,jk)
333	END DO
334	END DO
335	END DO
336	CALL iom_put( "av_ratio", zav_ratio )
337	DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with wave-driven mixing
338	p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk)
339	p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk)
340	p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk)
341	END DO
342	!
343	ELSE !* update momentum & tracer diffusivity with wave-driven mixing
344	DO jk = 2, jpkm1
345	p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk)
346	p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk)
347	p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk)
348	END DO
349	ENDIF
350
351	! !* output internal wave-driven mixing coefficient
352	CALL iom_put( "av_wave", zav_wave )
353	!* output useful diagnostics: Kz*N^2 ,
354	!!gm Kz*N2 should take into account the ratio avs/avt if it is used.... (see diaar5)
355	! vertical integral of rau0 * Kz * N^2 , energy density (zemx_iwm)
356	IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN
357	ALLOCATE( z2d(jpi,jpj) , z3d(jpi,jpj,jpk) )
358	z3d(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:)
359	z2d(:,:) = 0._wp
360	DO jk = 2, jpkm1
361	z2d(:,:) = z2d(:,:) + e3w_n(:,:,jk) * z3d(:,:,jk) * wmask(:,:,jk)
362	END DO
363	z2d(:,:) = rau0 * z2d(:,:)
364	CALL iom_put( "bflx_iwm", z3d )
365	CALL iom_put( "pcmap_iwm", z2d )
366	DEALLOCATE( z2d , z3d )
367	ENDIF
368	CALL iom_put( "emix_iwm", zemx_iwm )
369
370	IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk)
371	!
372	IF( ln_timing ) CALL timing_stop('zdf_iwm')
373	!
374	END SUBROUTINE zdf_iwm
375
376
377	SUBROUTINE zdf_iwm_init
378	!!----------------------------------------------------------------------
379	!! * ROUTINE zdf_iwm_init *
380	!!
381	!! ** Purpose : Initialization of the wave-driven vertical mixing, reading
382	!! of input power maps and decay length scales in netcdf files.
383	!!
384	!! ** Method : - Read the namzdf_iwm namelist and check the parameters
385	!!
386	!! - Read the input data in NetCDF files :
387	!! power available from high-mode wave breaking (mixing_power_bot.nc)
388	!! power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc)
389	!! power available from critical slope wave-breaking (mixing_power_cri.nc)
390	!! WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc)
391	!! decay scale for critical slope wave-breaking (decay_scale_cri.nc)
392	!!
393	!! ** input : - Namlist namzdf_iwm
394	!! - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc,
395	!! decay_scale_bot.nc decay_scale_cri.nc
396	!!
397	!! ** Action : - Increase by 1 the nstop flag is setting problem encounter
398	!! - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm
399	!!
400	!! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016
401	!! de Lavergne et al. in prep., 2017
402	!!----------------------------------------------------------------------
403	INTEGER :: ji, jj, jk ! dummy loop indices
404	INTEGER :: inum ! local integer
405	INTEGER :: ios
406	REAL(wp) :: zbot, zpyc, zcri ! local scalars
407	!!
408	NAMELIST/namzdf_iwm_new/ nn_zpyc, ln_mevar, ln_tsdiff
409	!!----------------------------------------------------------------------
410	!
411	IF( ln_timing ) CALL timing_start('zdf_iwm_init')
412	!
413	REWIND( numnam_ref ) ! Namelist namzdf_iwm in reference namelist : Wave-driven mixing
414	READ ( numnam_ref, namzdf_iwm_new, IOSTAT = ios, ERR = 901)
415	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist', lwp )
416	!
417	REWIND( numnam_cfg ) ! Namelist namzdf_iwm in configuration namelist : Wave-driven mixing
418	READ ( numnam_cfg, namzdf_iwm_new, IOSTAT = ios, ERR = 902 )
419	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist', lwp )
420	IF(lwm) WRITE ( numond, namzdf_iwm_new )
421	!
422	IF(lwp) THEN ! Control print
423	WRITE(numout,*)
424	WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing'
425	WRITE(numout,*) '~~~~~~~~~~~~'
426	WRITE(numout,*) ' Namelist namzdf_iwm_new : set wave-driven mixing parameters'
427	WRITE(numout,*) ' Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc
428	WRITE(numout,*) ' Variable (T) or constant (F) mixing efficiency = ', ln_mevar
429	WRITE(numout,*) ' Differential internal wave-driven mixing (T) or not (F) = ', ln_tsdiff
430	ENDIF
431
432	! The new wave-driven mixing parameterization elevates avt and avm in the interior, and
433	! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should
434	! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6).
435	avmb(:) = 1.4e-6_wp ! viscous molecular value
436	avtb(:) = 1.e-10_wp ! very small diffusive minimum (background avt is specified in zdf_iwm)
437	avtb_2d(:,:) = 1.e0_wp ! uniform
438	IF(lwp) THEN ! Control print
439	WRITE(numout,*)
440	WRITE(numout,*) ' Force the background value applied to avm & avt in TKE to be everywhere ', &
441	& 'the viscous molecular value & a very small diffusive value, resp.'
442	ENDIF
443
444	! ! allocate iwm arrays
445	IF( zdf_iwm_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' )
446	!
447	! ! read necessary fields
448	CALL iom_open('mixing_power_bot',inum) ! energy flux for high-mode wave breaking [W/m2]
449	CALL iom_get (inum, jpdom_data, 'field', ebot_iwm, 1 )
450	CALL iom_close(inum)
451	!
452	CALL iom_open('mixing_power_pyc',inum) ! energy flux for pynocline-intensified wave breaking [W/m2]
453	CALL iom_get (inum, jpdom_data, 'field', epyc_iwm, 1 )
454	CALL iom_close(inum)
455	!
456	CALL iom_open('mixing_power_cri',inum) ! energy flux for critical slope wave breaking [W/m2]
457	CALL iom_get (inum, jpdom_data, 'field', ecri_iwm, 1 )
458	CALL iom_close(inum)
459	!
460	CALL iom_open('decay_scale_bot',inum) ! spatially variable decay scale for high-mode wave breaking [m]
461	CALL iom_get (inum, jpdom_data, 'field', hbot_iwm, 1 )
462	CALL iom_close(inum)
463	!
464	CALL iom_open('decay_scale_cri',inum) ! spatially variable decay scale for critical slope wave breaking [m]
465	CALL iom_get (inum, jpdom_data, 'field', hcri_iwm, 1 )
466	CALL iom_close(inum)
467
468	ebot_iwm(:,:) = ebot_iwm(:,:) * ssmask(:,:)
469	epyc_iwm(:,:) = epyc_iwm(:,:) * ssmask(:,:)
470	ecri_iwm(:,:) = ecri_iwm(:,:) * ssmask(:,:)
471
472	zbot = glob_sum( e1e2t(:,:) * ebot_iwm(:,:) )
473	zpyc = glob_sum( e1e2t(:,:) * epyc_iwm(:,:) )
474	zcri = glob_sum( e1e2t(:,:) * ecri_iwm(:,:) )
475	IF(lwp) THEN
476	WRITE(numout,) ' High-mode wave-breaking energy: ', zbot 1.e-12_wp, 'TW'
477	WRITE(numout,) ' Pycnocline-intensifed wave-breaking energy: ', zpyc 1.e-12_wp, 'TW'
478	WRITE(numout,) ' Critical slope wave-breaking energy: ', zcri 1.e-12_wp, 'TW'
479	ENDIF
480	!
481	IF( ln_timing ) CALL timing_stop('zdf_iwm_init')
482	!
483	END SUBROUTINE zdf_iwm_init
484
485	!!======================================================================
486	END MODULE zdfiwm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: