New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 9119

Last change on this file since 9119 was 9023, checked in by timgraham, 6 years ago

Merged METO_MERCATOR branch and resolved all conflicts in OPA_SRC

  • Property svn:keywords set to Id
File size: 40.7 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
36   !!----------------------------------------------------------------------
37
38   !!----------------------------------------------------------------------
39   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
40   !!   nemo_init     : initialization of the NEMO system
41   !!   nemo_ctl      : initialisation of the contol print
42   !!   nemo_closefile: close remaining open files
43   !!   nemo_alloc    : dynamical allocation
44   !!   nemo_partition: calculate MPP domain decomposition
45   !!   factorise     : calculate the factors of the no. of MPI processes
46   !!----------------------------------------------------------------------
47   USE step_oce       ! module used in the ocean time stepping module (step.F90)
48   USE phycst         ! physical constant                  (par_cst routine)
49   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
50   USE usrdef_nam     ! user defined configuration
51   USE tideini        ! tidal components initialization   (tide_ini routine)
52   USE bdy_oce,  ONLY : ln_bdy
53   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
54   USE istate         ! initial state setting          (istate_init routine)
55   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
56   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
57   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
58   USE asminc         ! assimilation increments     
59   USE asmbkg         ! writing out state trajectory
60   USE diaptr         ! poleward transports           (dia_ptr_init routine)
61   USE diadct         ! sections transports           (dia_dct_init routine)
62   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
63   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
64   USE step           ! NEMO time-stepping                 (stp     routine)
65   USE icbini         ! handle bergs, initialisation
66   USE icbstp         ! handle bergs, calving, themodynamics and transport
67   USE cpl_oasis3     ! OASIS3 coupling
68   USE c1d            ! 1D configuration
69   USE step_c1d       ! Time stepping loop for the 1D configuration
70   USE dyndmp         ! Momentum damping
71   USE stopar         ! Stochastic param.: ???
72   USE stopts         ! Stochastic param.: ???
73   USE diurnal_bulk   ! diurnal bulk SST
74   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
75   USE crsini         ! initialise grid coarsening utility
76   USE diatmb         ! Top,middle,bottom output
77   USE dia25h         ! 25h mean output
78   USE sbc_oce , ONLY : lk_oasis
79   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
80#if defined key_top
81   USE trcini         ! passive tracer initialisation
82#endif
83#if defined key_nemocice_decomp
84   USE ice_domain_size, only: nx_global, ny_global
85#endif
86   !
87   USE lib_mpp        ! distributed memory computing
88   USE mppini         ! shared/distributed memory setting (mpp_init routine)
89   USE lbcnfd , ONLY  : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
90   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
91#if defined key_iomput
92   USE xios           ! xIOserver
93#endif
94
95   IMPLICIT NONE
96   PRIVATE
97
98   PUBLIC   nemo_gcm    ! called by model.F90
99   PUBLIC   nemo_init   ! needed by AGRIF
100   PUBLIC   nemo_alloc  ! needed by TAM
101
102   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
103
104   !!----------------------------------------------------------------------
105   !! NEMO/OPA 3.7 , NEMO Consortium (2016)
106   !! $Id$
107   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
108   !!----------------------------------------------------------------------
109CONTAINS
110
111   SUBROUTINE nemo_gcm
112      !!----------------------------------------------------------------------
113      !!                     ***  ROUTINE nemo_gcm  ***
114      !!
115      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
116      !!              curvilinear mesh on the sphere.
117      !!
118      !! ** Method  : - model general initialization
119      !!              - launch the time-stepping (stp routine)
120      !!              - finalize the run by closing files and communications
121      !!
122      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
123      !!              Madec, 2008, internal report, IPSL.
124      !!----------------------------------------------------------------------
125      INTEGER ::   istp   ! time step index
126      !!----------------------------------------------------------------------
127      !
128#if defined key_agrif
129      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
130#endif
131      !
132      !                            !-----------------------!
133      CALL nemo_init               !==  Initialisations  ==!
134      !                            !-----------------------!
135#if defined key_agrif
136      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
137      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
138# if defined key_top
139      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
140# endif
141# if defined key_lim3
142      CALL Agrif_Declare_Var_lim3  !  "      "   "   "      "  LIM3
143# endif
144#endif
145      ! check that all process are still there... If some process have an error,
146      ! they will never enter in step and other processes will wait until the end of the cpu time!
147      IF( lk_mpp )   CALL mpp_max( nstop )
148
149      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
150
151      !                            !-----------------------!
152      !                            !==   time stepping   ==!
153      !                            !-----------------------!
154      istp = nit000
155#if defined key_c1d
156         DO WHILE ( istp <= nitend .AND. nstop == 0 )
157            CALL stp_c1d( istp )
158            istp = istp + 1
159         END DO
160#else
161          IF( lk_asminc ) THEN
162             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
163             IF( ln_asmdin ) THEN                        ! Direct initialization
164                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
165                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
166                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
167             ENDIF
168          ENDIF
169
170#if defined key_agrif
171          CALL Agrif_Regrid()
172#endif
173
174         DO WHILE ( istp <= nitend .AND. nstop == 0 )
175#if defined key_agrif
176            CALL stp                         ! AGRIF: time stepping
177#else
178            IF ( .NOT. ln_diurnal_only ) THEN
179               CALL stp( istp )                 ! standard time stepping
180            ELSE
181               CALL stp_diurnal( istp )        ! time step only the diurnal SST
182            ENDIF 
183#endif
184            istp = istp + 1
185            IF( lk_mpp )   CALL mpp_max( nstop )
186         END DO
187#endif
188
189      IF( ln_diaobs   )   CALL dia_obs_wri
190      !
191      IF( ln_icebergs )   CALL icb_end( nitend )
192
193      !                            !------------------------!
194      !                            !==  finalize the run  ==!
195      !                            !------------------------!
196      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
197      !
198      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
199         WRITE(numout,cform_err)
200         WRITE(numout,*) nstop, ' error have been found'
201      ENDIF
202      !
203#if defined key_agrif
204      IF( .NOT. Agrif_Root() ) THEN
205         CALL Agrif_ParentGrid_To_ChildGrid()
206         IF( ln_diaobs )        CALL dia_obs_wri
207         IF( nn_timing == 1 )   CALL timing_finalize
208         CALL Agrif_ChildGrid_To_ParentGrid()
209      ENDIF
210#endif
211      IF( ln_timing    )   CALL timing_finalize
212      !
213      CALL nemo_closefile
214      !
215#if defined key_iomput
216      CALL xios_finalize                     ! end mpp communications with xios
217      IF( lk_oasis )   CALL cpl_finalize     ! end coupling and mpp communications with OASIS
218#else
219      IF( lk_oasis ) THEN
220         CALL cpl_finalize                   ! end coupling and mpp communications with OASIS
221      ELSE
222         IF( lk_mpp )   CALL mppstop         ! end mpp communications
223      ENDIF
224#endif
225      !
226   END SUBROUTINE nemo_gcm
227
228
229   SUBROUTINE nemo_init
230      !!----------------------------------------------------------------------
231      !!                     ***  ROUTINE nemo_init  ***
232      !!
233      !! ** Purpose :   initialization of the NEMO GCM
234      !!----------------------------------------------------------------------
235      INTEGER  ::   ji                 ! dummy loop indices
236      INTEGER  ::   ios, ilocal_comm   ! local integer
237      INTEGER  ::   iiarea, ijarea     ! local integers
238      INTEGER  ::   iirest, ijrest     ! local integers
239      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
240      !
241      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
242         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
243         &             ln_timing, ln_diacfl
244      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
245      !!----------------------------------------------------------------------
246      !
247      cltxt  = ''
248      cltxt2 = ''
249      clnam  = '' 
250      cxios_context = 'nemo'
251      !
252      !                             ! Open reference namelist and configuration namelist files
253      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
254      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
255      !
256      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints
257      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
258901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
259      !
260      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
261      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
262902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
263      !
264      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints
265      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
266903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
267
268      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
269      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
270904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
271
272      !                             !--------------------------!
273      !                             !  Set global domain size  !   (control print return in cltxt2)
274      !                             !--------------------------!
275      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
276         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
277         !
278      ELSE                                ! user-defined namelist
279         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
280      ENDIF
281      !
282      !
283      !                             !--------------------------------------------!
284      !                             !  set communicator & select the local node  !
285      !                             !  NB: mynode also opens output.namelist.dyn !
286      !                             !      on unit number numond on first proc   !
287      !                             !--------------------------------------------!
288#if defined key_iomput
289      IF( Agrif_Root() ) THEN
290         IF( lk_oasis ) THEN
291            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
292            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
293         ELSE
294            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
295         ENDIF
296      ENDIF
297      ! Nodes selection (control print return in cltxt)
298      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
299#else
300      IF( lk_oasis ) THEN
301         IF( Agrif_Root() ) THEN
302            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
303         ENDIF
304         ! Nodes selection (control print return in cltxt)
305         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
306      ELSE
307         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
308         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
309      ENDIF
310#endif
311
312      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
313
314      lwm = (narea == 1)                                    ! control of output namelists
315      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
316
317      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
318         !                       ! now that the file has been opened in call to mynode.
319         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
320         WRITE( numond, namctl )
321         WRITE( numond, namcfg )
322         IF( .NOT.ln_read_cfg ) THEN
323            DO ji = 1, SIZE(clnam)
324               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
325            END DO
326         ENDIF
327      ENDIF
328
329      ! If dimensions of processor grid weren't specified in the namelist file
330      ! then we calculate them here now that we have our communicator size
331      IF( jpni < 1 .OR. jpnj < 1 ) THEN
332#if   defined key_mpp_mpi
333         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
334#else
335         jpni  = 1
336         jpnj  = 1
337         jpnij = jpni*jpnj
338#endif
339      ENDIF
340      !
341#if defined key_agrif
342      IF( .NOT. Agrif_Root() ) THEN       ! AGRIF children: specific setting (cf. agrif_user.F90)
343         jpiglo  = nbcellsx + 2 + 2*nbghostcells
344         jpjglo  = nbcellsy + 2 + 2*nbghostcells
345         jpi     = ( jpiglo-2*nn_hls + (jpni-1+0) ) / jpni + 2*nn_hls
346         jpj     = ( jpjglo-2*nn_hls + (jpnj-1+0) ) / jpnj + 2*nn_hls
347         jpimax  = jpi
348         jpjmax  = jpj
349         nperio  = 0
350         jperio  = 0
351         ln_use_jattr = .false.
352      ENDIF
353#endif
354
355      IF( Agrif_Root() ) THEN       ! AGRIF mother: specific setting from jpni and jpnj
356         iiarea = 1 + MOD( narea - 1 , jpni )
357         ijarea = 1 + ( narea - 1 ) / jpni
358         iirest = 1 + MOD( jpiglo - 2*nn_hls - 1 , jpni )
359         ijrest = 1 + MOD( jpjglo - 2*nn_hls - 1 , jpnj )
360#if defined key_nemocice_decomp
361         jpi = ( nx_global+2-2*nn_hls + (jpni-1) ) / jpni + 2*nn_hls    ! first  dim.
362         jpj = ( ny_global+2-2*nn_hls + (jpnj-1) ) / jpnj + 2*nn_hls    ! second dim.
363         jpimax  = jpi
364         jpjmax  = jpj
365         IF( iiarea == jpni ) jpi = jpiglo - (jpni - 1) * (jpi - 2*nn_hls)
366         IF( ijarea == jpnj ) jpj = jpjglo - (jpnj - 1) * (jpj - 2*nn_hls)
367#else
368         jpi = ( jpiglo     -2*nn_hls + (jpni-1) ) / jpni + 2*nn_hls    ! first  dim.
369         jpj = ( jpjglo     -2*nn_hls + (jpnj-1) ) / jpnj + 2*nn_hls    ! second dim.
370         jpimax  = jpi
371         jpjmax  = jpj
372         IF( iiarea > iirest ) jpi = jpi - 1
373         IF( ijarea > ijrest ) jpj = jpj - 1
374#endif
375      ENDIF
376
377      jpk = jpkglo                                             ! third dim
378
379#if defined key_agrif
380      ! simple trick to use same vertical grid as parent but different number of levels:
381      ! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
382      ! Suppress once vertical online interpolation is ok
383      IF(.NOT.Agrif_Root())   jpkglo = Agrif_Parent( jpkglo )
384#endif
385      jpim1 = jpi-1                                            ! inner domain indices
386      jpjm1 = jpj-1                                            !   "           "
387      jpkm1 = MAX( 1, jpk-1 )                                  !   "           "
388      jpij  = jpi*jpj                                          !  jpi x j
389
390      IF(lwp) THEN                            ! open listing units
391         !
392         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
393         !
394         WRITE(numout,*)
395         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
396         WRITE(numout,*) '                       NEMO team'
397         WRITE(numout,*) '            Ocean General Circulation Model'
398         WRITE(numout,*) '                NEMO version 3.7  (2016) '
399         WRITE(numout,*)
400         WRITE(numout,*)
401         DO ji = 1, SIZE(cltxt)
402            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
403         END DO
404         WRITE(numout,*)
405         WRITE(numout,*)
406         DO ji = 1, SIZE(cltxt2)
407            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
408         END DO
409         !
410         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
411         !
412      ENDIF
413
414      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
415      CALL nemo_alloc()
416
417      !                             !-------------------------------!
418      !                             !  NEMO general initialization  !
419      !                             !-------------------------------!
420
421      CALL nemo_ctl                          ! Control prints
422
423      !                                      ! Domain decomposition
424      CALL mpp_init
425      IF( ln_nnogather )   CALL nemo_northcomms! northfold neighbour lists
426      !
427      IF( ln_timing    )   CALL timing_init
428      !
429      !                                      ! General initialization
430                           CALL     phy_cst    ! Physical constants
431                           CALL     eos_init   ! Equation of state
432      IF( lk_c1d       )   CALL     c1d_init   ! 1D column configuration
433                           CALL     wad_init   ! Wetting and drying options
434                           CALL     dom_init   ! Domain
435      IF( ln_crs       )   CALL     crs_init   ! coarsened grid: domain initialization
436      IF( ln_ctl       )   CALL prt_ctl_init   ! Print control
437     
438      CALL diurnal_sst_bulk_init             ! diurnal sst
439      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
440     
441      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
442      IF( ln_diurnal_only ) THEN
443         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
444         CALL     sbc_init   ! Forcings : surface module
445         CALL tra_qsr_init   ! penetrative solar radiation qsr
446         IF( ln_diaobs ) THEN                   ! Observation & model comparison
447            CALL dia_obs_init                      ! Initialize observational data
448            CALL dia_obs( nit000 - 1 )             ! Observation operator for restart
449         ENDIF     
450         !                                     ! Assimilation increments
451         IF( lk_asminc )   CALL asm_inc_init   ! Initialize assimilation increments
452                 
453         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
454         RETURN
455      ENDIF
456     
457                           CALL  istate_init   ! ocean initial state (Dynamics and tracers)
458
459      !                                      ! external forcing
460                           CALL    tide_init   ! tidal harmonics
461                           CALL     sbc_init   ! surface boundary conditions (including sea-ice)
462                           CALL     bdy_init   ! Open boundaries initialisation
463
464      !                                      ! Ocean physics
465                           CALL zdf_phy_init    ! Vertical physics
466                                     
467      !                                         ! Lateral physics
468                           CALL ldf_tra_init      ! Lateral ocean tracer physics
469                           CALL ldf_eiv_init      ! eddy induced velocity param.
470                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
471
472      !                                      ! Active tracers
473      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
474                           CALL tra_bbc_init      ! bottom heat flux
475      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
476                           CALL tra_dmp_init      ! internal tracer damping
477                           CALL tra_adv_init      ! horizontal & vertical advection
478                           CALL tra_ldf_init      ! lateral mixing
479
480      !                                      ! Dynamics
481      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
482                           CALL dyn_adv_init      ! advection (vector or flux form)
483                           CALL dyn_vor_init      ! vorticity term including Coriolis
484                           CALL dyn_ldf_init      ! lateral mixing
485                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
486                           CALL dyn_spg_init      ! surface pressure gradient
487
488#if defined key_top
489      !                                      ! Passive tracers
490                           CALL     trc_init
491#endif
492      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
493
494      !                                      ! Icebergs
495                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
496
497      !                                      ! Misc. options
498                           CALL sto_par_init    ! Stochastic parametrization
499      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
500     
501      !                                      ! Diagnostics
502      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
503      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
504                           CALL dia_ptr_init    ! Poleward TRansports initialization
505      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
506                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
507                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
508                           CALL dia_obs_init    ! Initialize observational data
509      IF( ln_diaobs    )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
510
511      !                                      ! Assimilation increments
512      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
513      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
514                           CALL dia_tmb_init    ! TMB outputs
515                           CALL dia_25h_init    ! 25h mean  outputs
516      !
517   END SUBROUTINE nemo_init
518
519
520   SUBROUTINE nemo_ctl
521      !!----------------------------------------------------------------------
522      !!                     ***  ROUTINE nemo_ctl  ***
523      !!
524      !! ** Purpose :   control print setting
525      !!
526      !! ** Method  : - print namctl information and check some consistencies
527      !!----------------------------------------------------------------------
528      !
529      IF(lwp) THEN                  ! control print
530         WRITE(numout,*)
531         WRITE(numout,*) 'nemo_ctl: Control prints'
532         WRITE(numout,*) '~~~~~~~ '
533         WRITE(numout,*) '   Namelist namctl'
534         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
535         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
536         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
537         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
538         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
539         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
540         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
541         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
542         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
543         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
544      ENDIF
545      !
546      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
547      nictls    = nn_ictls
548      nictle    = nn_ictle
549      njctls    = nn_jctls
550      njctle    = nn_jctle
551      isplt     = nn_isplt
552      jsplt     = nn_jsplt
553!!gm to be remove at the end of the 2017 merge party
554      if( ln_timing ) then  ;  nn_timing = 1
555      else                  ;  nn_timing = 0
556      endif
557!!gm end
558     
559
560      IF(lwp) THEN                  ! control print
561         WRITE(numout,*)
562         WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
563         WRITE(numout,*) '~~~~~~ '
564         WRITE(numout,*) '   Namelist namcfg'
565         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
566         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
567         WRITE(numout,*) '      write configuration definition file           ln_write_cfg     = ', ln_write_cfg
568         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
569         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
570      ENDIF
571      !                             ! Parameter control
572      !
573      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
574         IF( lk_mpp .AND. jpnij > 1 ) THEN
575            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
576         ELSE
577            IF( isplt == 1 .AND. jsplt == 1  ) THEN
578               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
579                  &           ' - the print control will be done over the whole domain' )
580            ENDIF
581            ijsplt = isplt * jsplt            ! total number of processors ijsplt
582         ENDIF
583         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
584         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
585         !
586         !                              ! indices used for the SUM control
587         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
588            lsp_area = .FALSE.
589         ELSE                                             ! print control done over a specific  area
590            lsp_area = .TRUE.
591            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
592               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
593               nictls = 1
594            ENDIF
595            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
596               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
597               nictle = jpiglo
598            ENDIF
599            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
600               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
601               njctls = 1
602            ENDIF
603            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
604               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
605               njctle = jpjglo
606            ENDIF
607         ENDIF
608      ENDIF
609      !
610      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
611         &                                               'f2003 standard. '                              ,  &
612         &                                               'Compile with key_nosignedzero enabled' )
613      !
614#if defined key_agrif
615      IF( nn_timing == 1 ) CALL ctl_stop( 'AGRIF not implemented with nn_timing = 1')
616#endif
617      !
618   END SUBROUTINE nemo_ctl
619
620
621   SUBROUTINE nemo_closefile
622      !!----------------------------------------------------------------------
623      !!                     ***  ROUTINE nemo_closefile  ***
624      !!
625      !! ** Purpose :   Close the files
626      !!----------------------------------------------------------------------
627      !
628      IF( lk_mpp )   CALL mppsync
629      !
630      CALL iom_close                                 ! close all input/output files managed by iom_*
631      !
632      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
633      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
634      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
635      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
636      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
637      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
638      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
639      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
640      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
641      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
642      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
643      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
644      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
645      !
646      numout = 6                                     ! redefine numout in case it is used after this point...
647      !
648   END SUBROUTINE nemo_closefile
649
650
651   SUBROUTINE nemo_alloc
652      !!----------------------------------------------------------------------
653      !!                     ***  ROUTINE nemo_alloc  ***
654      !!
655      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
656      !!
657      !! ** Method  :
658      !!----------------------------------------------------------------------
659      USE diawri    , ONLY: dia_wri_alloc
660      USE dom_oce   , ONLY: dom_oce_alloc
661      USE trc_oce   , ONLY: trc_oce_alloc
662#if defined key_diadct 
663      USE diadct    , ONLY: diadct_alloc 
664#endif
665      USE bdy_oce   , ONLY: bdy_oce_alloc
666      !
667      INTEGER :: ierr
668      !!----------------------------------------------------------------------
669      !
670      ierr =        oce_alloc       ()          ! ocean
671      ierr = ierr + dia_wri_alloc   ()
672      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
673      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
674      !
675      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
676      !
677#if defined key_diadct 
678      ierr = ierr + diadct_alloc    ()          !
679#endif
680      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
681      !
682      IF( lk_mpp    )   CALL mpp_sum( ierr )
683      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
684      !
685   END SUBROUTINE nemo_alloc
686
687
688   SUBROUTINE nemo_partition( num_pes )
689      !!----------------------------------------------------------------------
690      !!                 ***  ROUTINE nemo_partition  ***
691      !!
692      !! ** Purpose :
693      !!
694      !! ** Method  :
695      !!----------------------------------------------------------------------
696      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
697      !
698      INTEGER, PARAMETER :: nfactmax = 20
699      INTEGER :: nfact ! The no. of factors returned
700      INTEGER :: ierr  ! Error flag
701      INTEGER :: ji
702      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
703      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
704      !!----------------------------------------------------------------------
705      !
706      ierr = 0
707      !
708      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
709      !
710      IF( nfact <= 1 ) THEN
711         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
712         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
713         jpnj = 1
714         jpni = num_pes
715      ELSE
716         ! Search through factors for the pair that are closest in value
717         mindiff = 1000000
718         imin    = 1
719         DO ji = 1, nfact-1, 2
720            idiff = ABS( ifact(ji) - ifact(ji+1) )
721            IF( idiff < mindiff ) THEN
722               mindiff = idiff
723               imin = ji
724            ENDIF
725         END DO
726         jpnj = ifact(imin)
727         jpni = ifact(imin + 1)
728      ENDIF
729      !
730      jpnij = jpni*jpnj
731      !
732   END SUBROUTINE nemo_partition
733
734
735   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
736      !!----------------------------------------------------------------------
737      !!                     ***  ROUTINE factorise  ***
738      !!
739      !! ** Purpose :   return the prime factors of n.
740      !!                knfax factors are returned in array kfax which is of
741      !!                maximum dimension kmaxfax.
742      !! ** Method  :
743      !!----------------------------------------------------------------------
744      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
745      INTEGER                    , INTENT(  out) ::   kerr, knfax
746      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
747      !
748      INTEGER :: ifac, jl, inu
749      INTEGER, PARAMETER :: ntest = 14
750      INTEGER, DIMENSION(ntest) ::   ilfax
751      !!----------------------------------------------------------------------
752      !
753      ! lfax contains the set of allowed factors.
754      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
755      !
756      ! Clear the error flag and initialise output vars
757      kerr  = 0
758      kfax  = 1
759      knfax = 0
760      !
761      ! Find the factors of n.
762      IF( kn .NE. 1 ) THEN
763
764         ! nu holds the unfactorised part of the number.
765         ! knfax holds the number of factors found.
766         ! l points to the allowed factor list.
767         ! ifac holds the current factor.
768         !
769         inu   = kn
770         knfax = 0
771         !
772         DO jl = ntest, 1, -1
773            !
774            ifac = ilfax(jl)
775            IF( ifac > inu )   CYCLE
776   
777            ! Test whether the factor will divide.
778   
779            IF( MOD(inu,ifac) == 0 ) THEN
780               !
781               knfax = knfax + 1            ! Add the factor to the list
782               IF( knfax > kmaxfax ) THEN
783                  kerr = 6
784                  write (*,*) 'FACTOR: insufficient space in factor array ', knfax
785                  return
786               ENDIF
787               kfax(knfax) = ifac
788               ! Store the other factor that goes with this one
789               knfax = knfax + 1
790               kfax(knfax) = inu / ifac
791               !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
792            ENDIF
793            !
794         END DO
795         !
796      ENDIF
797      !
798   END SUBROUTINE factorise
799
800#if defined key_mpp_mpi
801
802   SUBROUTINE nemo_northcomms
803      !!----------------------------------------------------------------------
804      !!                     ***  ROUTINE  nemo_northcomms  ***
805      !! ** Purpose :   Setup for north fold exchanges with explicit
806      !!                point-to-point messaging
807      !!
808      !! ** Method :   Initialization of the northern neighbours lists.
809      !!----------------------------------------------------------------------
810      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
811      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
812      !!----------------------------------------------------------------------
813      INTEGER  ::   sxM, dxM, sxT, dxT, jn
814      INTEGER  ::   njmppmax
815      !!----------------------------------------------------------------------
816      !
817      njmppmax = MAXVAL( njmppt )
818      !
819      !initializes the north-fold communication variables
820      isendto(:) = 0
821      nsndto     = 0
822      !
823      !if I am a process in the north
824      IF ( njmpp == njmppmax ) THEN
825          !sxM is the first point (in the global domain) needed to compute the
826          !north-fold for the current process
827          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
828          !dxM is the last point (in the global domain) needed to compute the
829          !north-fold for the current process
830          dxM = jpiglo - nimppt(narea) + 2
831
832          !loop over the other north-fold processes to find the processes
833          !managing the points belonging to the sxT-dxT range
834 
835          DO jn = 1, jpni
836                !sxT is the first point (in the global domain) of the jn
837                !process
838                sxT = nfiimpp(jn, jpnj)
839                !dxT is the last point (in the global domain) of the jn
840                !process
841                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
842                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
843                   nsndto = nsndto + 1
844                   isendto(nsndto) = jn
845                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
846                   nsndto = nsndto + 1
847                   isendto(nsndto) = jn
848                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
849                   nsndto = nsndto + 1
850                   isendto(nsndto) = jn
851                ENDIF
852          END DO
853          nfsloop = 1
854          nfeloop = nlci
855          DO jn = 2,jpni-1
856           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
857              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
858                 nfsloop = nldi
859              ENDIF
860              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
861                 nfeloop = nlei
862              ENDIF
863           ENDIF
864        END DO
865
866      ENDIF
867      l_north_nogather = .TRUE.
868   END SUBROUTINE nemo_northcomms
869
870#else
871   SUBROUTINE nemo_northcomms      ! Dummy routine
872      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
873   END SUBROUTINE nemo_northcomms
874#endif
875
876   !!======================================================================
877END MODULE nemogcm
878
Note: See TracBrowser for help on using the repository browser.