New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2017/dev_merge_2017/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 9367

Last change on this file since 9367 was 9367, checked in by mathiot, 6 years ago

Add restart read/write via XIOS capability (#1953 and #1962 and twiki: 2017WP/Met_Office-1_Mirek_XIOSread). WARNING: need to upgrade XIOS to r1296 to compile
  • Property svn:keywords set to Id
File size: 40.6 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_nfdcom
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_nfdcom: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
36   !!----------------------------------------------------------------------
37
38   !!----------------------------------------------------------------------
39   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
40   !!   nemo_init     : initialization of the NEMO system
41   !!   nemo_ctl      : initialisation of the contol print
42   !!   nemo_closefile: close remaining open files
43   !!   nemo_alloc    : dynamical allocation
44   !!   nemo_partition: calculate MPP domain decomposition
45   !!   factorise     : calculate the factors of the no. of MPI processes
46   !!   nemo_nfdcom   : Setup for north fold exchanges with explicit point-to-point messaging
47   !!----------------------------------------------------------------------
48   USE step_oce       ! module used in the ocean time stepping module (step.F90)
49   USE phycst         ! physical constant                  (par_cst routine)
50   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
51   USE closea         ! treatment of closed seas (for ln_closea)
52   USE usrdef_nam     ! user defined configuration
53   USE tideini        ! tidal components initialization   (tide_ini routine)
54   USE bdy_oce,  ONLY : ln_bdy
55   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
56   USE istate         ! initial state setting          (istate_init routine)
57   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
58   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
59   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
60   USE asminc         ! assimilation increments     
61   USE asmbkg         ! writing out state trajectory
62   USE diaptr         ! poleward transports           (dia_ptr_init routine)
63   USE diadct         ! sections transports           (dia_dct_init routine)
64   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
65   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
66   USE step           ! NEMO time-stepping                 (stp     routine)
67   USE icbini         ! handle bergs, initialisation
68   USE icbstp         ! handle bergs, calving, themodynamics and transport
69   USE cpl_oasis3     ! OASIS3 coupling
70   USE c1d            ! 1D configuration
71   USE step_c1d       ! Time stepping loop for the 1D configuration
72   USE dyndmp         ! Momentum damping
73   USE stopar         ! Stochastic param.: ???
74   USE stopts         ! Stochastic param.: ???
75   USE diurnal_bulk   ! diurnal bulk SST
76   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
77   USE crsini         ! initialise grid coarsening utility
78   USE diatmb         ! Top,middle,bottom output
79   USE dia25h         ! 25h mean output
80   USE sbc_oce , ONLY : lk_oasis
81   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
82#if defined key_top
83   USE trcini         ! passive tracer initialisation
84#endif
85#if defined key_nemocice_decomp
86   USE ice_domain_size, only: nx_global, ny_global
87#endif
88   !
89   USE lib_mpp        ! distributed memory computing
90   USE mppini         ! shared/distributed memory setting (mpp_init routine)
91   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
92   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
93#if defined key_iomput
94   USE xios           ! xIOserver
95#endif
96
97   IMPLICIT NONE
98   PRIVATE
99
100   PUBLIC   nemo_gcm    ! called by model.F90
101   PUBLIC   nemo_init   ! needed by AGRIF
102   PUBLIC   nemo_alloc  ! needed by TAM
103
104   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
105
106   !!----------------------------------------------------------------------
107   !! NEMO/OPA 4.0 , NEMO Consortium (2018)
108   !! $Id$
109   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
110   !!----------------------------------------------------------------------
111CONTAINS
112
113   SUBROUTINE nemo_gcm
114      !!----------------------------------------------------------------------
115      !!                     ***  ROUTINE nemo_gcm  ***
116      !!
117      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
118      !!              curvilinear mesh on the sphere.
119      !!
120      !! ** Method  : - model general initialization
121      !!              - launch the time-stepping (stp routine)
122      !!              - finalize the run by closing files and communications
123      !!
124      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
125      !!              Madec, 2008, internal report, IPSL.
126      !!----------------------------------------------------------------------
127      INTEGER ::   istp   ! time step index
128      !!----------------------------------------------------------------------
129      !
130#if defined key_agrif
131      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
132#endif
133      !                            !-----------------------!
134      CALL nemo_init               !==  Initialisations  ==!
135      !                            !-----------------------!
136#if defined key_agrif
137      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
138      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
139# if defined key_top
140      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
141# endif
142# if defined key_lim3
143      CALL Agrif_Declare_Var_lim3  !  "      "   "   "      "  LIM3
144# endif
145#endif
146      ! check that all process are still there... If some process have an error,
147      ! they will never enter in step and other processes will wait until the end of the cpu time!
148      IF( lk_mpp )   CALL mpp_max( nstop )
149
150      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
151
152      !                            !-----------------------!
153      !                            !==   time stepping   ==!
154      !                            !-----------------------!
155      istp = nit000
156      !
157#if defined key_c1d
158      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
159         CALL stp_c1d( istp )
160         istp = istp + 1
161      END DO
162#else
163      !
164# if defined key_agrif
165      !                                               !==  AGRIF time-stepping  ==!
166      CALL Agrif_Regrid()
167      !
168      DO WHILE( istp <= nitend .AND. nstop == 0 )
169         CALL stp
170         istp = istp + 1
171      END DO
172      !
173      IF( .NOT. Agrif_Root() ) THEN
174         CALL Agrif_ParentGrid_To_ChildGrid()
175         IF( ln_diaobs )   CALL dia_obs_wri
176         IF( ln_timing )   CALL timing_finalize
177         CALL Agrif_ChildGrid_To_ParentGrid()
178      ENDIF
179      !
180# else
181      !
182      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
183         !
184         DO WHILE( istp <= nitend .AND. nstop == 0 )
185            CALL stp        ( istp ) 
186            istp = istp + 1
187         END DO
188         !
189      ELSE                                            !==  diurnal SST time-steeping only  ==!
190         !
191         DO WHILE( istp <= nitend .AND. nstop == 0 )
192            CALL stp_diurnal( istp )   ! time step only the diurnal SST
193            istp = istp + 1
194         END DO
195         !
196      ENDIF
197      !
198# endif
199      !
200#endif
201      !
202      IF( ln_diaobs   )   CALL dia_obs_wri
203      !
204      IF( ln_icebergs )   CALL icb_end( nitend )
205
206      !                            !------------------------!
207      !                            !==  finalize the run  ==!
208      !                            !------------------------!
209      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
210      !
211      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
212         WRITE(numout,cform_err)
213         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
214         WRITE(numout,*)
215      ENDIF
216      !
217      IF( ln_timing )   CALL timing_finalize
218      !
219      CALL nemo_closefile
220      !
221#if defined key_iomput
222                                    CALL xios_finalize  ! end mpp communications with xios
223      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
224#else
225      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
226      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
227      ENDIF
228#endif
229      !
230   END SUBROUTINE nemo_gcm
231
232
233   SUBROUTINE nemo_init
234      !!----------------------------------------------------------------------
235      !!                     ***  ROUTINE nemo_init  ***
236      !!
237      !! ** Purpose :   initialization of the NEMO GCM
238      !!----------------------------------------------------------------------
239      INTEGER  ::   ji                 ! dummy loop indices
240      INTEGER  ::   ios, ilocal_comm   ! local integers
241      INTEGER  ::   iiarea, ijarea     !   -       -
242      INTEGER  ::   iirest, ijrest     !   -       -
243      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
244      !!
245      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
246         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
247         &             ln_timing, ln_diacfl
248      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
249      !!----------------------------------------------------------------------
250      !
251      cltxt  = ''
252      cltxt2 = ''
253      clnam  = '' 
254      cxios_context = 'nemo'
255      !
256      !                             ! Open reference namelist and configuration namelist files
257      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
258      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
259      !
260      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
261      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
262901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
263      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
264      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
265902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
266      !
267      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
268      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
269903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
270      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
271      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
272904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
273
274      !                             !--------------------------!
275      !                             !  Set global domain size  !   (control print return in cltxt2)
276      !                             !--------------------------!
277      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
278         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
279         !
280      ELSE                                ! user-defined namelist
281         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
282      ENDIF
283      !
284      !
285      !                             !--------------------------------------------!
286      !                             !  set communicator & select the local node  !
287      !                             !  NB: mynode also opens output.namelist.dyn !
288      !                             !      on unit number numond on first proc   !
289      !                             !--------------------------------------------!
290#if defined key_iomput
291      IF( Agrif_Root() ) THEN
292         IF( lk_oasis ) THEN
293            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
294            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
295         ELSE
296            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
297         ENDIF
298      ENDIF
299      ! Nodes selection (control print return in cltxt)
300      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
301#else
302      IF( lk_oasis ) THEN
303         IF( Agrif_Root() ) THEN
304            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
305         ENDIF
306         ! Nodes selection (control print return in cltxt)
307         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
308      ELSE
309         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
310         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
311      ENDIF
312#endif
313
314      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
315
316      lwm = (narea == 1)                                    ! control of output namelists
317      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
318
319      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
320         !                       ! now that the file has been opened in call to mynode.
321         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
322         WRITE( numond, namctl )
323         WRITE( numond, namcfg )
324         IF( .NOT.ln_read_cfg ) THEN
325            DO ji = 1, SIZE(clnam)
326               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
327            END DO
328         ENDIF
329      ENDIF
330
331      ! If dimensions of processor grid weren't specified in the namelist file
332      ! then we calculate them here now that we have our communicator size
333      IF( jpni < 1 .OR. jpnj < 1 ) THEN
334#if   defined key_mpp_mpi
335         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
336#else
337         jpni  = 1
338         jpnj  = 1
339         jpnij = jpni*jpnj
340#endif
341      ENDIF
342      !
343#if defined key_agrif
344      IF( .NOT. Agrif_Root() ) THEN       ! AGRIF children: specific setting (cf. agrif_user.F90)
345         jpiglo  = nbcellsx + 2 + 2*nbghostcells
346         jpjglo  = nbcellsy + 2 + 2*nbghostcells
347         jpi     = ( jpiglo-2*nn_hls + (jpni-1+0) ) / jpni + 2*nn_hls
348         jpj     = ( jpjglo-2*nn_hls + (jpnj-1+0) ) / jpnj + 2*nn_hls
349         jpimax  = jpi
350         jpjmax  = jpj
351         nperio  = 0
352         jperio  = 0
353         ln_use_jattr = .false.
354      ENDIF
355#endif
356
357      IF( Agrif_Root() ) THEN       ! AGRIF mother: specific setting from jpni and jpnj
358         iiarea = 1 + MOD( narea - 1 , jpni )
359         ijarea = 1 + ( narea - 1 ) / jpni
360         iirest = 1 + MOD( jpiglo - 2*nn_hls - 1 , jpni )
361         ijrest = 1 + MOD( jpjglo - 2*nn_hls - 1 , jpnj )
362#if defined key_nemocice_decomp
363         jpi = ( nx_global+2-2*nn_hls + (jpni-1) ) / jpni + 2*nn_hls    ! first  dim.
364         jpj = ( ny_global+2-2*nn_hls + (jpnj-1) ) / jpnj + 2*nn_hls    ! second dim.
365         jpimax  = jpi
366         jpjmax  = jpj
367         IF( iiarea == jpni ) jpi = jpiglo - (jpni - 1) * (jpi - 2*nn_hls)
368         IF( ijarea == jpnj ) jpj = jpjglo - (jpnj - 1) * (jpj - 2*nn_hls)
369#else
370         jpi = ( jpiglo     -2*nn_hls + (jpni-1) ) / jpni + 2*nn_hls    ! first  dim.
371         jpj = ( jpjglo     -2*nn_hls + (jpnj-1) ) / jpnj + 2*nn_hls    ! second dim.
372         jpimax  = jpi
373         jpjmax  = jpj
374         IF( iiarea > iirest ) jpi = jpi - 1
375         IF( ijarea > ijrest ) jpj = jpj - 1
376#endif
377      ENDIF
378
379      jpk = jpkglo                                             ! third dim
380
381#if defined key_agrif
382      ! simple trick to use same vertical grid as parent but different number of levels:
383      ! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
384      ! Suppress once vertical online interpolation is ok
385      IF(.NOT.Agrif_Root())   jpkglo = Agrif_Parent( jpkglo )
386#endif
387      jpim1 = jpi-1                                            ! inner domain indices
388      jpjm1 = jpj-1                                            !   "           "
389      jpkm1 = MAX( 1, jpk-1 )                                  !   "           "
390      jpij  = jpi*jpj                                          !  jpi x j
391
392      IF(lwp) THEN                            ! open listing units
393         !
394         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
395         !
396         WRITE(numout,*)
397         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
398         WRITE(numout,*) '                       NEMO team'
399         WRITE(numout,*) '            Ocean General Circulation Model'
400         WRITE(numout,*) '                NEMO version 4.0  (2017) '
401         WRITE(numout,*)
402         WRITE(numout,*)
403         DO ji = 1, SIZE(cltxt)
404            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
405         END DO
406         WRITE(numout,*)
407         WRITE(numout,*)
408         DO ji = 1, SIZE(cltxt2)
409            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
410         END DO
411         !
412         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
413         !
414      ENDIF
415
416      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
417      CALL nemo_alloc()
418
419      !                             !-------------------------------!
420      !                             !  NEMO general initialization  !
421      !                             !-------------------------------!
422
423      CALL nemo_ctl                          ! Control prints
424
425      !                                      ! Domain decomposition
426      CALL mpp_init                             ! MPP
427      IF( ln_nnogather )   CALL nemo_nfdcom     ! northfold neighbour lists
428      !
429      !                                      ! General initialization
430      IF( ln_timing    )   CALL timing_init     ! timing
431      IF( ln_timing    )   CALL timing_start( 'nemo_init')
432      !
433                           CALL     phy_cst         ! Physical constants
434                           CALL     eos_init        ! Equation of state
435      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
436                           CALL     wad_init        ! Wetting and drying options
437                           CALL     dom_init("OPA") ! Domain
438      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
439      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
440     
441      CALL diurnal_sst_bulk_init                ! diurnal sst
442      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
443      !                           
444      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
445         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
446         CALL     sbc_init                            ! Forcings : surface module
447         CALL tra_qsr_init                            ! penetrative solar radiation qsr
448         IF( ln_diaobs ) THEN                         ! Observation & model comparison
449            CALL dia_obs_init                            ! Initialize observational data
450            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
451         ENDIF     
452         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
453         !
454         RETURN                                       ! end of initialization
455      ENDIF
456     
457                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
458
459      !                                      ! external forcing
460                           CALL    tide_init    ! tidal harmonics
461                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
462                           CALL     bdy_init    ! Open boundaries initialisation
463
464      !                                      ! Ocean physics
465                           CALL zdf_phy_init    ! Vertical physics
466                                     
467      !                                         ! Lateral physics
468                           CALL ldf_tra_init      ! Lateral ocean tracer physics
469                           CALL ldf_eiv_init      ! eddy induced velocity param.
470                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
471
472      !                                      ! Active tracers
473      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
474                           CALL tra_bbc_init      ! bottom heat flux
475      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
476                           CALL tra_dmp_init      ! internal tracer damping
477                           CALL tra_adv_init      ! horizontal & vertical advection
478                           CALL tra_ldf_init      ! lateral mixing
479
480      !                                      ! Dynamics
481      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
482                           CALL dyn_adv_init      ! advection (vector or flux form)
483                           CALL dyn_vor_init      ! vorticity term including Coriolis
484                           CALL dyn_ldf_init      ! lateral mixing
485                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
486                           CALL dyn_spg_init      ! surface pressure gradient
487
488#if defined key_top
489      !                                      ! Passive tracers
490                           CALL     trc_init
491#endif
492      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
493
494      !                                      ! Icebergs
495                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
496
497      !                                      ! Misc. options
498                           CALL sto_par_init    ! Stochastic parametrization
499      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
500     
501      !                                      ! Diagnostics
502      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
503      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
504                           CALL dia_ptr_init    ! Poleward TRansports initialization
505      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
506                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
507                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
508                           CALL dia_obs_init    ! Initialize observational data
509                           CALL dia_tmb_init    ! TMB outputs
510                           CALL dia_25h_init    ! 25h mean  outputs
511      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
512
513      !                                      ! Assimilation increments
514      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
515      !
516      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
517      !
518      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
519      !
520   END SUBROUTINE nemo_init
521
522
523   SUBROUTINE nemo_ctl
524      !!----------------------------------------------------------------------
525      !!                     ***  ROUTINE nemo_ctl  ***
526      !!
527      !! ** Purpose :   control print setting
528      !!
529      !! ** Method  : - print namctl information and check some consistencies
530      !!----------------------------------------------------------------------
531      !
532      IF(lwp) THEN                  ! control print
533         WRITE(numout,*)
534         WRITE(numout,*) 'nemo_ctl: Control prints'
535         WRITE(numout,*) '~~~~~~~~'
536         WRITE(numout,*) '   Namelist namctl'
537         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
538         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
539         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
540         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
541         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
542         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
543         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
544         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
545         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
546         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
547      ENDIF
548      !
549      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
550      nictls    = nn_ictls
551      nictle    = nn_ictle
552      njctls    = nn_jctls
553      njctle    = nn_jctle
554      isplt     = nn_isplt
555      jsplt     = nn_jsplt
556
557      IF(lwp) THEN                  ! control print
558         WRITE(numout,*)
559         WRITE(numout,*) '   Namelist namcfg'
560         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
561         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
562         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
563         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
564         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
565         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
566      ENDIF
567      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
568      !
569      !                             ! Parameter control
570      !
571      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
572         IF( lk_mpp .AND. jpnij > 1 ) THEN
573            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
574         ELSE
575            IF( isplt == 1 .AND. jsplt == 1  ) THEN
576               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
577                  &           ' - the print control will be done over the whole domain' )
578            ENDIF
579            ijsplt = isplt * jsplt            ! total number of processors ijsplt
580         ENDIF
581         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
582         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
583         !
584         !                              ! indices used for the SUM control
585         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
586            lsp_area = .FALSE.
587         ELSE                                             ! print control done over a specific  area
588            lsp_area = .TRUE.
589            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
590               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
591               nictls = 1
592            ENDIF
593            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
594               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
595               nictle = jpiglo
596            ENDIF
597            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
598               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
599               njctls = 1
600            ENDIF
601            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
602               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
603               njctle = jpjglo
604            ENDIF
605         ENDIF
606      ENDIF
607      !
608      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
609         &                                                'Compile with key_nosignedzero enabled' )
610      !
611#if defined key_agrif
612      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
613#endif
614      !
615   END SUBROUTINE nemo_ctl
616
617
618   SUBROUTINE nemo_closefile
619      !!----------------------------------------------------------------------
620      !!                     ***  ROUTINE nemo_closefile  ***
621      !!
622      !! ** Purpose :   Close the files
623      !!----------------------------------------------------------------------
624      !
625      IF( lk_mpp )   CALL mppsync
626      !
627      CALL iom_close                                 ! close all input/output files managed by iom_*
628      !
629      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
630      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
631      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
632      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
633      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
634      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
635      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
636      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
637      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
638      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
639      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
640      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
641      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
642      !
643      numout = 6                                     ! redefine numout in case it is used after this point...
644      !
645   END SUBROUTINE nemo_closefile
646
647
648   SUBROUTINE nemo_alloc
649      !!----------------------------------------------------------------------
650      !!                     ***  ROUTINE nemo_alloc  ***
651      !!
652      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
653      !!
654      !! ** Method  :
655      !!----------------------------------------------------------------------
656      USE diawri    , ONLY : dia_wri_alloc
657      USE dom_oce   , ONLY : dom_oce_alloc
658      USE trc_oce   , ONLY : trc_oce_alloc
659      USE bdy_oce   , ONLY : bdy_oce_alloc
660#if defined key_diadct 
661      USE diadct    , ONLY : diadct_alloc 
662#endif 
663      !
664      INTEGER :: ierr
665      !!----------------------------------------------------------------------
666      !
667      ierr =        oce_alloc    ()    ! ocean
668      ierr = ierr + dia_wri_alloc()
669      ierr = ierr + dom_oce_alloc()    ! ocean domain
670      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
671      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
672      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
673      !
674#if defined key_diadct 
675      ierr = ierr + diadct_alloc ()    !
676#endif 
677      !
678      IF( lk_mpp    )   CALL mpp_sum( ierr )
679      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
680      !
681   END SUBROUTINE nemo_alloc
682
683
684   SUBROUTINE nemo_partition( num_pes )
685      !!----------------------------------------------------------------------
686      !!                 ***  ROUTINE nemo_partition  ***
687      !!
688      !! ** Purpose :
689      !!
690      !! ** Method  :
691      !!----------------------------------------------------------------------
692      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
693      !
694      INTEGER, PARAMETER :: nfactmax = 20
695      INTEGER :: nfact ! The no. of factors returned
696      INTEGER :: ierr  ! Error flag
697      INTEGER :: ji
698      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
699      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
700      !!----------------------------------------------------------------------
701      !
702      ierr = 0
703      !
704      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
705      !
706      IF( nfact <= 1 ) THEN
707         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
708         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
709         jpnj = 1
710         jpni = num_pes
711      ELSE
712         ! Search through factors for the pair that are closest in value
713         mindiff = 1000000
714         imin    = 1
715         DO ji = 1, nfact-1, 2
716            idiff = ABS( ifact(ji) - ifact(ji+1) )
717            IF( idiff < mindiff ) THEN
718               mindiff = idiff
719               imin = ji
720            ENDIF
721         END DO
722         jpnj = ifact(imin)
723         jpni = ifact(imin + 1)
724      ENDIF
725      !
726      jpnij = jpni*jpnj
727      !
728   END SUBROUTINE nemo_partition
729
730
731   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
732      !!----------------------------------------------------------------------
733      !!                     ***  ROUTINE factorise  ***
734      !!
735      !! ** Purpose :   return the prime factors of n.
736      !!                knfax factors are returned in array kfax which is of
737      !!                maximum dimension kmaxfax.
738      !! ** Method  :
739      !!----------------------------------------------------------------------
740      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
741      INTEGER                    , INTENT(  out) ::   kerr, knfax
742      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
743      !
744      INTEGER :: ifac, jl, inu
745      INTEGER, PARAMETER :: ntest = 14
746      INTEGER, DIMENSION(ntest) ::   ilfax
747      !!----------------------------------------------------------------------
748      !
749      ! lfax contains the set of allowed factors.
750      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
751      !
752      ! Clear the error flag and initialise output vars
753      kerr  = 0
754      kfax  = 1
755      knfax = 0
756      !
757      IF( kn /= 1 ) THEN      ! Find the factors of n
758         !
759         ! nu holds the unfactorised part of the number.
760         ! knfax holds the number of factors found.
761         ! l points to the allowed factor list.
762         ! ifac holds the current factor.
763         !
764         inu   = kn
765         knfax = 0
766         !
767         DO jl = ntest, 1, -1
768            !
769            ifac = ilfax(jl)
770            IF( ifac > inu )   CYCLE
771            !
772            ! Test whether the factor will divide.
773            !
774            IF( MOD(inu,ifac) == 0 ) THEN
775               !
776               knfax = knfax + 1            ! Add the factor to the list
777               IF( knfax > kmaxfax ) THEN
778                  kerr = 6
779                  write (*,*) 'FACTOR: insufficient space in factor array ', knfax
780                  return
781               ENDIF
782               kfax(knfax) = ifac
783               ! Store the other factor that goes with this one
784               knfax = knfax + 1
785               kfax(knfax) = inu / ifac
786               !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
787            ENDIF
788            !
789         END DO
790         !
791      ENDIF
792      !
793   END SUBROUTINE factorise
794
795#if defined key_mpp_mpi
796
797   SUBROUTINE nemo_nfdcom
798      !!----------------------------------------------------------------------
799      !!                     ***  ROUTINE  nemo_nfdcom  ***
800      !! ** Purpose :   Setup for north fold exchanges with explicit
801      !!                point-to-point messaging
802      !!
803      !! ** Method :   Initialization of the northern neighbours lists.
804      !!----------------------------------------------------------------------
805      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
806      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
807      !!----------------------------------------------------------------------
808      INTEGER  ::   sxM, dxM, sxT, dxT, jn
809      INTEGER  ::   njmppmax
810      !!----------------------------------------------------------------------
811      !
812      njmppmax = MAXVAL( njmppt )
813      !
814      !initializes the north-fold communication variables
815      isendto(:) = 0
816      nsndto     = 0
817      !
818      IF ( njmpp == njmppmax ) THEN      ! if I am a process in the north
819         !
820         !sxM is the first point (in the global domain) needed to compute the north-fold for the current process
821         sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
822         !dxM is the last point (in the global domain) needed to compute the north-fold for the current process
823         dxM = jpiglo - nimppt(narea) + 2
824         !
825         ! loop over the other north-fold processes to find the processes
826         ! managing the points belonging to the sxT-dxT range
827         !
828         DO jn = 1, jpni
829            !
830            sxT = nfiimpp(jn, jpnj)                            ! sxT = 1st  point (in the global domain) of the jn process
831            dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1    ! dxT = last point (in the global domain) of the jn process
832            !
833            IF    ( sxT < sxM  .AND.  sxM < dxT ) THEN
834               nsndto          = nsndto + 1
835               isendto(nsndto) = jn
836            ELSEIF( sxM <= sxT  .AND.  dxM >= dxT ) THEN
837               nsndto          = nsndto + 1
838               isendto(nsndto) = jn
839            ELSEIF( dxM <  dxT  .AND.  sxT <  dxM ) THEN
840               nsndto          = nsndto + 1
841               isendto(nsndto) = jn
842            ENDIF
843            !
844         END DO
845         nfsloop = 1
846         nfeloop = nlci
847         DO jn = 2,jpni-1
848            IF( nfipproc(jn,jpnj) == (narea - 1) ) THEN
849               IF( nfipproc(jn-1,jpnj) == -1 )   nfsloop = nldi
850               IF( nfipproc(jn+1,jpnj) == -1 )   nfeloop = nlei
851            ENDIF
852         END DO
853         !
854      ENDIF
855      l_north_nogather = .TRUE.
856      !
857   END SUBROUTINE nemo_nfdcom
858
859#else
860   SUBROUTINE nemo_nfdcom      ! Dummy routine
861      WRITE(*,*) 'nemo_nfdcom: You should not have seen this print! error?'
862   END SUBROUTINE nemo_nfdcom
863#endif
864
865   !!======================================================================
866END MODULE nemogcm
867
Note: See TracBrowser for help on using the repository browser.