New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 9169

Last change on this file since 9169 was 9169, checked in by gm, 6 years ago

dev_merge_2017: all SRC: finalize the removal of useless warning when reading namelist_cfg + remove all nn_closea + nn_msh replaced by a logical

  • Property svn:keywords set to Id
File size: 40.6 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
36   !!----------------------------------------------------------------------
37
38   !!----------------------------------------------------------------------
39   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
40   !!   nemo_init     : initialization of the NEMO system
41   !!   nemo_ctl      : initialisation of the contol print
42   !!   nemo_closefile: close remaining open files
43   !!   nemo_alloc    : dynamical allocation
44   !!   nemo_partition: calculate MPP domain decomposition
45   !!   factorise     : calculate the factors of the no. of MPI processes
46   !!----------------------------------------------------------------------
47   USE step_oce       ! module used in the ocean time stepping module (step.F90)
48   USE phycst         ! physical constant                  (par_cst routine)
49   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
50   USE closea         ! treatment of closed seas (for ln_closea)
51   USE usrdef_nam     ! user defined configuration
52   USE tideini        ! tidal components initialization   (tide_ini routine)
53   USE bdy_oce,  ONLY : ln_bdy
54   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
55   USE istate         ! initial state setting          (istate_init routine)
56   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
57   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
58   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
59   USE asminc         ! assimilation increments     
60   USE asmbkg         ! writing out state trajectory
61   USE diaptr         ! poleward transports           (dia_ptr_init routine)
62   USE diadct         ! sections transports           (dia_dct_init routine)
63   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
64   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
65   USE step           ! NEMO time-stepping                 (stp     routine)
66   USE icbini         ! handle bergs, initialisation
67   USE icbstp         ! handle bergs, calving, themodynamics and transport
68   USE cpl_oasis3     ! OASIS3 coupling
69   USE c1d            ! 1D configuration
70   USE step_c1d       ! Time stepping loop for the 1D configuration
71   USE dyndmp         ! Momentum damping
72   USE stopar         ! Stochastic param.: ???
73   USE stopts         ! Stochastic param.: ???
74   USE diurnal_bulk   ! diurnal bulk SST
75   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
76   USE crsini         ! initialise grid coarsening utility
77   USE diatmb         ! Top,middle,bottom output
78   USE dia25h         ! 25h mean output
79   USE sbc_oce , ONLY : lk_oasis
80   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
81#if defined key_top
82   USE trcini         ! passive tracer initialisation
83#endif
84#if defined key_nemocice_decomp
85   USE ice_domain_size, only: nx_global, ny_global
86#endif
87   !
88   USE lib_mpp        ! distributed memory computing
89   USE mppini         ! shared/distributed memory setting (mpp_init routine)
90   USE lbcnfd , ONLY  : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
91   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
92#if defined key_iomput
93   USE xios           ! xIOserver
94#endif
95
96   IMPLICIT NONE
97   PRIVATE
98
99   PUBLIC   nemo_gcm    ! called by model.F90
100   PUBLIC   nemo_init   ! needed by AGRIF
101   PUBLIC   nemo_alloc  ! needed by TAM
102
103   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
104
105   !!----------------------------------------------------------------------
106   !! NEMO/OPA 3.7 , NEMO Consortium (2016)
107   !! $Id$
108   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
109   !!----------------------------------------------------------------------
110CONTAINS
111
112   SUBROUTINE nemo_gcm
113      !!----------------------------------------------------------------------
114      !!                     ***  ROUTINE nemo_gcm  ***
115      !!
116      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
117      !!              curvilinear mesh on the sphere.
118      !!
119      !! ** Method  : - model general initialization
120      !!              - launch the time-stepping (stp routine)
121      !!              - finalize the run by closing files and communications
122      !!
123      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
124      !!              Madec, 2008, internal report, IPSL.
125      !!----------------------------------------------------------------------
126      INTEGER ::   istp   ! time step index
127      !!----------------------------------------------------------------------
128      !
129#if defined key_agrif
130      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
131#endif
132      !
133      !                            !-----------------------!
134      CALL nemo_init               !==  Initialisations  ==!
135      !                            !-----------------------!
136#if defined key_agrif
137      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
138      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
139# if defined key_top
140      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
141# endif
142# if defined key_lim3
143      CALL Agrif_Declare_Var_lim3  !  "      "   "   "      "  LIM3
144# endif
145#endif
146      ! check that all process are still there... If some process have an error,
147      ! they will never enter in step and other processes will wait until the end of the cpu time!
148      IF( lk_mpp )   CALL mpp_max( nstop )
149
150      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
151
152      !                            !-----------------------!
153      !                            !==   time stepping   ==!
154      !                            !-----------------------!
155      istp = nit000
156#if defined key_c1d
157         DO WHILE ( istp <= nitend .AND. nstop == 0 )
158            CALL stp_c1d( istp )
159            istp = istp + 1
160         END DO
161#else
162          IF( lk_asminc ) THEN
163             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
164             IF( ln_asmdin ) THEN                        ! Direct initialization
165                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
166                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
167                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
168             ENDIF
169          ENDIF
170
171#if defined key_agrif
172          CALL Agrif_Regrid()
173#endif
174
175         DO WHILE ( istp <= nitend .AND. nstop == 0 )
176#if defined key_agrif
177            CALL stp                         ! AGRIF: time stepping
178#else
179            IF ( .NOT. ln_diurnal_only ) THEN
180               CALL stp( istp )                 ! standard time stepping
181            ELSE
182               CALL stp_diurnal( istp )        ! time step only the diurnal SST
183            ENDIF 
184#endif
185            istp = istp + 1
186            IF( lk_mpp )   CALL mpp_max( nstop )
187         END DO
188#endif
189
190      IF( ln_diaobs   )   CALL dia_obs_wri
191      !
192      IF( ln_icebergs )   CALL icb_end( nitend )
193
194      !                            !------------------------!
195      !                            !==  finalize the run  ==!
196      !                            !------------------------!
197      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
198      !
199      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
200         WRITE(numout,cform_err)
201         WRITE(numout,*) nstop, ' error have been found'
202      ENDIF
203      !
204#if defined key_agrif
205      IF( .NOT. Agrif_Root() ) THEN
206         CALL Agrif_ParentGrid_To_ChildGrid()
207         IF( ln_diaobs )        CALL dia_obs_wri
208         IF( ln_timing )   CALL timing_finalize
209         CALL Agrif_ChildGrid_To_ParentGrid()
210      ENDIF
211#endif
212      IF( ln_timing )   CALL timing_finalize
213      !
214      CALL nemo_closefile
215      !
216#if defined key_iomput
217      CALL xios_finalize                     ! end mpp communications with xios
218      IF( lk_oasis )   CALL cpl_finalize     ! end coupling and mpp communications with OASIS
219#else
220      IF( lk_oasis ) THEN
221         CALL cpl_finalize                   ! end coupling and mpp communications with OASIS
222      ELSE
223         IF( lk_mpp )   CALL mppstop         ! end mpp communications
224      ENDIF
225#endif
226      !
227   END SUBROUTINE nemo_gcm
228
229
230   SUBROUTINE nemo_init
231      !!----------------------------------------------------------------------
232      !!                     ***  ROUTINE nemo_init  ***
233      !!
234      !! ** Purpose :   initialization of the NEMO GCM
235      !!----------------------------------------------------------------------
236      INTEGER  ::   ji                 ! dummy loop indices
237      INTEGER  ::   ios, ilocal_comm   ! local integer
238      INTEGER  ::   iiarea, ijarea     ! local integers
239      INTEGER  ::   iirest, ijrest     ! local integers
240      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
241      !
242      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
243         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
244         &             ln_timing, ln_diacfl
245      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr, ln_closea
246      !!----------------------------------------------------------------------
247      !
248      cltxt  = ''
249      cltxt2 = ''
250      clnam  = '' 
251      cxios_context = 'nemo'
252      !
253      !                             ! Open reference namelist and configuration namelist files
254      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
255      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
256      !
257      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints
258      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
259901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
260      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
261      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
262902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
263      !
264      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints
265      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
266903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
267      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
268      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
269904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
270
271      !                             !--------------------------!
272      !                             !  Set global domain size  !   (control print return in cltxt2)
273      !                             !--------------------------!
274      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
275         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
276         !
277      ELSE                                ! user-defined namelist
278         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
279      ENDIF
280      !
281      !
282      !                             !--------------------------------------------!
283      !                             !  set communicator & select the local node  !
284      !                             !  NB: mynode also opens output.namelist.dyn !
285      !                             !      on unit number numond on first proc   !
286      !                             !--------------------------------------------!
287#if defined key_iomput
288      IF( Agrif_Root() ) THEN
289         IF( lk_oasis ) THEN
290            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
291            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
292         ELSE
293            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
294         ENDIF
295      ENDIF
296      ! Nodes selection (control print return in cltxt)
297      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
298#else
299      IF( lk_oasis ) THEN
300         IF( Agrif_Root() ) THEN
301            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
302         ENDIF
303         ! Nodes selection (control print return in cltxt)
304         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
305      ELSE
306         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
307         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
308      ENDIF
309#endif
310
311      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
312
313      lwm = (narea == 1)                                    ! control of output namelists
314      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
315
316      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
317         !                       ! now that the file has been opened in call to mynode.
318         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
319         WRITE( numond, namctl )
320         WRITE( numond, namcfg )
321         IF( .NOT.ln_read_cfg ) THEN
322            DO ji = 1, SIZE(clnam)
323               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
324            END DO
325         ENDIF
326      ENDIF
327
328      ! If dimensions of processor grid weren't specified in the namelist file
329      ! then we calculate them here now that we have our communicator size
330      IF( jpni < 1 .OR. jpnj < 1 ) THEN
331#if   defined key_mpp_mpi
332         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
333#else
334         jpni  = 1
335         jpnj  = 1
336         jpnij = jpni*jpnj
337#endif
338      ENDIF
339      !
340#if defined key_agrif
341      IF( .NOT. Agrif_Root() ) THEN       ! AGRIF children: specific setting (cf. agrif_user.F90)
342         jpiglo  = nbcellsx + 2 + 2*nbghostcells
343         jpjglo  = nbcellsy + 2 + 2*nbghostcells
344         jpi     = ( jpiglo-2*nn_hls + (jpni-1+0) ) / jpni + 2*nn_hls
345         jpj     = ( jpjglo-2*nn_hls + (jpnj-1+0) ) / jpnj + 2*nn_hls
346         jpimax  = jpi
347         jpjmax  = jpj
348         nperio  = 0
349         jperio  = 0
350         ln_use_jattr = .false.
351      ENDIF
352#endif
353
354      IF( Agrif_Root() ) THEN       ! AGRIF mother: specific setting from jpni and jpnj
355         iiarea = 1 + MOD( narea - 1 , jpni )
356         ijarea = 1 + ( narea - 1 ) / jpni
357         iirest = 1 + MOD( jpiglo - 2*nn_hls - 1 , jpni )
358         ijrest = 1 + MOD( jpjglo - 2*nn_hls - 1 , jpnj )
359#if defined key_nemocice_decomp
360         jpi = ( nx_global+2-2*nn_hls + (jpni-1) ) / jpni + 2*nn_hls    ! first  dim.
361         jpj = ( ny_global+2-2*nn_hls + (jpnj-1) ) / jpnj + 2*nn_hls    ! second dim.
362         jpimax  = jpi
363         jpjmax  = jpj
364         IF( iiarea == jpni ) jpi = jpiglo - (jpni - 1) * (jpi - 2*nn_hls)
365         IF( ijarea == jpnj ) jpj = jpjglo - (jpnj - 1) * (jpj - 2*nn_hls)
366#else
367         jpi = ( jpiglo     -2*nn_hls + (jpni-1) ) / jpni + 2*nn_hls    ! first  dim.
368         jpj = ( jpjglo     -2*nn_hls + (jpnj-1) ) / jpnj + 2*nn_hls    ! second dim.
369         jpimax  = jpi
370         jpjmax  = jpj
371         IF( iiarea > iirest ) jpi = jpi - 1
372         IF( ijarea > ijrest ) jpj = jpj - 1
373#endif
374      ENDIF
375
376      jpk = jpkglo                                             ! third dim
377
378#if defined key_agrif
379      ! simple trick to use same vertical grid as parent but different number of levels:
380      ! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
381      ! Suppress once vertical online interpolation is ok
382      IF(.NOT.Agrif_Root())   jpkglo = Agrif_Parent( jpkglo )
383#endif
384      jpim1 = jpi-1                                            ! inner domain indices
385      jpjm1 = jpj-1                                            !   "           "
386      jpkm1 = MAX( 1, jpk-1 )                                  !   "           "
387      jpij  = jpi*jpj                                          !  jpi x j
388
389      IF(lwp) THEN                            ! open listing units
390         !
391         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
392         !
393         WRITE(numout,*)
394         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
395         WRITE(numout,*) '                       NEMO team'
396         WRITE(numout,*) '            Ocean General Circulation Model'
397         WRITE(numout,*) '                NEMO version 4.0  (2017) '
398         WRITE(numout,*)
399         WRITE(numout,*)
400         DO ji = 1, SIZE(cltxt)
401            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
402         END DO
403         WRITE(numout,*)
404         WRITE(numout,*)
405         DO ji = 1, SIZE(cltxt2)
406            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
407         END DO
408         !
409         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
410         !
411      ENDIF
412
413      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
414      CALL nemo_alloc()
415
416      !                             !-------------------------------!
417      !                             !  NEMO general initialization  !
418      !                             !-------------------------------!
419
420      CALL nemo_ctl                          ! Control prints
421
422      !                                      ! Domain decomposition
423      CALL mpp_init
424      IF( ln_nnogather )   CALL nemo_northcomms! northfold neighbour lists
425      !
426      IF( ln_timing    )   CALL timing_init
427      !
428      !                                      ! General initialization
429                           CALL     phy_cst    ! Physical constants
430                           CALL     eos_init   ! Equation of state
431      IF( lk_c1d       )   CALL     c1d_init   ! 1D column configuration
432                           CALL     wad_init   ! Wetting and drying options
433                           CALL     dom_init   ! Domain
434      IF( ln_crs       )   CALL     crs_init   ! coarsened grid: domain initialization
435      IF( ln_ctl       )   CALL prt_ctl_init   ! Print control
436     
437      CALL diurnal_sst_bulk_init             ! diurnal sst
438      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
439     
440      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
441      IF( ln_diurnal_only ) THEN
442         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
443         CALL     sbc_init   ! Forcings : surface module
444         CALL tra_qsr_init   ! penetrative solar radiation qsr
445         IF( ln_diaobs ) THEN                   ! Observation & model comparison
446            CALL dia_obs_init                      ! Initialize observational data
447            CALL dia_obs( nit000 - 1 )             ! Observation operator for restart
448         ENDIF     
449         !                                     ! Assimilation increments
450         IF( lk_asminc )   CALL asm_inc_init   ! Initialize assimilation increments
451                 
452         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
453         RETURN
454      ENDIF
455     
456                           CALL  istate_init   ! ocean initial state (Dynamics and tracers)
457
458      !                                      ! external forcing
459                           CALL    tide_init   ! tidal harmonics
460                           CALL     sbc_init   ! surface boundary conditions (including sea-ice)
461                           CALL     bdy_init   ! Open boundaries initialisation
462
463      !                                      ! Ocean physics
464                           CALL zdf_phy_init    ! Vertical physics
465                                     
466      !                                         ! Lateral physics
467                           CALL ldf_tra_init      ! Lateral ocean tracer physics
468                           CALL ldf_eiv_init      ! eddy induced velocity param.
469                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
470
471      !                                      ! Active tracers
472      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
473                           CALL tra_bbc_init      ! bottom heat flux
474      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
475                           CALL tra_dmp_init      ! internal tracer damping
476                           CALL tra_adv_init      ! horizontal & vertical advection
477                           CALL tra_ldf_init      ! lateral mixing
478
479      !                                      ! Dynamics
480      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
481                           CALL dyn_adv_init      ! advection (vector or flux form)
482                           CALL dyn_vor_init      ! vorticity term including Coriolis
483                           CALL dyn_ldf_init      ! lateral mixing
484                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
485                           CALL dyn_spg_init      ! surface pressure gradient
486
487#if defined key_top
488      !                                      ! Passive tracers
489                           CALL     trc_init
490#endif
491      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
492
493      !                                      ! Icebergs
494                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
495
496      !                                      ! Misc. options
497                           CALL sto_par_init    ! Stochastic parametrization
498      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
499     
500      !                                      ! Diagnostics
501      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
502      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
503                           CALL dia_ptr_init    ! Poleward TRansports initialization
504      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
505                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
506                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
507                           CALL dia_obs_init    ! Initialize observational data
508      IF( ln_diaobs    )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
509
510      !                                      ! Assimilation increments
511      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
512      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
513                           CALL dia_tmb_init    ! TMB outputs
514                           CALL dia_25h_init    ! 25h mean  outputs
515      !
516   END SUBROUTINE nemo_init
517
518
519   SUBROUTINE nemo_ctl
520      !!----------------------------------------------------------------------
521      !!                     ***  ROUTINE nemo_ctl  ***
522      !!
523      !! ** Purpose :   control print setting
524      !!
525      !! ** Method  : - print namctl information and check some consistencies
526      !!----------------------------------------------------------------------
527      !
528      IF(lwp) THEN                  ! control print
529         WRITE(numout,*)
530         WRITE(numout,*) 'nemo_ctl: Control prints'
531         WRITE(numout,*) '~~~~~~~ '
532         WRITE(numout,*) '   Namelist namctl'
533         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
534         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
535         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
536         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
537         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
538         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
539         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
540         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
541         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
542         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
543      ENDIF
544      !
545      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
546      nictls    = nn_ictls
547      nictle    = nn_ictle
548      njctls    = nn_jctls
549      njctle    = nn_jctle
550      isplt     = nn_isplt
551      jsplt     = nn_jsplt     
552
553      IF(lwp) THEN                  ! control print
554         WRITE(numout,*)
555         WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
556         WRITE(numout,*) '~~~~~~ '
557         WRITE(numout,*) '   Namelist namcfg'
558         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
559         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
560         WRITE(numout,*) '      write configuration definition file           ln_write_cfg     = ', ln_write_cfg
561         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
562         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
563      ENDIF
564      !                             ! Parameter control
565      !
566      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
567         IF( lk_mpp .AND. jpnij > 1 ) THEN
568            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
569         ELSE
570            IF( isplt == 1 .AND. jsplt == 1  ) THEN
571               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
572                  &           ' - the print control will be done over the whole domain' )
573            ENDIF
574            ijsplt = isplt * jsplt            ! total number of processors ijsplt
575         ENDIF
576         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
577         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
578         !
579         !                              ! indices used for the SUM control
580         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
581            lsp_area = .FALSE.
582         ELSE                                             ! print control done over a specific  area
583            lsp_area = .TRUE.
584            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
585               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
586               nictls = 1
587            ENDIF
588            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
589               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
590               nictle = jpiglo
591            ENDIF
592            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
593               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
594               njctls = 1
595            ENDIF
596            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
597               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
598               njctle = jpjglo
599            ENDIF
600         ENDIF
601      ENDIF
602      !
603      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
604         &                                               'f2003 standard. '                              ,  &
605         &                                               'Compile with key_nosignedzero enabled' )
606      !
607#if defined key_agrif
608      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
609#endif
610      !
611   END SUBROUTINE nemo_ctl
612
613
614   SUBROUTINE nemo_closefile
615      !!----------------------------------------------------------------------
616      !!                     ***  ROUTINE nemo_closefile  ***
617      !!
618      !! ** Purpose :   Close the files
619      !!----------------------------------------------------------------------
620      !
621      IF( lk_mpp )   CALL mppsync
622      !
623      CALL iom_close                                 ! close all input/output files managed by iom_*
624      !
625      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
626      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
627      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
628      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
629      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
630      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
631      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
632      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
633      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
634      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
635      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
636      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
637      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
638      !
639      numout = 6                                     ! redefine numout in case it is used after this point...
640      !
641   END SUBROUTINE nemo_closefile
642
643
644   SUBROUTINE nemo_alloc
645      !!----------------------------------------------------------------------
646      !!                     ***  ROUTINE nemo_alloc  ***
647      !!
648      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
649      !!
650      !! ** Method  :
651      !!----------------------------------------------------------------------
652      USE diawri    , ONLY: dia_wri_alloc
653      USE dom_oce   , ONLY: dom_oce_alloc
654      USE trc_oce   , ONLY: trc_oce_alloc
655#if defined key_diadct 
656      USE diadct    , ONLY: diadct_alloc 
657#endif
658      USE bdy_oce   , ONLY: bdy_oce_alloc
659      !
660      INTEGER :: ierr
661      !!----------------------------------------------------------------------
662      !
663      ierr =        oce_alloc       ()          ! ocean
664      ierr = ierr + dia_wri_alloc   ()
665      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
666      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
667      !
668      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
669      !
670#if defined key_diadct 
671      ierr = ierr + diadct_alloc    ()          !
672#endif
673      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
674      !
675      IF( lk_mpp    )   CALL mpp_sum( ierr )
676      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
677      !
678   END SUBROUTINE nemo_alloc
679
680
681   SUBROUTINE nemo_partition( num_pes )
682      !!----------------------------------------------------------------------
683      !!                 ***  ROUTINE nemo_partition  ***
684      !!
685      !! ** Purpose :
686      !!
687      !! ** Method  :
688      !!----------------------------------------------------------------------
689      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
690      !
691      INTEGER, PARAMETER :: nfactmax = 20
692      INTEGER :: nfact ! The no. of factors returned
693      INTEGER :: ierr  ! Error flag
694      INTEGER :: ji
695      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
696      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
697      !!----------------------------------------------------------------------
698      !
699      ierr = 0
700      !
701      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
702      !
703      IF( nfact <= 1 ) THEN
704         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
705         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
706         jpnj = 1
707         jpni = num_pes
708      ELSE
709         ! Search through factors for the pair that are closest in value
710         mindiff = 1000000
711         imin    = 1
712         DO ji = 1, nfact-1, 2
713            idiff = ABS( ifact(ji) - ifact(ji+1) )
714            IF( idiff < mindiff ) THEN
715               mindiff = idiff
716               imin = ji
717            ENDIF
718         END DO
719         jpnj = ifact(imin)
720         jpni = ifact(imin + 1)
721      ENDIF
722      !
723      jpnij = jpni*jpnj
724      !
725   END SUBROUTINE nemo_partition
726
727
728   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
729      !!----------------------------------------------------------------------
730      !!                     ***  ROUTINE factorise  ***
731      !!
732      !! ** Purpose :   return the prime factors of n.
733      !!                knfax factors are returned in array kfax which is of
734      !!                maximum dimension kmaxfax.
735      !! ** Method  :
736      !!----------------------------------------------------------------------
737      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
738      INTEGER                    , INTENT(  out) ::   kerr, knfax
739      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
740      !
741      INTEGER :: ifac, jl, inu
742      INTEGER, PARAMETER :: ntest = 14
743      INTEGER, DIMENSION(ntest) ::   ilfax
744      !!----------------------------------------------------------------------
745      !
746      ! lfax contains the set of allowed factors.
747      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
748      !
749      ! Clear the error flag and initialise output vars
750      kerr  = 0
751      kfax  = 1
752      knfax = 0
753      !
754      ! Find the factors of n.
755      IF( kn .NE. 1 ) THEN
756
757         ! nu holds the unfactorised part of the number.
758         ! knfax holds the number of factors found.
759         ! l points to the allowed factor list.
760         ! ifac holds the current factor.
761         !
762         inu   = kn
763         knfax = 0
764         !
765         DO jl = ntest, 1, -1
766            !
767            ifac = ilfax(jl)
768            IF( ifac > inu )   CYCLE
769   
770            ! Test whether the factor will divide.
771   
772            IF( MOD(inu,ifac) == 0 ) THEN
773               !
774               knfax = knfax + 1            ! Add the factor to the list
775               IF( knfax > kmaxfax ) THEN
776                  kerr = 6
777                  write (*,*) 'FACTOR: insufficient space in factor array ', knfax
778                  return
779               ENDIF
780               kfax(knfax) = ifac
781               ! Store the other factor that goes with this one
782               knfax = knfax + 1
783               kfax(knfax) = inu / ifac
784               !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
785            ENDIF
786            !
787         END DO
788         !
789      ENDIF
790      !
791   END SUBROUTINE factorise
792
793#if defined key_mpp_mpi
794
795   SUBROUTINE nemo_northcomms
796      !!----------------------------------------------------------------------
797      !!                     ***  ROUTINE  nemo_northcomms  ***
798      !! ** Purpose :   Setup for north fold exchanges with explicit
799      !!                point-to-point messaging
800      !!
801      !! ** Method :   Initialization of the northern neighbours lists.
802      !!----------------------------------------------------------------------
803      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
804      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
805      !!----------------------------------------------------------------------
806      INTEGER  ::   sxM, dxM, sxT, dxT, jn
807      INTEGER  ::   njmppmax
808      !!----------------------------------------------------------------------
809      !
810      njmppmax = MAXVAL( njmppt )
811      !
812      !initializes the north-fold communication variables
813      isendto(:) = 0
814      nsndto     = 0
815      !
816      !if I am a process in the north
817      IF ( njmpp == njmppmax ) THEN
818          !sxM is the first point (in the global domain) needed to compute the
819          !north-fold for the current process
820          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
821          !dxM is the last point (in the global domain) needed to compute the
822          !north-fold for the current process
823          dxM = jpiglo - nimppt(narea) + 2
824
825          !loop over the other north-fold processes to find the processes
826          !managing the points belonging to the sxT-dxT range
827 
828          DO jn = 1, jpni
829                !sxT is the first point (in the global domain) of the jn
830                !process
831                sxT = nfiimpp(jn, jpnj)
832                !dxT is the last point (in the global domain) of the jn
833                !process
834                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
835                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
836                   nsndto = nsndto + 1
837                   isendto(nsndto) = jn
838                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
839                   nsndto = nsndto + 1
840                   isendto(nsndto) = jn
841                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
842                   nsndto = nsndto + 1
843                   isendto(nsndto) = jn
844                ENDIF
845          END DO
846          nfsloop = 1
847          nfeloop = nlci
848          DO jn = 2,jpni-1
849           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
850              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
851                 nfsloop = nldi
852              ENDIF
853              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
854                 nfeloop = nlei
855              ENDIF
856           ENDIF
857        END DO
858
859      ENDIF
860      l_north_nogather = .TRUE.
861   END SUBROUTINE nemo_northcomms
862
863#else
864   SUBROUTINE nemo_northcomms      ! Dummy routine
865      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
866   END SUBROUTINE nemo_northcomms
867#endif
868
869   !!======================================================================
870END MODULE nemogcm
871
Note: See TracBrowser for help on using the repository browser.